+
+#
+# AC_WIRESHARK_GEOIP_CHECK
+#
+AC_DEFUN([AC_WIRESHARK_GEOIP_CHECK],
+[
+ want_geoip=defaultyes
+
+ if test "x$want_geoip" = "xdefaultyes"; then
+ want_geoip=yes
+ if test "x$ac_cv_enable_usr_local" = "xyes" ; then
+ withval=/usr/local
+ if test -d "$withval"; then
+ AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
+ fi
+ fi
+ fi
+
+ if test "x$want_geoip" = "xyes"; then
+ AC_CHECK_LIB(GeoIP, GeoIP_new,
+ [
+ GEOIP_LIBS=-lGeoIP
+ AC_DEFINE(HAVE_GEOIP, 1, [Define to use GeoIP library])
+ have_good_geoip=yes
+ ],,
+ )
+ else
+ AC_MSG_RESULT(not required)
+ fi
+])
+
+#AC_WIRESHARK_LDFLAGS_CHECK
+#
+# $1 : ldflag(s) to test
+#
+# The macro first determines if the compiler supports "-Wl,{option}" to
+# pass options through to the linker. Then it attempts to compile with
+# the defined ldflags. The defined flags are added to LDFLAGS only if
+# the compilation succeeds.
+#
+AC_DEFUN([AC_WIRESHARK_LDFLAGS_CHECK],
+[GCC_OPTION="$1"
+AC_MSG_CHECKING(whether we can add $GCC_OPTION to LDFLAGS)
+if test "x$ac_supports_W_linker_passthrough" = "xyes"; then
+ LDFLAGS_saved="$LDFLAGS"
+ LDFLAGS="$LDFLAGS $GCC_OPTION"
+ AC_LINK_IFELSE([
+ AC_LANG_SOURCE([[
+ main() { return; }
+ ]])],
+ [
+ AC_MSG_RESULT(yes)
+ ],
+ [
+ AC_MSG_RESULT(no)
+ LDFLAGS="$LDFLAGS_saved"
+ ])
+else
+ AC_MSG_RESULT(no)
+fi
+])
+
+#
+# AC_WIRESHARK_GCC_CFLAGS_CHECK
+#
+# $1 : cflags to test
+#
+# The macro first determines if the compiler supports GCC-style flags.
+# Then it attempts to compile with the defined cflags. The defined
+# flags are added to CFLAGS only if the compilation succeeds.
+#
+# We do this because not all such options are necessarily supported by
+# the version of the particular compiler we're using.
+#
+# NOTE: clang, by default, only warns about unknown -W options.
+# If we're using clang, we turn on -Werror=unknown-warning-option
+# so that it fails if we pass it a -W option it doesn't know about
+# but doesn't fail for any other warning that the test program might
+# produce.
+#
+AC_DEFUN([AC_WIRESHARK_GCC_CFLAGS_CHECK],
+[GCC_OPTION="$1"
+AC_MSG_CHECKING(whether we can add $GCC_OPTION to CFLAGS)
+if test "x$ac_supports_gcc_flags" = "xyes" ; then
+ CFLAGS_saved="$CFLAGS"
+ CFLAGS="$CFLAGS $GCC_OPTION"
+ if test "x$CC" = "xclang" ; then
+ CFLAGS="$CFLAGS -Werror=unknown-warning-option"
+ fi
+ AC_COMPILE_IFELSE([
+ AC_LANG_SOURCE([[
+ int foo;
+ ]])],
+ [
+ AC_MSG_RESULT(yes)
+ ],
+ [
+ AC_MSG_RESULT(no)
+ CFLAGS="$CFLAGS_saved"
+ ])
+else
+ AC_MSG_RESULT(no)
+fi
+])
+
+#
+# AC_WIRESHARK_OSX_INTEGRATION_CHECK
+#
+# Checks for the presence of OS X integration functions in the GTK+ framework
+# or as a separate library.
+#
+# http://sourceforge.net/apps/trac/gtk-osx/wiki/Integrate
+#
+# http://live.gnome.org/GTK%2B/OSX/Integration
+# for the old Carbon-based integration functions
+#
+# http://gtk-osx.sourceforge.net/ige-mac-integration/
+# for the new Cocoa-based integration functions
+#
+AC_DEFUN([AC_WIRESHARK_OSX_INTEGRATION_CHECK],
+[
+ ac_save_CFLAGS="$CFLAGS"
+ ac_save_LIBS="$LIBS"
+ CFLAGS="$CFLAGS $GTK_CFLAGS"
+ LIBS="$GTK_LIBS $LIBS"
+
+ #
+ # Check for the new integration functions in a -ligemacintegration
+ # library.
+ #
+ AC_CHECK_LIB(igemacintegration, gtk_osxapplication_set_menu_bar,
+ [
+ AC_DEFINE(HAVE_GTKOSXAPPLICATION, 1,
+ [Define to 1 if -ligemacintegration includes the GtkOSXApplication Integration functions.])
+ have_ige_mac=yes
+ # We don't want gtk stuff in LIBS (which is reset below) so
+ # manually set GTK_LIBS (which is more appropriate)
+ GTK_LIBS="$GTK_LIBS -ligemacintegration"
+ ])
+
+ if test x$have_ige_mac = x
+ then
+ #
+ # Not found - check for the old integration functions in
+ # the Gtk framework.
+ #
+ AC_CHECK_LIB(Gtk, ige_mac_menu_set_menu_bar,
+ [
+ AC_DEFINE(HAVE_IGE_MAC_INTEGRATION, 1,
+ [Define to 1 if the the Gtk+ framework or a separate library includes the Imendio IGE Mac OS X Integration functions.])
+ have_ige_mac=yes
+ # We don't want gtk stuff in LIBS (which is reset below) so
+ # manually set GTK_LIBS (which is more appropriate)
+ GTK_LIBS="$GTK_LIBS -lGtk"
+ ])
+ fi
+
+ if test x$have_ige_mac = x
+ then
+ #
+ # Not found - check for the old integration functions in
+ # a -ligemacintegration library.
+ #
+ AC_CHECK_LIB(igemacintegration, ige_mac_menu_set_menu_bar,
+ [
+ AC_DEFINE(HAVE_IGE_MAC_INTEGRATION, 1,
+ [Define to 1 if the the Gtk+ framework or a separate library includes the Imendio IGE Mac OS X Integration functions.])
+ have_ige_mac=yes
+ # We don't want gtk stuff in LIBS (which is reset below) so
+ # manually set GTK_LIBS (which is more appropriate)
+ GTK_LIBS="$GTK_LIBS -ligemacintegration"
+ ])
+ fi
+ CFLAGS="$ac_save_CFLAGS"
+ LIBS="$ac_save_LIBS"
+])
+
+#
+# AC_WIRESHARK_PYTHON_CHECK
+#
+# Check whether python devel package is present
+#
+AC_DEFUN([AC_WIRESHARK_PYTHON_CHECK],
+ [
+ #
+ # Checking whether we have a python devel environment available
+ #
+# AC_CACHE_CHECK([checking python devel package], ac_cv_wireshark_python_devel,
+# [
+ AC_CHECK_PROG([ac_ws_python_config], python-config, "yes", "no")
+ if test "x$ac_ws_python_config" = "xno"; then
+ ac_cv_wireshark_python_devel=no
+ if test "x$want_python" = "xyes"
+ then
+ #
+ # The user tried to force us to use Python, but we
+ # couldn't find the python-config tool; report an error.
+ #
+ AC_MSG_ERROR("python-config not found")
+ fi
+ #
+ # Set want_python to no, so we report that we aren't using
+ # the Python interpreter.
+ #
+ want_python=no
+ else
+ AC_MSG_CHECKING([python devel])
+ ac_save_ws_cflags=$CFLAGS
+ ac_save_ws_libs=$LIBS
+ CFLAGS=$(python-config --includes)
+ LIBS=$(python-config --ldflags)
+ AC_COMPILE_IFELSE(
+ [
+ AC_LANG_PROGRAM(
+ [[#include <Python.h>]],
+ [[Py_Initialiaze();]]
+ )
+ ],
+ [
+ #
+ # Compilation successful, we have python devel available
+ #
+ ac_cv_wireshark_python_devel=yes
+ PY_LIBS=$LIBS
+ PY_CFLAGS=$CFLAGS
+ AC_SUBST(PY_LIBS)
+ AC_SUBST(PY_CFLAGS)
+ CFLAGS="$ac_save_ws_cflags"
+ LIBS="$ac_save_ws_libs"
+ AC_DEFINE(HAVE_PYTHON, 1, [Define if python devel package available])
+ AC_MSG_RESULT([yes])
+ ],
+ [
+ #
+ # Compilation unsuccessful, python devel not available
+ #
+ ac_cv_wireshark_python_devel=no
+ CFLAGS=$ac_save_ws_cflags
+ LIBS=$ac_save_ws_libs
+ if test "x$want_python" = "xyes"
+ then
+ #
+ # The user tried to force us to use Python, but we
+ # couldn't compile the test program; report an error.
+ #
+ AC_MSG_ERROR("Python test program failed compilation")
+ fi
+ AC_MSG_RESULT([no])
+ #
+ # Set want_python to no, so we report that we aren't using
+ # the Python interpreter.
+ #
+ want_python=no
+ ])
+ fi
+# ])
+])