configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT([rsync],[3.1.4dev],[http://rsync.samba.org/bugzilla.html])
   4
   5 AC_CONFIG_MACRO_DIR([m4])
   6 AC_CONFIG_SRCDIR([byteorder.h])
   7 AC_CONFIG_HEADER(config.h)
   8 AC_PREREQ([2.69])
   9
  10 AC_SUBST(RSYNC_VERSION, $PACKAGE_VERSION)
  11 AC_MSG_NOTICE([Configuring rsync $PACKAGE_VERSION])
  12
  13 AC_DEFINE_UNQUOTED(RSYNC_VERSION, ["$PACKAGE_VERSION"], [rsync release version])
  14
  15 LDFLAGS=${LDFLAGS-""}
  16
  17 AC_CANONICAL_HOST
  18
  19 dnl define the directory for replacement function since AC_LIBOBJ does not
  20 dnl officially support subdirs and fails with automake
  21 AC_CONFIG_LIBOBJ_DIR([lib])
  22
  23 # We must decide this before testing the compiler.
  24
  25 # Please allow this to default to yes, so that your users have more
  26 # chance of getting a useful stack trace if problems occur.
  27
  28 AC_MSG_CHECKING([whether to include debugging symbols])
  29 AC_ARG_ENABLE(debug,
  30         AS_HELP_STRING([--disable-debug],[disable debugging symbols and features]))
  31
  32 if test x"$enable_debug" = x"no"; then
  33     AC_MSG_RESULT(no)
  34     ac_cv_prog_cc_g=no
  35 else
  36     AC_MSG_RESULT([yes])
  37     dnl AC_DEFINE(DEBUG, 1, [Define to turn on debugging code that may slow normal operation])
  38     # leave ac_cv_prog_cc_g alone; AC_PROG_CC will try to include -g if it can
  39 fi
  40
  41 dnl Checks for programs.
  42 AC_PROG_CC
  43 AC_PROG_CPP
  44 AC_PROG_EGREP
  45 AC_PROG_INSTALL
  46 AC_PROG_MKDIR_P
  47 AC_PROG_CC_STDC
  48 AC_SUBST(SHELL)
  49 AC_PATH_PROG([PERL], [perl])
  50
  51 AC_DEFINE([_GNU_SOURCE], 1,
  52           [Define _GNU_SOURCE so that we get all necessary prototypes])
  53
  54 if test x"$ac_cv_prog_cc_stdc" = x"no"; then
  55         AC_MSG_WARN([rsync requires an ANSI C compiler and you do not seem to have one])
  56 fi
  57
  58 AC_ARG_ENABLE(profile,
  59         AS_HELP_STRING([--enable-profile],[turn on CPU profiling]))
  60 if test x"$enable_profile" = x"yes"; then
  61         CFLAGS="$CFLAGS -pg"
  62 fi
  63
  64
  65 # Specifically, this turns on panic_action handling.
  66 AC_ARG_ENABLE(maintainer-mode,
  67         AS_HELP_STRING([--enable-maintainer-mode],[turn on extra debug features]))
  68 if test x"$enable_maintainer_mode" = x"yes"; then
  69         CFLAGS="$CFLAGS -DMAINTAINER_MODE"
  70 fi
  71
  72
  73 # This is needed for our included version of popt.  Kind of silly, but
  74 # I don't want our version too far out of sync.
  75 CFLAGS="$CFLAGS -DHAVE_CONFIG_H"
  76
  77 # If GCC, turn on warnings.
  78 if test x"$GCC" = x"yes"; then
  79         CFLAGS="$CFLAGS -Wall -W"
  80 fi
  81
  82 AC_ARG_WITH(included-popt,
  83         AS_HELP_STRING([--with-included-popt],[use bundled popt library, not from system]))
  84
  85 AC_ARG_WITH(included-zlib,
  86         AS_HELP_STRING([--with-included-zlib],[use bundled zlib library, not from system]))
  87
  88 AC_ARG_WITH(protected-args,
  89         AS_HELP_STRING([--with-protected-args],[make --protected-args option the default]))
  90 if test x"$with_protected_args" = x"yes"; then
  91         AC_DEFINE_UNQUOTED(RSYNC_USE_PROTECTED_ARGS, 1, [Define to 1 if --protected-args should be the default])
  92 fi
  93
  94 AC_ARG_WITH(rsync-path,
  95         AS_HELP_STRING([--with-rsync-path=PATH],[set default --rsync-path to PATH (default: rsync)]),
  96         [ RSYNC_PATH="$with_rsync_path" ],
  97         [ RSYNC_PATH="rsync" ])
  98
  99 AC_DEFINE_UNQUOTED(RSYNC_PATH, "$RSYNC_PATH", [location of rsync on remote machine])
 100
 101 AC_ARG_WITH(rsyncd-conf,
 102         AS_HELP_STRING([--with-rsyncd-conf=PATH],[set configuration file for rsync server to PATH (default: /etc/rsyncd.conf)]),
 103         [ if test ! -z "$with_rsyncd_conf" ; then
 104                 case $with_rsyncd_conf in
 105                         yes|no)
 106                                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 107                                 ;;
 108                         /*)
 109                                 RSYNCD_SYSCONF="$with_rsyncd_conf"
 110                                 ;;
 111                         *)
 112                                 AC_MSG_ERROR(You must specify an absolute path to --with-rsyncd-conf=PATH)
 113                                 ;;
 114                 esac
 115         else
 116                 RSYNCD_SYSCONF="/etc/rsyncd.conf"
 117         fi ],
 118         [ RSYNCD_SYSCONF="/etc/rsyncd.conf" ])
 119
 120 AC_DEFINE_UNQUOTED(RSYNCD_SYSCONF, "$RSYNCD_SYSCONF", [location of configuration file for rsync server])
 121
 122 AC_ARG_WITH(rsh,
 123         AS_HELP_STRING([--with-rsh=CMD],[set remote shell command to CMD (default: ssh)]))
 124
 125 AC_CHECK_PROG(HAVE_REMSH, remsh, 1, 0)
 126 if test x$HAVE_REMSH = x1; then
 127         AC_DEFINE(HAVE_REMSH, 1, [Define to 1 if remote shell is remsh, not rsh])
 128 fi
 129
 130 if test x"$with_rsh" != x; then
 131         RSYNC_RSH="$with_rsh"
 132 else
 133         RSYNC_RSH="ssh"
 134 fi
 135 AC_DEFINE_UNQUOTED(RSYNC_RSH, "$RSYNC_RSH", [default -e command])
 136
 137 AC_CHECK_PROG(HAVE_YODL2MAN, yodl2man, 1, 0)
 138 if test x$HAVE_YODL2MAN = x1; then
 139     MAKE_MAN=man
 140 else
 141     MAKE_MAN=man-copy
 142 fi
 143
 144 # Some programs on solaris are only found in /usr/xpg4/bin (or work better than others versions).
 145 AC_PATH_PROG(SHELL_PATH, sh, /bin/sh, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 146 AC_PATH_PROG(FAKEROOT_PATH, fakeroot, /usr/bin/fakeroot, [/usr/xpg4/bin$PATH_SEPARATOR$PATH])
 147
 148 AC_ARG_WITH(nobody-group,
 149     AS_HELP_STRING([--with-nobody-group=GROUP],[set the default unprivileged group (default nobody or nogroup)]),
 150     [ NOBODY_GROUP="$with_nobody_group" ])
 151
 152 if test x"$with_nobody_group" = x; then
 153     AC_MSG_CHECKING([the group for user "nobody"])
 154     if grep '^nobody:' /etc/group >/dev/null 2>&1; then
 155         NOBODY_GROUP=nobody
 156     elif grep '^nogroup:' /etc/group >/dev/null 2>&1; then
 157         NOBODY_GROUP=nogroup
 158     else
 159         NOBODY_GROUP=nobody # test for others?
 160     fi
 161     AC_MSG_RESULT($NOBODY_GROUP)
 162 fi
 163
 164 AC_DEFINE_UNQUOTED(NOBODY_USER, "nobody", [unprivileged user--e.g. nobody])
 165 AC_DEFINE_UNQUOTED(NOBODY_GROUP, "$NOBODY_GROUP", [unprivileged group for unprivileged user])
 166
 167 # arrgh. libc in some old debian version screwed up the largefile
 168 # stuff, getting byte range locking wrong
 169 AC_CACHE_CHECK([for broken largefile support],rsync_cv_HAVE_BROKEN_LARGEFILE,[
 170 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 171 #define _FILE_OFFSET_BITS 64
 172 #include <stdio.h>
 173 #include <fcntl.h>
 174 #include <sys/types.h>
 175 #include <sys/wait.h>
 176
 177 int main(void)
 178 {
 179         struct flock lock;
 180         int status;
 181         char tpl[32] = "/tmp/locktest.XXXXXX";
 182         int fd = mkstemp(tpl);
 183         if (fd < 0) {
 184                 strcpy(tpl, "conftest.dat");
 185                 fd = open(tpl, O_CREAT|O_RDWR, 0600);
 186         }
 187
 188         lock.l_type = F_WRLCK;
 189         lock.l_whence = SEEK_SET;
 190         lock.l_start = 0;
 191         lock.l_len = 1;
 192         lock.l_pid = 0;
 193         fcntl(fd,F_SETLK,&lock);
 194         if (fork() == 0) {
 195                 lock.l_start = 1;
 196                 _exit(fcntl(fd,F_SETLK,&lock) == 0);
 197         }
 198         wait(&status);
 199         unlink(tpl);
 200         exit(WEXITSTATUS(status));
 201 }
 202 ]])],[rsync_cv_HAVE_BROKEN_LARGEFILE=yes],[rsync_cv_HAVE_BROKEN_LARGEFILE=no],[rsync_cv_HAVE_BROKEN_LARGEFILE=cross])])
 203 if test x"$rsync_cv_HAVE_BROKEN_LARGEFILE" != x"yes"; then
 204    AC_SYS_LARGEFILE
 205 fi
 206
 207 ipv6type=unknown
 208 ipv6lib=none
 209 ipv6trylibc=yes
 210
 211 AC_ARG_ENABLE(ipv6,
 212         AS_HELP_STRING([--disable-ipv6],[do not even try to use IPv6]))
 213 if test x"$enable_ipv6" != x"no"; then
 214         AC_MSG_CHECKING([ipv6 stack type])
 215         for i in inria kame linux-glibc linux-inet6 solaris toshiba v6d zeta cygwin; do
 216                 case $i in
 217                 inria)
 218                         # http://www.kame.net/
 219                         AC_EGREP_CPP(yes, [
 220 #include <netinet/in.h>
 221 #ifdef IPV6_INRIA_VERSION
 222 yes
 223 #endif],
 224                                 [ipv6type=$i;
 225                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 226                                 ])
 227                         ;;
 228                 kame)
 229                         # http://www.kame.net/
 230                         AC_EGREP_CPP(yes, [
 231 #include <netinet/in.h>
 232 #ifdef __KAME__
 233 yes
 234 #endif],
 235                                 [ipv6type=$i;
 236                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 237                         ;;
 238                 linux-glibc)
 239                         # http://www.v6.linux.or.jp/
 240                         AC_EGREP_CPP(yes, [
 241 #include <features.h>
 242 #if defined(__GLIBC__) && __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
 243 yes
 244 #endif],
 245                                 [ipv6type=$i;
 246 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 247                         ;;
 248                 linux-inet6)
 249                         # http://www.v6.linux.or.jp/
 250                         if test -d /usr/inet6 -o -f /usr/inet6/lib/libinet6.a; then
 251                                 ipv6type=$i
 252                                 ipv6lib=inet6
 253                                 ipv6libdir=/usr/inet6/lib
 254                                 ipv6trylibc=yes;
 255                                 AC_DEFINE(INET6, 1, [true if you have IPv6])
 256                                 CFLAGS="-I/usr/inet6/include $CFLAGS"
 257                         fi
 258                         ;;
 259                 solaris)
 260                         # http://www.sun.com
 261                         AC_EGREP_CPP(yes, [
 262 #include <netinet/ip6.h>
 263 #ifdef __sun
 264 yes
 265 #endif],
 266                                 [ipv6type=$i;
 267                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 268                         ;;
 269                 toshiba)
 270                         AC_EGREP_CPP(yes, [
 271 #include <sys/param.h>
 272 #ifdef _TOSHIBA_INET6
 273 yes
 274 #endif],
 275                                 [ipv6type=$i;
 276                                 ipv6lib=inet6;
 277                                 ipv6libdir=/usr/local/v6/lib;
 278                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 279                         ;;
 280                 v6d)
 281                         AC_EGREP_CPP(yes, [
 282 #include </usr/local/v6/include/sys/v6config.h>
 283 #ifdef __V6D__
 284 yes
 285 #endif],
 286                                 [ipv6type=$i;
 287                                 ipv6lib=v6;
 288                                 ipv6libdir=/usr/local/v6/lib;
 289                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 290                         ;;
 291                 zeta)
 292                         AC_EGREP_CPP(yes, [
 293 #include <sys/param.h>
 294 #ifdef _ZETA_MINAMI_INET6
 295 yes
 296 #endif],
 297                                 [ipv6type=$i;
 298                                 ipv6lib=inet6;
 299                                 ipv6libdir=/usr/local/v6/lib;
 300                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 301                         ;;
 302                 cygwin)
 303                         AC_EGREP_CPP(yes, [
 304 #include <netinet/in.h>
 305 #ifdef _CYGWIN_IN6_H
 306 yes
 307 #endif],
 308                                 [ipv6type=$i;
 309                                 AC_DEFINE(INET6, 1, [true if you have IPv6])])
 310                         ;;
 311                 esac
 312                 if test "$ipv6type" != "unknown"; then
 313                         break
 314                 fi
 315         done
 316         AC_MSG_RESULT($ipv6type)
 317
 318         AC_SEARCH_LIBS(getaddrinfo, inet6)
 319 fi
 320
 321 dnl Do you want to disable use of locale functions
 322 AC_ARG_ENABLE([locale],
 323         AS_HELP_STRING([--disable-locale],[disable locale features]))
 324 AH_TEMPLATE([CONFIG_LOCALE],
 325 [Undefine if you do not want locale features.  By default this is defined.])
 326 if test x"$enable_locale" != x"no"; then
 327         AC_DEFINE(CONFIG_LOCALE)
 328 fi
 329
 330 AC_MSG_CHECKING([whether to call shutdown on all sockets])
 331 case $host_os in
 332         *cygwin* ) AC_MSG_RESULT(yes)
 333                    AC_DEFINE(SHUTDOWN_ALL_SOCKETS, 1,
 334                             [Define to 1 if sockets need to be shutdown])
 335                    ;;
 336                * ) AC_MSG_RESULT(no);;
 337 esac
 338
 339 AC_C_BIGENDIAN
 340 AC_HEADER_DIRENT
 341 AC_HEADER_TIME
 342 AC_HEADER_SYS_WAIT
 343 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h \
 344     unistd.h utime.h grp.h compat.h sys/param.h ctype.h sys/wait.h \
 345     sys/ioctl.h sys/filio.h string.h stdlib.h sys/socket.h sys/mode.h \
 346     sys/un.h sys/attr.h mcheck.h arpa/inet.h arpa/nameser.h locale.h \
 347     netdb.h malloc.h float.h limits.h iconv.h libcharset.h langinfo.h \
 348     sys/acl.h acl/libacl.h attr/xattr.h sys/xattr.h sys/extattr.h \
 349     popt.h popt/popt.h linux/falloc.h netinet/in_systm.h netinet/ip.h \
 350     zlib.h)
 351 AC_HEADER_MAJOR
 352
 353 AC_CACHE_CHECK([if makedev takes 3 args],rsync_cv_MAKEDEV_TAKES_3_ARGS,[
 354 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 355 #include <sys/types.h>
 356 #ifdef MAJOR_IN_MKDEV
 357 #include <sys/mkdev.h>
 358 # if !defined makedev && (defined mkdev || defined _WIN32 || defined __WIN32__)
 359 #  define makedev mkdev
 360 # endif
 361 #elif defined MAJOR_IN_SYSMACROS
 362 #include <sys/sysmacros.h>
 363 #endif
 364
 365 int main(void)
 366 {
 367         dev_t dev = makedev(0, 5, 7);
 368         if (major(dev) != 5 || minor(dev) != 7)
 369                 exit(1);
 370         return 0;
 371 }
 372 ]])],[rsync_cv_MAKEDEV_TAKES_3_ARGS=yes],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no],[rsync_cv_MAKEDEV_TAKES_3_ARGS=no])])
 373 if test x"$rsync_cv_MAKEDEV_TAKES_3_ARGS" = x"yes"; then
 374    AC_DEFINE(MAKEDEV_TAKES_3_ARGS, 1, [Define to 1 if makedev() takes 3 args])
 375 fi
 376
 377 AC_CHECK_SIZEOF(int)
 378 AC_CHECK_SIZEOF(long)
 379 AC_CHECK_SIZEOF(long long)
 380 AC_CHECK_SIZEOF(short)
 381 AC_CHECK_SIZEOF(int16_t)
 382 AC_CHECK_SIZEOF(uint16_t)
 383 AC_CHECK_SIZEOF(int32_t)
 384 AC_CHECK_SIZEOF(uint32_t)
 385 AC_CHECK_SIZEOF(int64_t)
 386 AC_CHECK_SIZEOF(off_t)
 387 AC_CHECK_SIZEOF(off64_t)
 388 AC_CHECK_SIZEOF(time_t)
 389
 390 AC_C_INLINE
 391
 392 AC_TYPE_LONG_DOUBLE_WIDER
 393 ac_cv_c_long_double=$ac_cv_type_long_double_wider
 394 if test $ac_cv_c_long_double = yes; then
 395   AC_DEFINE([HAVE_LONG_DOUBLE],[1],[Define to 1 if the type `long double' works and has more range or precision than `double'.])
 396 fi
 397
 398 AC_TYPE_UID_T
 399 AC_CHECK_TYPES([mode_t,off_t,size_t,pid_t,id_t])
 400 AC_TYPE_GETGROUPS
 401 AC_CHECK_MEMBERS([struct stat.st_rdev,
 402                   struct stat.st_mtimensec,
 403                   struct stat.st_mtimespec.tv_nsec,
 404                   struct stat.st_mtim.tv_nsec],,,[
 405 #ifdef HAVE_SYS_TYPES_H
 406 #include <sys/types.h>
 407 #endif
 408 #ifdef HAVE_SYS_STAT_H
 409 #include <sys/stat.h>
 410 #endif
 411 #ifdef HAVE_UNISTD_H
 412 #include <unistd.h>
 413 #endif])
 414
 415 TYPE_SOCKLEN_T
 416
 417 AC_CACHE_CHECK([for errno in errno.h],rsync_cv_errno, [
 418     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]], [[int i = errno]])],[rsync_cv_errno=yes],[rsync_cv_have_errno_decl=no])])
 419 if test x"$rsync_cv_errno" = x"yes"; then
 420    AC_DEFINE(HAVE_ERRNO_DECL, 1, [Define to 1 if errno is declared in errno.h])
 421 fi
 422
 423 # The following test taken from the cvs sources
 424 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 425 # These need checks to be before checks for any other functions that
 426 #    might be in the same libraries.
 427 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 428 # libsocket.so which has a bad implementation of gethostbyname (it
 429 # only looks in /etc/hosts), so we only look for -lsocket if we need
 430 # it.
 431 AC_CHECK_FUNCS(connect)
 432 if test x"$ac_cv_func_connect" = x"no"; then
 433     case "$LIBS" in
 434     *-lnsl*) ;;
 435     *) AC_CHECK_LIB(nsl_s, printf) ;;
 436     esac
 437     case "$LIBS" in
 438     *-lnsl*) ;;
 439     *) AC_CHECK_LIB(nsl, printf) ;;
 440     esac
 441     case "$LIBS" in
 442     *-lsocket*) ;;
 443     *) AC_CHECK_LIB(socket, connect) ;;
 444     esac
 445     case "$LIBS" in
 446     *-linet*) ;;
 447     *) AC_CHECK_LIB(inet, connect) ;;
 448     esac
 449     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 450     dnl has been cached.
 451     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 452        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 453         # ac_cv_func_connect=yes
 454         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 455         AC_DEFINE(HAVE_CONNECT, 1, [Define to 1 if you have the "connect" function])
 456     fi
 457 fi
 458
 459 AC_SEARCH_LIBS(inet_ntop, resolv)
 460
 461 # For OS X, Solaris, HP-UX, etc.: figure out if -liconv is needed.  We'll
 462 # accept either iconv_open or libiconv_open, since some include files map
 463 # the former to the latter.
 464 AC_SEARCH_LIBS(iconv_open, iconv)
 465 AC_SEARCH_LIBS(libiconv_open, iconv)
 466
 467 AC_MSG_CHECKING([for iconv declaration])
 468 AC_CACHE_VAL(am_cv_proto_iconv, [
 469     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 470 #include <stdlib.h>
 471 #include <iconv.h>
 472 extern
 473 #ifdef __cplusplus
 474 "C"
 475 #endif
 476 #if defined(__STDC__) || defined(__cplusplus)
 477 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 478 #else
 479 size_t iconv();
 480 #endif
 481 ]], [[]])],[am_cv_proto_iconv_arg1=""],[am_cv_proto_iconv_arg1="const"])
 482       am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
 483     am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
 484 AC_MSG_RESULT([$]{ac_t:-
 485          }[$]am_cv_proto_iconv)
 486 AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1,
 487                    [Define as const if the declaration of iconv() needs const.])
 488
 489 dnl AC_MSG_NOTICE([Looking in libraries: $LIBS])
 490
 491 AC_REPLACE_FUNCS([inet_ntop inet_pton])
 492
 493 AC_HAVE_TYPE([struct addrinfo], [#include <netdb.h>])
 494 AC_HAVE_TYPE([struct sockaddr_storage], [#include <sys/types.h>
 495 #include <sys/socket.h>])
 496
 497 # Irix 6.5 has getaddrinfo but not the corresponding defines, so use
 498 #   builtin getaddrinfo if one of the defines don't exist
 499 AC_CACHE_CHECK([whether defines needed by getaddrinfo exist],
 500                rsync_cv_HAVE_GETADDR_DEFINES,[
 501                         AC_EGREP_CPP(yes, [
 502                         #include <sys/types.h>
 503                         #include <sys/socket.h>
 504                         #include <netdb.h>
 505                         #ifdef AI_PASSIVE
 506                         yes
 507                         #endif],
 508                         rsync_cv_HAVE_GETADDR_DEFINES=yes,
 509                         rsync_cv_HAVE_GETADDR_DEFINES=no)])
 510 AS_IF([test x"$rsync_cv_HAVE_GETADDR_DEFINES" = x"yes" -a x"$ac_cv_type_struct_addrinfo" = x"yes"],[
 511         # Tru64 UNIX has getaddrinfo() but has it renamed in libc as
 512         # something else so we must include <netdb.h> to get the
 513         # redefinition.
 514         AC_CHECK_FUNCS(getaddrinfo, ,
 515                 [AC_MSG_CHECKING([for getaddrinfo by including <netdb.h>])
 516                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 517                 #include <sys/socket.h>
 518                 #include <netdb.h>]], [[getaddrinfo(NULL, NULL, NULL, NULL);]])],[AC_MSG_RESULT([yes])
 519                         AC_DEFINE(HAVE_GETADDRINFO, 1,
 520                                 [Define to 1 if you have the "getaddrinfo" function and required types.])],[AC_MSG_RESULT([no])
 521                         AC_LIBOBJ([getaddrinfo])])])
 522     ],[AC_LIBOBJ([getaddrinfo])])
 523
 524 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 525                 [ AC_DEFINE(HAVE_SOCKADDR_LEN, 1, [Do we have sockaddr.sa_len?]) ],
 526                 [],
 527                 [
 528 #include <sys/types.h>
 529 #include <sys/socket.h>
 530 ])
 531
 532 AC_CHECK_MEMBER([struct sockaddr_in.sin_len],
 533                 [ AC_DEFINE(HAVE_SOCKADDR_IN_LEN, 1, [Do we have sockaddr_in.sin_len?]) ],
 534                 [],
 535                 [
 536 #include <sys/types.h>
 537 #include <sys/socket.h>
 538 #include <netinet/in.h>
 539 ])
 540
 541 AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
 542                 [ AC_DEFINE(HAVE_SOCKADDR_UN_LEN, 1, [Do we have sockaddr_un.sun_len?]) ],
 543                 [],
 544                 [
 545 #include <sys/types.h>
 546 #include <sys/socket.h>
 547 #include <netinet/in.h>
 548 ])
 549
 550 AC_CHECK_MEMBER([struct sockaddr_in6.sin6_scope_id],
 551                 [ AC_DEFINE(HAVE_SOCKADDR_IN6_SCOPE_ID, 1, [Do we have sockaddr_in6.sin6_scope_id?]) ],
 552                 [],
 553                 [
 554 #include <sys/types.h>
 555 #include <sys/socket.h>
 556 #include <netinet/in.h>
 557 ])
 558
 559 AC_HAVE_TYPE([struct stat64], [#include <stdio.h>
 560 #if HAVE_SYS_TYPES_H
 561 # include <sys/types.h>
 562 #endif
 563 #if HAVE_SYS_STAT_H
 564 # include <sys/stat.h>
 565 #endif
 566 #if STDC_HEADERS
 567 # include <stdlib.h>
 568 # include <stddef.h>
 569 #else
 570 # if HAVE_STDLIB_H
 571 #  include <stdlib.h>
 572 # endif
 573 #endif
 574 ])
 575
 576 # if we can't find strcasecmp, look in -lresolv (for Unixware at least)
 577 #
 578 AC_CHECK_FUNCS(strcasecmp)
 579 if test x"$ac_cv_func_strcasecmp" = x"no"; then
 580     AC_CHECK_LIB(resolv, strcasecmp)
 581 fi
 582
 583 AC_CHECK_FUNCS(aclsort)
 584 if test x"$ac_cv_func_aclsort" = x"no"; then
 585     AC_CHECK_LIB(sec, aclsort)
 586 fi
 587
 588 dnl At the moment we don't test for a broken memcmp(), because all we
 589 dnl need to do is test for equality, not comparison, and it seems that
 590 dnl every platform has a memcmp that can do at least that.
 591 dnl AC_FUNC_MEMCMP
 592
 593 AC_FUNC_UTIME_NULL
 594 AC_FUNC_ALLOCA
 595 AC_CHECK_FUNCS(waitpid wait4 getcwd strdup chown chmod lchmod mknod mkfifo \
 596     fchmod fstat ftruncate strchr readlink link utime utimes lutimes strftime \
 597     memmove lchown vsnprintf snprintf vasprintf asprintf setsid strpbrk \
 598     strlcat strlcpy strtol mallinfo getgroups setgroups geteuid getegid \
 599     setlocale setmode open64 lseek64 mkstemp64 mtrace va_copy __va_copy \
 600     seteuid strerror putenv iconv_open locale_charset nl_langinfo getxattr \
 601     extattr_get_link sigaction sigprocmask setattrlist getgrouplist \
 602     initgroups utimensat posix_fallocate attropen setvbuf usleep)
 603
 604 dnl cygwin iconv.h defines iconv_open as libiconv_open
 605 if test x"$ac_cv_func_iconv_open" != x"yes"; then
 606     AC_CHECK_FUNC(libiconv_open, [ac_cv_func_iconv_open=yes; AC_DEFINE(HAVE_ICONV_OPEN, 1)])
 607 fi
 608
 609 dnl Preallocation stuff (also fallocate, posix_fallocate function tests above):
 610
 611 AC_CACHE_CHECK([for useable fallocate],rsync_cv_have_fallocate,[
 612 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <fcntl.h>
 613 #include <sys/types.h>]], [[fallocate(0, 0, 0, 0);]])],[rsync_cv_have_fallocate=yes],[rsync_cv_have_fallocate=no])])
 614 if test x"$rsync_cv_have_fallocate" = x"yes"; then
 615     AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the fallocate function and it compiles and links without error])
 616 fi
 617
 618 AC_MSG_CHECKING([for FALLOC_FL_PUNCH_HOLE])
 619 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 620         #define _GNU_SOURCE 1
 621         #include <linux/falloc.h>
 622         #ifndef FALLOC_FL_PUNCH_HOLE
 623         #error FALLOC_FL_PUNCH_HOLE is missing
 624         #endif
 625     ]])], [
 626         AC_MSG_RESULT([yes])
 627         AC_DEFINE([HAVE_FALLOC_FL_PUNCH_HOLE], [1], [Define if FALLOC_FL_PUNCH_HOLE is available.])
 628     ], [
 629         AC_MSG_RESULT([no])
 630     ]
 631 )
 632
 633 AC_MSG_CHECKING([for FALLOC_FL_ZERO_RANGE])
 634 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 635         #define _GNU_SOURCE 1
 636         #include <linux/falloc.h>
 637         #ifndef FALLOC_FL_ZERO_RANGE
 638         #error FALLOC_FL_ZERO_RANGE is missing
 639         #endif
 640     ]])], [
 641         AC_MSG_RESULT([yes])
 642         AC_DEFINE([HAVE_FALLOC_FL_ZERO_RANGE], [1], [Define if FALLOC_FL_ZERO_RANGE is available.])
 643     ], [
 644         AC_MSG_RESULT([no])
 645     ]
 646 )
 647
 648 AC_CACHE_CHECK([for SYS_fallocate],rsync_cv_have_sys_fallocate,[
 649 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/syscall.h>
 650 #include <sys/types.h>]], [[syscall(SYS_fallocate, 0, 0, (loff_t)0, (loff_t)0);]])],[rsync_cv_have_sys_fallocate=yes],[rsync_cv_have_sys_fallocate=no])])
 651 if test x"$rsync_cv_have_sys_fallocate" = x"yes"; then
 652     AC_DEFINE(HAVE_SYS_FALLOCATE, 1, [Define to 1 if you have the SYS_fallocate syscall number])
 653 fi
 654
 655 if test x"$ac_cv_func_posix_fallocate" = x"yes"; then
 656     AC_MSG_CHECKING([whether posix_fallocate is efficient])
 657     case $host_os in
 658     *cygwin*)
 659         AC_MSG_RESULT(yes)
 660         AC_DEFINE(HAVE_EFFICIENT_POSIX_FALLOCATE, 1,
 661                   [Define if posix_fallocate is efficient (Cygwin)])
 662         ;;
 663     *)
 664         AC_MSG_RESULT(no)
 665         ;;
 666     esac
 667 fi
 668
 669 dnl End of preallocation stuff
 670
 671 AC_CHECK_FUNCS(getpgrp tcgetpgrp)
 672 if test $ac_cv_func_getpgrp = yes; then
 673     AC_FUNC_GETPGRP
 674 fi
 675
 676 AC_ARG_ENABLE(iconv-open,
 677     AS_HELP_STRING([--disable-iconv-open],[disable all use of iconv_open() function]),
 678     [], [enable_iconv_open=$ac_cv_func_iconv_open])
 679
 680 if test x"$enable_iconv_open" != x"no"; then
 681     AC_DEFINE(USE_ICONV_OPEN, 1, [Define to 1 if you want rsync to make use of iconv_open()])
 682 fi
 683
 684 AC_ARG_ENABLE(iconv,
 685     AS_HELP_STRING([--disable-iconv],[disable rsync's --iconv option]),
 686     [], [enable_iconv=$enable_iconv_open])
 687 AH_TEMPLATE([ICONV_OPTION],
 688 [Define if you want the --iconv option.  Specifing a value will set the
 689 default iconv setting (a NULL means no --iconv processing by default).])
 690 if test x"$enable_iconv" != x"no"; then
 691         if test x"$enable_iconv" = x"yes"; then
 692                 AC_DEFINE(ICONV_OPTION, NULL)
 693         else
 694                 AC_DEFINE_UNQUOTED(ICONV_OPTION, "$enable_iconv")
 695         fi
 696         AC_DEFINE(UTF8_CHARSET, "UTF-8", [String to pass to iconv() for the UTF-8 charset.])
 697 fi
 698
 699 AC_CACHE_CHECK([whether chown() modifies symlinks],rsync_cv_chown_modifies_symlink,[
 700   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 701 #if HAVE_UNISTD_H
 702 # include <unistd.h>
 703 #endif
 704 #include <stdlib.h>
 705 #include <errno.h>
 706     main() {
 707         char const *dangling_symlink = "conftest.dangle";
 708         unlink(dangling_symlink);
 709         if (symlink("conftest.no-such", dangling_symlink) < 0) abort();
 710         if (chown(dangling_symlink, getuid(), getgid()) < 0 && errno == ENOENT) exit(1);
 711         exit(0);
 712     }]])],[rsync_cv_chown_modifies_symlink=yes],[rsync_cv_chown_modifies_symlink=no],[rsync_cv_chown_modifies_symlink=no])])
 713 if test $rsync_cv_chown_modifies_symlink = yes; then
 714   AC_DEFINE(CHOWN_MODIFIES_SYMLINK, 1, [Define to 1 if chown modifies symlinks.])
 715 fi
 716
 717 AC_CACHE_CHECK([whether link() can hard-link symlinks],rsync_cv_can_hardlink_symlink,[
 718   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 719 #if HAVE_UNISTD_H
 720 # include <unistd.h>
 721 #endif
 722 #include <stdlib.h>
 723 #include <errno.h>
 724 #define FILENAME "conftest.dangle"
 725     main() {
 726         unlink(FILENAME);
 727         if (symlink("conftest.no-such", FILENAME) < 0) abort();
 728         unlink(FILENAME "2");
 729         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 730         exit(0);
 731     }]])],[rsync_cv_can_hardlink_symlink=yes],[rsync_cv_can_hardlink_symlink=no],[rsync_cv_can_hardlink_symlink=no])])
 732 if test $rsync_cv_can_hardlink_symlink = yes; then
 733   AC_DEFINE(CAN_HARDLINK_SYMLINK, 1, [Define to 1 if link() can hard-link symlinks.])
 734 fi
 735
 736 AC_CACHE_CHECK([whether link() can hard-link special files],rsync_cv_can_hardlink_special,[
 737   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 738 #if HAVE_UNISTD_H
 739 # include <unistd.h>
 740 #endif
 741 #include <stdlib.h>
 742 #include <errno.h>
 743 #define FILENAME "conftest.fifi"
 744     main() {
 745         unlink(FILENAME);
 746         if (mkfifo(FILENAME, 0777) < 0) abort();
 747         unlink(FILENAME "2");
 748         if (link(FILENAME, FILENAME "2") < 0) exit(1);
 749         exit(0);
 750     }]])],[rsync_cv_can_hardlink_special=yes],[rsync_cv_can_hardlink_special=no],[rsync_cv_can_hardlink_special=no])])
 751 if test $rsync_cv_can_hardlink_special = yes; then
 752     AC_DEFINE(CAN_HARDLINK_SPECIAL, 1, [Define to 1 if link() can hard-link special files.])
 753 fi
 754
 755 AC_CACHE_CHECK([for working socketpair],rsync_cv_HAVE_SOCKETPAIR,[
 756 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 757 #include <sys/types.h>
 758 #include <sys/socket.h>
 759
 760 main() {
 761        int fd[2];
 762        exit((socketpair(AF_UNIX, SOCK_STREAM, 0, fd) != -1) ? 0 : 1);
 763 }]])],[rsync_cv_HAVE_SOCKETPAIR=yes],[rsync_cv_HAVE_SOCKETPAIR=no],[rsync_cv_HAVE_SOCKETPAIR=cross])])
 764 if test x"$rsync_cv_HAVE_SOCKETPAIR" = x"yes"; then
 765     AC_DEFINE(HAVE_SOCKETPAIR, 1, [Define to 1 if you have the "socketpair" function])
 766 fi
 767
 768 AC_REPLACE_FUNCS([getpass])
 769
 770 if test x"$with_included_popt" != x"yes"; then
 771     AC_CHECK_LIB(popt, poptGetContext, , [with_included_popt=yes])
 772 fi
 773 if test x"$ac_cv_header_popt_popt_h" = x"yes"; then
 774     # If the system has /usr/include/popt/popt.h, we enable the
 775     # included popt because an attempt to "#include <popt/popt.h>"
 776     # would use our included header file anyway (due to -I.), and
 777     # might conflict with the system popt.
 778     with_included_popt=yes
 779 elif test x"$ac_cv_header_popt_h" != x"yes"; then
 780     with_included_popt=yes
 781 fi
 782
 783 AC_MSG_CHECKING([whether to use included libpopt])
 784 if test x"$with_included_popt" = x"yes"; then
 785     AC_MSG_RESULT($srcdir/popt)
 786     BUILD_POPT='$(popt_OBJS)'
 787     CFLAGS="-I$srcdir/popt $CFLAGS"
 788     if test x"$ALLOCA" != x
 789     then
 790         # this can be removed when/if we add an included alloca.c;
 791         #  see autoconf documentation on AC_FUNC_ALLOCA
 792         AC_MSG_WARN([included libpopt will use malloc, not alloca (which wastes a small amount of memory)])
 793     fi
 794 else
 795     AC_MSG_RESULT(no)
 796 fi
 797
 798 # We default to using our zlib unless --with-included-zlib=no is given.
 799 if test x"$with_included_zlib" != x"no"; then
 800     with_included_zlib=yes
 801 elif test x"$ac_cv_header_zlib_h" != x"yes"; then
 802     with_included_zlib=yes
 803 fi
 804 if test x"$with_included_zlib" != x"yes"; then
 805     AC_CHECK_LIB(z, deflateParams, , [with_included_zlib=yes])
 806 fi
 807
 808 AC_MSG_CHECKING([whether to use included zlib])
 809 if test x"$with_included_zlib" = x"yes"; then
 810     AC_MSG_RESULT($srcdir/zlib)
 811     BUILD_ZLIB='$(zlib_OBJS)'
 812     CFLAGS="-I$srcdir/zlib $CFLAGS"
 813 else
 814     AC_DEFINE(EXTERNAL_ZLIB, 1, [Define to 1 if using external zlib])
 815     AC_MSG_RESULT(no)
 816 fi
 817
 818 AC_CACHE_CHECK([for unsigned char],rsync_cv_SIGNED_CHAR_OK,[
 819 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[signed char *s = ""]])],[rsync_cv_SIGNED_CHAR_OK=yes],[rsync_cv_SIGNED_CHAR_OK=no])])
 820 if test x"$rsync_cv_SIGNED_CHAR_OK" = x"yes"; then
 821     AC_DEFINE(SIGNED_CHAR_OK, 1, [Define to 1 if "signed char" is a valid type])
 822 fi
 823
 824 AC_CACHE_CHECK([for broken readdir],rsync_cv_HAVE_BROKEN_READDIR,[
 825 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <sys/types.h>
 826 #include <dirent.h>
 827 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 828 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 829 di->d_name[0] == 0) exit(0); exit(1);} ]])],[rsync_cv_HAVE_BROKEN_READDIR=yes],[rsync_cv_HAVE_BROKEN_READDIR=no],[rsync_cv_HAVE_BROKEN_READDIR=cross])])
 830 if test x"$rsync_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 831     AC_DEFINE(HAVE_BROKEN_READDIR, 1, [Define to 1 if readdir() is broken])
 832 fi
 833
 834 AC_CACHE_CHECK([for utimbuf],rsync_cv_HAVE_STRUCT_UTIMBUF,[
 835 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 836 #include <utime.h>]], [[struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));]])],[rsync_cv_HAVE_STRUCT_UTIMBUF=yes],[rsync_cv_HAVE_STRUCT_UTIMBUF=no])])
 837 if test x"$rsync_cv_HAVE_STRUCT_UTIMBUF" = x"yes"; then
 838     AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if you have the "struct utimbuf" type])
 839 fi
 840
 841 AC_CACHE_CHECK([if gettimeofday takes tz argument],rsync_cv_HAVE_GETTIMEOFDAY_TZ,[
 842 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/time.h>
 843 #include <unistd.h>]], [[struct timeval tv; exit(gettimeofday(&tv, NULL));]])],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=yes],[rsync_cv_HAVE_GETTIMEOFDAY_TZ=no])])
 844 if test x"$rsync_cv_HAVE_GETTIMEOFDAY_TZ" != x"no"; then
 845     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ, 1, [Define to 1 if gettimeofday() takes a time-zone arg])
 846 fi
 847
 848 AC_CACHE_CHECK([for C99 vsnprintf],rsync_cv_HAVE_C99_VSNPRINTF,[
 849 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 850 #include <sys/types.h>
 851 #include <stdarg.h>
 852 void foo(const char *format, ...) {
 853        va_list ap;
 854        int len;
 855        char buf[5];
 856
 857        va_start(ap, format);
 858        len = vsnprintf(0, 0, format, ap);
 859        va_end(ap);
 860        if (len != 5) exit(1);
 861
 862        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 863
 864        exit(0);
 865 }
 866 main() { foo("hello"); }
 867 ]])],[rsync_cv_HAVE_C99_VSNPRINTF=yes],[rsync_cv_HAVE_C99_VSNPRINTF=no],[rsync_cv_HAVE_C99_VSNPRINTF=cross])])
 868 if test x"$rsync_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 869     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [Define to 1 if vsprintf has a C99-compatible return value])
 870 fi
 871
 872
 873 AC_CACHE_CHECK([for secure mkstemp],rsync_cv_HAVE_SECURE_MKSTEMP,[
 874 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 875 #include <sys/types.h>
 876 #include <sys/stat.h>
 877 #include <unistd.h>
 878 main() {
 879   struct stat st;
 880   char tpl[20]="/tmp/test.XXXXXX";
 881   int fd = mkstemp(tpl);
 882   if (fd == -1) exit(1);
 883   unlink(tpl);
 884   if (fstat(fd, &st) != 0) exit(1);
 885   if ((st.st_mode & 0777) != 0600) exit(1);
 886   exit(0);
 887 }]])],[rsync_cv_HAVE_SECURE_MKSTEMP=yes],[rsync_cv_HAVE_SECURE_MKSTEMP=no],[rsync_cv_HAVE_SECURE_MKSTEMP=cross])])
 888 if test x"$rsync_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
 889     case $host_os in
 890     hpux*)
 891         dnl HP-UX has a broken mkstemp() implementation they refuse to fix,
 892         dnl so we noisily skip using it.  See HP change request JAGaf34426
 893         dnl for details. (sbonds)
 894         AC_MSG_WARN(Skipping broken HP-UX mkstemp() -- using mktemp() instead)
 895         ;;
 896     *)
 897         AC_DEFINE(HAVE_SECURE_MKSTEMP, 1, [Define to 1 if mkstemp() is available and works right])
 898         ;;
 899     esac
 900 fi
 901
 902
 903 AC_CACHE_CHECK([if mknod creates FIFOs],rsync_cv_MKNOD_CREATES_FIFOS,[
 904 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 905 #include <stdio.h>
 906 #include <sys/stat.h>
 907 #include <errno.h>
 908 main() { int rc, ec; char *fn = "fifo-test";
 909 unlink(fn); rc = mknod(fn,S_IFIFO,0600); ec = errno; unlink(fn);
 910 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 911 return 0;}]])],[rsync_cv_MKNOD_CREATES_FIFOS=yes],[rsync_cv_MKNOD_CREATES_FIFOS=no],[rsync_cv_MKNOD_CREATES_FIFOS=cross])])
 912 if test x"$rsync_cv_MKNOD_CREATES_FIFOS" = x"yes"; then
 913     AC_DEFINE(MKNOD_CREATES_FIFOS, 1, [Define to 1 if mknod() can create FIFOs.])
 914 fi
 915
 916 AC_CACHE_CHECK([if mknod creates sockets],rsync_cv_MKNOD_CREATES_SOCKETS,[
 917 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 918 #include <stdio.h>
 919 #include <sys/stat.h>
 920 #include <errno.h>
 921 main() { int rc, ec; char *fn = "sock-test";
 922 unlink(fn); rc = mknod(fn,S_IFSOCK,0600); ec = errno; unlink(fn);
 923 if (rc) {printf("(%d %d) ",rc,ec); return ec;}
 924 return 0;}]])],[rsync_cv_MKNOD_CREATES_SOCKETS=yes],[rsync_cv_MKNOD_CREATES_SOCKETS=no],[rsync_cv_MKNOD_CREATES_SOCKETS=cross])])
 925 if test x"$rsync_cv_MKNOD_CREATES_SOCKETS" = x"yes"; then
 926     AC_DEFINE(MKNOD_CREATES_SOCKETS, 1, [Define to 1 if mknod() can create sockets.])
 927 fi
 928
 929 #
 930 # The following test was mostly taken from the tcl/tk plus patches
 931 #
 932 AC_CACHE_CHECK([whether -c -o works],rsync_cv_DASHC_WORKS_WITH_DASHO,[
 933 rm -rf conftest*
 934 cat > conftest.$ac_ext <<EOF
 935 int main() { return 0; }
 936 EOF
 937 ${CC-cc} -c -o conftest..o conftest.$ac_ext
 938 if test -f conftest..o; then
 939     rsync_cv_DASHC_WORKS_WITH_DASHO=yes
 940 else
 941     rsync_cv_DASHC_WORKS_WITH_DASHO=no
 942 fi
 943 rm -rf conftest*
 944 ])
 945 if test x"$rsync_cv_DASHC_WORKS_WITH_DASHO" = x"yes"; then
 946     OBJ_SAVE="#"
 947     OBJ_RESTORE="#"
 948     CC_SHOBJ_FLAG='-o $@'
 949 else
 950     OBJ_SAVE='  @b=`basename $@ .o`;rm -f $$b.o.sav;if test -f $$b.o; then mv $$b.o $$b.o.sav;fi;'
 951     OBJ_RESTORE='       @b=`basename $@ .o`;if test "$$b.o" != "$@"; then mv $$b.o $@; if test -f $$b.o.sav; then mv $$b.o.sav $$b.o; fi; fi'
 952     CC_SHOBJ_FLAG=""
 953 fi
 954
 955 AC_SUBST(OBJ_SAVE)
 956 AC_SUBST(OBJ_RESTORE)
 957 AC_SUBST(CC_SHOBJ_FLAG)
 958 AC_SUBST(BUILD_POPT)
 959 AC_SUBST(BUILD_ZLIB)
 960 AC_SUBST(MAKE_MAN)
 961
 962 AC_PATH_PROG([STUNNEL], [stunnel], [stunnel], [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 963 AC_PATH_PROG([STUNNEL4], [stunnel4], [$STUNNEL], [$PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin])
 964
 965 AC_CHECK_FUNCS(_acl __acl _facl __facl)
 966 #################################################
 967 # check for ACL support
 968
 969 AC_MSG_CHECKING([whether to support ACLs])
 970 AC_ARG_ENABLE(acl-support,
 971         AS_HELP_STRING([--disable-acl-support],[disable ACL support]))
 972
 973 if test x"$enable_acl_support" = x"no"; then
 974     AC_MSG_RESULT(no)
 975 else
 976     case "$host_os" in
 977     *sysv5*)
 978         AC_MSG_RESULT(Using UnixWare ACLs)
 979         AC_DEFINE(HAVE_UNIXWARE_ACLS, 1, [true if you have UnixWare ACLs])
 980         AC_DEFINE(SUPPORT_ACLS, 1, [Define to 1 to add support for ACLs])
 981         ;;
 982     solaris*)
 983         AC_MSG_RESULT(Using solaris ACLs)
 984         AC_DEFINE(HAVE_SOLARIS_ACLS, 1, [true if you have solaris ACLs])
 985         AC_DEFINE(SUPPORT_ACLS, 1)
 986         ;;
 987     *hpux*)
 988         AC_MSG_RESULT(Using HPUX ACLs)
 989         AC_DEFINE(HAVE_HPUX_ACLS, 1, [true if you have HPUX ACLs])
 990         AC_DEFINE(SUPPORT_ACLS, 1)
 991         ;;
 992     *irix*)
 993         AC_MSG_RESULT(Using IRIX ACLs)
 994         AC_DEFINE(HAVE_IRIX_ACLS, 1, [true if you have IRIX ACLs])
 995         AC_DEFINE(SUPPORT_ACLS, 1)
 996         ;;
 997     *aix*)
 998         AC_MSG_RESULT(Using AIX ACLs)
 999         AC_DEFINE(HAVE_AIX_ACLS, 1, [true if you have AIX ACLs])
1000         AC_DEFINE(SUPPORT_ACLS, 1)
1001         ;;
1002     *osf*)
1003         AC_MSG_RESULT(Using Tru64 ACLs)
1004         AC_DEFINE(HAVE_TRU64_ACLS, 1, [true if you have Tru64 ACLs])
1005         AC_DEFINE(SUPPORT_ACLS, 1)
1006         LIBS="$LIBS -lpacl"
1007         ;;
1008     darwin*)
1009         AC_MSG_RESULT(Using OS X ACLs)
1010         AC_DEFINE(HAVE_OSX_ACLS, 1, [true if you have Mac OS X ACLs])
1011         AC_DEFINE(SUPPORT_ACLS, 1)
1012         ;;
1013     *)
1014         AC_MSG_RESULT(running tests:)
1015         AC_CHECK_LIB(acl,acl_get_file)
1016         AC_CACHE_CHECK([for ACL support],samba_cv_HAVE_POSIX_ACLS,[
1017             AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1018 #include <sys/acl.h>]], [[ acl_t acl; int entry_id; acl_entry_t *entry_p; return acl_get_entry( acl, entry_id, entry_p);]])],[samba_cv_HAVE_POSIX_ACLS=yes],[samba_cv_HAVE_POSIX_ACLS=no])])
1019         AC_MSG_CHECKING(ACL test results)
1020         if test x"$samba_cv_HAVE_POSIX_ACLS" = x"yes"; then
1021             AC_MSG_RESULT(Using posix ACLs)
1022             AC_DEFINE(HAVE_POSIX_ACLS, 1, [true if you have posix ACLs])
1023             AC_DEFINE(SUPPORT_ACLS, 1)
1024             AC_CACHE_CHECK([for acl_get_perm_np],samba_cv_HAVE_ACL_GET_PERM_NP,[
1025                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1026 #include <sys/acl.h>]], [[ acl_permset_t permset_d; acl_perm_t perm; return acl_get_perm_np( permset_d, perm);]])],[samba_cv_HAVE_ACL_GET_PERM_NP=yes],[samba_cv_HAVE_ACL_GET_PERM_NP=no])])
1027             if test x"$samba_cv_HAVE_ACL_GET_PERM_NP" = x"yes"; then
1028                 AC_DEFINE(HAVE_ACL_GET_PERM_NP, 1, [true if you have acl_get_perm_np])
1029             fi
1030         else
1031             if test x"$enable_acl_support" = x"yes"; then
1032                 AC_MSG_ERROR(Failed to find ACL support)
1033             else
1034                 AC_MSG_RESULT(No ACL support found)
1035             fi
1036         fi
1037         ;;
1038     esac
1039 fi
1040
1041 #################################################
1042 # check for extended attribute support
1043 AC_MSG_CHECKING(whether to support extended attributes)
1044 AC_ARG_ENABLE(xattr-support,
1045     AS_HELP_STRING([--disable-xattr-support],[disable extended attributes]),
1046     [], [case "$ac_cv_func_getxattr$ac_cv_func_extattr_get_link$ac_cv_func_attropen" in
1047         *yes*) enable_xattr_support=maybe ;;
1048         *) enable_xattr_support=no ;;
1049         esac])
1050 AH_TEMPLATE([SUPPORT_XATTRS],
1051 [Define to 1 to add support for extended attributes])
1052 if test x"$enable_xattr_support" = x"no"; then
1053     AC_MSG_RESULT(no)
1054 else
1055     case "$host_os" in
1056     *linux*|*netbsd*)
1057         AC_MSG_RESULT(Using Linux xattrs)
1058         AC_DEFINE(HAVE_LINUX_XATTRS, 1, [True if you have Linux xattrs (or equivalent)])
1059         AC_DEFINE(SUPPORT_XATTRS, 1)
1060         AC_DEFINE(NO_SYMLINK_USER_XATTRS, 1, [True if symlinks do not support user xattrs])
1061         AC_CHECK_LIB(attr,getxattr)
1062         ;;
1063     darwin*)
1064         AC_MSG_RESULT(Using OS X xattrs)
1065         AC_DEFINE(HAVE_OSX_XATTRS, 1, [True if you have Mac OS X xattrs])
1066         AC_DEFINE(SUPPORT_XATTRS, 1)
1067         AC_DEFINE(NO_DEVICE_XATTRS, 1, [True if device files do not support xattrs])
1068         AC_DEFINE(NO_SPECIAL_XATTRS, 1, [True if special files do not support xattrs])
1069         ;;
1070     freebsd*)
1071         AC_MSG_RESULT(Using FreeBSD extattrs)
1072         AC_DEFINE(HAVE_FREEBSD_XATTRS, 1, [True if you have FreeBSD xattrs])
1073         AC_DEFINE(SUPPORT_XATTRS, 1)
1074         ;;
1075     solaris*)
1076         AC_MSG_RESULT(Using Solaris xattrs)
1077         AC_DEFINE(HAVE_SOLARIS_XATTRS, 1, [True if you have Solaris xattrs])
1078         AC_DEFINE(SUPPORT_XATTRS, 1)
1079         AC_DEFINE(NO_SYMLINK_XATTRS, 1, [True if symlinks do not support xattrs])
1080         ;;
1081     *)
1082         if test x"$enable_xattr_support" = x"yes"; then
1083             AC_MSG_ERROR(Failed to find extended attribute support)
1084         else
1085             AC_MSG_RESULT(No extended attribute support found)
1086         fi
1087         ;;
1088     esac
1089 fi
1090
1091 if test x"$enable_acl_support" = x"no" -o x"$enable_xattr_support" = x"no" -o x"$enable_iconv" = x"no"; then
1092     AC_MSG_CHECKING([whether $CC supports -Wno-unused-parameter])
1093     OLD_CFLAGS="$CFLAGS"
1094     CFLAGS="$CFLAGS -Wno-unused-parameter"
1095     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>]], [[printf("hello\n");]])],[rsync_warn_flag=yes],[rsync_warn_flag=no])
1096     AC_MSG_RESULT([$rsync_warn_flag])
1097     if test x"$rsync_warn_flag" = x"no"; then
1098         CFLAGS="$OLD_CFLAGS"
1099     fi
1100 fi
1101
1102 case "$CC" in
1103 ' checker'*|checker*)
1104     AC_DEFINE(FORCE_FD_ZERO_MEMSET, 1, [Used to make "checker" understand that FD_ZERO() clears memory.])
1105     ;;
1106 esac
1107
1108 AC_CONFIG_FILES([Makefile lib/dummy zlib/dummy popt/dummy shconfig])
1109 AC_OUTPUT
1110
1111 AC_MSG_RESULT()
1112 AC_MSG_RESULT([    rsync ${RSYNC_VERSION} configuration successful])
1113 AC_MSG_RESULT()
1114 if test x$HAVE_YODL2MAN != x1; then
1115     AC_MSG_RESULT([    Note that yodl2man was not found, so pre-existing manpage files will be])
1116     AC_MSG_RESULT([    used w/o change (if available) -- no .yo file changes will be used.])
1117     AC_MSG_RESULT()
1118 fi