configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT()
   4 AC_CONFIG_SRCDIR([byteorder.h])
   5 AC_CONFIG_HEADER(config.h)
   6 AC_PREREQ(2.52)
   7
   8 LDFLAGS=${LDFLAGS-""}
   9
  10 AC_CANONICAL_TARGET([])
  11
  12 dnl Checks for programs.
  13 AC_PROG_CC
  14 AC_PROG_CPP
  15 AC_PROG_INSTALL
  16 AC_SUBST(SHELL)
  17
  18 RSYNC_VERSION=2.4.7pre3
  19 AC_SUBST(RSYNC_VERSION)
  20 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
  21
  22 # compile with optimisation and without debugging by default, unless
  23 # --debug is given.  We must decide this before testing the compiler.
  24
  25 AC_MSG_CHECKING([whether to include debugging symbols])
  26 AC_ARG_ENABLE(debug,
  27         AC_HELP_STRING([--enable-debug],
  28                 [including debugging symbols and features (default yes)]),
  29                 [], [])
  30
  31 if test x"$enable_debug" = x"no"
  32 then
  33     AC_MSG_RESULT(no)
  34     CFLAGS=${CFLAGS-"-O"}
  35 else
  36     AC_MSG_RESULT([yes])
  37     # leave CFLAGS alone; AC_PROG_CC will try to include -g if it can
  38     AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  39     dnl CFLAGS=${CFLAGS-"-g"}
  40 fi
  41
  42 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  43
  44 AC_ARG_WITH(included-popt,
  45         [  --with-included-popt    use bundled popt library, not from system])
  46
  47 AC_ARG_WITH(rsync-path,
  48         [  --with-rsync-path=PATH  set default --rsync-path to PATH (default: \"rsync\")],
  49         [ RSYNC_PATH="$with_rsync_path" ],
  50         [ RSYNC_PATH="rsync" ])
  51 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [ ])
  52
  53 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
  54 AC_DEFINE_UNQUOTED(HAVE_REMSH, $HAVE_REMSH, [ ])
  55
  56
  57 # arrgh. libc in the current debian stable screws up the largefile
  58 # stuff, getting byte range locking wrong
  59 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
  60 AC_TRY_RUN([
  61 #define _FILE_OFFSET_BITS 64
  62 #include <stdio.h>
  63 #include <fcntl.h>
  64 #include <sys/types.h>
  65 #include <sys/wait.h>
  66
  67 int main(void)
  68 {
  69         struct flock lock;
  70         int status;
  71         int fd = open("conftest.dat", O_CREAT|O_RDWR, 0600);
  72         lock.l_type = F_WRLCK;
  73         lock.l_whence = SEEK_SET;
  74         lock.l_start = 0;
  75         lock.l_len = 1;
  76         lock.l_pid = 0;
  77
  78         fcntl(fd,F_SETLK,&lock);
  79         if (fork() == 0) {
  80                 lock.l_start = 1;
  81                 exit(fcntl(fd,F_SETLK,&lock) == 0);
  82         }
  83         wait(&status);
  84         unlink("conftest.dat");
  85         exit(WEXITSTATUS(status));
  86 }
  87 ],
  88 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
  89 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
  90    AC_SYS_LARGEFILE
  91 fi
  92
  93
  94
  95 AC_DEFINE(ss_family, __ss_family, [KAME hack])
  96 AC_DEFINE(ss_len, __ss_len, [KAME hack])
  97
  98 CFLAGS="$CFLAGS"
  99 AC_ARG_ENABLE(ipv6,
 100         AC_HELP_STRING([--enable-ipv6], [try to support IPv6]))
 101 AC_MSG_CHECKING([whether IPv6 is requested])
 102 if test "$xenable_ipv6" = xyes
 103 then
 104         AC_MSG_RESULT(yes)
 105         ipv6=yes
 106 else
 107         AC_MSG_RESULT(no)
 108         ipv6=no
 109 fi
 110
 111 ipv6type=unknown
 112 ipv6lib=none
 113 ipv6trylibc=no
 114
 115 if test "$ipv6" = "yes"; then
 116         AC_MSG_CHECKING([ipv6 stack type])
 117         for i in inria kame linux-glibc linux-inet6 toshiba v6d zeta; do
 118                 case $i in
 119                 inria)
 120                         # http://www.kame.net/
 121                         AC_EGREP_CPP(yes, [
 122 #include <netinet/in.h>
 123 #ifdef IPV6_INRIA_VERSION
 124 yes
 125 #endif],
 126                                 [ipv6type=$i;
 127                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 128                                 ])
 129                         ;;
 130                 kame)
 131                         # http://www.kame.net/
 132                         AC_EGREP_CPP(yes, [
 133 #include <netinet/in.h>
 134 #ifdef __KAME__
 135 yes
 136 #endif],
 137                                 [ipv6type=$i;
 138                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 139                         ;;
 140                 linux-glibc)
 141                         # http://www.v6.linux.or.jp/
 142                         AC_EGREP_CPP(yes, [
 143 #include <features.h>
 144 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 145 yes
 146 #endif],
 147                                 [ipv6type=$i;
 148 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 149                         ;;
 150                 linux-inet6)
 151                         # http://www.v6.linux.or.jp/
 152                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 153                                 ipv6type=$i
 154                                 ipv6lib=inet6
 155                                 ipv6libdir=/usr/inet6/lib
 156                                 ipv6trylibc=yes;
 157                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 158                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 159                         fi
 160                         ;;
 161                 toshiba)
 162                         AC_EGREP_CPP(yes, [
 163 #include <sys/param.h>
 164 #ifdef _TOSHIBA_INET6
 165 yes
 166 #endif],
 167                                 [ipv6type=$i;
 168                                 ipv6lib=inet6;
 169                                 ipv6libdir=/usr/local/v6/lib;
 170                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 171                         ;;
 172                 v6d)
 173                         AC_EGREP_CPP(yes, [
 174 #include </usr/local/v6/include/sys/v6config.h>
 175 #ifdef __V6D__
 176 yes
 177 #endif],
 178                                 [ipv6type=$i;
 179                                 ipv6lib=v6;
 180                                 ipv6libdir=/usr/local/v6/lib;
 181                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 182                         ;;
 183                 zeta)
 184                         AC_EGREP_CPP(yes, [
 185 #include <sys/param.h>
 186 #ifdef _ZETA_MINAMI_INET6
 187 yes
 188 #endif],
 189                                 [ipv6type=$i;
 190                                 ipv6lib=inet6;
 191                                 ipv6libdir=/usr/local/v6/lib;
 192                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 193                         ;;
 194                 esac
 195                 if test "$ipv6type" != "unknown"; then
 196                         break
 197                 fi
 198         done
 199         AC_MSG_RESULT($ipv6type)
 200 fi
 201
 202 if test "$ipv6" = "yes" -a -f /usr/local/v6/lib/libinet6.a; then
 203         ac_inet6_LDFLAGS="inet6"
 204         ipv6libdir=/usr/local/v6/lib
 205         LDFLAGS="$LDFLAGS -L/usr/local/v6/lib"
 206         AC_CHECK_LIB(inet6, getaddrinfo, , ipv6lib="$ac_inet6_LDFLAGS")
 207 fi
 208
 209 if test "$ipv6" = "yes" -a -f /usr/lib/libinet6.a; then
 210         ac_inet6_LDFLAGS="inet6"
 211         AC_CHECK_LIB(inet6, getaddrinfo, , ipv6lib="$ac_inet6_LDFLAGS")
 212 fi
 213
 214 if test "$ipv6" = "yes" -a "$ipv6lib" != "none"; then
 215         if test -d $ipv6libdir -a -f $ipv6libdir/lib$ipv6lib.a; then
 216                 LIBS="-L$ipv6libdir -l$ipv6lib $LIBS"
 217                 AC_MSG_NOTICE([You have $ipv6lib library, using it])
 218         else
 219                 if test "$ipv6trylibc" = "yes"; then
 220                         AC_MSG_WARN([You do not have $ipv6lib library, using libc])
 221                 else
 222                         AC_MSG_ERROR([No $ipv6lib library found.  cannot continue.  You need to fetch lib$ipv6lib.a from appropriate ipv6 kit and compile beforehand.])
 223                 fi
 224         fi
 225 fi
 226
 227 AC_REPLACE_FUNCS(getaddrinfo getnameinfo)
 228
 229 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 230                 [ AC_DEFINE(HAVE_SOCKADDR_LEN) ],
 231                 [],
 232                 [
 233 #include <sys/types.h>
 234 #include <sys/socket.h>
 235 ])
 236
 237 AC_C_BIGENDIAN
 238 AC_HEADER_DIRENT
 239 AC_HEADER_TIME
 240 AC_HEADER_SYS_WAIT
 241 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h unistd.h utime.h grp.h)
 242 AC_CHECK_HEADERS(compat.h sys/param.h ctype.h sys/wait.h sys/ioctl.h)
 243 AC_CHECK_HEADERS(sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h)
 244 AC_CHECK_HEADERS(glob.h alloca.h mcheck.h sys/sysctl.h arpa/inet.h arpa/nameser.h)
 245 AC_CHECK_HEADERS(netdb.h)
 246
 247 AC_CHECK_SIZEOF(int)
 248 AC_CHECK_SIZEOF(long)
 249 AC_CHECK_SIZEOF(short)
 250
 251 AC_C_INLINE
 252
 253 AC_TYPE_SIGNAL
 254 AC_TYPE_UID_T
 255 AC_TYPE_MODE_T
 256 AC_TYPE_OFF_T
 257 AC_TYPE_SIZE_T
 258 AC_TYPE_PID_T
 259 AC_TYPE_GETGROUPS
 260 AC_CHECK_MEMBERS([struct stat.st_rdev])
 261
 262 AC_CHECK_TYPE([ino_t], [unsigned])
 263 TYPE_SOCKLEN_T
 264
 265 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 266     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
 267         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
 268 if test x"$rsync_cv_errno" = x"yes"; then
 269    AC_DEFINE(HAVE_ERRNO_DECL, 1, [ ])
 270 fi
 271
 272 # The following test taken from the cvs sources
 273 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 274 # These need checks to be before checks for any other functions that
 275 #    might be in the same libraries.
 276 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 277 # libsocket.so which has a bad implementation of gethostbyname (it
 278 # only looks in /etc/hosts), so we only look for -lsocket if we need
 279 # it.
 280 AC_CHECK_FUNCS(connect)
 281 if test x"$ac_cv_func_connect" = x"no"; then
 282     case "$LIBS" in
 283     *-lnsl*) ;;
 284     *) AC_CHECK_LIB(nsl_s, printf) ;;
 285     esac
 286     case "$LIBS" in
 287     *-lnsl*) ;;
 288     *) AC_CHECK_LIB(nsl, printf) ;;
 289     esac
 290     case "$LIBS" in
 291     *-lsocket*) ;;
 292     *) AC_CHECK_LIB(socket, connect) ;;
 293     esac
 294     case "$LIBS" in
 295     *-linet*) ;;
 296     *) AC_CHECK_LIB(inet, connect) ;;
 297     esac
 298     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 299     dnl has been cached.
 300     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 301        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 302         # ac_cv_func_connect=yes
 303         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 304         AC_DEFINE(HAVE_CONNECT, 1, [ ])
 305     fi
 306 fi
 307
 308 #
 309 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 310 #
 311 AC_CHECK_FUNCS(strcasecmp)
 312 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 313     AC_CHECK_LIB(resolv, strcasecmp)
 314 fi
 315
 316 AC_FUNC_MEMCMP
 317 AC_FUNC_UTIME_NULL
 318 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup strerror chown chmod mknod)
 319 AC_CHECK_FUNCS(fchmod fstat strchr readlink link utime utimes strftime)
 320 AC_CHECK_FUNCS(memmove lchown vsnprintf snprintf asprintf setsid glob strpbrk)
 321 AC_CHECK_FUNCS(strlcat strlcpy mtrace)
 322
 323 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 324 AC_TRY_RUN([#include <sys/types.h>
 325             #include <sys/socket.h>
 326             main() {
 327                 int fd[2];
 328                 exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 329             }],
 330 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 331 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 332     AC_DEFINE(HAVE_SOCKETPAIR, 1, [ ])
 333 fi
 334
 335 AC_CACHE_CHECK([for working fnmatch],rsync_cv_HAVE_FNMATCH,[
 336 AC_TRY_RUN([#include <fnmatch.h>
 337 main() { exit((fnmatch("*.o", "x.o", FNM_PATHNAME) == 0 &&
 338                fnmatch("a/b/*", "a/b/c/d", FNM_PATHNAME) != 0) ? 0: 1); }],
 339 rsync_cv_HAVE_FNMATCH=yes,rsync_cv_HAVE_FNMATCH=no,rsync_cv_HAVE_FNMATCH=cross)])
 340 if test x"$rsync_cv_HAVE_FNMATCH" = x"yes"; then
 341     AC_DEFINE(HAVE_FNMATCH, 1, [ ])
 342 fi
 343
 344 if test x"$with_included_popt" != x"yes"
 345 then
 346     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 347 fi
 348
 349 AC_MSG_CHECKING([whether to use included libpopt])
 350 if test x"$with_included_popt" = x"yes"
 351 then
 352     AC_MSG_RESULT($srcdir/popt)
 353     BUILD_POPT='$(popt_OBJS)'
 354     CFLAGS="$CFLAGS -I$srcdir/popt"
 355 else
 356     AC_MSG_RESULT(no)
 357 fi
 358
 359 AC_CACHE_CHECK([for long long],rsync_cv_HAVE_LONGLONG,[
 360 AC_TRY_RUN([#include <stdio.h>
 361 main() { long long x = 1000000; x *= x; exit(((x/1000000) == 1000000)? 0: 1); }],
 362 rsync_cv_HAVE_LONGLONG=yes,rsync_cv_HAVE_LONGLONG=no,rsync_cv_HAVE_LONGLONG=cross)])
 363 if test x"$rsync_cv_HAVE_LONGLONG" = x"yes"; then
 364     AC_DEFINE(HAVE_LONGLONG, 1, [ ])
 365 fi
 366
 367 AC_CACHE_CHECK([for off64_t],rsync_cv_HAVE_OFF64_T,[
 368 AC_TRY_RUN([#include <stdio.h>
 369 #include <sys/stat.h>
 370 main() { struct stat64 st; off64_t s; if (sizeof(off_t) == sizeof(off64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }],
 371 rsync_cv_HAVE_OFF64_T=yes,rsync_cv_HAVE_OFF64_T=no,rsync_cv_HAVE_OFF64_T=cross)])
 372 if test x"$rsync_cv_HAVE_OFF64_T" = x"yes"; then
 373     AC_DEFINE(HAVE_OFF64_T, 1, [ ])
 374 fi
 375
 376 AC_CACHE_CHECK([for short ino_t],rsync_cv_HAVE_SHORT_INO_T,[
 377 AC_TRY_RUN([#include <stdio.h>
 378 #include <sys/types.h>
 379 #include <sys/stat.h>
 380 main() { if (sizeof(ino_t) < sizeof(unsigned int)) return 0; return 1; }],
 381 rsync_cv_HAVE_SHORT_INO_T=yes,rsync_cv_HAVE_SHORT_INO_T=no,rsync_cv_HAVE_SHORT_INO_T=cross)])
 382 if test x"$rsync_cv_HAVE_SHORT_INO_T" = x"yes"; then
 383     AC_DEFINE(HAVE_SHORT_INO_T, 1, [ ])
 384 fi
 385
 386 AC_CACHE_CHECK([for unsigned char],rsync_cv_HAVE_UNSIGNED_CHAR,[
 387 AC_TRY_RUN([#include <stdio.h>
 388 main() { char c; c=250; exit((c > 0)?0:1); }],
 389 rsync_cv_HAVE_UNSIGNED_CHAR=yes,rsync_cv_HAVE_UNSIGNED_CHAR=no,rsync_cv_HAVE_UNSIGNED_CHAR=cross)])
 390 if test x"$rsync_cv_HAVE_UNSIGNED_CHAR" = x"yes"; then
 391     AC_DEFINE(HAVE_UNSIGNED_CHAR, 1, [ ])
 392 fi
 393
 394 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 395 AC_TRY_RUN([#include <sys/types.h>
 396 #include <dirent.h>
 397 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 398 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 399 di->d_name[0] == 0) exit(0); exit(1);} ],
 400 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 401 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 402     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [ ])
 403 fi
 404
 405 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_UTIMBUF,[
 406 AC_TRY_COMPILE([#include <sys/types.h>
 407 #include <utime.h>],
 408 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 409 rsync_cv_HAVE_UTIMBUF=yes,rsync_cv_HAVE_UTIMBUF=no,rsync_cv_HAVE_UTIMBUF=cross)])
 410 if test x"$rsync_cv_HAVE_UTIMBUF" = x"yes"; then
 411     AC_DEFINE(HAVE_UTIMBUF, 1, [ ])
 412 fi
 413
 414 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 415 AC_TRY_RUN([
 416 #include <sys/time.h>
 417 #include <unistd.h>
 418 main() { struct timeval tv; exit(gettimeofday(&tv, NULL));}],
 419            rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no,rsync_cv_HAVE_GETTIMEOFDAY_TZ=cross)])
 420 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" = x"yes"; then
 421     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [ ])
 422 fi
 423
 424 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 425 AC_TRY_RUN([
 426 #include <sys/types.h>
 427 #include <stdarg.h>
 428 void foo(const char *format, ...) {
 429        va_list ap;
 430        int len;
 431        char buf[5];
 432
 433        va_start(ap, format);
 434        len = vsnprintf(0, 0, format, ap);
 435        va_end(ap);
 436        if (len != 5) exit(1);
 437
 438        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 439
 440        exit(0);
 441 }
 442 main() { foo("hello"); }
 443 ],
 444 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
 445 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 446     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [ ])
 447 fi
 448
 449
 450 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 451 AC_TRY_RUN([#include <stdlib.h>
 452 #include <sys/types.h>
 453 #include <sys/stat.h>
 454 #include <unistd.h>
 455 main() {
 456   struct stat st;
 457   char tpl[20]="/tmp/test.XXXXXX";
 458   int fd = mkstemp(tpl);
 459   if (fd == -1) exit(1);
 460   unlink(tpl);
 461   if (fstat(fd, &st) != 0) exit(1);
 462   if ((st.st_mode & 0777) != 0600) exit(1);
 463   exit(0);
 464 }],
 465 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
 466 rsync_cv_HAVE_SECURE_MKSTEMP=no,
 467 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
 468 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 469     AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [ ])
 470 fi
 471
 472
 473 AC_CACHE_CHECK([for broken inet_ntoa],rsync_cv_REPLACE_INET_NTOA,[
 474 AC_TRY_RUN([
 475 #include <stdio.h>
 476 #include <sys/types.h>
 477 #include <netinet/in.h>
 478 #include <arpa/inet.h>
 479 main() { struct in_addr ip; ip.s_addr = 0x12345678;
 480 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
 481     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(1); }
 482 exit(0);}],
 483            rsync_cv_REPLACE_INET_NTOA=no,rsync_cv_REPLACE_INET_NTOA=yes,rsync_cv_REPLACE_INET_NTOA=cross)])
 484 if test x"$rsync_cv_REPLACE_INET_NTOA" = x"yes"; then
 485     AC_DEFINE(REPLACE_INET_NTOA, 1, [ ])
 486 fi
 487
 488
 489 AC_CACHE_CHECK([for broken inet_aton],rsync_cv_REPLACE_INET_ATON,[
 490 AC_TRY_RUN([
 491 #include <stdio.h>
 492 #include <sys/types.h>
 493 #include <netinet/in.h>
 494 #include <arpa/inet.h>
 495 main() { struct in_addr ip;
 496 if (inet_aton("example", &ip) == 0) exit(0); exit(1);}],
 497            rsync_cv_REPLACE_INET_ATON=no,rsync_cv_REPLACE_INET_ATON=yes,rsync_cv_REPLACE_INET_ATON=cross)])
 498 if test x"$rsync_cv_REPLACE_INET_ATON" = x"yes"; then
 499     AC_DEFINE(REPLACE_INET_ATON, 1, [ ])
 500 fi
 501
 502 #
 503 # The following test was mostly taken from the tcl/tk plus patches
 504 #
 505 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 506 rm -rf conftest*
 507 cat > conftest.$ac_ext <<EOF
 508 int main() { return 0; }
 509 EOF
 510 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 511 if test -f conftest..o; then
 512     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 513 else
 514     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 515 fi
 516 rm -rf conftest*
 517 ])
 518 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 519     OBJ_SAVE="#"
 520     OBJ_RESTORE="#"
 521     CC_SHOBJ_FLAG='-o $@'
 522 else
 523     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 524     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 525     CC_SHOBJ_FLAG=""
 526 fi
 527
 528 AC_SUBST(OBJ_SAVE)
 529 AC_SUBST(OBJ_RESTORE)
 530 AC_SUBST(CC_SHOBJ_FLAG)
 531 AC_SUBST(BUILD_POPT)
 532
 533 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
 534 AC_OUTPUT