configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT()
   4 AC_CONFIG_SRCDIR([byteorder.h])
   5 AC_CONFIG_HEADER(config.h)
   6 AC_PREREQ(2.59)
   7
   8 RSYNC_VERSION=3.1.0dev
   9 AC_SUBST(RSYNC_VERSION)
  10 AC_MSG_NOTICE([Configuring rsync $RSYNC_VERSION])
  11
  12 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$RSYNC_VERSION"], [rsync release version])
  13
  14 LDFLAGS=${LDFLAGS-""}
  15
  16 AC_CANONICAL_HOST
  17
  18 # We must decide this before testing the compiler.
  19
  20 # Please allow this to default to yes, so that your users have more
  21 # chance of getting a useful stack trace if problems occur.
  22
  23 AC_MSG_CHECKING([whether to include debugging symbols])
  24 AC_ARG_ENABLE(debug,
  25         AC_HELP_STRING([--disable-debug],
  26                 [disable debugging symbols and features]))
  27
  28 if test x"$enable_debug" = x"no"; then
  29     AC_MSG_RESULT(no)
  30     ac_cv_prog_cc_g=no
  31 else
  32     AC_MSG_RESULT([yes])
  33     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  34     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  35 fi
  36
  37 dnl Checks for programs.
  38 AC_PROG_CC
  39 AC_PROG_CPP
  40 AC_PROG_EGREP
  41 AC_PROG_INSTALL
  42 AC_PROG_CC_STDC
  43 AC_SUBST(SHELL)
  44
  45 AC_DEFINE([_GNU_SOURCE], 1,
  46           [Define _GNU_SOURCE so that we get all necessary prototypes])
  47
  48 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  49         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  50 fi
  51
  52 AC_ARG_ENABLE(profile,
  53         AC_HELP_STRING([--enable-profile],
  54                 [turn on CPU profiling]))
  55 if test x"$enable_profile" = x"yes"; then
  56         CFLAGS="$CFLAGS -pg"
  57 fi
  58
  59
  60 # Specifically, this turns on panic_action handling.
  61 AC_ARG_ENABLE(maintainer-mode,
  62         AC_HELP_STRING([--enable-maintainer-mode],
  63                 [turn on extra debug features]))
  64 if test x"$enable_maintainer_mode" = x"yes"; then
  65         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  66 fi
  67
  68
  69 # This is needed for our included version of popt.  Kind of silly, but
  70 # I don't want our version too far out of sync.
  71 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  72
  73 # If GCC, turn on warnings.
  74 if test x"$GCC" = x"yes"; then
  75         CFLAGS="$CFLAGS -Wall -W"
  76 fi
  77
  78 AC_ARG_WITH(included-popt,
  79         AC_HELP_STRING([--with-included-popt], [use bundled popt library, not from system]))
  80
  81 AC_ARG_WITH(included-zlib,
  82         AC_HELP_STRING([--with-included-zlib], [use bundled zlib library, not from system]))
  83
  84 AC_ARG_WITH(protected-args,
  85         AC_HELP_STRING([--with-protected-args], [make --protected-args option the default]))
  86 if test x"$with_protected_args" = x"yes"; then
  87         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
  88 fi
  89
  90 AC_ARG_WITH(rsync-path,
  91         AC_HELP_STRING([--with-rsync-path=PATH], [set default --rsync-path to PATH (default: rsync)]),
  92         [ RSYNC_PATH="$with_rsync_path" ],
  93         [ RSYNC_PATH="rsync" ])
  94
  95 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
  96
  97 AC_ARG_WITH(rsyncd-conf,
  98         AC_HELP_STRING([--with-rsyncd-conf=PATH], [set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
  99         [ if test ! -z "$with_rsyncd_conf" ; then
 100                 case $with_rsyncd_conf in
 101                         yes|no)
 102                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 103                                 ;;
 104                         /*)
 105                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 106                                 ;;
 107                         *)
 108                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 109                                 ;;
 110                 esac
 111         else
 112                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 113         fi ],
 114         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 115
 116 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 117
 118 AC_ARG_WITH(rsh,
 119         AC_HELP_STRING([--with-rsh=CMD], [set remote shell command to CMD (default: ssh)]))
 120
 121 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 122 if test x$HAVE_REMSH = x1; then
 123         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 124 fi
 125
 126 if test x"$with_rsh" != x; then
 127         RSYNC_RSH="$with_rsh"
 128 else
 129         RSYNC_RSH="ssh"
 130 fi
 131 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 132
 133 AC_CHECK_PROG(HAVE_YODL2MAN, yodl2man, 1, 0)
 134 if test x$HAVE_YODL2MAN = x1; then
 135     MAKE_MAN=man
 136 else
 137     MAKE_MAN=man-copy
 138 fi
 139
 140 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 141 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 142 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 143
 144 AC_ARG_WITH(nobody-group,
 145     AC_HELP_STRING([--with-nobody-group=GROUP],
 146                    [set the default unprivileged group (default nobody or nogroup)]),
 147     [ NOBODY_GROUP="$with_nobody_group" ])
 148
 149 if test x"$with_nobody_group" = x; then
 150     AC_MSG_CHECKING([the group for user "nobody"])
 151     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 152         NOBODY_GROUP=nobody
 153     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 154         NOBODY_GROUP=nogroup
 155     else
 156         NOBODY_GROUP=nobody # test for others?
 157     fi
 158     AC_MSG_RESULT($NOBODY_GROUP)
 159 fi
 160
 161 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 162 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 163
 164 # arrgh. libc in some old debian version screwed up the largefile
 165 # stuff, getting byte range locking wrong
 166 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 167 AC_TRY_RUN([
 168 #define _FILE_OFFSET_BITS 64
 169 #include <stdio.h>
 170 #include <fcntl.h>
 171 #include <sys/types.h>
 172 #include <sys/wait.h>
 173
 174 int main(void)
 175 {
 176         struct flock lock;
 177         int status;
 178         char tpl[32] = "/tmp/locktest.XXXXXX";
 179         int fd = mkstemp(tpl);
 180         if (fd < 0) {
 181                 strcpy(tpl, "conftest.dat");
 182                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 183         }
 184
 185         lock.l_type = F_WRLCK;
 186         lock.l_whence = SEEK_SET;
 187         lock.l_start = 0;
 188         lock.l_len = 1;
 189         lock.l_pid = 0;
 190         fcntl(fd,F_SETLK,&lock);
 191         if (fork() == 0) {
 192                 lock.l_start = 1;
 193                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 194         }
 195         wait(&status);
 196         unlink(tpl);
 197         exit(WEXITSTATUS(status));
 198 }
 199 ],
 200 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
 201 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 202    AC_SYS_LARGEFILE
 203 fi
 204
 205 ipv6type=unknown
 206 ipv6lib=none
 207 ipv6trylibc=yes
 208
 209 AC_ARG_ENABLE(ipv6,
 210         AC_HELP_STRING([--disable-ipv6],
 211                 [do not even try to use IPv6]))
 212 if test x"$enable_ipv6" != x"no"; then
 213         AC_MSG_CHECKING([ipv6 stack type])
 214         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
 215                 case $i in
 216                 inria)
 217                         # http://www.kame.net/
 218                         AC_EGREP_CPP(yes, [
 219 #include <netinet/in.h>
 220 #ifdef IPV6_INRIA_VERSION
 221 yes
 222 #endif],
 223                                 [ipv6type=$i;
 224                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 225                                 ])
 226                         ;;
 227                 kame)
 228                         # http://www.kame.net/
 229                         AC_EGREP_CPP(yes, [
 230 #include <netinet/in.h>
 231 #ifdef __KAME__
 232 yes
 233 #endif],
 234                                 [ipv6type=$i;
 235                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 236                         ;;
 237                 linux-glibc)
 238                         # http://www.v6.linux.or.jp/
 239                         AC_EGREP_CPP(yes, [
 240 #include <features.h>
 241 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 242 yes
 243 #endif],
 244                                 [ipv6type=$i;
 245 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 246                         ;;
 247                 linux-inet6)
 248                         # http://www.v6.linux.or.jp/
 249                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 250                                 ipv6type=$i
 251                                 ipv6lib=inet6
 252                                 ipv6libdir=/usr/inet6/lib
 253                                 ipv6trylibc=yes;
 254                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 255                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 256                         fi
 257                         ;;
 258                 solaris)
 259                         # http://www.sun.com
 260                         AC_EGREP_CPP(yes, [
 261 #include <netinet/ip6.h>
 262 #ifdef __sun
 263 yes
 264 #endif],
 265                                 [ipv6type=$i;
 266                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 267                         ;;
 268                 toshiba)
 269                         AC_EGREP_CPP(yes, [
 270 #include <sys/param.h>
 271 #ifdef _TOSHIBA_INET6
 272 yes
 273 #endif],
 274                                 [ipv6type=$i;
 275                                 ipv6lib=inet6;
 276                                 ipv6libdir=/usr/local/v6/lib;
 277                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 278                         ;;
 279                 v6d)
 280                         AC_EGREP_CPP(yes, [
 281 #include </usr/local/v6/include/sys/v6config.h>
 282 #ifdef __V6D__
 283 yes
 284 #endif],
 285                                 [ipv6type=$i;
 286                                 ipv6lib=v6;
 287                                 ipv6libdir=/usr/local/v6/lib;
 288                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 289                         ;;
 290                 zeta)
 291                         AC_EGREP_CPP(yes, [
 292 #include <sys/param.h>
 293 #ifdef _ZETA_MINAMI_INET6
 294 yes
 295 #endif],
 296                                 [ipv6type=$i;
 297                                 ipv6lib=inet6;
 298                                 ipv6libdir=/usr/local/v6/lib;
 299                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 300                         ;;
 301                 cygwin)
 302                         AC_EGREP_CPP(yes, [
 303 #include <netinet/in.h>
 304 #ifdef _CYGWIN_IN6_H
 305 yes
 306 #endif],
 307                                 [ipv6type=$i;
 308                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 309                         ;;
 310                 esac
 311                 if test "$ipv6type" != "unknown"; then
 312                         break
 313                 fi
 314         done
 315         AC_MSG_RESULT($ipv6type)
 316
 317         AC_SEARCH_LIBS(getaddrinfo, inet6)
 318 fi
 319
 320 dnl Do you want to disable use of locale functions
 321 AC_ARG_ENABLE([locale],
 322         AC_HELP_STRING([--disable-locale],
 323                 [disable locale features]))
 324 AH_TEMPLATE([CONFIG_LOCALE],
 325 [Undefine if you do not want locale features.  By default this is defined.])
 326 if test x"$enable_locale" != x"no"; then
 327         AC_DEFINE(CONFIG_LOCALE)
 328 fi
 329
 330 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 331 case $host_os in
 332         *cygwin* ) AC_MSG_RESULT(yes)
 333                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 334                             [Define to 1 if sockets need to be shutdown])
 335                    ;;
 336                * ) AC_MSG_RESULT(no);;
 337 esac
 338
 339 AC_C_BIGENDIAN
 340 AC_HEADER_DIRENT
 341 AC_HEADER_TIME
 342 AC_HEADER_SYS_WAIT
 343 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 344     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 345     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 346     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 347     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 348     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 349     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h \
 350     zlib.h)
 351 AC_HEADER_MAJOR
 352
 353 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 354 AC_TRY_RUN([
 355 #include <sys/types.h>
 356 #ifdef MAJOR_IN_MKDEV
 357 #include <sys/mkdev.h>
 358 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 359 #  define makedev mkdev
 360 # endif
 361 #elif defined MAJOR_IN_SYSMACROS
 362 #include <sys/sysmacros.h>
 363 #endif
 364
 365 int main(void)
 366 {
 367         dev_t dev = makedev(0, 5, 7);
 368         if (major(dev) != 5 || minor(dev) != 7)
 369                 exit(1);
 370         return 0;
 371 }
 372 ],
 373 rsync_cv_MAKEDEV_TAKES_3_ARGS=yes,rsync_cv_MAKEDEV_TAKES_3_ARGS=no,rsync_cv_MAKEDEV_TAKES_3_ARGS=no)])
 374 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 375    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 376 fi
 377
 378 AC_CHECK_SIZEOF(int)
 379 AC_CHECK_SIZEOF(long)
 380 AC_CHECK_SIZEOF(long long)
 381 AC_CHECK_SIZEOF(short)
 382 AC_CHECK_SIZEOF(int16_t)
 383 AC_CHECK_SIZEOF(uint16_t)
 384 AC_CHECK_SIZEOF(int32_t)
 385 AC_CHECK_SIZEOF(uint32_t)
 386 AC_CHECK_SIZEOF(int64_t)
 387 AC_CHECK_SIZEOF(off_t)
 388 AC_CHECK_SIZEOF(off64_t)
 389 AC_CHECK_SIZEOF(time_t)
 390
 391 AC_C_INLINE
 392 AC_C_LONG_DOUBLE
 393
 394 AC_TYPE_SIGNAL
 395 AC_TYPE_UID_T
 396 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 397 AC_TYPE_GETGROUPS
 398 AC_CHECK_MEMBERS([struct stat.st_rdev,
 399                   struct stat.st_mtimensec,
 400                   struct stat.st_mtim.tv_nsec],,,[
 401 #ifdef HAVE_SYS_TYPES_H
 402 #include <sys/types.h>
 403 #endif
 404 #ifdef HAVE_SYS_STAT_H
 405 #include <sys/stat.h>
 406 #endif
 407 #ifdef HAVE_UNISTD_H
 408 #include <unistd.h>
 409 #endif])
 410
 411 TYPE_SOCKLEN_T
 412
 413 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 414     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
 415         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
 416 if test x"$rsync_cv_errno" = x"yes"; then
 417    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 418 fi
 419
 420 # The following test taken from the cvs sources
 421 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 422 # These need checks to be before checks for any other functions that
 423 #    might be in the same libraries.
 424 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 425 # libsocket.so which has a bad implementation of gethostbyname (it
 426 # only looks in /etc/hosts), so we only look for -lsocket if we need
 427 # it.
 428 AC_CHECK_FUNCS(connect)
 429 if test x"$ac_cv_func_connect" = x"no"; then
 430     case "$LIBS" in
 431     *-lnsl*) ;;
 432     *) AC_CHECK_LIB(nsl_s, printf) ;;
 433     esac
 434     case "$LIBS" in
 435     *-lnsl*) ;;
 436     *) AC_CHECK_LIB(nsl, printf) ;;
 437     esac
 438     case "$LIBS" in
 439     *-lsocket*) ;;
 440     *) AC_CHECK_LIB(socket, connect) ;;
 441     esac
 442     case "$LIBS" in
 443     *-linet*) ;;
 444     *) AC_CHECK_LIB(inet, connect) ;;
 445     esac
 446     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 447     dnl has been cached.
 448     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 449        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 450         # ac_cv_func_connect=yes
 451         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 452         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 453     fi
 454 fi
 455
 456 AC_SEARCH_LIBS(inet_ntop, resolv)
 457
 458 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 459 # accept either iconv_open or libiconv_open, since some include files map
 460 # the former to the latter.
 461 AC_SEARCH_LIBS(iconv_open, iconv)
 462 AC_SEARCH_LIBS(libiconv_open, iconv)
 463
 464 AC_MSG_CHECKING([for iconv declaration])
 465 AC_CACHE_VAL(am_cv_proto_iconv, [
 466     AC_TRY_COMPILE([
 467 #include <stdlib.h>
 468 #include <iconv.h>
 469 extern
 470 #ifdef __cplusplus
 471 "C"
 472 #endif
 473 #if defined(__STDC__) || defined(__cplusplus)
 474 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 475 #else
 476 size_t iconv();
 477 #endif
 478 ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const")
 479       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 480     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 481 AC_MSG_RESULT([$]{ac_t:-
 482          }[$]am_cv_proto_iconv)
 483 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 484                    [Define as const if the declaration of iconv() needs const.])
 485
 486 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 487
 488 AC_CHECK_FUNCS(inet_ntop, , [AC_LIBOBJ(lib/inet_ntop)])
 489 AC_CHECK_FUNCS(inet_pton, , [AC_LIBOBJ(lib/inet_pton)])
 490
 491 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 492 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 493 #include <sys/socket.h>])
 494
 495 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 496 #   builtin getaddrinfo if one of the defines don't exist
 497 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 498                rsync_cv_HAVE_GETADDR_DEFINES,[
 499                         AC_EGREP_CPP(yes, [
 500                         #include <sys/types.h>
 501                         #include <sys/socket.h>
 502                         #include <netdb.h>
 503                         #ifdef AI_PASSIVE
 504                         yes
 505                         #endif],
 506                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 507                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 508 if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"; then
 509         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 510         # something else so we must include <netdb.h> to get the
 511         # redefinition.
 512         AC_CHECK_FUNCS(getaddrinfo, ,
 513                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 514                 AC_TRY_LINK([#include <sys/types.h>
 515                 #include <sys/socket.h>
 516                 #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);],
 517                         [AC_MSG_RESULT([yes])
 518                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 519                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],
 520                         [AC_MSG_RESULT([no])
 521                         AC_LIBOBJ(lib/getaddrinfo)])])
 522 else
 523         AC_LIBOBJ(lib/getaddrinfo)
 524 fi
 525
 526 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 527                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 528                 [],
 529                 [
 530 #include <sys/types.h>
 531 #include <sys/socket.h>
 532 ])
 533
 534 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 535                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 536                 [],
 537                 [
 538 #include <sys/types.h>
 539 #include <sys/socket.h>
 540 #include <netinet/in.h>
 541 ])
 542
 543 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 544                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 545                 [],
 546                 [
 547 #include <sys/types.h>
 548 #include <sys/socket.h>
 549 #include <netinet/in.h>
 550 ])
 551
 552 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 553                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 554                 [],
 555                 [
 556 #include <sys/types.h>
 557 #include <sys/socket.h>
 558 #include <netinet/in.h>
 559 ])
 560
 561 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 562 #if HAVE_SYS_TYPES_H
 563 # include <sys/types.h>
 564 #endif
 565 #if HAVE_SYS_STAT_H
 566 # include <sys/stat.h>
 567 #endif
 568 #if STDC_HEADERS
 569 # include <stdlib.h>
 570 # include <stddef.h>
 571 #else
 572 # if HAVE_STDLIB_H
 573 #  include <stdlib.h>
 574 # endif
 575 #endif
 576 ])
 577
 578 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 579 #
 580 AC_CHECK_FUNCS(strcasecmp)
 581 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 582     AC_CHECK_LIB(resolv, strcasecmp)
 583 fi
 584
 585 AC_CHECK_FUNCS(aclsort)
 586 if test x"$ac_cv_func_aclsort" = x"no"; then
 587     AC_CHECK_LIB(sec, aclsort)
 588 fi
 589
 590 dnl At the moment we don't test for a broken memcmp(), because all we
 591 dnl need to do is test for equality, not comparison, and it seems that
 592 dnl every platform has a memcmp that can do at least that.
 593 dnl AC_FUNC_MEMCMP
 594
 595 AC_FUNC_UTIME_NULL
 596 AC_FUNC_ALLOCA
 597 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 598     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 599     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 600     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 601     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 602     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 603     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 604     initgroups utimensat posix_fallocate attropen)
 605
 606 dnl cygwin iconv.h defines iconv_open as libiconv_open
 607 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 608     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 609 fi
 610
 611 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 612
 613 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 614 AC_TRY_LINK([#include <fcntl.h>
 615 #include <sys/types.h>],
 616 [fallocate(0, 0, 0, 0);],
 617 rsync_cv_have_fallocate=yes,rsync_cv_have_fallocate=no)])
 618 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 619     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 620 fi
 621
 622 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 623 AC_TRY_COMPILE([#include <sys/syscall.h>
 624 #include <sys/types.h>],
 625 [syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);],
 626 rsync_cv_have_sys_fallocate=yes,rsync_cv_have_sys_fallocate=no)])
 627 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 628     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 629 fi
 630
 631 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 632     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 633     case $host_os in
 634     *cygwin*)
 635         AC_MSG_RESULT(yes)
 636         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 637                   [Define if posix_fallocate is efficient (Cygwin)])
 638         ;;
 639     *)
 640         AC_MSG_RESULT(no)
 641         ;;
 642     esac
 643 fi
 644
 645 dnl End of preallocation stuff
 646
 647 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 648 if test $ac_cv_func_getpgrp = yes; then
 649     AC_FUNC_GETPGRP
 650 fi
 651
 652 AC_ARG_ENABLE(iconv-open,
 653     AC_HELP_STRING([--disable-iconv-open],
 654             [disable all use of iconv_open() function]),
 655     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 656
 657 if test x"$enable_iconv_open" != x"no"; then
 658     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 659 fi
 660
 661 AC_ARG_ENABLE(iconv,
 662     AC_HELP_STRING([--disable-iconv],
 663             [disable rsync's --iconv option]),
 664     [], [enable_iconv=$enable_iconv_open])
 665 AH_TEMPLATE([ICONV_OPTION],
 666 [Define if you want the --iconv option.  Specifing a value will set the
 667 default iconv setting (a NULL means no --iconv processing by default).])
 668 if test x"$enable_iconv" != x"no"; then
 669         if test x"$enable_iconv" = x"yes"; then
 670                 AC_DEFINE(ICONV_OPTION, NULL)
 671         else
 672                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 673         fi
 674         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 675 fi
 676
 677 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 678   AC_TRY_RUN([
 679 #if HAVE_UNISTD_H
 680 # include <unistd.h>
 681 #endif
 682 #include <stdlib.h>
 683 #include <errno.h>
 684     main() {
 685         char const *dangling_symlink = "conftest.dangle";
 686         unlink(dangling_symlink);
 687         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 688         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(1);
 689         exit(0);
 690     }],
 691   rsync_cv_chown_modifies_symlink=yes,rsync_cv_chown_modifies_symlink=no,rsync_cv_chown_modifies_symlink=no)])
 692 if test $rsync_cv_chown_modifies_symlink = yes; then
 693   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 694 fi
 695
 696 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 697   AC_TRY_RUN([
 698 #if HAVE_UNISTD_H
 699 # include <unistd.h>
 700 #endif
 701 #include <stdlib.h>
 702 #include <errno.h>
 703 #define FILENAME "conftest.dangle"
 704     main() {
 705         unlink(FILENAME);
 706         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 707         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 708         exit(0);
 709     }],
 710   rsync_cv_can_hardlink_symlink=yes,rsync_cv_can_hardlink_symlink=no,rsync_cv_can_hardlink_symlink=no)])
 711 if test $rsync_cv_can_hardlink_symlink = yes; then
 712   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 713 fi
 714
 715 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 716   AC_TRY_RUN([
 717 #if HAVE_UNISTD_H
 718 # include <unistd.h>
 719 #endif
 720 #include <stdlib.h>
 721 #include <errno.h>
 722 #define FILENAME "conftest.fifi"
 723     main() {
 724         unlink(FILENAME);
 725         if (mkfifo(FILENAME, 0777) < 0) abort();
 726         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 727         exit(0);
 728     }],
 729   rsync_cv_can_hardlink_special=yes,rsync_cv_can_hardlink_special=no,rsync_cv_can_hardlink_special=no)])
 730 if test $rsync_cv_can_hardlink_special = yes; then
 731     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 732 fi
 733
 734 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 735 AC_TRY_RUN([
 736 #include <sys/types.h>
 737 #include <sys/socket.h>
 738
 739 main() {
 740        int fd[2];
 741 #ifdef __CYGWIN__
 742        exit(1);
 743 #else
 744        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 745 #endif
 746 }],
 747 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
 748 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 749     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 750 fi
 751
 752 if test x"$with_included_popt" != x"yes"; then
 753     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 754 fi
 755 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 756     # If the system has /usr/include/popt/popt.h, we enable the
 757     # included popt because an attempt to "#include <popt/popt.h>"
 758     # would use our included header file anyway (due to -I.), and
 759     # might conflict with the system popt.
 760     with_included_popt=yes
 761 elif test x"$ac_cv_header_popt_h" != x"yes"; then
 762     with_included_popt=yes
 763 fi
 764
 765 AC_MSG_CHECKING([whether to use included libpopt])
 766 if test x"$with_included_popt" = x"yes"; then
 767     AC_MSG_RESULT($srcdir/popt)
 768     BUILD_POPT='$(popt_OBJS)'
 769     CFLAGS="$CFLAGS -I$srcdir/popt"
 770     if test x"$ALLOCA" != x
 771     then
 772         # this can be removed when/if we add an included alloca.c;
 773         #  see autoconf documentation on AC_FUNC_ALLOCA
 774         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 775     fi
 776 else
 777     AC_MSG_RESULT(no)
 778 fi
 779
 780 # We default to using our zlib unless --with-included-zlib=no is given.
 781 if test x"$with_included_zlib" != x"no"; then
 782     with_included_zlib=yes
 783 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
 784     with_included_zlib=yes
 785 fi
 786 if test x"$with_included_zlib" != x"yes"; then
 787     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
 788 fi
 789
 790 AC_MSG_CHECKING([whether to use included zlib])
 791 if test x"$with_included_zlib" = x"yes"; then
 792     AC_MSG_RESULT($srcdir/zlib)
 793     BUILD_ZLIB='$(zlib_OBJS)'
 794     CFLAGS="$CFLAGS -I$srcdir/zlib"
 795 else
 796     AC_MSG_RESULT(no)
 797 fi
 798
 799 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 800 AC_TRY_COMPILE([],[signed char *s = ""],
 801 rsync_cv_SIGNED_CHAR_OK=yes,rsync_cv_SIGNED_CHAR_OK=no)])
 802 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 803     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 804 fi
 805
 806 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 807 AC_TRY_RUN([#include <sys/types.h>
 808 #include <dirent.h>
 809 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 810 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 811 di->d_name[0] == 0) exit(0); exit(1);} ],
 812 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
 813 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 814     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 815 fi
 816
 817 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
 818 AC_TRY_COMPILE([#include <sys/types.h>
 819 #include <utime.h>],
 820 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 821 rsync_cv_HAVE_STRUCT_UTIMBUF=yes,rsync_cv_HAVE_STRUCT_UTIMBUF=no)])
 822 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
 823     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 824 fi
 825
 826 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 827 AC_TRY_COMPILE([#include <sys/time.h>
 828 #include <unistd.h>],
 829 [struct timeval tv; exit(gettimeofday(&tv, NULL));],
 830 rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no)])
 831 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
 832     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
 833 fi
 834
 835 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 836 AC_TRY_RUN([
 837 #include <sys/types.h>
 838 #include <stdarg.h>
 839 void foo(const char *format, ...) {
 840        va_list ap;
 841        int len;
 842        char buf[5];
 843
 844        va_start(ap, format);
 845        len = vsnprintf(0, 0, format, ap);
 846        va_end(ap);
 847        if (len != 5) exit(1);
 848
 849        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 850
 851        exit(0);
 852 }
 853 main() { foo("hello"); }
 854 ],
 855 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
 856 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 857     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
 858 fi
 859
 860
 861 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 862 AC_TRY_RUN([#include <stdlib.h>
 863 #include <sys/types.h>
 864 #include <sys/stat.h>
 865 #include <unistd.h>
 866 main() {
 867   struct stat st;
 868   char tpl[20]="/tmp/test.XXXXXX";
 869   int fd = mkstemp(tpl);
 870   if (fd == -1) exit(1);
 871   unlink(tpl);
 872   if (fstat(fd, &st) != 0) exit(1);
 873   if ((st.st_mode & 0777) != 0600) exit(1);
 874   exit(0);
 875 }],
 876 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
 877 rsync_cv_HAVE_SECURE_MKSTEMP=no,
 878 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
 879 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 880     case $host_os in
 881     hpux*)
 882         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
 883         dnl so we noisily skip using it.  See HP change request JAGaf34426
 884         dnl for details. (sbonds)
 885         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
 886         ;;
 887     *)
 888         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
 889         ;;
 890     esac
 891 fi
 892
 893
 894 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
 895 AC_TRY_RUN([
 896 #include <stdio.h>
 897 #include <sys/stat.h>
 898 #include <errno.h>
 899 main() { int rc, ec; char *fn = "fifo-test";
 900 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
 901 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 902 return 0;}],
 903            rsync_cv_MKNOD_CREATES_FIFOS=yes,rsync_cv_MKNOD_CREATES_FIFOS=no,rsync_cv_MKNOD_CREATES_FIFOS=cross)])
 904 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
 905     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
 906 fi
 907
 908 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
 909 AC_TRY_RUN([
 910 #include <stdio.h>
 911 #include <sys/stat.h>
 912 #include <errno.h>
 913 main() { int rc, ec; char *fn = "sock-test";
 914 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
 915 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 916 return 0;}],
 917            rsync_cv_MKNOD_CREATES_SOCKETS=yes,rsync_cv_MKNOD_CREATES_SOCKETS=no,rsync_cv_MKNOD_CREATES_SOCKETS=cross)])
 918 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
 919     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
 920 fi
 921
 922 #
 923 # The following test was mostly taken from the tcl/tk plus patches
 924 #
 925 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 926 rm -rf conftest*
 927 cat > conftest.$ac_ext <<EOF
 928 int main() { return 0; }
 929 EOF
 930 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 931 if test -f conftest..o; then
 932     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 933 else
 934     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 935 fi
 936 rm -rf conftest*
 937 ])
 938 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 939     OBJ_SAVE="#"
 940     OBJ_RESTORE="#"
 941     CC_SHOBJ_FLAG='-o $@'
 942 else
 943     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 944     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 945     CC_SHOBJ_FLAG=""
 946 fi
 947
 948 AC_SUBST(OBJ_SAVE)
 949 AC_SUBST(OBJ_RESTORE)
 950 AC_SUBST(CC_SHOBJ_FLAG)
 951 AC_SUBST(BUILD_POPT)
 952 AC_SUBST(BUILD_ZLIB)
 953 AC_SUBST(MAKE_MAN)
 954
 955 AC_CHECK_FUNCS(_acl __acl _facl __facl)
 956 #################################################
 957 # check for ACL support
 958
 959 AC_MSG_CHECKING([whether to support ACLs])
 960 AC_ARG_ENABLE(acl-support,
 961         AC_HELP_STRING([--disable-acl-support],
 962                        [disable ACL support]))
 963
 964 if test x"$enable_acl_support" = x"no"; then
 965     AC_MSG_RESULT(no)
 966 else
 967     case "$host_os" in
 968     *sysv5*)
 969         AC_MSG_RESULT(Using UnixWare ACLs)
 970         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
 971         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
 972         ;;
 973     solaris*|*cygwin*)
 974         AC_MSG_RESULT(Using solaris ACLs)
 975         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
 976         AC_DEFINE(SUPPORT_ACLS, 1)
 977         ;;
 978     *hpux*)
 979         AC_MSG_RESULT(Using HPUX ACLs)
 980         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
 981         AC_DEFINE(SUPPORT_ACLS, 1)
 982         ;;
 983     *irix*)
 984         AC_MSG_RESULT(Using IRIX ACLs)
 985         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
 986         AC_DEFINE(SUPPORT_ACLS, 1)
 987         ;;
 988     *aix*)
 989         AC_MSG_RESULT(Using AIX ACLs)
 990         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
 991         AC_DEFINE(SUPPORT_ACLS, 1)
 992         ;;
 993     *osf*)
 994         AC_MSG_RESULT(Using Tru64 ACLs)
 995         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
 996         AC_DEFINE(SUPPORT_ACLS, 1)
 997         LIBS="$LIBS -lpacl"
 998         ;;
 999     darwin*)
1000         AC_MSG_RESULT(Using OS X ACLs)
1001         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1002         AC_DEFINE(SUPPORT_ACLS, 1)
1003         ;;
1004     *)
1005         AC_MSG_RESULT(running tests:)
1006         AC_CHECK_LIB(acl,acl_get_file)
1007             AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1008             AC_TRY_LINK([#include <sys/types.h>
1009 #include <sys/acl.h>],
1010 [ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);],
1011 samba_cv_HAVE_POSIX_ACLS=yes,samba_cv_HAVE_POSIX_ACLS=no)])
1012         AC_MSG_CHECKING(ACL test results)
1013         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1014             AC_MSG_RESULT(Using posix ACLs)
1015             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1016             AC_DEFINE(SUPPORT_ACLS, 1)
1017             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1018                 AC_TRY_LINK([#include <sys/types.h>
1019 #include <sys/acl.h>],
1020 [ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);],
1021 samba_cv_HAVE_ACL_GET_PERM_NP=yes,samba_cv_HAVE_ACL_GET_PERM_NP=no)])
1022             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1023                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1024             fi
1025         else
1026             if test x"$enable_acl_support" = x"yes"; then
1027                 AC_MSG_ERROR(Failed to find ACL support)
1028             else
1029                 AC_MSG_RESULT(No ACL support found)
1030             fi
1031         fi
1032         ;;
1033     esac
1034 fi
1035
1036 #################################################
1037 # check for extended attribute support
1038 AC_MSG_CHECKING(whether to support extended attributes)
1039 AC_ARG_ENABLE(xattr-support,
1040     AC_HELP_STRING([--disable-xattr-support],
1041             [disable extended attributes]),
1042     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1043         *yes*) enable_xattr_support=maybe ;;
1044         *) enable_xattr_support=no ;;
1045         esac])
1046 AH_TEMPLATE([SUPPORT_XATTRS],
1047 [Define to 1 to add support for extended attributes])
1048 if test x"$enable_xattr_support" = x"no"; then
1049     AC_MSG_RESULT(no)
1050 else
1051     case "$host_os" in
1052     *linux*)
1053         AC_MSG_RESULT(Using Linux xattrs)
1054         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs])
1055         AC_DEFINE(SUPPORT_XATTRS, 1)
1056         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1057         ;;
1058     darwin*)
1059         AC_MSG_RESULT(Using OS X xattrs)
1060         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1061         AC_DEFINE(SUPPORT_XATTRS, 1)
1062         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1063         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1064         ;;
1065     freebsd*)
1066         AC_MSG_RESULT(Using FreeBSD extattrs)
1067         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1068         AC_DEFINE(SUPPORT_XATTRS, 1)
1069         ;;
1070     solaris*)
1071         AC_MSG_RESULT(Using Solaris xattrs)
1072         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1073         AC_DEFINE(SUPPORT_XATTRS, 1)
1074         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1075         ;;
1076     *)
1077         if test x"$enable_xattr_support" = x"yes"; then
1078             AC_MSG_ERROR(Failed to find extended attribute support)
1079         else
1080             AC_MSG_RESULT(No extended attribute support found)
1081         fi
1082         ;;
1083     esac
1084 fi
1085
1086 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1087     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1088     OLD_CFLAGS="$CFLAGS"
1089     CFLAGS="$CFLAGS -Wno-unused-parameter"
1090     AC_TRY_LINK([#include <stdio.h>], [printf("hello\n");], [rsync_warn_flag=yes], [rsync_warn_flag=no])
1091     AC_MSG_RESULT([$rsync_warn_flag])
1092     if test x"$rsync_warn_flag" = x"no"; then
1093         CFLAGS="$OLD_CFLAGS"
1094     fi
1095 fi
1096
1097 case "$CC" in
1098 ' checker'*|checker*)
1099     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1100     ;;
1101 esac
1102
1103 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1104 AC_OUTPUT
1105
1106 AC_MSG_RESULT()
1107 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1108 AC_MSG_RESULT()