configure.in

   1 # $Id: configure.in,v 1.128 2001/06/02 06:21:13 guy Exp $
   2 dnl
   3 dnl Process this file with autoconf 2.13 or later to produce a
   4 dnl configure script; 2.12 doesn't generate a "configure" script that
   5 dnl defines SHELL, and "Makefile.in" has
   6 dnl
   7 dnl     SHELL = @SHELL@
   8 dnl
   9 dnl which requires it to be defined - and there may be other problems
  10 dnl with pre-2.13 "autoconf" as well.
  11 dnl
  12 AC_INIT(etypes.h)
  13
  14 AC_PREREQ(2.13)
  15
  16 AM_INIT_AUTOMAKE(ethereal, 0.8.18)
  17
  18 AM_CONDITIONAL(SETUID_INSTALL, test x$enable_setuid_install = xyes)
  19
  20 dnl Check for CPU / vendor / OS
  21 AC_CANONICAL_HOST
  22
  23 dnl Checks for programs.
  24 AC_PROG_CC
  25 AC_PROG_CPP
  26 AC_PROG_RANLIB
  27 AC_PROG_YACC
  28 AM_PROG_LEX
  29 AC_PATH_PROG(PERL, perl)
  30 AC_PATH_PROG(LEX, flex)
  31 AC_PATH_PROG(PYTHON, python)
  32
  33 AC_SUBST(PERL)
  34 AC_SUBST(LEX)
  35 AC_SUBST(PYTHON)
  36
  37
  38 # Check for packaging utilities
  39 # For now, we check to see if the various packaging utilites are in our
  40 # path.  I'm too lazy to write code to go hunt for them.  -  Gerald
  41 AC_CHECK_PROG(HAVE_PKGPROTO, pkgproto, "yes", "no")
  42 AC_CHECK_PROG(HAVE_PKGMK, pkgmk, "yes", "no")
  43 AC_CHECK_PROG(HAVE_PKGTRANS, pkgtrans, "yes", "no")
  44 AC_CHECK_PROG(HAVE_RPM, rpm, "yes", "no")
  45
  46 if test x$HAVE_PKGPROTO = xyes -a x$HAVE_PKGMK = xyes \
  47      -a x$HAVE_PKGTRANS = xyes ; then
  48   HAVE_SVR4_PACKAGING=yes
  49 else
  50   HAVE_SVR4_PACKAGING=no
  51 fi
  52 AC_SUBST(HAVE_SVR4_PACKAGING)
  53
  54 # Grr.  Rpm 2.x has a nifty "--showrc" flag that lists all of the current
  55 # configuration values.  Version 3.x took the niftiness away by returning
  56 # the values in their raw, unexpanded, macro-embedded form.  We can either
  57 # try to expand the values we get from 3.x, or poke around for popular build
  58 # directories.
  59 HAVE_RPM_PACKAGING=no
  60 if test x$HAVE_RPM = xyes ; then
  61   AC_MSG_CHECKING(for rpm build directories)
  62   RPM_SOURCESDIR=`rpm --showrc | grep "^sourcedir" | \
  63     sed -e 's/.*: //' 2> /dev/null`
  64   if test x$RPM_SPECDIR = x ; then
  65     # Red Hat  : /usr/src/redhat
  66     # Mandrake : /usr/scr/rpm
  67     # SuSE     : /usr/src/packages
  68     for TEST_DIR in /usr/src/redhat /usr/src/rpm /usr/src/packages ; do
  69       if test -d $TEST_DIR/SPECS -a -d $TEST_DIR/SOURCES -a \
  70               -d $TEST_DIR/RPMS -a -d $TEST_DIR/SRPMS -a \
  71               -d $TEST_DIR/BUILD ; then
  72         RPM_SOURCESDIR=$TEST_DIR/SOURCES
  73       fi
  74     done
  75   fi
  76   if test x$RPM_SOURCESDIR = x ; then
  77     AC_MSG_RESULT(not found)
  78     RPM_SOURCESDIR=""
  79   else
  80     AC_MSG_RESULT(found)
  81     HAVE_RPM_PACKAGING=yes
  82   fi
  83 fi
  84 AC_SUBST(HAVE_RPM_PACKAGING)
  85
  86
  87 # If we're running gcc, add '-Wall' to CFLAGS.
  88 AC_MSG_CHECKING(to see if we can add '-Wall' to CFLAGS)
  89 if test x$GCC != x ; then
  90   CFLAGS="-Wall $CFLAGS"
  91   AC_MSG_RESULT(yes)
  92 else
  93   AC_MSG_RESULT(no)
  94 fi
  95
  96 #
  97 # Add any platform-specific compiler flags needed.
  98 #
  99 AC_MSG_CHECKING(for platform-specific compiler flags)
 100 if test "x$GCC" = x
 101 then
 102         #
 103         # Not GCC - assume it's the vendor's compiler.
 104         #
 105         case "$host_os" in
 106         hpux*)
 107                 #
 108                 # HP's ANSI C compiler; flags suggested by Jost Martin.
 109                 # "-Ae" for ANSI C plus extensions such as "long long".
 110                 # "+O2", for optimization.  XXX - works with "-g"?
 111                 #
 112                 CFLAGS="-Ae +O2 $CFLAGS"
 113                 AC_MSG_RESULT(HP ANSI C compiler - added -Ae +O2)
 114                 ;;
 115         *)
 116                 AC_MSG_RESULT(none needed)
 117                 ;;
 118         esac
 119 else
 120         case "$host_os" in
 121         solaris*)
 122                 # the X11 headers don't automatically include prototype info
 123                 # and a lot don't include the return type
 124                 CFLAGS="$CFLAGS -Wno-return-type -DFUNCPROTO=15"
 125                 AC_MSG_RESULT(GCC on Solaris - added -Wno-return-type -DFUNCPROTO=15)
 126                 ;;
 127         *)
 128                 AC_MSG_RESULT(none needed)
 129                 ;;
 130         esac
 131 fi
 132
 133 #
 134 # Arrange that we search for header files in the source directory
 135 # and in its "wiretap" subdirectory, as well as in "/usr/local/include",
 136 # as various packages we use ("libpcap", "zlib", an SNMP library)
 137 # may have been installed under "/usr/local/include".
 138 #
 139 CFLAGS="$CFLAGS -I\$(top_srcdir) -I\$(top_srcdir)/wiretap -I\$(top_srcdir)/epan -I/usr/local/include"
 140 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir) -I\$(top_srcdir)/wiretap -I\$(top_srcdir)/epan -I/usr/local/include"
 141
 142 #
 143 # Arrange that we search for libraries in "/usr/local/lib".
 144 #
 145 AC_ETHEREAL_ADD_DASH_L(LDFLAGS, /usr/local/lib)
 146
 147 # Create DATAFILE_DIR #define for config.h
 148 DATAFILE_DIR=$sysconfdir
 149 DATAFILE_DIR=`(
 150     test "x$prefix" = xNONE && prefix=$ac_default_prefix
 151     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
 152     eval echo "$DATAFILE_DIR"
 153 )`
 154 AC_DEFINE_UNQUOTED(DATAFILE_DIR,"$DATAFILE_DIR")
 155 AC_SUBST(DATAFILE_DIR)
 156
 157 # If we're running Solaris, and LD_LIBRARY_PATH is defined, add it as a
 158 # link directory.
 159 case "$host_os" in
 160   solaris*)
 161     AC_MSG_CHECKING(for LD_LIBRARY_PATH, since you appear to be running Solaris)
 162     if test x$LD_LIBRARY_PATH != x ; then
 163       LIBS="$LIBS -R$LD_LIBRARY_PATH"
 164       AC_MSG_RESULT(yes -- added LD_LIBRARY_PATH to run-time linker path)
 165     else
 166       AC_MSG_RESULT(no -- this may be a problem in a few seconds)
 167     fi
 168   ;;
 169 esac
 170
 171
 172 # Enable/disable tethereal
 173
 174 GTK_OK=yes
 175
 176 AC_ARG_ENABLE(ethereal,
 177 [  --enable-ethereal       build GTK+-based ethereal.  [default=yes]],,enable_ethereal=yes)
 178
 179 # GTK checks
 180 # We don't add $GLIB_LIBS to LIBS, because we don't want to force all
 181 # programs to be built with GTK+.
 182 #
 183 if test "x$enable_ethereal" = "xyes" ; then
 184         AM_PATH_GTK(1.2.0, CFLAGS="$CFLAGS $GTK_CFLAGS", GTK_OK=no )
 185 fi
 186
 187 # GLib checks
 188 # This doesn't add GLIB_CFLAGS to CFLAGS, because AM_PATH_GTK will add
 189 # GTK_CFLAGS to CFLAGS, and GTK_CFLAGS is a superset of CFLAGS.
 190 # However, this means that both @GLIB_LIBS@ and @GTK_LIBS@ will be
 191 # set when generating the Makefile, so we can make programs that require
 192 # only GLib link with @GLIB_LIBS@ and make programs that require GTK+
 193 # link with @GTK_LIBS@ (which includes @GLIB_LIBS@).
 194 # We don't add $GLIB_LIBS to LIBS, because we don't want to force all
 195 # programs to be built with GLib.
 196 #
 197 if test "$GTK_OK" = "yes" -a "x$enable_ethereal" = "xyes" ; then
 198         ethereal_bin="ethereal"
 199         ethereal_man="ethereal.1"
 200         ethereal_SUBDIRS="gtk"
 201
 202         # Ignore GLIB_CFLAGS
 203         AM_PATH_GLIB(1.2.0, , AC_MSG_ERROR(GLib distribution not found.), gmodule)
 204 else
 205         enable_ethereal="no"
 206         ethereal_bin=""
 207         ethereal_man=""
 208         # Honor GLIB_CFLAGS
 209         AM_PATH_GLIB(1.2.0, CFLAGS="$CFLAGS $GLIB_CFLAGS", AC_MSG_ERROR(GLib distribution not found.), gmodule)
 210 fi
 211
 212 #
 213 # Check whether GLib modules are supported, to determine whether we
 214 # can support plugins.
 215 #
 216 AC_MSG_CHECKING(whether GLib supports loadable modules)
 217 ac_save_CFLAGS="$CFLAGS"
 218 ac_save_LIBS="$LIBS"
 219 CFLAGS="$CFLAGS $GLIB_CFLAGS"
 220 LIBS="$GLIB_LIBS $LIBS"
 221 AC_TRY_RUN([
 222 #include <glib.h>
 223 #include <gmodule.h>
 224 #include <stdio.h>
 225 #include <stdlib.h>
 226
 227 int
 228 main ()
 229 {
 230   if (g_module_supported())
 231     return 0;   /* success */
 232   else
 233     return 1;   /* failure */
 234 }
 235 ], ac_cv_glib_supports_modules=yes, ac_cv_glib_supports_modules=no,
 236    [echo $ac_n "cross compiling; assumed OK... $ac_c"])
 237 CFLAGS="$ac_save_CFLAGS"
 238 LIBS="$ac_save_LIBS"
 239 if test "$ac_cv_glib_supports_modules" = yes ; then
 240   AC_MSG_RESULT(yes)
 241   AC_DEFINE(HAVE_PLUGINS)
 242 else
 243   AC_MSG_RESULT(no)
 244 fi
 245
 246
 247 AC_SUBST(ethereal_bin)
 248 AC_SUBST(ethereal_man)
 249
 250
 251
 252 # Enable/disable tethereal
 253
 254 AC_ARG_ENABLE(tethereal,
 255 [  --enable-tethereal      build tethereal.  [default=yes]],,enable_tethereal=yes)
 256
 257 if test "x$enable_tethereal" = "xyes" ; then
 258         tethereal_bin="tethereal"
 259         tethereal_man="tethereal.1"
 260 else
 261         tethereal_bin=""
 262         tethereal_man=""
 263 fi
 264 AC_SUBST(tethereal_bin)
 265 AC_SUBST(tethereal_man)
 266
 267
 268
 269 # Enable/disable editcap
 270
 271 AC_ARG_ENABLE(editcap,
 272 [  --enable-editcap        build editcap.  [default=yes]],,enable_editcap=yes)
 273
 274 if test "x$enable_editcap" = "xyes" ; then
 275         editcap_bin="editcap"
 276         editcap_man="editcap.1"
 277 else
 278         editcap_bin=""
 279         editcap_man=""
 280 fi
 281 AC_SUBST(editcap_bin)
 282 AC_SUBST(editcap_man)
 283
 284
 285 # Enable/disable text2pcap
 286
 287 AC_ARG_ENABLE(text2pcap,
 288 [  --enable-text2pcap        build text2pcap.  [default=yes]],,enable_text2pcap=yes)
 289
 290 if test "x$enable_text2pcap" = "xyes" ; then
 291         text2pcap_bin="text2pcap"
 292         text2pcap_man="text2pcap.1"
 293 else
 294         text2pcap_bin=""
 295         text2pcap_man=""
 296 fi
 297 AC_SUBST(text2pcap_bin)
 298 AC_SUBST(text2pcap_man)
 299
 300
 301 # Enable/disable dftest
 302
 303 AC_ARG_ENABLE(dftest,
 304 [  --enable-dftest         build dftest.  [default=no]],,enable_dftest=no)
 305
 306 if test "x$enable_dftest" = "xyes" ; then
 307         dftest_bin="dftest"
 308 else
 309         dftest_bin=""
 310 fi
 311 AC_SUBST(dftest_bin)
 312
 313
 314 # Enable/disable randpkt
 315
 316 AC_ARG_ENABLE(randpkt,
 317 [  --enable-randpkt        build randpkt.  [default=no]],,enable_randpkt=no)
 318
 319 if test "x$enable_randpkt" = "xyes" ; then
 320         randpkt_bin="randpkt"
 321 else
 322         randpkt_bin=""
 323 fi
 324 AC_SUBST(randpkt_bin)
 325
 326
 327 dnl Checks for "gethostbyname()" - and "-lnsl", if we need it to get
 328 dnl "gethostbyname()".
 329 AC_ETHEREAL_GETHOSTBY_LIB_CHECK
 330
 331 dnl Checks for "connect()", used as a proxy for "socket()" - and
 332 dnl "-lsocket", if we need it to get "connect()".
 333 AC_ETHEREAL_SOCKET_LIB_CHECK
 334
 335 dnl pcap check
 336 AC_ARG_ENABLE(pcap,
 337 [  --enable-pcap           use libpcap for packet capturing.  [default=yes]],,enable_pcap=yes)
 338
 339 AC_MSG_CHECKING(whether to use libpcap for packet capture)
 340 if test "x$enable_pcap" = "xno" ; then
 341         AC_MSG_RESULT(no)
 342 else
 343         AC_MSG_RESULT(yes)
 344         AC_ETHEREAL_PCAP_CHECK
 345 fi
 346
 347 dnl zlib check
 348 AC_ARG_ENABLE(zlib,
 349 [  --enable-zlib           use zlib to read compressed data.  [default=yes]],,enable_zlib=yes)
 350
 351 AC_MSG_CHECKING(whether to use zlib for reading compressed capture files)
 352 if test "x$enable_zlib" = "xno" ; then
 353         AC_MSG_RESULT(no)
 354 else
 355         AC_MSG_RESULT(yes)
 356         AC_ETHEREAL_ZLIB_CHECK
 357         if test "x$enable_zlib" = "xno" ; then
 358                 AC_MSG_RESULT(zlib not found - disabling compressed capture file support)
 359         fi
 360 fi
 361
 362
 363 dnl ipv6 check
 364 AC_ARG_ENABLE(ipv6,
 365 [  --enable-ipv6           use ipv6 name resolution, if available.  [default=yes]],,enable_ipv6=yes)
 366
 367 AC_MSG_CHECKING(whether to enable ipv6 name resolution if available)
 368 if test "x$enable_ipv6" = "xno" ; then
 369         AC_MSG_RESULT(no)
 370 else
 371         AC_MSG_RESULT(yes)
 372         AC_ETHEREAL_IPV6_STACK
 373 fi
 374
 375
 376 dnl Check if ethereal should be installed setuid
 377 AC_ARG_ENABLE(setuid-install,
 378 [  --enable-setuid-install install ethereal as setuid. DANGEROUS!!! [default=no]],,enable_setuid_install=no)
 379
 380 AC_MSG_CHECKING(whether to install ethereal setuid)
 381 if test "x$enable_setuid_install" = "xno" ; then
 382         AC_MSG_RESULT(no)
 383 else
 384         AC_MSG_RESULT(yes)
 385 fi
 386
 387 dnl Checks for header files.
 388 AC_HEADER_STDC
 389 AC_CHECK_HEADERS(fcntl.h sys/ioctl.h sys/time.h unistd.h stdarg.h netdb.h)
 390 AC_CHECK_HEADERS(sys/stat.h sys/sockio.h sys/types.h sys/socket.h)
 391 AC_CHECK_HEADERS(sys/wait.h)
 392 AC_CHECK_HEADERS(netinet/in.h)
 393 AC_CHECK_HEADERS(stddef.h)
 394 AC_CHECK_HEADERS(arpa/inet.h)
 395
 396 dnl SSL Check
 397 SSL_LIBS=''
 398 AC_MSG_CHECKING(whether to use SSL library if available)
 399 if test "x$enable_ssl" = "xno" ; then
 400         AC_MSG_RESULT(no)
 401 else
 402         AC_MSG_RESULT(yes)
 403         AC_ETHEREAL_SSL_CHECK
 404 fi
 405 AC_SUBST(SSL_LIBS)
 406
 407 dnl SNMP Check
 408 AC_ARG_ENABLE(snmp,
 409 [  --enable-snmp           use SNMP library, if available.  [default=yes]],,enable_snmp=yes)
 410
 411 SNMP_LIBS=''
 412 AC_MSG_CHECKING(whether to use SNMP library if available)
 413 if test "x$enable_snmp" = "xno" ; then
 414         AC_MSG_RESULT(no)
 415 else
 416         AC_MSG_RESULT(yes)
 417         AC_ETHEREAL_UCDSNMP_CHECK
 418         AC_CHECK_HEADERS(ucd-snmp/snmp.h ucd-snmp/version.h snmp/snmp.h snmp/version.h)
 419
 420         #
 421         # If we found both UCD and CMU SNMP headers, die, as both
 422         # packages install the SNMP library as "libsnmp", so either
 423         # only one of them is present or they're in different
 424         # directories, and we run the risk of picking up the headers
 425         # from one and the library from another.
 426         #
 427         if test "$ac_cv_header_ucd_snmp_snmp_h" = yes -a \
 428            "$ac_cv_header_snmp_snmp_h" = yes ; then
 429             AC_MSG_ERROR([Both UCD and CMU SNMP libraries found - uninstall one of them.])
 430         fi
 431
 432         #
 433         # This may require "-lkstat" on Solaris, sigh.
 434         #
 435         AC_CHECK_LIB(snmp, sprint_objid,
 436           SNMP_LIBS=-lsnmp,
 437           [
 438             #
 439             # Throw away the cached "we didn't find it" answer.
 440             #
 441             unset ac_cv_lib_snmp_sprint_objid
 442             AC_CHECK_LIB(snmp, sprint_objid,
 443               [
 444                 #
 445                 # Throw away the cached "we found it" answer, so that if
 446                 # we rerun "configure", we don't just blow off this check
 447                 # and blithely assume that we don't need "-lkstat".
 448                 #
 449                 # XXX - autoconf really needs a way to test for a given
 450                 # routine in a given library *and* to test whether additional
 451                 # "-L"/"-R"/whatever flags are needed *before* the "-l"
 452                 # flag for the library and to test whether additional libraries
 453                 # are needed after the library *and* to cache all that
 454                 # information.
 455                 #
 456                 unset ac_cv_lib_snmp_sprint_objid
 457                 SNMP_LIBS="-lsnmp -lkstat"
 458               ],,$SOCKET_LIBS $NSL_LIBS $SSL_LIBS -lkstat
 459             )
 460           ], $SOCKET_LIBS $NSL_LIBS $SSL_LIBS
 461         )
 462
 463         #
 464         # If we have SNMP header files but didn't find "sprint_objid()",
 465         # fail, as there's something wrong (perhaps the user needs to
 466         # specify "--with-ssl").
 467         #
 468         if test '(' "$ac_cv_header_ucd_snmp_snmp_h" = yes -o \
 469            "$ac_cv_header_snmp_snmp_h" = yes ')' -a \
 470            "$ac_cv_lib_snmp_sprint_objid" = no; then
 471             AC_MSG_ERROR([SNMP header files found, but sprint_objid not found in SNMP library.])
 472         fi
 473 fi
 474 AC_SUBST(SNMP_LIBS)
 475
 476 dnl Checks for typedefs, structures, and compiler characteristics.
 477 # AC_C_CONST
 478
 479 # We need to know whether "struct sockaddr" has an "sa_len" member
 480 # for get_interface_list().
 481
 482 AC_ETHEREAL_STRUCT_SA_LEN
 483
 484 # We must know our byte order
 485 AC_C_BIGENDIAN
 486
 487 # Checks whether "-traditional" is needed when using "ioctl".
 488 # XXX - do we need this?
 489 AC_PROG_GCC_TRADITIONAL
 490
 491 # If there's a system out there that has snprintf and _doesn't_ have vsnprintf,
 492 # then this won't work.
 493 SNPRINTF_C=""
 494 SNPRINTF_O=""
 495 AC_CHECK_FUNC(snprintf, SNPRINTF_O="",
 496   SNPRINTF_O="snprintf.o" [AC_DEFINE(NEED_SNPRINTF_H)])
 497 if test "$ac_cv_func_snprintf" = no ; then
 498   SNPRINTF_C="snprintf.c"
 499   SNPRINTF_O="snprintf.o"
 500 fi
 501 AC_SUBST(SNPRINTF_C)
 502 AC_SUBST(SNPRINTF_O)
 503
 504 AC_CHECK_FUNC(strerror, STRERROR_O="",
 505   STRERROR_O="strerror.o" [AC_DEFINE(NEED_STRERROR_H)])
 506 if test "$ac_cv_func_strerror" = no ; then
 507   STRERROR_C="strerror.c"
 508   STRERROR_O="strerror.o"
 509 fi
 510 AC_SUBST(STRERROR_C)
 511 AC_SUBST(STRERROR_O)
 512
 513 AC_CHECK_FUNC(strcasecmp, STRCASECMP_O="",
 514   STRCASECMP_O="strcasecmp.o")
 515 if test "$ac_cv_func_strcasecmp" = no ; then
 516   STRCASECMP_C="strcasecmp.c"
 517   STRCASECMP_O="strcasecmp.o"
 518 fi
 519 AC_SUBST(STRCASECMP_C)
 520 AC_SUBST(STRCASECMP_O)
 521
 522 AC_CHECK_FUNC(strncasecmp, STRNCASECMP_O="",
 523   STRNCASECMP_O="strncasecmp.o")
 524 if test "$ac_cv_func_strncasecmp" = no ; then
 525   STRNCASECMP_C="strncasecmp.c"
 526   STRNCASECMP_O="strncasecmp.o"
 527 fi
 528 AC_SUBST(STRNCASECMP_C)
 529 AC_SUBST(STRNCASECMP_O)
 530
 531 AC_CHECK_FUNC(mkstemp, MKSTEMP_O="",
 532   MKSTEMP_O="mkstemp.o")
 533 if test "$ac_cv_func_mkstemp" = no ; then
 534   MKSTEMP_C="mkstemp.c"
 535   MKSTEMP_O="mkstemp.o"
 536 fi
 537 AC_SUBST(MKSTEMP_C)
 538 AC_SUBST(MKSTEMP_O)
 539
 540 AC_CHECK_FUNC(strptime, STRPTIME_O="",
 541   STRPTIME_O="strptime.o" [AC_DEFINE(NEED_STRPTIME_H)])
 542 if test "$ac_cv_func_strptime" = no ; then
 543   STRPTIME_C="strptime.c"
 544   STRPTIME_O="strptime.o"
 545 fi
 546 AC_SUBST(STRPTIME_C)
 547 AC_SUBST(STRPTIME_O)
 548
 549 AC_CHECK_FUNCS(getprotobynumber gethostbyname2)
 550
 551 dnl blank for now, but will be used in future
 552 AC_SUBST(ethereal_SUBDIRS)
 553
 554 dnl check for plugins directory - stolen from Amanda's configure.in
 555 PLUGIN_DIR="$libdir/ethereal/plugins/$VERSION"
 556 AC_ARG_WITH(plugindir,
 557   [  --with-plugindir=DIR    install plugins in DIR],
 558   [
 559   case "$withval" in
 560   "" | y | ye | yes )
 561     AC_MSG_ERROR([*** You must supply an argument to the --with-plugindir option.])
 562   ;;
 563   n | no)
 564     AC_MSG_ERROR([*** The --without-plugindir option is not supported.])
 565   ;;
 566   *) PLUGIN_DIR="$withval"
 567   esac
 568   ]
 569 )
 570
 571 PLUGIN_DIR=`(
 572   test "x$prefix" = xNONE && prefix=$ac_default_prefix
 573   test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
 574   eval echo "$PLUGIN_DIR"
 575 )`
 576 AC_DEFINE_UNQUOTED(PLUGIN_DIR,"$PLUGIN_DIR", [Plugin installation directory])
 577 AC_SUBST(PLUGIN_DIR)
 578
 579 dnl libtool defs
 580 AC_LIBTOOL_DLOPEN
 581 AM_PROG_LIBTOOL
 582 AC_SUBST(LIBTOOL_DEPS)
 583
 584 AM_CONFIG_HEADER(config.h)
 585 AC_CONFIG_SUBDIRS(epan wiretap)
 586 AC_OUTPUT(
 587   Makefile
 588   doc/Makefile
 589   gtk/Makefile
 590   packaging/Makefile
 591   packaging/nsis/Makefile
 592   packaging/rpm/Makefile
 593   packaging/rpm/ethereal.spec
 594   packaging/svr4/Makefile
 595   packaging/svr4/checkinstall
 596   packaging/svr4/pkginfo
 597   plugins/Makefile
 598   plugins/gryphon/Makefile
 599   plugins/mgcp/Makefile
 600   tools/Makefile
 601   tools/lemon/Makefile
 602   ,)
 603
 604
 605 # Pretty messages
 606
 607 if test "x$enable_setuid_install" = "xyes" ; then
 608         setuid_message="yes (DANGEROUS!!!)"
 609 else
 610         setuid_message="no"
 611 fi
 612
 613 if test "x$SNMP_LIBS" = "x" ; then
 614         snmp_libs_message="no"
 615 else
 616         snmp_libs_message="yes"
 617 fi
 618
 619
 620
 621 echo ""
 622 echo "The Ethereal package has been configured with the following options."
 623 echo "                    Build ethereal : $enable_ethereal"
 624 echo "                   Build tethereal : $enable_tethereal"
 625 echo "                     Build editcap : $enable_editcap"
 626 echo "                   Build text2pcap : $enable_text2pcap"
 627 echo "                     Build randpkt : $enable_randpkt"
 628 echo "                      Build dftest : $enable_dftest"
 629 echo ""
 630 echo "                    Install setuid : $setuid_message"
 631 echo "                  Use pcap library : $enable_pcap"
 632 echo "                  Use zlib library : $enable_zlib"
 633 echo "          Use IPv6 name resolution : $enable_ipv6"
 634 echo "                  Use SNMP library : $snmp_libs_message"
 635
 636