configure.in

   1 # $Id: configure.in,v 1.209 2003/06/11 09:17:00 guy Exp $
   2 dnl
   3 dnl Process this file with autoconf 2.13 or later to produce a
   4 dnl configure script; 2.12 doesn't generate a "configure" script that
   5 dnl defines SHELL, and "Makefile.in" has
   6 dnl
   7 dnl     SHELL = @SHELL@
   8 dnl
   9 dnl which requires it to be defined - and there may be other problems
  10 dnl with pre-2.13 "autoconf" as well.
  11 dnl
  12 AC_INIT(etypes.h)
  13
  14 AC_PREREQ(2.13)
  15
  16 dnl Check for CPU / vendor / OS
  17 AC_CANONICAL_HOST
  18 AC_CANONICAL_TARGET
  19
  20 AM_INIT_AUTOMAKE(ethereal, 0.9.13)
  21
  22 dnl Checks for programs.
  23 AC_PROG_CC
  24 AC_PROG_CPP
  25 AM_DISABLE_STATIC
  26 AC_LIBTOOL_DLOPEN
  27 AC_PROG_LIBTOOL
  28 AC_PROG_YACC
  29 AM_PROG_LEX
  30 AC_PATH_PROG(PERL, perl)
  31 AC_PATH_PROG(POD2MAN, pod2man)
  32 AC_PATH_PROG(LEX, flex)
  33 AC_PATH_PROG(PYTHON, python)
  34
  35 AC_SUBST(PERL)
  36 AC_SUBST(LEX)
  37 AC_SUBST(PYTHON)
  38
  39 # Check for packaging utilities
  40 # For now, we check to see if the various packaging utilites are in our
  41 # path.  I'm too lazy to write code to go hunt for them.  -  Gerald
  42 AC_CHECK_PROG(HAVE_PKGPROTO, pkgproto, "yes", "no")
  43 AC_CHECK_PROG(HAVE_PKGMK, pkgmk, "yes", "no")
  44 AC_CHECK_PROG(HAVE_PKGTRANS, pkgtrans, "yes", "no")
  45
  46 if test x$HAVE_PKGPROTO = xyes -a x$HAVE_PKGMK = xyes \
  47      -a x$HAVE_PKGTRANS = xyes ; then
  48   HAVE_SVR4_PACKAGING=yes
  49 else
  50   HAVE_SVR4_PACKAGING=no
  51 fi
  52 AC_SUBST(HAVE_SVR4_PACKAGING)
  53
  54 AC_ETHEREAL_RPM_CHECK
  55 AC_SUBST(HAVE_RPM)
  56
  57 #
  58 # If we're running gcc, add '-Wall -W' to CFLAGS, and add
  59 # '-D_U_="__attribute__((unused))"' as well, so we can use _U_ to
  60 # flag unused function arguments and not get warnings about them.
  61 # If "--with-extra-gcc-checks" was specified, add "-Wcast-qual
  62 # -Wcast-align" as well.  (Add more checks here in the future?)
  63 #
  64 # Otherwise, add '-D_U_=""', so that _U_ used to flag an unused function
  65 # argument will compile with non-GCC compilers.
  66 #
  67 AC_ARG_WITH(extra-gcc-checks,
  68 [  --with-extra-gcc-checks do additional -W checks in GCC.  [default=no]],
  69 [
  70         if test $withval != no
  71         then
  72                 ethereal_extra_gcc_flags=" -Wcast-qual -Wcast-align"
  73         fi
  74 ],)
  75 AC_MSG_CHECKING(to see if we can add '-Wall -W$ethereal_extra_gcc_flags' to CFLAGS)
  76 if test x$GCC != x ; then
  77   CFLAGS="-D_U_=\"__attribute__((unused))\" -Wall -W$ethereal_extra_gcc_flags $CFLAGS"
  78   AC_MSG_RESULT(yes)
  79 else
  80   CFLAGS="-D_U_=\"\" $CFLAGS"
  81   AC_MSG_RESULT(no)
  82 fi
  83
  84 #
  85 # Add any platform-specific compiler flags needed.
  86 #
  87 AC_MSG_CHECKING(for platform-specific compiler flags)
  88 if test "x$GCC" = x
  89 then
  90         #
  91         # Not GCC - assume it's the vendor's compiler.
  92         #
  93         case "$host_os" in
  94         hpux*)
  95                 #
  96                 # HP's ANSI C compiler; flags suggested by Jost Martin.
  97                 # "-Ae" for ANSI C plus extensions such as "long long".
  98                 # "+O2", for optimization.  XXX - works with "-g"?
  99                 #
 100                 CFLAGS="-Ae +O2 $CFLAGS"
 101                 AC_MSG_RESULT(HP ANSI C compiler - added -Ae +O2)
 102                 ;;
 103         darwin*)
 104                 #
 105                 # It may be called "cc", but it's really a GCC derivative
 106                 # with a problematic special precompiler and precompiled
 107                 # headers; turn off the special precompiler, as some
 108                 # apparently-legal code won't compile with its precompiled
 109                 # headers.
 110                 #
 111                 CFLAGS="-no-cpp-precomp $CFLAGS"
 112                 AC_MSG_RESULT(Apple GCC - added -no-cpp-precomp)
 113                 ;;
 114         *)
 115                 AC_MSG_RESULT(none needed)
 116                 ;;
 117         esac
 118 else
 119         case "$host_os" in
 120         solaris*)
 121                 # the X11 headers don't automatically include prototype info
 122                 # and a lot don't include the return type
 123                 CFLAGS="$CFLAGS -Wno-return-type -DFUNCPROTO=15"
 124                 AC_MSG_RESULT(GCC on Solaris - added -Wno-return-type -DFUNCPROTO=15)
 125                 ;;
 126         darwin*)
 127                 #
 128                 # See comments above about Apple's lovely C compiler.
 129                 #
 130                 CFLAGS="-no-cpp-precomp $CFLAGS"
 131                 AC_MSG_RESULT(Apple GCC - added -no-cpp-precomp)
 132                 ;;
 133         *)
 134                 AC_MSG_RESULT(none needed)
 135                 ;;
 136         esac
 137 fi
 138
 139 CFLAGS="$CFLAGS -I\$(top_srcdir) -I\$(top_srcdir)/wiretap"
 140 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir) -I\$(top_srcdir)/wiretap"
 141
 142 dnl Look in /usr/local for header files and libraries ?
 143 dnl XXX FIXME don't include /usr/local if it is already in the system
 144 dnl search path as this causes gcc 3.2 on Linux to complain about a change
 145 dnl of the system search order for includes
 146 AC_ARG_ENABLE(usr-local,
 147 [  --enable-usr-local      look for headers and libs in /usr/local tree.  [default=yes]],enable_usr_local=$enableval,enable_usr_local=yes)
 148
 149 AC_MSG_CHECKING(whether to use /usr/local for headers and libraries)
 150 if test "x$enable_usr_local" = "xyes" ; then
 151         AC_MSG_RESULT(yes)
 152         #
 153         # Arrange that we search for header files in the source directory
 154         # and in its "wiretap" subdirectory, as well as in "/usr/local/include",
 155         # as various packages we use ("libpcap", "zlib", an SNMP library)
 156         # may have been installed under "/usr/local/include".
 157         #
 158         CFLAGS="$CFLAGS -I/usr/local/include"
 159         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 160
 161         #
 162         # Arrange that we search for libraries in "/usr/local/lib".
 163         #
 164         AC_ETHEREAL_ADD_DASH_L(LDFLAGS, /usr/local/lib)
 165 else
 166         AC_MSG_RESULT(no)
 167 fi
 168
 169 #
 170 # If we're running Solaris, and LD_LIBRARY_PATH is defined, add it as a
 171 # link directory.
 172 #
 173 case "$host_os" in
 174   solaris*)
 175     AC_MSG_CHECKING(for LD_LIBRARY_PATH, since you appear to be running Solaris)
 176     if test x$LD_LIBRARY_PATH != x ; then
 177       LIBS="$LIBS -R$LD_LIBRARY_PATH"
 178       AC_MSG_RESULT(yes -- added LD_LIBRARY_PATH to run-time linker path)
 179     else
 180       AC_MSG_RESULT(no -- this may be a problem in a few seconds)
 181     fi
 182   ;;
 183 esac
 184
 185 #
 186 # Check for versions of "sed" inadequate to handle, in libtool, a list
 187 # of object files as large as the list in Ethereal.
 188 #
 189 # On Solaris, we check for "/bin/sed", "/usr/bin/sed", and "/usr/ucb/sed",
 190 # as both "/usr/bin/sed" (which is also "/bin/sed", as "/bin" is just a
 191 # symlink to "/usr/bin", but people may have "/bin" before "/usr/bin" in
 192 # their search path) and "/usr/ucb/sed" are inadequate; "/usr/xpg4/bin/sed"
 193 # is the only "sed" that comes with Solaris that can handle Ethereal.
 194 #
 195 # Add any checks here that are necessary for other OSes.
 196 #
 197 AC_ETHEREAL_GNU_SED_CHECK
 198 if test "$HAVE_GNU_SED" = no ; then
 199         case "$host_os" in
 200         solaris*)
 201                 AC_MSG_CHECKING(whether one of /usr/bin/sed or /bin/sed or /usr/ucb/sed will be used)
 202                 case `which sed` in
 203                         /bin/sed|/usr/bin/sed|/usr/ucb/sed)
 204                         AC_MSG_RESULT(yes)
 205                         AC_MSG_ERROR([change your path to search /usr/xpg4/bin or directory containing GNU sed before /usr/bin (and /bin and /usr/ucb)])
 206                         ;;
 207
 208                         *)
 209                         AC_MSG_RESULT(no)
 210                         ;;
 211                 esac
 212                 ;;
 213
 214         *)
 215                 :
 216                 ;;
 217         esac
 218 fi
 219
 220 # Enable/disable tethereal
 221
 222 AC_ARG_ENABLE(ethereal,
 223 [  --enable-ethereal       build GTK+-based ethereal.  [default=yes]],enable_ethereal=$enableval,enable_ethereal=yes)
 224
 225 AC_ARG_ENABLE(gtk2,
 226 [  --enable-gtk2           build Glib2/Gtk2+-based (t)ethereal.  [default=no]],enable_gtk2=$enableval,enable_gtk2=no)
 227 AM_CONDITIONAL(USE_GTK2, test x$enable_gtk2 = xyes)
 228
 229 AC_ARG_ENABLE(threads,
 230 [  --enable-threads        use threads in ethereal.  [default=yes]],enable_threads=$enableval,enable_threads=yes)
 231 AM_CONDITIONAL(USE_THREADS, test x$enable_threads = xyes)
 232
 233 # GTK checks
 234 # We don't add $GLIB_LIBS to LIBS, because we don't want to force all
 235 # programs to be built with GTK+.
 236 #
 237 if test "x$enable_gtk2" = "xyes" -a "x$enable_ethereal" = "xyes" ; then
 238         GTK_OK=two
 239         AM_PATH_GTK_2_0(2.0.0, CFLAGS="$CFLAGS $GTK_CFLAGS", GTK_OK=no, gthread)
 240 elif test "x$enable_gtk2" != "xyes" -a "x$enable_ethereal" = "xyes" ; then
 241         GTK_OK=one
 242         AM_PATH_GTK(1.2.0, CFLAGS="$CFLAGS $GTK_CFLAGS", GTK_OK=no )
 243 else
 244         GTK_OK=no
 245 fi
 246
 247 # GLib checks
 248 # This doesn't add GLIB_CFLAGS to CFLAGS, because AM_PATH_GTK will add
 249 # GTK_CFLAGS to CFLAGS, and GTK_CFLAGS is a superset of CFLAGS.
 250 # However, this means that both @GLIB_LIBS@ and @GTK_LIBS@ will be
 251 # set when generating the Makefile, so we can make programs that require
 252 # only GLib link with @GLIB_LIBS@ and make programs that require GTK+
 253 # link with @GTK_LIBS@ (which includes @GLIB_LIBS@).
 254 # We don't add $GLIB_LIBS to LIBS, because we don't want to force all
 255 # programs to be built with GLib.
 256 #
 257 if test "$GTK_OK" = "no" ; then
 258         enable_ethereal="no"
 259         ethereal_bin=""
 260         ethereal_man=""
 261         # Honor GLIB_CFLAGS
 262         if test "x$enable_gtk2" = "xyes" ; then
 263                 AM_PATH_GLIB_2_0(2.0.0, CFLAGS="$CFLAGS $GLIB_CFLAGS", AC_MSG_ERROR(GLib distribution not found.), gmodule)
 264         else
 265                 AM_PATH_GLIB(1.2.0, CFLAGS="$CFLAGS $GLIB_CFLAGS", AC_MSG_ERROR(GLib distribution not found.), gmodule)
 266         fi
 267 else
 268         ethereal_bin="ethereal"
 269         ethereal_man="ethereal.1"
 270         ethereal_SUBDIRS="gtk"
 271         # Honor GLIB_CFLAGS
 272         if test "$GTK_OK" = "two" ; then
 273                 AM_PATH_GLIB_2_0(2.0.0, , AC_MSG_ERROR(GLib distribution not found.), gmodule)
 274         else
 275                 AM_PATH_GLIB(1.2.0, , AC_MSG_ERROR(GLib distribution not found.), gmodule)
 276         fi
 277 fi
 278
 279 #
 280 # Check whether GLib modules are supported, to determine whether we
 281 # can support plugins.
 282 #
 283 AC_MSG_CHECKING(whether GLib supports loadable modules)
 284 ac_save_CFLAGS="$CFLAGS"
 285 ac_save_LIBS="$LIBS"
 286 CFLAGS="$CFLAGS $GLIB_CFLAGS"
 287 LIBS="$GLIB_LIBS $LIBS"
 288 AC_TRY_RUN([
 289 #include <glib.h>
 290 #include <gmodule.h>
 291 #include <stdio.h>
 292 #include <stdlib.h>
 293
 294 int
 295 main ()
 296 {
 297   if (g_module_supported())
 298     return 0;   /* success */
 299   else
 300     return 1;   /* failure */
 301 }
 302 ], ac_cv_glib_supports_modules=yes, ac_cv_glib_supports_modules=no,
 303    [echo $ac_n "cross compiling; assumed OK... $ac_c"])
 304 CFLAGS="$ac_save_CFLAGS"
 305 LIBS="$ac_save_LIBS"
 306 if test "$ac_cv_glib_supports_modules" = yes ; then
 307   AC_MSG_RESULT(yes)
 308   have_plugins=yes
 309 else
 310   AC_MSG_RESULT(no)
 311   have_plugins=no
 312 fi
 313
 314
 315 AC_SUBST(ethereal_bin)
 316 AC_SUBST(ethereal_man)
 317
 318
 319
 320 # Enable/disable tethereal
 321
 322 AC_ARG_ENABLE(tethereal,
 323 [  --enable-tethereal      build tethereal.  [default=yes]],tethereal=$enableval,enable_tethereal=yes)
 324
 325 if test "x$enable_tethereal" = "xyes" ; then
 326         tethereal_bin="tethereal"
 327         tethereal_man="tethereal.1"
 328 else
 329         tethereal_bin=""
 330         tethereal_man=""
 331 fi
 332 AC_SUBST(tethereal_bin)
 333 AC_SUBST(tethereal_man)
 334
 335
 336
 337 # Enable/disable editcap
 338
 339 AC_ARG_ENABLE(editcap,
 340 [  --enable-editcap        build editcap.  [default=yes]],enable_editcap=$enableval,enable_editcap=yes)
 341
 342 if test "x$enable_editcap" = "xyes" ; then
 343         editcap_bin="editcap"
 344         editcap_man="editcap.1"
 345 else
 346         editcap_bin=""
 347         editcap_man=""
 348 fi
 349 AC_SUBST(editcap_bin)
 350 AC_SUBST(editcap_man)
 351
 352
 353 # Enable/disable mergecap
 354
 355 AC_ARG_ENABLE(mergecap,
 356 [  --enable-mergecap       build mergecap.  [default=yes]],enable_mergecap=$enableval,enable_mergecap=yes)
 357
 358 if test "x$enable_mergecap" = "xyes" ; then
 359         mergecap_bin="mergecap"
 360         mergecap_man="mergecap.1"
 361 else
 362         mergecap_bin=""
 363         mergecap_man=""
 364 fi
 365 AC_SUBST(mergecap_bin)
 366 AC_SUBST(mergecap_man)
 367
 368
 369 # Enable/disable text2pcap
 370
 371 AC_ARG_ENABLE(text2pcap,
 372 [  --enable-text2pcap      build text2pcap.  [default=yes]],text2pcap=$enableval,enable_text2pcap=yes)
 373
 374 if test "x$enable_text2pcap" = "xyes" ; then
 375         text2pcap_bin="text2pcap"
 376         text2pcap_man="text2pcap.1"
 377 else
 378         text2pcap_bin=""
 379         text2pcap_man=""
 380 fi
 381 AC_SUBST(text2pcap_bin)
 382 AC_SUBST(text2pcap_man)
 383
 384 # Enable/disable idl2eth
 385
 386 AC_ARG_ENABLE(idl2eth,
 387 [  --enable-idl2eth        build idl2eth.  [default=yes]],enable_idl2eth=$enableval,enable_idl2eth=yes)
 388
 389 if test "x$enable_idl2eth" = "xyes" ; then
 390         idl2eth_bin="idl2eth"
 391         idl2eth_man="idl2eth.1"
 392 else
 393         idl2eth_bin=""
 394         idl2eth_man=""
 395 fi
 396 AC_SUBST(idl2eth_bin)
 397 AC_SUBST(idl2eth_man)
 398
 399
 400 # Enable/disable dftest
 401
 402 AC_ARG_ENABLE(dftest,
 403 [  --enable-dftest         build dftest.  [default=no]],enable_dftest=$enableval,enable_dftest=no)
 404
 405 if test "x$enable_dftest" = "xyes" ; then
 406         dftest_bin="dftest"
 407 else
 408         dftest_bin=""
 409 fi
 410 AC_SUBST(dftest_bin)
 411
 412
 413 # Enable/disable randpkt
 414
 415 AC_ARG_ENABLE(randpkt,
 416 [  --enable-randpkt        build randpkt.  [default=no]],enable_randpkt=$enableval,enable_randpkt=no)
 417
 418 if test "x$enable_randpkt" = "xyes" ; then
 419         randpkt_bin="randpkt"
 420 else
 421         randpkt_bin=""
 422 fi
 423 AC_SUBST(randpkt_bin)
 424
 425
 426 dnl Checks for "gethostbyname()" - and "-lnsl", if we need it to get
 427 dnl "gethostbyname()".
 428 AC_ETHEREAL_GETHOSTBY_LIB_CHECK
 429
 430 dnl Checks for "connect()", used as a proxy for "socket()" - and
 431 dnl "-lsocket", if we need it to get "connect()".
 432 AC_ETHEREAL_SOCKET_LIB_CHECK
 433
 434 dnl pcap check
 435 AC_MSG_CHECKING(whether to use libpcap for packet capture)
 436
 437 AC_ARG_WITH(pcap,
 438 [  --with-pcap[=DIR]       use libpcap for packet capturing.  [default=yes]],
 439 [
 440         if test $withval = no
 441         then
 442                 want_pcap=no
 443         elif test $withval = yes
 444         then
 445                 want_pcap=yes
 446         else
 447                 want_pcap=yes
 448                 pcap_dir=$withval
 449         fi
 450 ],[
 451         want_pcap=yes
 452         pcap_dir=
 453 ])
 454 if test "x$want_pcap" = "xno" ; then
 455         AC_MSG_RESULT(no)
 456 else
 457         AC_MSG_RESULT(yes)
 458         AC_ETHEREAL_PCAP_CHECK
 459         AC_ETHEREAL_PCAP_VERSION_CHECK
 460 fi
 461
 462 dnl zlib check
 463 AC_MSG_CHECKING(whether to use zlib for reading compressed capture files)
 464
 465 AC_ARG_WITH(zlib,
 466 [  --with-zlib[=DIR]       use zlib (located in directory DIR, if supplied) to read compressed data.  [default=yes, if present]],
 467 [
 468         if test $withval = no
 469         then
 470                 want_zlib=no
 471         elif test $withval = yes
 472         then
 473                 want_zlib=yes
 474         else
 475                 want_zlib=yes
 476                 zlib_dir=$withval
 477         fi
 478 ],[
 479         #
 480         # Use zlib if it's present, otherwise don't.
 481         #
 482         want_zlib=ifpresent
 483         zlib_dir=
 484 ])
 485 if test "x$want_zlib" = "xno" ; then
 486         AC_MSG_RESULT(no)
 487 else
 488         AC_MSG_RESULT(yes)
 489         AC_ETHEREAL_ZLIB_CHECK
 490         if test "x$want_zlib" = "xno" ; then
 491                 AC_MSG_RESULT(zlib not found - disabling compressed capture file support)
 492         fi
 493 fi
 494
 495
 496 dnl ipv6 check
 497 AC_ARG_ENABLE(ipv6,
 498 [  --enable-ipv6           use ipv6 name resolution, if available.  [default=yes]],enable_ipv6=$enableval,enable_ipv6=yes)
 499
 500 AC_MSG_CHECKING(whether to enable ipv6 name resolution if available)
 501 if test "x$enable_ipv6" = "xno" ; then
 502         AC_MSG_RESULT(no)
 503 else
 504         AC_MSG_RESULT(yes)
 505         AC_ETHEREAL_IPV6_STACK
 506 fi
 507
 508
 509 dnl Check if ethereal should be installed setuid
 510 AC_ARG_ENABLE(setuid-install,
 511 [  --enable-setuid-install install ethereal as setuid. DANGEROUS!!! [default=no]],enable_setuid_install=$enableval,enable_setuid_install=no)
 512
 513 AC_MSG_CHECKING(whether to install ethereal setuid)
 514 if test "x$enable_setuid_install" = "xno" ; then
 515         AC_MSG_RESULT(no)
 516 else
 517         AC_MSG_RESULT(yes)
 518 fi
 519
 520 AM_CONDITIONAL(SETUID_INSTALL, test x$enable_setuid_install = xyes)
 521
 522 dnl Checks for header files.
 523 AC_HEADER_STDC
 524 AC_CHECK_HEADERS(fcntl.h sys/ioctl.h sys/time.h unistd.h stdarg.h netdb.h)
 525 AC_CHECK_HEADERS(sys/stat.h sys/sockio.h sys/types.h sys/socket.h)
 526 AC_CHECK_HEADERS(sys/utsname.h sys/wait.h)
 527 AC_CHECK_HEADERS(netinet/in.h)
 528 AC_CHECK_HEADERS(stddef.h)
 529 AC_CHECK_HEADERS(arpa/inet.h)
 530 AC_CHECK_HEADERS(iconv.h)
 531
 532 dnl SSL Check
 533 SSL_LIBS=''
 534 AC_MSG_CHECKING(whether to use SSL library if available)
 535 if test "x$enable_ssl" = "xno" ; then
 536         AC_MSG_RESULT(no)
 537 else
 538         AC_MSG_RESULT(yes)
 539         AC_ETHEREAL_SSL_CHECK
 540 fi
 541 AC_SUBST(SSL_LIBS)
 542
 543 dnl UCD SNMP Check
 544 SNMP_LIBS=''
 545
 546 AC_ARG_WITH(net-snmp,
 547 [  --with-net-snmp=PATH    use PATH as the location of the net-snmp-config shell script that comes with the net-snmp package.],
 548 [netsnmpconfig=$withval]
 549 )
 550
 551 AC_ARG_WITH(ucdsnmp,
 552 [  --with-ucdsnmp[=DIR]    use UCD SNMP/NET-SNMP client library (located in directory DIR, if supplied).  [default=yes, if present]],
 553 [
 554         if test $withval = no
 555         then
 556                 want_ucdsnmp=no
 557         elif test $withval = yes
 558         then
 559                 want_ucdsnmp=yes
 560         else
 561                 want_ucdsnmp=yes
 562                 ucdsnmp_dir=$withval
 563         fi
 564 ],[
 565         #
 566         # Set "want_ucdsnmp" to "ifpresent" to make the default "use it
 567         # if you find it, otherwise don't".
 568         #
 569         want_ucdsnmp=ifpresent
 570         ucdsnmp_dir=
 571 ])
 572
 573 dnl try net-snmp first
 574 if test "x$netsnmpconfig" != "xno" ; then
 575         dnl get the net-snmp-config binary
 576         if test "x$netsnmpconfig" = "xyes" -o "x$netsnmpconfig" = "x" ; then
 577                 dnl search for it
 578                 AC_PATH_PROG(NETSNMPCONFIG,net-snmp-config)
 579         else
 580                 NETSNMPCONFIG=$netsnmpconfig
 581                 if test ! -x $NETSNMPCONFIG ; then
 582                         AC_MSG_ERROR(Invalid net-snmp-config: $NETSNMPCONFIG)
 583                 fi
 584         fi
 585 fi
 586
 587 AC_MSG_CHECKING(whether to use UCD SNMP/NET-SNMP library if available)
 588 if test "x$NETSNMPCONFIG" != "xno" -a "x$NETSNMPCONFIG" != "x" -a -x "$NETSNMPCONFIG" ; then
 589         dnl other choices for flags to use here: could also use
 590         dnl --prefix or --exec-prefix if you don't want the full list.
 591
 592         AC_CHECK_HEADERS(net-snmp/net-snmp-config.h net-snmp/library/default_store.h)
 593         if test "x$ac_cv_header_net_snmp_net_snmp_config_h" = "xyes" -a "x$ac_cv_header_net_snmp_library_default_store_h" = "xyes" ; then
 594                 CFLAGS="$CFLAGS `net-snmp-config --cflags`"
 595                 CPPFLAGS="$CPPLAGS `net-snmp-config --cflags`"
 596                 SNMP_LIBS=`net-snmp-config --libs`
 597                 AC_DEFINE(HAVE_NET_SNMP, 1, [Define to enable support for NET-SNMP])
 598                 have_net_snmp="yes"
 599                 AC_MSG_RESULT(yes (net-snmp))
 600         else
 601                 # technically, we should retry ucd-snmp but it's
 602                 # unlikely they have installed net-snmp-config and not
 603                 # the net-snmp headers but do have the ucd-snmp
 604                 # headers.  This would likely be a broken system to
 605                 # try and use anyway.
 606                 NETSNMPCONFIG="no"
 607                 AC_MSG_RESULT(no)
 608         fi
 609 else
 610         if test "x$want_ucdsnmp" = "xno" ; then
 611                 AC_MSG_RESULT(no)
 612         else
 613                 AC_MSG_RESULT(yes (ucd-snmp))
 614                 AC_ETHEREAL_UCDSNMP_CHECK
 615         fi
 616 fi
 617
 618 if test "x$have_net_snmp" = "xyes" || test "x$have_ucd_snmp" = "xyes"; then
 619         AC_DEFINE(HAVE_SOME_SNMP, 1, [Define to if some SNMP support is to be used])
 620 fi
 621
 622 AC_SUBST(SNMP_LIBS)
 623
 624 dnl ADNS Check
 625 ADNS_LIBS=''
 626 AC_MSG_CHECKING(whether to use the GNU ADNS library if available)
 627 if test "x$enable_adns" = "xno" ; then
 628         AC_MSG_RESULT(no)
 629 else
 630         AC_MSG_RESULT(yes)
 631         AC_ETHEREAL_ADNS_CHECK
 632 fi
 633 AC_SUBST(ADNS_LIBS)
 634
 635 dnl Checks for typedefs, structures, and compiler characteristics.
 636 # AC_C_CONST
 637
 638 # We need to know whether "struct sockaddr" has an "sa_len" member
 639 # for get_interface_list().
 640
 641 AC_ETHEREAL_STRUCT_SA_LEN
 642
 643 # We must know our byte order
 644 AC_C_BIGENDIAN
 645
 646 # Checks whether "-traditional" is needed when using "ioctl".
 647 # XXX - do we need this?
 648 AC_PROG_GCC_TRADITIONAL
 649
 650 # If there's a system out there that has snprintf and _doesn't_ have vsnprintf,
 651 # then this won't work.
 652 SNPRINTF_C=""
 653 SNPRINTF_O=""
 654 AC_CHECK_FUNC(snprintf, SNPRINTF_O="",
 655   [SNPRINTF_O="snprintf.o"
 656    AC_DEFINE(NEED_SNPRINTF_H, 1, [Define if sprintf.h needs to be included])
 657 ])
 658 if test "$ac_cv_func_snprintf" = no ; then
 659   SNPRINTF_C="snprintf.c"
 660   SNPRINTF_O="snprintf.o"
 661 fi
 662 AC_SUBST(SNPRINTF_C)
 663 AC_SUBST(SNPRINTF_O)
 664
 665 AC_CHECK_FUNC(strerror, STRERROR_O="",
 666   [STRERROR_O="strerror.o"
 667    AC_DEFINE(NEED_STRERROR_H, 1, [Define if strerror.h needs to be included])
 668 ])
 669 if test "$ac_cv_func_strerror" = no ; then
 670   STRERROR_C="strerror.c"
 671   STRERROR_O="strerror.o"
 672 fi
 673 AC_SUBST(STRERROR_C)
 674 AC_SUBST(STRERROR_O)
 675
 676 AC_CHECK_FUNC(strcasecmp, STRCASECMP_O="",
 677   STRCASECMP_O="strcasecmp.o")
 678 if test "$ac_cv_func_strcasecmp" = no ; then
 679   STRCASECMP_C="strcasecmp.c"
 680   STRCASECMP_O="strcasecmp.o"
 681 fi
 682 AC_SUBST(STRCASECMP_C)
 683 AC_SUBST(STRCASECMP_O)
 684
 685 AC_CHECK_FUNC(strncasecmp, STRNCASECMP_O="",
 686   STRNCASECMP_O="strncasecmp.o")
 687 if test "$ac_cv_func_strncasecmp" = no ; then
 688   STRNCASECMP_C="strncasecmp.c"
 689   STRNCASECMP_O="strncasecmp.o"
 690 fi
 691 AC_SUBST(STRNCASECMP_C)
 692 AC_SUBST(STRNCASECMP_O)
 693
 694 AC_CHECK_FUNC(mkstemp, MKSTEMP_O="",
 695   MKSTEMP_O="mkstemp.o")
 696 if test "$ac_cv_func_mkstemp" = no ; then
 697   MKSTEMP_C="mkstemp.c"
 698   MKSTEMP_O="mkstemp.o"
 699 fi
 700 AC_SUBST(MKSTEMP_C)
 701 AC_SUBST(MKSTEMP_O)
 702
 703 AC_CHECK_FUNC(strptime, STRPTIME_O="",
 704   [STRPTIME_O="strptime.o"
 705    AC_DEFINE(NEED_STRPTIME_H, 1, [Define if strptime.h needs to be included])
 706 ])
 707 if test "$ac_cv_func_strptime" = no ; then
 708   STRPTIME_C="strptime.c"
 709   STRPTIME_O="strptime.o"
 710 fi
 711 AC_SUBST(STRPTIME_C)
 712 AC_SUBST(STRPTIME_O)
 713
 714 AC_CHECK_FUNCS(getprotobynumber gethostbyname2)
 715
 716 dnl blank for now, but will be used in future
 717 AC_SUBST(ethereal_SUBDIRS)
 718
 719 dnl
 720 dnl check whether plugins should be enabled and, if they should be,
 721 dnl check for plugins directory - stolen from Amanda's configure.in
 722 dnl
 723 plugindir="$libdir/ethereal/plugins/$VERSION"
 724 AC_ARG_WITH(plugins,
 725   [  --with-plugins[=DIR]    support plugins (installed in DIR, if supplied).],
 726   [
 727   case "$withval" in
 728   "" | y | ye | yes )
 729     if test x$have_plugins = xno
 730     then
 731       AC_MSG_ERROR([GLib on this platform doesn't support loadable modules, so you can't enable plugins.])
 732     fi
 733     ;;
 734   n | no)
 735     have_plugins=no
 736     ;;
 737   *)
 738     if test x$have_plugins = xno
 739     then
 740       AC_MSG_ERROR([GLib on this platform doesn't support loadable modules, so you can't enable plugins.])
 741     fi
 742     plugindir="$withval"
 743     ;;
 744   esac
 745   ]
 746 )
 747
 748 AM_CONDITIONAL(HAVE_PLUGINS, test x$have_plugins = xyes)
 749 if test x$have_plugins = xyes
 750 then
 751   AC_DEFINE(HAVE_PLUGINS, 1, [Define if plugins are enabled])
 752   plugindir=`(
 753     test "x$prefix" = xNONE && prefix=$ac_default_prefix
 754     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
 755     eval echo "$plugindir"
 756   )`
 757   AC_DEFINE_UNQUOTED(PLUGIN_DIR, "$plugindir", [Plugin installation directory])
 758 else
 759   AC_DEFINE(PLUGIN_DIR, NULL, [Plugin installation directory])
 760 fi
 761 AC_SUBST(plugindir)
 762
 763 dnl libtool defs
 764 AM_PROG_LIBTOOL
 765 AC_SUBST(LIBTOOL_DEPS)
 766
 767 AM_CONDITIONAL(ENABLE_STATIC, test x$enable_shared = xno)
 768 AM_CONFIG_HEADER(config.h)
 769 AC_CONFIG_SUBDIRS(epan wiretap)
 770 AC_OUTPUT(
 771   Makefile
 772   doc/Makefile
 773   gtk/Makefile
 774   packaging/Makefile
 775   packaging/nsis/Makefile
 776   packaging/rpm/Makefile
 777   packaging/rpm/SPECS/Makefile
 778   packaging/rpm/SPECS/ethereal.spec
 779   packaging/svr4/Makefile
 780   packaging/svr4/checkinstall
 781   packaging/svr4/pkginfo
 782   plugins/Makefile
 783   plugins/artnet/Makefile
 784   plugins/docsis/Makefile
 785   plugins/giop/Makefile
 786   plugins/gryphon/Makefile
 787   plugins/megaco/Makefile
 788   plugins/mgcp/Makefile
 789   plugins/pcli/Makefile
 790   plugins/rtnet/Makefile
 791   tools/Makefile
 792   tools/lemon/Makefile
 793   ,)
 794
 795
 796 # Pretty messages
 797
 798 if test "x$enable_setuid_install" = "xyes" ; then
 799         setuid_message="yes (DANGEROUS!!!)"
 800 else
 801         setuid_message="no"
 802 fi
 803
 804 if test "x$want_zlib" = "xno" ; then
 805         zlib_message="no"
 806 else
 807         zlib_message="yes"
 808 fi
 809
 810 if test "x$want_adns" = "xno" ; then
 811         adns_message="no"
 812 else
 813         adns_message="yes"
 814 fi
 815
 816 if test "x$NETSNMPCONFIG" != "xno" -a "x$NETSNMPCONFIG" != "x" -a -x "$NETSNMPCONFIG" ; then
 817         snmp_libs_message="yes (net-snmp)"
 818 elif test "x$SNMP_LIBS" = "x" ; then
 819         snmp_libs_message="no"
 820 else
 821         snmp_libs_message="yes (ucd-snmp)"
 822 fi
 823
 824 echo ""
 825 echo "The Ethereal package has been configured with the following options."
 826 echo "                    Build ethereal : $enable_ethereal"
 827 echo "                   Build tethereal : $enable_tethereal"
 828 echo "                     Build editcap : $enable_editcap"
 829 echo "                    Build mergecap : $enable_mergecap"
 830 echo "                   Build text2pcap : $enable_text2pcap"
 831 echo "                     Build idl2eth : $enable_idl2eth"
 832 echo "                     Build randpkt : $enable_randpkt"
 833 echo "                      Build dftest : $enable_dftest"
 834 echo ""
 835 echo "                    Install setuid : $setuid_message"
 836 echo "                       Use plugins : $have_plugins"
 837 echo "               Use GTK+ v2 library : $enable_gtk2"
 838 if test "x$enable_gtk2" = "xyes" ; then
 839 echo "                       Use threads : $enable_threads"
 840 fi
 841 echo "                  Use pcap library : $want_pcap"
 842 echo "                  Use zlib library : $zlib_message"
 843 echo "              Use GNU ADNS library : $adns_message"
 844 echo "          Use IPv6 name resolution : $enable_ipv6"
 845 echo "     Use UCD SNMP/NET-SNMP library : $snmp_libs_message"