Removed trailing whitespaces from .h and .c files using the
[obnox/wireshark/wip.git] / configure.in
1 # $Id: configure.in,v 1.174 2002/08/28 00:37:17 jmayer Exp $
2 dnl
3 dnl Process this file with autoconf 2.13 or later to produce a
4 dnl configure script; 2.12 doesn't generate a "configure" script that
5 dnl defines SHELL, and "Makefile.in" has
6 dnl
7 dnl     SHELL = @SHELL@
8 dnl
9 dnl which requires it to be defined - and there may be other problems
10 dnl with pre-2.13 "autoconf" as well.
11 dnl
12 AC_INIT(etypes.h)
13
14 AC_PREREQ(2.13)
15
16 AM_INIT_AUTOMAKE(ethereal, 0.9.6)
17
18 dnl Check for CPU / vendor / OS
19 AC_CANONICAL_HOST
20
21 dnl Checks for programs.
22 AC_PROG_CC
23 AC_PROG_CPP
24 AC_LIBTOOL_DLOPEN
25 AC_PROG_LIBTOOL
26 AC_PROG_YACC
27 AM_PROG_LEX
28 AC_PATH_PROG(PERL, perl)
29 AC_PATH_PROG(POD2MAN, pod2man)
30 AC_PATH_PROG(LEX, flex)
31 AC_PATH_PROG(PYTHON, python)
32
33 AC_SUBST(PERL)
34 AC_SUBST(LEX)
35 AC_SUBST(PYTHON)
36
37 # Check for packaging utilities
38 # For now, we check to see if the various packaging utilites are in our
39 # path.  I'm too lazy to write code to go hunt for them.  -  Gerald
40 AC_CHECK_PROG(HAVE_PKGPROTO, pkgproto, "yes", "no")
41 AC_CHECK_PROG(HAVE_PKGMK, pkgmk, "yes", "no")
42 AC_CHECK_PROG(HAVE_PKGTRANS, pkgtrans, "yes", "no")
43
44 if test x$HAVE_PKGPROTO = xyes -a x$HAVE_PKGMK = xyes \
45      -a x$HAVE_PKGTRANS = xyes ; then
46   HAVE_SVR4_PACKAGING=yes
47 else
48   HAVE_SVR4_PACKAGING=no
49 fi
50 AC_SUBST(HAVE_SVR4_PACKAGING)
51
52 AC_ETHEREAL_RPM_CHECK
53 AC_SUBST(HAVE_RPM)
54
55 #
56 # If we're running gcc, add '-Wall -W' to CFLAGS, and add
57 # '-D_U_="__attribute__((unused))"' as well, so we can use _U_ to
58 # flag unused function arguments and not get warnings about them.
59 #
60 # Otherwise, add '-D_U_=""', so that _U_ used to flag an unused function
61 # argument will compile with non-GCC compilers.
62 #
63 AC_MSG_CHECKING(to see if we can add '-Wall -W' to CFLAGS)
64 if test x$GCC != x ; then
65   CFLAGS="-D_U_=\"__attribute__((unused))\" -Wall -W $CFLAGS"
66   AC_MSG_RESULT(yes)
67 else
68   CFLAGS="-D_U_=\"\" $CFLAGS"
69   AC_MSG_RESULT(no)
70 fi
71
72 #
73 # Add any platform-specific compiler flags needed.
74 #
75 AC_MSG_CHECKING(for platform-specific compiler flags)
76 if test "x$GCC" = x
77 then
78         #
79         # Not GCC - assume it's the vendor's compiler.
80         #
81         case "$host_os" in
82         hpux*)
83                 #
84                 # HP's ANSI C compiler; flags suggested by Jost Martin.
85                 # "-Ae" for ANSI C plus extensions such as "long long".
86                 # "+O2", for optimization.  XXX - works with "-g"?
87                 #
88                 CFLAGS="-Ae +O2 $CFLAGS"
89                 AC_MSG_RESULT(HP ANSI C compiler - added -Ae +O2)
90                 ;;
91         darwin*)
92                 #
93                 # It may be called "cc", but it's really a GCC derivative
94                 # with a problematic special precompiler and precompiled
95                 # headers; turn off the special precompiler, as some
96                 # apparently-legal code won't compile with its precompiled
97                 # headers.
98                 #
99                 CFLAGS="-no-cpp-precomp $CFLAGS"
100                 AC_MSG_RESULT(Apple GCC - added -no-cpp-precomp)
101                 ;;
102         *)
103                 AC_MSG_RESULT(none needed)
104                 ;;
105         esac
106 else
107         case "$host_os" in
108         solaris*)
109                 # the X11 headers don't automatically include prototype info
110                 # and a lot don't include the return type
111                 CFLAGS="$CFLAGS -Wno-return-type -DFUNCPROTO=15"
112                 AC_MSG_RESULT(GCC on Solaris - added -Wno-return-type -DFUNCPROTO=15)
113                 ;;
114         darwin*)
115                 #
116                 # See comments above about Apple's lovely C compiler.
117                 #
118                 CFLAGS="-no-cpp-precomp $CFLAGS"
119                 AC_MSG_RESULT(Apple GCC - added -no-cpp-precomp)
120                 ;;
121         *)
122                 AC_MSG_RESULT(none needed)
123                 ;;
124         esac
125 fi
126
127 CFLAGS="$CFLAGS -I\$(top_srcdir) -I\$(top_srcdir)/wiretap"
128 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir) -I\$(top_srcdir)/wiretap"
129
130 dnl Look in /usr/local for header files and libraries ?
131 AC_ARG_ENABLE(usr-local,
132 [  --enable-usr-local      look for headers and libs in /usr/local tree.  [default=yes]],enable_usr_local=$enableval,enable_usr_local=yes)
133
134 AC_MSG_CHECKING(whether to use /usr/local for headers and libraries)
135 if test "x$enable_usr_local" = "xyes" ; then
136         AC_MSG_RESULT(yes)
137         #
138         # Arrange that we search for header files in the source directory
139         # and in its "wiretap" subdirectory, as well as in "/usr/local/include",
140         # as various packages we use ("libpcap", "zlib", an SNMP library)
141         # may have been installed under "/usr/local/include".
142         #
143         CFLAGS="$CFLAGS -I/usr/local/include"
144         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
145
146         #
147         # Arrange that we search for libraries in "/usr/local/lib".
148         #
149         AC_ETHEREAL_ADD_DASH_L(LDFLAGS, /usr/local/lib)
150 else
151         AC_MSG_RESULT(no)
152 fi
153
154 # Create DATAFILE_DIR #define for config.h
155 DATAFILE_DIR=$sysconfdir
156 DATAFILE_DIR=`(
157     test "x$prefix" = xNONE && prefix=$ac_default_prefix
158     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
159     eval echo "$DATAFILE_DIR"
160 )`
161 AC_DEFINE_UNQUOTED(DATAFILE_DIR,"$DATAFILE_DIR")
162 AC_SUBST(DATAFILE_DIR)
163
164 #
165 # If we're running Solaris, and LD_LIBRARY_PATH is defined, add it as a
166 # link directory.
167 #
168 case "$host_os" in
169   solaris*)
170     AC_MSG_CHECKING(for LD_LIBRARY_PATH, since you appear to be running Solaris)
171     if test x$LD_LIBRARY_PATH != x ; then
172       LIBS="$LIBS -R$LD_LIBRARY_PATH"
173       AC_MSG_RESULT(yes -- added LD_LIBRARY_PATH to run-time linker path)
174     else
175       AC_MSG_RESULT(no -- this may be a problem in a few seconds)
176     fi
177   ;;
178 esac
179
180 #
181 # Check for versions of "sed" inadequate to handle, in libtool, a list
182 # of object files as large as the list in Ethereal.
183 #
184 # On Solaris, we check for "/bin/sed", "/usr/bin/sed", and "/usr/ucb/sed",
185 # as both "/usr/bin/sed" (which is also "/bin/sed", as "/bin" is just a
186 # symlink to "/usr/bin", but people may have "/bin" before "/usr/bin" in
187 # their search path) and "/usr/ucb/sed" are inadequate; "/usr/xpg4/bin/sed"
188 # is the only "sed" that comes with Solaris that can handle Ethereal.
189 #
190 # Add any checks here that are necessary for other OSes.
191 #
192 AC_ETHEREAL_GNU_SED_CHECK
193 if test "$HAVE_GNU_SED" = no ; then
194         case "$host_os" in
195         solaris*)
196                 AC_MSG_CHECKING(whether one of /usr/bin/sed or /bin/sed or /usr/ucb/sed will be used)
197                 case `which sed` in
198                         /bin/sed|/usr/bin/sed|/usr/ucb/sed)
199                         AC_MSG_RESULT(yes)              
200                         AC_MSG_ERROR([change your path to search /usr/xpg4/bin or directory containing GNU sed before /usr/bin (and /bin and /usr/ucb)])
201                         ;;
202
203                         *)
204                         AC_MSG_RESULT(no)
205                         ;;
206                 esac
207                 ;;
208
209         *)
210                 :
211                 ;;
212         esac
213 fi
214
215 # Enable/disable tethereal
216
217 AC_ARG_ENABLE(ethereal,
218 [  --enable-ethereal       build GTK+-based ethereal.  [default=yes]],,enable_ethereal=yes)
219
220 AC_ARG_ENABLE(gtk2,
221 [  --enable-gtk2           build Glib2/Gtk2+-based (t)ethereal.  [default=no]],enable_gtk2=yes,enable_gtk2=no)
222
223 # GTK checks
224 # We don't add $GLIB_LIBS to LIBS, because we don't want to force all
225 # programs to be built with GTK+.
226 #
227 if test "x$enable_gtk2" = "xyes" -a "x$enable_ethereal" = "xyes" ; then
228         GTK_OK=two
229         AM_PATH_GTK_2_0(2.0.0, CFLAGS="$CFLAGS $GTK_CFLAGS", GTK_OK=no )
230 elif test "x$enable_gtk2" = "xno" -a "x$enable_ethereal" = "xyes" ; then
231         GTK_OK=one
232         AM_PATH_GTK(1.2.0, CFLAGS="$CFLAGS $GTK_CFLAGS", GTK_OK=no )
233 else
234         GTK_OK=no
235 fi
236
237 # GLib checks
238 # This doesn't add GLIB_CFLAGS to CFLAGS, because AM_PATH_GTK will add
239 # GTK_CFLAGS to CFLAGS, and GTK_CFLAGS is a superset of CFLAGS.
240 # However, this means that both @GLIB_LIBS@ and @GTK_LIBS@ will be
241 # set when generating the Makefile, so we can make programs that require
242 # only GLib link with @GLIB_LIBS@ and make programs that require GTK+
243 # link with @GTK_LIBS@ (which includes @GLIB_LIBS@).
244 # We don't add $GLIB_LIBS to LIBS, because we don't want to force all
245 # programs to be built with GLib.
246 #
247 if test "$GTK_OK" = "two" ; then
248         ethereal_bin="ethereal"
249         ethereal_man="ethereal.1"
250         ethereal_SUBDIRS="gtk"   # <--- change to gtk2, if we can't use the same directory
251
252         # Ignore GLIB_CFLAGS
253         AM_PATH_GLIB_2_0(2.0.0, , AC_MSG_ERROR(GLib distribution not found.), gmodule)
254 elif test "$GTK_OK" = "one" ; then
255         ethereal_bin="ethereal"
256         ethereal_man="ethereal.1"
257         ethereal_SUBDIRS="gtk"
258
259         # Ignore GLIB_CFLAGS
260         AM_PATH_GLIB(1.2.0, , AC_MSG_ERROR(GLib distribution not found.), gmodule)
261 else
262         enable_ethereal="no"
263         ethereal_bin=""
264         ethereal_man=""
265         # Honor GLIB_CFLAGS
266         if test "x$enable_gtk2" = "xyes" ; then
267                 AM_PATH_GLIB_2_0(2.0.0, CFLAGS="$CFLAGS $GLIB_CFLAGS", AC_MSG_ERROR(GLib distribution not found.), gmodule)
268         else
269                 AM_PATH_GLIB(1.2.0, CFLAGS="$CFLAGS $GLIB_CFLAGS", AC_MSG_ERROR(GLib distribution not found.), gmodule)
270         fi
271 fi
272
273 #
274 # Check whether GLib modules are supported, to determine whether we
275 # can support plugins.
276 #
277 AC_MSG_CHECKING(whether GLib supports loadable modules)
278 ac_save_CFLAGS="$CFLAGS"
279 ac_save_LIBS="$LIBS"
280 CFLAGS="$CFLAGS $GLIB_CFLAGS"
281 LIBS="$GLIB_LIBS $LIBS"
282 AC_TRY_RUN([
283 #include <glib.h>
284 #include <gmodule.h>
285 #include <stdio.h>
286 #include <stdlib.h>
287
288 int 
289 main ()
290 {
291   if (g_module_supported())
292     return 0;   /* success */
293   else
294     return 1;   /* failure */
295 }
296 ], ac_cv_glib_supports_modules=yes, ac_cv_glib_supports_modules=no,
297    [echo $ac_n "cross compiling; assumed OK... $ac_c"])
298 CFLAGS="$ac_save_CFLAGS"
299 LIBS="$ac_save_LIBS"
300 if test "$ac_cv_glib_supports_modules" = yes ; then
301   AC_MSG_RESULT(yes)
302   have_plugins=yes
303 else
304   AC_MSG_RESULT(no)
305   have_plugins=no
306 fi
307
308
309 AC_SUBST(ethereal_bin)
310 AC_SUBST(ethereal_man)
311
312
313
314 # Enable/disable tethereal
315
316 AC_ARG_ENABLE(tethereal,
317 [  --enable-tethereal      build tethereal.  [default=yes]],,enable_tethereal=yes)
318
319 if test "x$enable_tethereal" = "xyes" ; then
320         tethereal_bin="tethereal"
321         tethereal_man="tethereal.1"
322 else
323         tethereal_bin=""
324         tethereal_man=""
325 fi
326 AC_SUBST(tethereal_bin)
327 AC_SUBST(tethereal_man)
328
329
330
331 # Enable/disable editcap
332
333 AC_ARG_ENABLE(editcap,
334 [  --enable-editcap        build editcap.  [default=yes]],,enable_editcap=yes)
335
336 if test "x$enable_editcap" = "xyes" ; then
337         editcap_bin="editcap"
338         editcap_man="editcap.1"
339 else
340         editcap_bin=""
341         editcap_man=""
342 fi
343 AC_SUBST(editcap_bin)
344 AC_SUBST(editcap_man)
345
346
347 # Enable/disable mergecap
348
349 AC_ARG_ENABLE(mergecap,
350 [  --enable-mergecap       build mergecap.  [default=yes]],,enable_mergecap=yes)
351
352 if test "x$enable_mergecap" = "xyes" ; then
353         mergecap_bin="mergecap"
354         mergecap_man="mergecap.1"
355 else
356         mergecap_bin=""
357         mergecap_man=""
358 fi
359 AC_SUBST(mergecap_bin)
360 AC_SUBST(mergecap_man)
361
362
363 # Enable/disable text2pcap
364
365 AC_ARG_ENABLE(text2pcap,
366 [  --enable-text2pcap      build text2pcap.  [default=yes]],,enable_text2pcap=yes)
367
368 if test "x$enable_text2pcap" = "xyes" ; then
369         text2pcap_bin="text2pcap"
370         text2pcap_man="text2pcap.1"
371 else
372         text2pcap_bin=""
373         text2pcap_man=""
374 fi
375 AC_SUBST(text2pcap_bin)
376 AC_SUBST(text2pcap_man)
377
378 # Enable/disable idl2eth
379
380 AC_ARG_ENABLE(idl2eth,
381 [  --enable-idl2eth        build idl2eth.  [default=yes]],,enable_idl2eth=yes)
382
383 if test "x$enable_idl2eth" = "xyes" ; then
384         idl2eth_bin="idl2eth"
385         idl2eth_man="idl2eth.1"
386 else
387         idl2eth_bin=""
388         idl2eth_man=""
389 fi
390 AC_SUBST(idl2eth_bin)
391 AC_SUBST(idl2eth_man)
392
393
394 # Enable/disable dftest
395
396 AC_ARG_ENABLE(dftest,
397 [  --enable-dftest         build dftest.  [default=no]],,enable_dftest=no)
398
399 if test "x$enable_dftest" = "xyes" ; then
400         dftest_bin="dftest"
401 else
402         dftest_bin=""
403 fi
404 AC_SUBST(dftest_bin)
405
406
407 # Enable/disable randpkt
408
409 AC_ARG_ENABLE(randpkt,
410 [  --enable-randpkt        build randpkt.  [default=no]],,enable_randpkt=no)
411
412 if test "x$enable_randpkt" = "xyes" ; then
413         randpkt_bin="randpkt"
414 else
415         randpkt_bin=""
416 fi
417 AC_SUBST(randpkt_bin)
418
419
420 dnl Checks for "gethostbyname()" - and "-lnsl", if we need it to get
421 dnl "gethostbyname()".
422 AC_ETHEREAL_GETHOSTBY_LIB_CHECK
423
424 dnl Checks for "connect()", used as a proxy for "socket()" - and
425 dnl "-lsocket", if we need it to get "connect()".
426 AC_ETHEREAL_SOCKET_LIB_CHECK
427
428 dnl pcap check
429 AC_MSG_CHECKING(whether to use libpcap for packet capture)
430
431 AC_ARG_WITH(pcap,
432 [  --with-pcap[=DIR]       use libpcap for packet capturing.  [default=yes]],
433 [
434         if test $withval = no
435         then
436                 want_pcap=no
437         elif test $withval = yes
438         then
439                 want_pcap=yes
440         else
441                 want_pcap=yes
442                 pcap_dir=$withval
443         fi
444 ],[
445         want_pcap=yes
446         pcap_dir=
447 ])
448 if test "x$want_pcap" = "xno" ; then
449         AC_MSG_RESULT(no)
450 else
451         AC_MSG_RESULT(yes)
452         AC_ETHEREAL_PCAP_CHECK
453         AC_ETHEREAL_PCAP_VERSION_CHECK
454 fi
455
456 dnl zlib check
457 AC_MSG_CHECKING(whether to use zlib for reading compressed capture files)
458
459 AC_ARG_WITH(zlib,
460 [  --with-zlib[=DIR]       use zlib (located in directory DIR, if supplied) to read compressed data.  [default=yes, if present]],
461 [
462         if test $withval = no
463         then
464                 want_zlib=no
465         elif test $withval = yes
466         then
467                 want_zlib=yes
468         else
469                 want_zlib=yes
470                 zlib_dir=$withval
471         fi
472 ],[
473         #
474         # Use zlib if it's present, otherwise don't.
475         #
476         want_zlib=ifpresent
477         zlib_dir=
478 ])
479 if test "x$want_zlib" = "xno" ; then
480         AC_MSG_RESULT(no)
481 else
482         AC_MSG_RESULT(yes)
483         AC_ETHEREAL_ZLIB_CHECK
484         if test "x$want_zlib" = "xno" ; then
485                 AC_MSG_RESULT(zlib not found - disabling compressed capture file support)
486         fi
487 fi
488
489
490 dnl ipv6 check
491 AC_ARG_ENABLE(ipv6,
492 [  --enable-ipv6           use ipv6 name resolution, if available.  [default=yes]],,enable_ipv6=yes)
493
494 AC_MSG_CHECKING(whether to enable ipv6 name resolution if available)
495 if test "x$enable_ipv6" = "xno" ; then
496         AC_MSG_RESULT(no)
497 else
498         AC_MSG_RESULT(yes)
499         AC_ETHEREAL_IPV6_STACK
500 fi
501
502
503 dnl Check if ethereal should be installed setuid
504 AC_ARG_ENABLE(setuid-install,
505 [  --enable-setuid-install install ethereal as setuid. DANGEROUS!!! [default=no]],,enable_setuid_install=no)
506
507 AC_MSG_CHECKING(whether to install ethereal setuid)
508 if test "x$enable_setuid_install" = "xno" ; then
509         AC_MSG_RESULT(no)
510 else
511         AC_MSG_RESULT(yes)
512 fi
513
514 AM_CONDITIONAL(SETUID_INSTALL, test x$enable_setuid_install = xyes)
515
516 dnl Checks for header files.
517 AC_HEADER_STDC
518 AC_CHECK_HEADERS(fcntl.h sys/ioctl.h sys/time.h unistd.h stdarg.h netdb.h)
519 AC_CHECK_HEADERS(sys/stat.h sys/sockio.h sys/types.h sys/socket.h)
520 AC_CHECK_HEADERS(sys/wait.h)
521 AC_CHECK_HEADERS(netinet/in.h)
522 AC_CHECK_HEADERS(stddef.h)
523 AC_CHECK_HEADERS(arpa/inet.h)
524 AC_CHECK_HEADERS(iconv.h)
525
526 dnl SSL Check
527 SSL_LIBS=''
528 AC_MSG_CHECKING(whether to use SSL library if available)
529 if test "x$enable_ssl" = "xno" ; then
530         AC_MSG_RESULT(no)
531 else
532         AC_MSG_RESULT(yes)
533         AC_ETHEREAL_SSL_CHECK
534 fi
535 AC_SUBST(SSL_LIBS)
536
537 dnl UCD SNMP Check
538 SNMP_LIBS=''
539 AC_MSG_CHECKING(whether to use UCD SNMP/NET-SNMP library if available)
540
541 AC_ARG_WITH(ucdsnmp,
542 [  --with-ucdsnmp[=DIR]    use UCD SNMP/NET-SNMP client library (located in directory DIR, if supplied).  [default=yes, if present]],
543 [
544         if test $withval = no
545         then
546                 want_ucdsnmp=no
547         elif test $withval = yes
548         then
549                 want_ucdsnmp=yes
550         else
551                 want_ucdsnmp=yes
552                 ucdsnmp_dir=$withval
553         fi
554 ],[
555         #
556         # Set "want_ucdsnmp" to "ifpresent" to make the default "use it
557         # if you find it, otherwise don't".
558         #
559         want_ucdsnmp=ifpresent
560         ucdsnmp_dir=
561 ])
562
563 if test "x$want_ucdsnmp" = "xno" ; then
564         AC_MSG_RESULT(no)
565 else
566         AC_MSG_RESULT(yes)
567         AC_ETHEREAL_UCDSNMP_CHECK
568 fi
569 AC_SUBST(SNMP_LIBS)
570
571 dnl Checks for typedefs, structures, and compiler characteristics.
572 # AC_C_CONST
573
574 # We need to know whether "struct sockaddr" has an "sa_len" member
575 # for get_interface_list().
576
577 AC_ETHEREAL_STRUCT_SA_LEN
578
579 # We must know our byte order
580 AC_C_BIGENDIAN
581
582 # Checks whether "-traditional" is needed when using "ioctl".
583 # XXX - do we need this?
584 AC_PROG_GCC_TRADITIONAL
585
586 # If there's a system out there that has snprintf and _doesn't_ have vsnprintf,
587 # then this won't work.
588 SNPRINTF_C=""
589 SNPRINTF_O=""
590 AC_CHECK_FUNC(snprintf, SNPRINTF_O="",
591   SNPRINTF_O="snprintf.o" [AC_DEFINE(NEED_SNPRINTF_H)])
592 if test "$ac_cv_func_snprintf" = no ; then
593   SNPRINTF_C="snprintf.c"
594   SNPRINTF_O="snprintf.o"
595 fi
596 AC_SUBST(SNPRINTF_C)
597 AC_SUBST(SNPRINTF_O)
598
599 AC_CHECK_FUNC(strerror, STRERROR_O="",
600   STRERROR_O="strerror.o" [AC_DEFINE(NEED_STRERROR_H)])
601 if test "$ac_cv_func_strerror" = no ; then
602   STRERROR_C="strerror.c"
603   STRERROR_O="strerror.o"
604 fi
605 AC_SUBST(STRERROR_C)
606 AC_SUBST(STRERROR_O)
607
608 AC_CHECK_FUNC(strcasecmp, STRCASECMP_O="",
609   STRCASECMP_O="strcasecmp.o")
610 if test "$ac_cv_func_strcasecmp" = no ; then
611   STRCASECMP_C="strcasecmp.c"
612   STRCASECMP_O="strcasecmp.o"
613 fi
614 AC_SUBST(STRCASECMP_C)
615 AC_SUBST(STRCASECMP_O)
616
617 AC_CHECK_FUNC(strncasecmp, STRNCASECMP_O="",
618   STRNCASECMP_O="strncasecmp.o")
619 if test "$ac_cv_func_strncasecmp" = no ; then
620   STRNCASECMP_C="strncasecmp.c"
621   STRNCASECMP_O="strncasecmp.o"
622 fi
623 AC_SUBST(STRNCASECMP_C)
624 AC_SUBST(STRNCASECMP_O)
625
626 AC_CHECK_FUNC(mkstemp, MKSTEMP_O="",
627   MKSTEMP_O="mkstemp.o")
628 if test "$ac_cv_func_mkstemp" = no ; then
629   MKSTEMP_C="mkstemp.c"
630   MKSTEMP_O="mkstemp.o"
631 fi
632 AC_SUBST(MKSTEMP_C)
633 AC_SUBST(MKSTEMP_O)
634
635 AC_CHECK_FUNC(strptime, STRPTIME_O="",
636   STRPTIME_O="strptime.o" [AC_DEFINE(NEED_STRPTIME_H)])
637 if test "$ac_cv_func_strptime" = no ; then
638   STRPTIME_C="strptime.c"
639   STRPTIME_O="strptime.o"
640 fi
641 AC_SUBST(STRPTIME_C)
642 AC_SUBST(STRPTIME_O)
643
644 AC_CHECK_FUNCS(getprotobynumber gethostbyname2)
645
646 dnl blank for now, but will be used in future
647 AC_SUBST(ethereal_SUBDIRS)
648
649 dnl
650 dnl check whether plugins should be enabled and, if they should be,
651 dnl check for plugins directory - stolen from Amanda's configure.in
652 dnl
653 plugindir="$libdir/ethereal/plugins/$VERSION"
654 PLUGIN_DIR="$plugindir"
655 AC_ARG_WITH(plugins,
656   [  --with-plugins[=DIR]    support plugins (installed in DIR, if supplied).],
657   [
658   case "$withval" in
659   "" | y | ye | yes )
660     if test x$have_plugins = xno
661     then
662       AC_MSG_ERROR([GLib on this platform doesn't support loadable modules, so you can't enable plugins.])
663     fi
664     ;;
665   n | no)
666     have_plugins=no
667     ;;
668   *)
669     if test x$have_plugins = xno
670     then
671       AC_MSG_ERROR([GLib on this platform doesn't support loadable modules, so you can't enable plugins.])
672     fi
673     PLUGIN_DIR="$withval"
674     ;;
675   esac
676   ]
677 )
678
679 AM_CONDITIONAL(HAVE_PLUGINS, test x$have_plugins = xyes)
680 if test x$have_plugins = xyes
681 then
682   AC_DEFINE(HAVE_PLUGINS)
683   PLUGIN_DIR=`(
684     test "x$prefix" = xNONE && prefix=$ac_default_prefix
685     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
686     eval echo "$PLUGIN_DIR"
687   )`
688   AC_DEFINE_UNQUOTED(PLUGIN_DIR,"$PLUGIN_DIR", [Plugin installation directory])
689 else
690   AC_DEFINE(PLUGIN_DIR,NULL)
691 fi
692 AC_SUBST(PLUGIN_DIR)
693 AC_SUBST(plugindir)
694
695 dnl libtool defs
696 AM_PROG_LIBTOOL
697 AC_SUBST(LIBTOOL_DEPS)
698
699 AM_CONFIG_HEADER(config.h)
700 AC_CONFIG_SUBDIRS(epan wiretap)
701 AC_OUTPUT(
702   Makefile
703   doc/Makefile
704   gtk/Makefile
705   packaging/Makefile
706   packaging/nsis/Makefile
707   packaging/rpm/Makefile
708   packaging/rpm/SPECS/Makefile
709   packaging/rpm/SPECS/ethereal.spec
710   packaging/svr4/Makefile
711   packaging/svr4/checkinstall
712   packaging/svr4/pkginfo
713   plugins/Makefile
714   plugins/docsis/Makefile
715   plugins/giop/Makefile
716   plugins/gryphon/Makefile
717   plugins/mgcp/Makefile
718   tools/Makefile
719   tools/lemon/Makefile
720   ,)
721
722
723 # Pretty messages
724
725 if test "x$enable_setuid_install" = "xyes" ; then
726         setuid_message="yes (DANGEROUS!!!)"
727 else
728         setuid_message="no"
729 fi
730
731 if test "x$want_libz" = "no" ; then
732         zlib_message="no"
733 else
734         zlib_message="yes"
735 fi
736
737 if test "x$SNMP_LIBS" = "x" ; then
738         snmp_libs_message="no"
739 else
740         snmp_libs_message="yes"
741 fi
742
743 echo ""
744 echo "The Ethereal package has been configured with the following options."
745 echo "                    Build ethereal : $enable_ethereal"
746 echo "                   Build tethereal : $enable_tethereal"
747 echo "                     Build editcap : $enable_editcap"
748 echo "                    Build mergecap : $enable_mergecap"
749 echo "                   Build text2pcap : $enable_text2pcap"
750 echo "                     Build idl2eth : $enable_idl2eth"
751 echo "                     Build randpkt : $enable_randpkt"
752 echo "                      Build dftest : $enable_dftest"
753 echo ""
754 echo "                    Install setuid : $setuid_message"
755 echo "                       Use plugins : $have_plugins"
756 echo "                  Use pcap library : $want_pcap"
757 echo "                  Use zlib library : $zlib_message"
758 echo "          Use IPv6 name resolution : $enable_ipv6"
759 echo "              Use UCD SNMP library : $snmp_libs_message"