Specify package name and version in call to AC_INIT
[rsync.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2
3 AC_INIT([rsync], [3.1.2dev], [http://rsync.samba.org/bugzilla.html])
4
5 AC_CONFIG_MACRO_DIR([m4])
6 AC_CONFIG_SRCDIR([byteorder.h])
7 AC_CONFIG_HEADER(config.h)
8 AC_PREREQ(2.60)
9
10 AC_SUBST(RSYNC_VERSION, $PACKAGE_VERSION)
11 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
12
13 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$PACKAGE_VERSION"], [rsync release version])
14
15 LDFLAGS=${LDFLAGS-""}
16
17 AC_CANONICAL_HOST
18
19 dnl define the directory for replacement function since AC_LIBOBJ does not
20 dnl officially support subdirs and fails with automake
21 AC_CONFIG_LIBOBJ_DIR([lib])
22
23 # We must decide this before testing the compiler.
24
25 # Please allow this to default to yes, so that your users have more
26 # chance of getting a useful stack trace if problems occur.
27
28 AC_MSG_CHECKING([whether to include debugging symbols])
29 AC_ARG_ENABLE(debug,
30         AC_HELP_STRING([--disable-debug],
31                 [disable debugging symbols and features]))
32
33 if test x"$enable_debug" = x"no"; then
34     AC_MSG_RESULT(no)
35     ac_cv_prog_cc_g=no
36 else
37     AC_MSG_RESULT([yes])
38     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
39     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
40 fi
41
42 dnl Checks for programs.
43 AC_PROG_CC
44 AC_PROG_CPP
45 AC_PROG_EGREP
46 AC_PROG_INSTALL
47 AC_PROG_MKDIR_P
48 AC_PROG_CC_STDC
49 AC_SUBST(SHELL)
50
51 AC_DEFINE([_GNU_SOURCE], 1,
52           [Define _GNU_SOURCE so that we get all necessary prototypes])
53
54 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
55         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
56 fi
57
58 AC_ARG_ENABLE(profile,
59         AC_HELP_STRING([--enable-profile],
60                 [turn on CPU profiling]))
61 if test x"$enable_profile" = x"yes"; then
62         CFLAGS="$CFLAGS -pg"
63 fi
64
65
66 # Specifically, this turns on panic_action handling.
67 AC_ARG_ENABLE(maintainer-mode,
68         AC_HELP_STRING([--enable-maintainer-mode],
69                 [turn on extra debug features]))
70 if test x"$enable_maintainer_mode" = x"yes"; then
71         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
72 fi
73
74
75 # This is needed for our included version of popt.  Kind of silly, but
76 # I don't want our version too far out of sync.
77 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
78
79 # If GCC, turn on warnings.
80 if test x"$GCC" = x"yes"; then
81         CFLAGS="$CFLAGS -Wall -W"
82 fi
83
84 AC_ARG_WITH(included-popt,
85         AC_HELP_STRING([--with-included-popt], [use bundled popt library, not from system]))
86
87 AC_ARG_WITH(included-zlib,
88         AC_HELP_STRING([--with-included-zlib], [use bundled zlib library, not from system]))
89
90 AC_ARG_WITH(protected-args,
91         AC_HELP_STRING([--with-protected-args], [make --protected-args option the default]))
92 if test x"$with_protected_args" = x"yes"; then
93         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
94 fi
95
96 AC_ARG_WITH(rsync-path,
97         AC_HELP_STRING([--with-rsync-path=PATH], [set default --rsync-path to PATH (default: rsync)]),
98         [ RSYNC_PATH="$with_rsync_path" ],
99         [ RSYNC_PATH="rsync" ])
100
101 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
102
103 AC_ARG_WITH(rsyncd-conf,
104         AC_HELP_STRING([--with-rsyncd-conf=PATH], [set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
105         [ if test ! -z "$with_rsyncd_conf" ; then
106                 case $with_rsyncd_conf in
107                         yes|no)
108                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
109                                 ;;
110                         /*)
111                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
112                                 ;;
113                         *)
114                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
115                                 ;;
116                 esac
117         else
118                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
119         fi ],
120         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
121
122 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
123
124 AC_ARG_WITH(rsh,
125         AC_HELP_STRING([--with-rsh=CMD], [set remote shell command to CMD (default: ssh)]))
126
127 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
128 if test x$HAVE_REMSH = x1; then
129         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
130 fi
131
132 if test x"$with_rsh" != x; then
133         RSYNC_RSH="$with_rsh"
134 else
135         RSYNC_RSH="ssh"
136 fi
137 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
138
139 AC_CHECK_PROG(HAVE_YODL2MAN, yodl2man, 1, 0)
140 if test x$HAVE_YODL2MAN = x1; then
141     MAKE_MAN=man
142 else
143     MAKE_MAN=man-copy
144 fi
145
146 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
147 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
148 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
149
150 AC_ARG_WITH(nobody-group,
151     AC_HELP_STRING([--with-nobody-group=GROUP],
152                    [set the default unprivileged group (default nobody or nogroup)]),
153     [ NOBODY_GROUP="$with_nobody_group" ])
154
155 if test x"$with_nobody_group" = x; then
156     AC_MSG_CHECKING([the group for user "nobody"])
157     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
158         NOBODY_GROUP=nobody
159     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
160         NOBODY_GROUP=nogroup
161     else
162         NOBODY_GROUP=nobody # test for others?
163     fi
164     AC_MSG_RESULT($NOBODY_GROUP)
165 fi
166
167 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
168 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
169
170 # arrgh. libc in some old debian version screwed up the largefile
171 # stuff, getting byte range locking wrong
172 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
173 AC_TRY_RUN([
174 #define _FILE_OFFSET_BITS 64
175 #include <stdio.h>
176 #include <fcntl.h>
177 #include <sys/types.h>
178 #include <sys/wait.h>
179
180 int main(void)
181 {
182         struct flock lock;
183         int status;
184         char tpl[32] = "/tmp/locktest.XXXXXX";
185         int fd = mkstemp(tpl);
186         if (fd < 0) {
187                 strcpy(tpl, "conftest.dat");
188                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
189         }
190
191         lock.l_type = F_WRLCK;
192         lock.l_whence = SEEK_SET;
193         lock.l_start = 0;
194         lock.l_len = 1;
195         lock.l_pid = 0;
196         fcntl(fd,F_SETLK,&lock);
197         if (fork() == 0) {
198                 lock.l_start = 1;
199                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
200         }
201         wait(&status);
202         unlink(tpl);
203         exit(WEXITSTATUS(status));
204 }
205 ],
206 rsync_cv_HAVE_BROKEN_LARGEFILE=yes,rsync_cv_HAVE_BROKEN_LARGEFILE=no,rsync_cv_HAVE_BROKEN_LARGEFILE=cross)])
207 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
208    AC_SYS_LARGEFILE
209 fi
210
211 ipv6type=unknown
212 ipv6lib=none
213 ipv6trylibc=yes
214
215 AC_ARG_ENABLE(ipv6,
216         AC_HELP_STRING([--disable-ipv6],
217                 [do not even try to use IPv6]))
218 if test x"$enable_ipv6" != x"no"; then
219         AC_MSG_CHECKING([ipv6 stack type])
220         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
221                 case $i in
222                 inria)
223                         # http://www.kame.net/
224                         AC_EGREP_CPP(yes, [
225 #include <netinet/in.h>
226 #ifdef IPV6_INRIA_VERSION
227 yes
228 #endif],
229                                 [ipv6type=$i;
230                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
231                                 ])
232                         ;;
233                 kame)
234                         # http://www.kame.net/
235                         AC_EGREP_CPP(yes, [
236 #include <netinet/in.h>
237 #ifdef __KAME__
238 yes
239 #endif],
240                                 [ipv6type=$i;
241                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
242                         ;;
243                 linux-glibc)
244                         # http://www.v6.linux.or.jp/
245                         AC_EGREP_CPP(yes, [
246 #include <features.h>
247 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
248 yes
249 #endif],
250                                 [ipv6type=$i;
251 AC_DEFINE(INET6, 1, [true if you have IPv6])])
252                         ;;
253                 linux-inet6)
254                         # http://www.v6.linux.or.jp/
255                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
256                                 ipv6type=$i
257                                 ipv6lib=inet6
258                                 ipv6libdir=/usr/inet6/lib
259                                 ipv6trylibc=yes;
260                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
261                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
262                         fi
263                         ;;
264                 solaris)
265                         # http://www.sun.com
266                         AC_EGREP_CPP(yes, [
267 #include <netinet/ip6.h>
268 #ifdef __sun
269 yes
270 #endif],
271                                 [ipv6type=$i;
272                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
273                         ;;
274                 toshiba)
275                         AC_EGREP_CPP(yes, [
276 #include <sys/param.h>
277 #ifdef _TOSHIBA_INET6
278 yes
279 #endif],
280                                 [ipv6type=$i;
281                                 ipv6lib=inet6;
282                                 ipv6libdir=/usr/local/v6/lib;
283                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
284                         ;;
285                 v6d)
286                         AC_EGREP_CPP(yes, [
287 #include </usr/local/v6/include/sys/v6config.h>
288 #ifdef __V6D__
289 yes
290 #endif],
291                                 [ipv6type=$i;
292                                 ipv6lib=v6;
293                                 ipv6libdir=/usr/local/v6/lib;
294                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
295                         ;;
296                 zeta)
297                         AC_EGREP_CPP(yes, [
298 #include <sys/param.h>
299 #ifdef _ZETA_MINAMI_INET6
300 yes
301 #endif],
302                                 [ipv6type=$i;
303                                 ipv6lib=inet6;
304                                 ipv6libdir=/usr/local/v6/lib;
305                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
306                         ;;
307                 cygwin)
308                         AC_EGREP_CPP(yes, [
309 #include <netinet/in.h>
310 #ifdef _CYGWIN_IN6_H
311 yes
312 #endif],
313                                 [ipv6type=$i;
314                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
315                         ;;
316                 esac
317                 if test "$ipv6type" != "unknown"; then
318                         break
319                 fi
320         done
321         AC_MSG_RESULT($ipv6type)
322
323         AC_SEARCH_LIBS(getaddrinfo, inet6)
324 fi
325
326 dnl Do you want to disable use of locale functions
327 AC_ARG_ENABLE([locale],
328         AC_HELP_STRING([--disable-locale],
329                 [disable locale features]))
330 AH_TEMPLATE([CONFIG_LOCALE],
331 [Undefine if you do not want locale features.  By default this is defined.])
332 if test x"$enable_locale" != x"no"; then
333         AC_DEFINE(CONFIG_LOCALE)
334 fi
335
336 AC_MSG_CHECKING([whether to call shutdown on all sockets])
337 case $host_os in
338         *cygwin* ) AC_MSG_RESULT(yes)
339                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
340                             [Define to 1 if sockets need to be shutdown])
341                    ;;
342                * ) AC_MSG_RESULT(no);;
343 esac
344
345 AC_C_BIGENDIAN
346 AC_HEADER_DIRENT
347 AC_HEADER_TIME
348 AC_HEADER_SYS_WAIT
349 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
350     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
351     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
352     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
353     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
354     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
355     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h \
356     zlib.h)
357 AC_HEADER_MAJOR
358
359 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
360 AC_TRY_RUN([
361 #include <sys/types.h>
362 #ifdef MAJOR_IN_MKDEV
363 #include <sys/mkdev.h>
364 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
365 #  define makedev mkdev
366 # endif
367 #elif defined MAJOR_IN_SYSMACROS
368 #include <sys/sysmacros.h>
369 #endif
370
371 int main(void)
372 {
373         dev_t dev = makedev(0, 5, 7);
374         if (major(dev) != 5 || minor(dev) != 7)
375                 exit(1);
376         return 0;
377 }
378 ],
379 rsync_cv_MAKEDEV_TAKES_3_ARGS=yes,rsync_cv_MAKEDEV_TAKES_3_ARGS=no,rsync_cv_MAKEDEV_TAKES_3_ARGS=no)])
380 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
381    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
382 fi
383
384 AC_CHECK_SIZEOF(int)
385 AC_CHECK_SIZEOF(long)
386 AC_CHECK_SIZEOF(long long)
387 AC_CHECK_SIZEOF(short)
388 AC_CHECK_SIZEOF(int16_t)
389 AC_CHECK_SIZEOF(uint16_t)
390 AC_CHECK_SIZEOF(int32_t)
391 AC_CHECK_SIZEOF(uint32_t)
392 AC_CHECK_SIZEOF(int64_t)
393 AC_CHECK_SIZEOF(off_t)
394 AC_CHECK_SIZEOF(off64_t)
395 AC_CHECK_SIZEOF(time_t)
396
397 AC_C_INLINE
398 AC_C_LONG_DOUBLE
399
400 AC_TYPE_SIGNAL
401 AC_TYPE_UID_T
402 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
403 AC_TYPE_GETGROUPS
404 AC_CHECK_MEMBERS([struct stat.st_rdev,
405                   struct stat.st_mtimensec,
406                   struct stat.st_mtim.tv_nsec],,,[
407 #ifdef HAVE_SYS_TYPES_H
408 #include <sys/types.h>
409 #endif
410 #ifdef HAVE_SYS_STAT_H
411 #include <sys/stat.h>
412 #endif
413 #ifdef HAVE_UNISTD_H
414 #include <unistd.h>
415 #endif])
416
417 TYPE_SOCKLEN_T
418
419 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
420     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
421         rsync_cv_errno=yes,rsync_cv_have_errno_decl=no)])
422 if test x"$rsync_cv_errno" = x"yes"; then
423    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
424 fi
425
426 # The following test taken from the cvs sources
427 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
428 # These need checks to be before checks for any other functions that
429 #    might be in the same libraries.
430 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
431 # libsocket.so which has a bad implementation of gethostbyname (it
432 # only looks in /etc/hosts), so we only look for -lsocket if we need
433 # it.
434 AC_CHECK_FUNCS(connect)
435 if test x"$ac_cv_func_connect" = x"no"; then
436     case "$LIBS" in
437     *-lnsl*) ;;
438     *) AC_CHECK_LIB(nsl_s, printf) ;;
439     esac
440     case "$LIBS" in
441     *-lnsl*) ;;
442     *) AC_CHECK_LIB(nsl, printf) ;;
443     esac
444     case "$LIBS" in
445     *-lsocket*) ;;
446     *) AC_CHECK_LIB(socket, connect) ;;
447     esac
448     case "$LIBS" in
449     *-linet*) ;;
450     *) AC_CHECK_LIB(inet, connect) ;;
451     esac
452     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
453     dnl has been cached.
454     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
455        test x"$ac_cv_lib_inet_connect" = x"yes"; then
456         # ac_cv_func_connect=yes
457         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
458         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
459     fi
460 fi
461
462 AC_SEARCH_LIBS(inet_ntop, resolv)
463
464 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
465 # accept either iconv_open or libiconv_open, since some include files map
466 # the former to the latter.
467 AC_SEARCH_LIBS(iconv_open, iconv)
468 AC_SEARCH_LIBS(libiconv_open, iconv)
469
470 AC_MSG_CHECKING([for iconv declaration])
471 AC_CACHE_VAL(am_cv_proto_iconv, [
472     AC_TRY_COMPILE([
473 #include <stdlib.h>
474 #include <iconv.h>
475 extern
476 #ifdef __cplusplus
477 "C"
478 #endif
479 #if defined(__STDC__) || defined(__cplusplus)
480 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
481 #else
482 size_t iconv();
483 #endif
484 ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const")
485       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
486     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
487 AC_MSG_RESULT([$]{ac_t:-
488          }[$]am_cv_proto_iconv)
489 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
490                    [Define as const if the declaration of iconv() needs const.])
491
492 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
493
494 AC_REPLACE_FUNCS([inet_ntop inet_pton])
495
496 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
497 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
498 #include <sys/socket.h>])
499
500 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
501 #   builtin getaddrinfo if one of the defines don't exist
502 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
503                rsync_cv_HAVE_GETADDR_DEFINES,[
504                         AC_EGREP_CPP(yes, [
505                         #include <sys/types.h>
506                         #include <sys/socket.h>
507                         #include <netdb.h>
508                         #ifdef AI_PASSIVE
509                         yes
510                         #endif],
511                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
512                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
513 if test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"; then
514         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
515         # something else so we must include <netdb.h> to get the
516         # redefinition.
517         AC_CHECK_FUNCS(getaddrinfo, ,
518                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
519                 AC_TRY_LINK([#include <sys/types.h>
520                 #include <sys/socket.h>
521                 #include <netdb.h>],[getaddrinfo(NULL, NULL, NULL, NULL);],
522                         [AC_MSG_RESULT([yes])
523                         AC_DEFINE(HAVE_GETADDRINFO, 1,
524                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],
525                         [AC_MSG_RESULT([no])
526                         AC_LIBOBJ([getaddrinfo])])])
527 else
528         AC_LIBOBJ([getaddrinfo])
529 fi
530
531 AC_CHECK_MEMBER([struct sockaddr.sa_len],
532                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
533                 [],
534                 [
535 #include <sys/types.h>
536 #include <sys/socket.h>
537 ])
538
539 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
540                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
541                 [],
542                 [
543 #include <sys/types.h>
544 #include <sys/socket.h>
545 #include <netinet/in.h>
546 ])
547
548 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
549                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
550                 [],
551                 [
552 #include <sys/types.h>
553 #include <sys/socket.h>
554 #include <netinet/in.h>
555 ])
556
557 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
558                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
559                 [],
560                 [
561 #include <sys/types.h>
562 #include <sys/socket.h>
563 #include <netinet/in.h>
564 ])
565
566 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
567 #if HAVE_SYS_TYPES_H
568 # include <sys/types.h>
569 #endif
570 #if HAVE_SYS_STAT_H
571 # include <sys/stat.h>
572 #endif
573 #if STDC_HEADERS
574 # include <stdlib.h>
575 # include <stddef.h>
576 #else
577 # if HAVE_STDLIB_H
578 #  include <stdlib.h>
579 # endif
580 #endif
581 ])
582
583 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
584 #
585 AC_CHECK_FUNCS(strcasecmp)
586 if test x"$ac_cv_func_strcasecmp" = x"no"; then
587     AC_CHECK_LIB(resolv, strcasecmp)
588 fi
589
590 AC_CHECK_FUNCS(aclsort)
591 if test x"$ac_cv_func_aclsort" = x"no"; then
592     AC_CHECK_LIB(sec, aclsort)
593 fi
594
595 dnl At the moment we don't test for a broken memcmp(), because all we
596 dnl need to do is test for equality, not comparison, and it seems that
597 dnl every platform has a memcmp that can do at least that.
598 dnl AC_FUNC_MEMCMP
599
600 AC_FUNC_UTIME_NULL
601 AC_FUNC_ALLOCA
602 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
603     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
604     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
605     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
606     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
607     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
608     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
609     initgroups utimensat posix_fallocate attropen setvbuf usleep)
610
611 dnl cygwin iconv.h defines iconv_open as libiconv_open
612 if test x"$ac_cv_func_iconv_open" != x"yes"; then
613     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
614 fi
615
616 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
617
618 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
619 AC_TRY_LINK([#include <fcntl.h>
620 #include <sys/types.h>],
621 [fallocate(0, 0, 0, 0);],
622 rsync_cv_have_fallocate=yes,rsync_cv_have_fallocate=no)])
623 if test x"$rsync_cv_have_fallocate" = x"yes"; then
624     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
625 fi
626
627 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
628 AC_TRY_COMPILE([#include <sys/syscall.h>
629 #include <sys/types.h>],
630 [syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);],
631 rsync_cv_have_sys_fallocate=yes,rsync_cv_have_sys_fallocate=no)])
632 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
633     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
634 fi
635
636 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
637     AC_MSG_CHECKING([whether posix_fallocate is efficient])
638     case $host_os in
639     *cygwin*)
640         AC_MSG_RESULT(yes)
641         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
642                   [Define if posix_fallocate is efficient (Cygwin)])
643         ;;
644     *)
645         AC_MSG_RESULT(no)
646         ;;
647     esac
648 fi
649
650 dnl End of preallocation stuff
651
652 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
653 if test $ac_cv_func_getpgrp = yes; then
654     AC_FUNC_GETPGRP
655 fi
656
657 AC_ARG_ENABLE(iconv-open,
658     AC_HELP_STRING([--disable-iconv-open],
659             [disable all use of iconv_open() function]),
660     [], [enable_iconv_open=$ac_cv_func_iconv_open])
661
662 if test x"$enable_iconv_open" != x"no"; then
663     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
664 fi
665
666 AC_ARG_ENABLE(iconv,
667     AC_HELP_STRING([--disable-iconv],
668             [disable rsync's --iconv option]),
669     [], [enable_iconv=$enable_iconv_open])
670 AH_TEMPLATE([ICONV_OPTION],
671 [Define if you want the --iconv option.  Specifing a value will set the
672 default iconv setting (a NULL means no --iconv processing by default).])
673 if test x"$enable_iconv" != x"no"; then
674         if test x"$enable_iconv" = x"yes"; then
675                 AC_DEFINE(ICONV_OPTION, NULL)
676         else
677                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
678         fi
679         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
680 fi
681
682 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
683   AC_TRY_RUN([
684 #if HAVE_UNISTD_H
685 # include <unistd.h>
686 #endif
687 #include <stdlib.h>
688 #include <errno.h>
689     main() {
690         char const *dangling_symlink = "conftest.dangle";
691         unlink(dangling_symlink);
692         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
693         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(1);
694         exit(0);
695     }],
696   rsync_cv_chown_modifies_symlink=yes,rsync_cv_chown_modifies_symlink=no,rsync_cv_chown_modifies_symlink=no)])
697 if test $rsync_cv_chown_modifies_symlink = yes; then
698   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
699 fi
700
701 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
702   AC_TRY_RUN([
703 #if HAVE_UNISTD_H
704 # include <unistd.h>
705 #endif
706 #include <stdlib.h>
707 #include <errno.h>
708 #define FILENAME "conftest.dangle"
709     main() {
710         unlink(FILENAME);
711         if (symlink("conftest.no-such", FILENAME) < 0) abort();
712         unlink(FILENAME "2");
713         if (link(FILENAME, FILENAME "2") < 0) exit(1);
714         exit(0);
715     }],
716   rsync_cv_can_hardlink_symlink=yes,rsync_cv_can_hardlink_symlink=no,rsync_cv_can_hardlink_symlink=no)])
717 if test $rsync_cv_can_hardlink_symlink = yes; then
718   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
719 fi
720
721 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
722   AC_TRY_RUN([
723 #if HAVE_UNISTD_H
724 # include <unistd.h>
725 #endif
726 #include <stdlib.h>
727 #include <errno.h>
728 #define FILENAME "conftest.fifi"
729     main() {
730         unlink(FILENAME);
731         if (mkfifo(FILENAME, 0777) < 0) abort();
732         unlink(FILENAME "2");
733         if (link(FILENAME, FILENAME "2") < 0) exit(1);
734         exit(0);
735     }],
736   rsync_cv_can_hardlink_special=yes,rsync_cv_can_hardlink_special=no,rsync_cv_can_hardlink_special=no)])
737 if test $rsync_cv_can_hardlink_special = yes; then
738     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
739 fi
740
741 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
742 AC_TRY_RUN([
743 #include <sys/types.h>
744 #include <sys/socket.h>
745
746 main() {
747        int fd[2];
748        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
749 }],
750 rsync_cv_HAVE_SOCKETPAIR=yes,rsync_cv_HAVE_SOCKETPAIR=no,rsync_cv_HAVE_SOCKETPAIR=cross)])
751 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
752     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
753 fi
754
755 AC_REPLACE_FUNCS([getpass])
756
757 if test x"$with_included_popt" != x"yes"; then
758     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
759 fi
760 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
761     # If the system has /usr/include/popt/popt.h, we enable the
762     # included popt because an attempt to "#include <popt/popt.h>"
763     # would use our included header file anyway (due to -I.), and
764     # might conflict with the system popt.
765     with_included_popt=yes
766 elif test x"$ac_cv_header_popt_h" != x"yes"; then
767     with_included_popt=yes
768 fi
769
770 AC_MSG_CHECKING([whether to use included libpopt])
771 if test x"$with_included_popt" = x"yes"; then
772     AC_MSG_RESULT($srcdir/popt)
773     BUILD_POPT='$(popt_OBJS)'
774     CFLAGS="-I$srcdir/popt $CFLAGS"
775     if test x"$ALLOCA" != x
776     then
777         # this can be removed when/if we add an included alloca.c;
778         #  see autoconf documentation on AC_FUNC_ALLOCA
779         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
780     fi
781 else
782     AC_MSG_RESULT(no)
783 fi
784
785 # We default to using our zlib unless --with-included-zlib=no is given.
786 if test x"$with_included_zlib" != x"no"; then
787     with_included_zlib=yes
788 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
789     with_included_zlib=yes
790 fi
791 if test x"$with_included_zlib" != x"yes"; then
792     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
793 fi
794
795 AC_MSG_CHECKING([whether to use included zlib])
796 if test x"$with_included_zlib" = x"yes"; then
797     AC_MSG_RESULT($srcdir/zlib)
798     BUILD_ZLIB='$(zlib_OBJS)'
799     CFLAGS="-I$srcdir/zlib $CFLAGS"
800 else
801     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
802     AC_MSG_RESULT(no)
803 fi
804
805 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
806 AC_TRY_COMPILE([],[signed char *s = ""],
807 rsync_cv_SIGNED_CHAR_OK=yes,rsync_cv_SIGNED_CHAR_OK=no)])
808 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
809     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
810 fi
811
812 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
813 AC_TRY_RUN([#include <sys/types.h>
814 #include <dirent.h>
815 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
816 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
817 di->d_name[0] == 0) exit(0); exit(1);} ],
818 rsync_cv_HAVE_BROKEN_READDIR=yes,rsync_cv_HAVE_BROKEN_READDIR=no,rsync_cv_HAVE_BROKEN_READDIR=cross)])
819 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
820     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
821 fi
822
823 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
824 AC_TRY_COMPILE([#include <sys/types.h>
825 #include <utime.h>],
826 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
827 rsync_cv_HAVE_STRUCT_UTIMBUF=yes,rsync_cv_HAVE_STRUCT_UTIMBUF=no)])
828 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
829     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
830 fi
831
832 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
833 AC_TRY_COMPILE([#include <sys/time.h>
834 #include <unistd.h>],
835 [struct timeval tv; exit(gettimeofday(&tv, NULL));],
836 rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes,rsync_cv_HAVE_GETTIMEOFDAY_TZ=no)])
837 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
838     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
839 fi
840
841 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
842 AC_TRY_RUN([
843 #include <sys/types.h>
844 #include <stdarg.h>
845 void foo(const char *format, ...) {
846        va_list ap;
847        int len;
848        char buf[5];
849
850        va_start(ap, format);
851        len = vsnprintf(0, 0, format, ap);
852        va_end(ap);
853        if (len != 5) exit(1);
854
855        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
856
857        exit(0);
858 }
859 main() { foo("hello"); }
860 ],
861 rsync_cv_HAVE_C99_VSNPRINTF=yes,rsync_cv_HAVE_C99_VSNPRINTF=no,rsync_cv_HAVE_C99_VSNPRINTF=cross)])
862 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
863     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
864 fi
865
866
867 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
868 AC_TRY_RUN([#include <stdlib.h>
869 #include <sys/types.h>
870 #include <sys/stat.h>
871 #include <unistd.h>
872 main() {
873   struct stat st;
874   char tpl[20]="/tmp/test.XXXXXX";
875   int fd = mkstemp(tpl);
876   if (fd == -1) exit(1);
877   unlink(tpl);
878   if (fstat(fd, &st) != 0) exit(1);
879   if ((st.st_mode & 0777) != 0600) exit(1);
880   exit(0);
881 }],
882 rsync_cv_HAVE_SECURE_MKSTEMP=yes,
883 rsync_cv_HAVE_SECURE_MKSTEMP=no,
884 rsync_cv_HAVE_SECURE_MKSTEMP=cross)])
885 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
886     case $host_os in
887     hpux*)
888         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
889         dnl so we noisily skip using it.  See HP change request JAGaf34426
890         dnl for details. (sbonds)
891         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
892         ;;
893     *)
894         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
895         ;;
896     esac
897 fi
898
899
900 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
901 AC_TRY_RUN([
902 #include <stdio.h>
903 #include <sys/stat.h>
904 #include <errno.h>
905 main() { int rc, ec; char *fn = "fifo-test";
906 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
907 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
908 return 0;}],
909            rsync_cv_MKNOD_CREATES_FIFOS=yes,rsync_cv_MKNOD_CREATES_FIFOS=no,rsync_cv_MKNOD_CREATES_FIFOS=cross)])
910 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
911     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
912 fi
913
914 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
915 AC_TRY_RUN([
916 #include <stdio.h>
917 #include <sys/stat.h>
918 #include <errno.h>
919 main() { int rc, ec; char *fn = "sock-test";
920 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
921 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
922 return 0;}],
923            rsync_cv_MKNOD_CREATES_SOCKETS=yes,rsync_cv_MKNOD_CREATES_SOCKETS=no,rsync_cv_MKNOD_CREATES_SOCKETS=cross)])
924 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
925     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
926 fi
927
928 #
929 # The following test was mostly taken from the tcl/tk plus patches
930 #
931 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
932 rm -rf conftest*
933 cat > conftest.$ac_ext <<EOF
934 int main() { return 0; }
935 EOF
936 ${CC-cc} -c -o conftest..o conftest.$ac_ext
937 if test -f conftest..o; then
938     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
939 else
940     rsync_cv_DASHC_WORKS_WITH_DASHO=no
941 fi
942 rm -rf conftest*
943 ])
944 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
945     OBJ_SAVE="#"
946     OBJ_RESTORE="#"
947     CC_SHOBJ_FLAG='-o $@'
948 else
949     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
950     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
951     CC_SHOBJ_FLAG=""
952 fi
953
954 AC_SUBST(OBJ_SAVE)
955 AC_SUBST(OBJ_RESTORE)
956 AC_SUBST(CC_SHOBJ_FLAG)
957 AC_SUBST(BUILD_POPT)
958 AC_SUBST(BUILD_ZLIB)
959 AC_SUBST(MAKE_MAN)
960
961 AC_PATH_PROG([STUNNEL], [stunnel], [stunnel], [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
962 AC_PATH_PROG([STUNNEL4], [stunnel4], [$STUNNEL], [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
963
964 AC_CHECK_FUNCS(_acl __acl _facl __facl)
965 #################################################
966 # check for ACL support
967
968 AC_MSG_CHECKING([whether to support ACLs])
969 AC_ARG_ENABLE(acl-support,
970         AC_HELP_STRING([--disable-acl-support],
971                        [disable ACL support]))
972
973 if test x"$enable_acl_support" = x"no"; then
974     AC_MSG_RESULT(no)
975 else
976     case "$host_os" in
977     *sysv5*)
978         AC_MSG_RESULT(Using UnixWare ACLs)
979         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
980         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
981         ;;
982     solaris*|*cygwin*)
983         AC_MSG_RESULT(Using solaris ACLs)
984         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
985         AC_DEFINE(SUPPORT_ACLS, 1)
986         ;;
987     *hpux*)
988         AC_MSG_RESULT(Using HPUX ACLs)
989         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
990         AC_DEFINE(SUPPORT_ACLS, 1)
991         ;;
992     *irix*)
993         AC_MSG_RESULT(Using IRIX ACLs)
994         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
995         AC_DEFINE(SUPPORT_ACLS, 1)
996         ;;
997     *aix*)
998         AC_MSG_RESULT(Using AIX ACLs)
999         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1000         AC_DEFINE(SUPPORT_ACLS, 1)
1001         ;;
1002     *osf*)
1003         AC_MSG_RESULT(Using Tru64 ACLs)
1004         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1005         AC_DEFINE(SUPPORT_ACLS, 1)
1006         LIBS="$LIBS -lpacl"
1007         ;;
1008     darwin*)
1009         AC_MSG_RESULT(Using OS X ACLs)
1010         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1011         AC_DEFINE(SUPPORT_ACLS, 1)
1012         ;;
1013     *)
1014         AC_MSG_RESULT(running tests:)
1015         AC_CHECK_LIB(acl,acl_get_file)
1016         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1017             AC_TRY_LINK([#include <sys/types.h>
1018 #include <sys/acl.h>],
1019 [ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);],
1020 samba_cv_HAVE_POSIX_ACLS=yes,samba_cv_HAVE_POSIX_ACLS=no)])
1021         AC_MSG_CHECKING(ACL test results)
1022         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1023             AC_MSG_RESULT(Using posix ACLs)
1024             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1025             AC_DEFINE(SUPPORT_ACLS, 1)
1026             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1027                 AC_TRY_LINK([#include <sys/types.h>
1028 #include <sys/acl.h>],
1029 [ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);],
1030 samba_cv_HAVE_ACL_GET_PERM_NP=yes,samba_cv_HAVE_ACL_GET_PERM_NP=no)])
1031             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1032                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1033             fi
1034         else
1035             if test x"$enable_acl_support" = x"yes"; then
1036                 AC_MSG_ERROR(Failed to find ACL support)
1037             else
1038                 AC_MSG_RESULT(No ACL support found)
1039             fi
1040         fi
1041         ;;
1042     esac
1043 fi
1044
1045 #################################################
1046 # check for extended attribute support
1047 AC_MSG_CHECKING(whether to support extended attributes)
1048 AC_ARG_ENABLE(xattr-support,
1049     AC_HELP_STRING([--disable-xattr-support],
1050             [disable extended attributes]),
1051     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1052         *yes*) enable_xattr_support=maybe ;;
1053         *) enable_xattr_support=no ;;
1054         esac])
1055 AH_TEMPLATE([SUPPORT_XATTRS],
1056 [Define to 1 to add support for extended attributes])
1057 if test x"$enable_xattr_support" = x"no"; then
1058     AC_MSG_RESULT(no)
1059 else
1060     case "$host_os" in
1061     *linux*)
1062         AC_MSG_RESULT(Using Linux xattrs)
1063         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs])
1064         AC_DEFINE(SUPPORT_XATTRS, 1)
1065         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1066         AC_CHECK_LIB(attr,getxattr)
1067         ;;
1068     darwin*)
1069         AC_MSG_RESULT(Using OS X xattrs)
1070         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1071         AC_DEFINE(SUPPORT_XATTRS, 1)
1072         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1073         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1074         ;;
1075     freebsd*)
1076         AC_MSG_RESULT(Using FreeBSD extattrs)
1077         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1078         AC_DEFINE(SUPPORT_XATTRS, 1)
1079         ;;
1080     solaris*)
1081         AC_MSG_RESULT(Using Solaris xattrs)
1082         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1083         AC_DEFINE(SUPPORT_XATTRS, 1)
1084         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1085         ;;
1086     *)
1087         if test x"$enable_xattr_support" = x"yes"; then
1088             AC_MSG_ERROR(Failed to find extended attribute support)
1089         else
1090             AC_MSG_RESULT(No extended attribute support found)
1091         fi
1092         ;;
1093     esac
1094 fi
1095
1096 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1097     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1098     OLD_CFLAGS="$CFLAGS"
1099     CFLAGS="$CFLAGS -Wno-unused-parameter"
1100     AC_TRY_LINK([#include <stdio.h>], [printf("hello\n");], [rsync_warn_flag=yes], [rsync_warn_flag=no])
1101     AC_MSG_RESULT([$rsync_warn_flag])
1102     if test x"$rsync_warn_flag" = x"no"; then
1103         CFLAGS="$OLD_CFLAGS"
1104     fi
1105 fi
1106
1107 case "$CC" in
1108 ' checker'*|checker*)
1109     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1110     ;;
1111 esac
1112
1113 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1114 AC_OUTPUT
1115
1116 AC_MSG_RESULT()
1117 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1118 AC_MSG_RESULT()
1119 if test x$HAVE_YODL2MAN != x1; then
1120     AC_MSG_RESULT([    Note that yodl2man was not found, so pre-existing manpage files will be])
1121     AC_MSG_RESULT([    used w/o change (if available) -- no .yo file changes will be used.])
1122     AC_MSG_RESULT()
1123 fi