This commit contains support for reading capture files compressed using
[obnox/wireshark/wip.git] / configure.in
1 # $Id: configure.in,v 1.43 1999/09/22 01:26:23 ashokn Exp $
2 dnl Process this file with autoconf to produce a configure script.
3 AC_INIT(etypes.h)
4
5 AM_INIT_AUTOMAKE(ethereal, 0.7.3)
6
7 dnl Check for CPU / vendor / OS
8 AC_CANONICAL_HOST
9
10 dnl Checks for programs.
11 AC_PROG_CC
12 AC_PROG_CPP
13 AC_PROG_RANLIB
14 AC_PROG_YACC
15 AM_PROG_LEX
16 AC_PATH_PROG(PERL_PATH, perl)
17 AC_PATH_PROG(LEX, flex)
18
19 AC_SUBST(PERL_PATH)
20 AC_SUBST(FLEX_PATH)
21
22
23 # If we're running gcc, add '-Wall' to CFLAGS.
24 AC_MSG_CHECKING(to see if we can add '-Wall' to CFLAGS)
25 if test x$GCC != x ; then
26   CFLAGS="-Wall $CFLAGS"
27   AC_MSG_RESULT(yes)
28 else
29   AC_MSG_RESULT(no)
30 fi
31
32 CFLAGS="$CFLAGS -Iwiretap"
33
34 # Create DATAFILE_DIR #define for config.h
35 DATAFILE_DIR=$sysconfdir
36 DATAFILE_DIR=`(
37     test "x$prefix" = xNONE && prefix=$ac_default_prefix
38     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
39     eval echo "$DATAFILE_DIR"
40 )`
41 AC_DEFINE_UNQUOTED(DATAFILE_DIR,"$DATAFILE_DIR")
42 AC_SUBST(DATAFILE_DIR)
43
44 # If we're running Solaris, and LD_LIBRARY_PATH is defined, add it as a
45 # link directory.
46 case "$host_os" in
47   solaris*)
48     AC_MSG_CHECKING(for LD_LIBRARY_PATH, since you appear to be running Solaris)
49     if test x$LD_LIBRARY_PATH != x ; then
50       LIBS="$LIBS -R$LD_LIBRARY_PATH"
51       AC_MSG_RESULT(yes -- added LD_LIBRARY_PATH to run-time linker path)
52     else
53       AC_MSG_RESULT(no -- this may be a problem in a few seconds)
54     fi
55   ;;
56 esac
57
58 # GTK checks
59 AM_PATH_GTK(1.2.0, CFLAGS="$CFLAGS $GTK_CFLAGS" LIBS="$LIBS $GTK_LIBS",
60                    AC_MSG_ERROR(GTK+ distribution not found.))
61
62 dnl pcap check
63 AC_ARG_ENABLE(pcap,
64 [  --enable-pcap           use libpcap for packet capturing.  [default=yes]],,enable_pcap=yes)
65
66 AC_MSG_CHECKING(whether to use libpcap for packet capture)
67 if test "x$enable_pcap" = "xno" ; then
68         AC_MSG_RESULT(no)
69 else
70         AC_MSG_RESULT(yes)
71         AC_ETHEREAL_PCAP_CHECK
72 fi
73
74 dnl zlib check
75 AC_ARG_ENABLE(zlib,
76 [  --enable-zlib           use zlib to read compressed data.  [default=yes]],,enable_zlib=yes)
77
78 AC_MSG_CHECKING(whether to use zlib for reading compressed capture files)
79 if test "x$enable_zlib" = "xno" ; then
80         AC_MSG_RESULT(no)
81 else
82         AC_MSG_RESULT(yes)
83         AC_ETHEREAL_ZLIB_CHECK
84         if test "x$enable_zlib" = "xno" ; then
85                 AC_MSG_RESULT(zlib not found - disabling compressed capture file support)
86         fi
87 fi
88
89
90 dnl ipv6 check
91 AC_ARG_ENABLE(ipv6,
92 [  --enable-ipv6           use ipv6 name resolution, if available.  [default=yes]],,enable_ipv6=yes)
93
94 AC_MSG_CHECKING(whether to enable ipv6 name resolution if available)
95 if test "x$enable_ipv6" = "xno" ; then
96         AC_MSG_RESULT(no)
97 else
98         AC_MSG_RESULT(yes)
99         AC_ETHEREAL_IPV6_STACK
100 fi
101
102
103 dnl Checks for header files.
104 AC_HEADER_STDC
105 AC_CHECK_HEADERS(fcntl.h sys/ioctl.h sys/time.h unistd.h stdarg.h netdb.h)
106 AC_CHECK_HEADERS(sys/stat.h sys/sockio.h sys/types.h netinet/in.h sys/socket.h net/if.h)
107
108 dnl SNMP Check
109 AC_ARG_ENABLE(snmp,
110 [  --enable-snmp           use SNMP library, if available.  [default=yes]],,enable_snmp=yes)
111
112 SNMP_A=''
113 SNMP_O=''
114 AC_MSG_CHECKING(whether to use SNMP library if available)
115 if test "x$enable_snmp" = "xno" ; then
116         AC_MSG_RESULT(no)
117 else
118         AC_MSG_RESULT(yes)
119         AC_ETHEREAL_UCDSNMP_CHECK
120         AC_CHECK_HEADERS(ucd-snmp/snmp.h snmp/snmp.h)
121         AC_CHECK_LIB(snmp, asn_parse_header,
122                 [
123                 SNMP_A=-lsnmp
124                 SNMP_O=packet-snmp.o
125                 ], )
126 fi
127 AC_SUBST(SNMP_A)
128 AC_SUBST(SNMP_O)
129
130 dnl Checks for typedefs, structures, and compiler characteristics.
131 # AC_C_CONST
132
133 # We need to know whether "struct sockaddr" has an "sa_len" member
134 # for get_interface_list().
135
136 AC_ETHEREAL_STRUCT_SA_LEN
137
138 # We must know our byte order
139 AC_C_BIGENDIAN
140
141 dnl Checks for library functions.
142 AC_PROG_GCC_TRADITIONAL
143 AC_CHECK_FUNC(socket,, AC_MSG_ERROR(Function 'socket' not found.))
144
145 # If there's a system out there that has snprintf and _doesn't_ have vsnprintf,
146 # then this won't work.
147 SNPRINTF_C=""
148 SNPRINTF_O=""
149 AC_CHECK_FUNC(snprintf, SNPRINTF_O="",
150   SNPRINTF_O="snprintf.o" [AC_DEFINE(NEED_SNPRINTF_H)])
151 if test "$ac_cv_func_snprintf" = no ; then
152   SNPRINTF_C="snprintf.c"
153   SNPRINTF_O="snprintf.o"
154 fi
155 AC_SUBST(SNPRINTF_C)
156 AC_SUBST(SNPRINTF_O)
157
158 AC_CHECK_FUNC(strerror, STRERROR_O="",
159   STRERROR_O="strerror.o" [AC_DEFINE(NEED_STRERROR_H)])
160 if test "$ac_cv_func_strerror" = no ; then
161   STRERROR_C="strerror.c"
162   STRERROR_O="strerror.o"
163 fi
164 AC_SUBST(STRERROR_C)
165 AC_SUBST(STRERROR_O)
166
167 dnl blank for now, but will be used in future
168 AC_SUBST(SUBDIRS)
169
170 AM_CONFIG_HEADER(config.h)
171 AC_CONFIG_SUBDIRS(wiretap)
172 AC_OUTPUT(Makefile ethereal.spec doc/Makefile doc/dfilter2pod gtk/Makefile,
173         [chmod +x doc/dfilter2pod])