Bump development version.
[obnox/wireshark/wip.git] / configure.in
1 # $Id$
2 #
3 AC_PREREQ(2.60)
4
5 AC_INIT(wireshark, 1.3.2)
6
7 dnl Check for CPU / vendor / OS
8 dnl The user is encouraged to use either `AC_CANONICAL_BUILD', or
9 dnl `AC_CANONICAL_HOST', or `AC_CANONICAL_TARGET', depending on the
10 dnl needs.  Using `AC_CANONICAL_TARGET' is enough to run the two other
11 dnl macros.
12 dnl
13 dnl As nothing in the Wireshark is itself a build tool (we are not,
14 dnl for example, a compiler that generates machine code), we probably
15 dnl don't need AC_CANONICAL_TARGET, so, in theory, we should be able
16 dnl to use AC_CANONICAL_BUILD and AC_CANONICAL_HOST - or perhaps just
17 dnl AC_CANONICAL_HOST - instead.  Note that we do have tools, such as
18 dnl lemon, that need to be built for the build machine, not for the
19 dnl host machine, so we might need both.
20 dnl
21 dnl This has to be done *after* AC_INIT, otherwise autogen.sh fails.
22
23 dnl AC_CANONICAL_BUILD
24 dnl AC_CANONICAL_HOST
25 AC_CANONICAL_TARGET
26
27 AM_INIT_AUTOMAKE([1.9 tar-ustar])
28
29 AM_DISABLE_STATIC
30
31 dnl Checks for programs.
32 AC_PROG_CC
33 AM_PROG_CC_C_O
34 AC_PROG_CPP
35 dnl Work around libtool bug (fixed in the version 1.5a?)
36 AC_DEFUN([AC_PROVIDE_AC_LIBTOOL_DLOPEN], )
37 AC_LIBTOOL_DLOPEN
38 AC_PROG_LIBTOOL
39 AC_PATH_PROG(PERL, perl)
40 AC_PROG_YACC
41 AC_PATH_PROG(YACCDUMMY, $YACC)
42 if test "x$YACCDUMMY" = x
43 then
44         AC_MSG_ERROR(I couldn't find yacc (or bison or ...); make sure it's installed and in your path)
45 fi
46 AM_PROG_LEX
47 AC_PATH_PROG(LEX, flex)
48 if test "x$LEX" = x
49 then
50         AC_MSG_ERROR(I couldn't find flex; make sure it's installed and in your path)
51 fi
52 AC_PATH_PROG(POD2MAN, pod2man)
53 if test "x$POD2MAN" = x
54 then
55         #
56         # The alternative is not to build the man pages....
57         #
58         AC_MSG_ERROR(I couldn't find pod2man; make sure it's installed and in your path)
59 fi
60 AC_PATH_PROG(POD2HTML, pod2html)
61 if test "x$POD2HTML" = x
62 then
63         #
64         # The alternative is not to build the HTML man pages....
65         #
66         AC_MSG_ERROR(I couldn't find pod2html; make sure it's installed and in your path)
67 fi
68
69 #
70 # XXX - this looks for various HTML viewers on the host, not the target;
71 # we really want to know what's available on the target, for cross-builds.
72 # That would probably require us to, at run time, look for xdg-open and,
73 # if we don't find it, look for mozilla, htmlview, etc.
74 #
75 AC_PATH_PROG(HTML_VIEWER, xdg-open)
76 if test "x$HTML_VIEWER" != x
77 then
78         #
79         # XXX - the HTML_VIEWER shell variable is the full path of xdg-open.
80         # Define some variable to be that, so we just run that?
81         #
82         AC_DEFINE(HAVE_XDG_OPEN, 1, [Define if we have xdg-open])
83
84         #
85         # XXX - we have to define HTML_VIEWER for the prefs.c code that
86         # sets the default value of the Web browser preference, even
87         # though that preference won't be offered.
88         #
89         AC_DEFINE_UNQUOTED(HTML_VIEWER, "xdg-open", [HTML viewer, e.g. mozilla])
90 else
91         AC_PATH_PROG(HTML_VIEWER, htmlview)
92         if test "x$HTML_VIEWER" = x
93         then
94                 AC_DEFINE_UNQUOTED(HTML_VIEWER, "mozilla", [HTML viewer, e.g. mozilla])
95         else
96                 AC_DEFINE_UNQUOTED(HTML_VIEWER, "htmlview", [HTML viewer, e.g. mozilla])
97         fi
98 fi
99
100 AC_PATH_PROG(LEX, flex)
101 AC_PATH_PROG(PYTHON, python)
102
103 AC_SUBST(PERL)
104 AC_SUBST(POD2MAN)
105 AC_SUBST(POD2HTML)
106 AC_SUBST(LEX)
107 AC_SUBST(FLEX_PATH)
108 AC_SUBST(PYTHON)
109 AC_SUBST(XSLTPROC)
110 AC_SUBST(XMLLINT)
111
112 if test "x$CC_FOR_BUILD" = x
113 then
114        CC_FOR_BUILD=$CC
115 fi
116 AC_SUBST(CC_FOR_BUILD)
117
118 # Check for doxygen
119 AC_PATH_PROG(DOXYGEN, doxygen)
120 AC_CHECK_PROG(HAVE_DOXYGEN, doxygen, "yes", "no")
121 AM_CONDITIONAL(HAVE_DOXYGEN, test x$HAVE_DOXYGEN = xyes)
122
123 # gnu tls
124 tls_message="no"
125 AC_ARG_WITH([gnutls],
126   AC_HELP_STRING( [--with-gnutls=@<:@yes/no@:>@],
127                   [use gnutls library @<:@default=yes@:>@]),
128   with_gnutls="$withval", with_gnutls="yes")
129 if test "x$with_gnutls" = "xyes"; then
130   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 1.2.0],
131         [
132                 echo "gnuTLS found, enabling ssl decryption"
133                 AC_DEFINE(HAVE_LIBGNUTLS, 1, [Define to use gnutls library])
134                 tls_message="yes"
135         ]
136         , [
137                 echo echo "gnuTLS not found, disabling ssl decryption"
138                 tls_message="no"
139         ]
140   )
141 fi
142
143 # libgrypt
144 gcrypt_message="no"
145 AC_ARG_WITH([gcrypt],
146   AC_HELP_STRING( [--with-gcrypt=@<:@yes/no@:>@],
147                   [use gcrypt library @<:@default=yes@:>@]),
148   with_gcrypt="$withval", with_gcrypt="yes")
149 if test "x$with_gcrypt" = "xyes"; then
150   AM_PATH_LIBGCRYPT(1.1.92,
151         [
152                 echo "libgcrypt found, enabling ipsec decryption"
153                 AC_DEFINE(HAVE_LIBGCRYPT, 1, [Define to use libgcrypt])
154                 gcrypt_message="yes"
155         ]
156         , [
157                 if test x$libgcrypt_config_prefix != x ; then
158                         AC_MSG_ERROR([[libgcrypt not found; install libgcrypt-devel package for your system]])
159                 else
160                         echo "libgcrypt not found, disabling ipsec decryption"
161                         gcrypt_message="no"
162                 fi
163         ]
164   )
165 fi
166
167 # libsmi
168 # FIXME: currently the path argument to with-libsmi is being ignored
169 AX_LIBSMI
170
171 # Check for xsltproc
172 AC_PATH_PROG(XSLTPROC, xsltproc)
173 AC_CHECK_PROG(HAVE_XSLTPROC, xsltproc, "yes", "no")
174 AM_CONDITIONAL(HAVE_XSLTPROC, test x$HAVE_XSLTPROC = xyes)
175
176 # Check for xmllint
177 AC_PATH_PROG(XMLLINT, xmllint)
178 AC_CHECK_PROG(HAVE_XMLLINT, xmllint, "yes", "no")
179 AM_CONDITIONAL(HAVE_XMLLINT, test x$HAVE_XMLLINT = xyes)
180
181 # Check for fop (translate .fo to e.g. pdf)
182 AC_PATH_PROG(FOP, fop)
183 AC_CHECK_PROG(HAVE_FOP, fop, "yes", "no")
184 AM_CONDITIONAL(HAVE_FOP, test x$HAVE_FOP = xyes)
185
186 # Check for hhc (html help compiler)
187 AC_PATH_PROG(HHC, hhc.exe)
188 AC_CHECK_PROG(HAVE_HHC, hhc.exe, "yes", "no")
189 AM_CONDITIONAL(HAVE_HHC, test x$HAVE_HHC = xyes)
190
191 # Check for packaging utilities
192 # For now, we check to see if the various packaging utilites are in our
193 # path.  I'm too lazy to write code to go hunt for them.  -  Gerald
194
195 # SVR4/Solaris
196 AC_CHECK_PROG(HAVE_PKGPROTO, pkgproto, "yes", "no")
197 AC_CHECK_PROG(HAVE_PKGMK, pkgmk, "yes", "no")
198 AC_CHECK_PROG(HAVE_PKGTRANS, pkgtrans, "yes", "no")
199
200 if test x$HAVE_PKGPROTO = xyes -a x$HAVE_PKGMK = xyes \
201      -a x$HAVE_PKGTRANS = xyes ; then
202   HAVE_SVR4_PACKAGING=yes
203 else
204   HAVE_SVR4_PACKAGING=no
205 fi
206 AC_SUBST(HAVE_SVR4_PACKAGING)
207
208 # RPM
209 AC_WIRESHARK_RPM_CHECK
210 AC_SUBST(HAVE_RPM)
211
212 # Debian
213 AC_CHECK_PROG(HAVE_DPKG_BUILDPACKAGE, dpkg-buildpackage, "yes", "no")
214
215 # Mac OS X
216 AC_CHECK_PROG(HAVE_XCODEBUILD, xcodebuild, "yes", "no")
217 AC_CHECK_PROG(HAVE_HDIUTIL, hdiutil, "yes", "no")
218 AC_CHECK_PROG(HAVE_BLESS, bless, "yes", "no")
219
220 if test x$HAVE_XCODEBUILD = xyes -a x$HAVE_HDIUTIL = xyes \
221      -a x$HAVE_BLESS = xyes ; then
222   HAVE_OSX_PACKAGING=yes
223 else
224   HAVE_OSX_PACKAGING=no
225 fi
226 AC_SUBST(HAVE_OSX_PACKAGING)
227
228 #
229 # Try to add some additional gcc checks to CFLAGS
230 #
231 AC_ARG_ENABLE(extra-gcc-checks,
232   AC_HELP_STRING( [--enable-extra-gcc-checks],
233                   [Do additional -W checks in GCC.  @<:@default=no@:>@]),
234 [
235         wireshark_extra_gcc_flags=$enableval
236         if test $enableval != no
237         then
238                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-pedantic)
239                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Woverflow)
240                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wlogical-op)
241                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wno-overlength-strings)
242 #               AC_WIRESHARK_GCC_CFLAGS_CHECK(-fstrict-overflow -Wstrict-overflow=4)
243 #               AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wunreachable-code)
244 #               AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wunsafe-loop-optimizations)
245                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wno-long-long)
246                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wbad-function-cast)
247                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wcast-qual)
248                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Waddress)
249                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Warray-bounds)
250                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wattributes)
251                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wdeclaration-after-statement)
252                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wdiv-by-zero)
253                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wformat-security)
254                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wignored-qualifiers)
255                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wpragmas)
256                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wredundant-decls)
257                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wvla)
258                 #
259                 # epan/dissectors/packet-ncp2222.inc blocks this one
260                 # for now.
261                 #
262                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wwrite-strings)
263                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wstrict-prototypes)
264                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wmissing-declarations)
265                 #
266                 # epan/dissectors/packet-afs.c blocks this one for now.
267                 #
268                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wshadow)
269                 #
270                 # More cleanup needed for this on LP64.
271                 #
272                 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wshorten-64-to-32)
273         fi
274 ],)
275 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wall -W) # -W is now known as -Wextra
276 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wextra) # -W is now known as -Wextra
277 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wdeclaration-after-statement)
278 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wendif-labels)
279 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wpointer-arith)
280 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wno-pointer-sign)
281 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Warray-bounds)
282 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wcast-align)
283 AC_WIRESHARK_GCC_CFLAGS_CHECK(-Wformat-security)
284
285 AC_WIRESHARK_GCC_LDFLAGS_CHECK([-Wl,--as-needed])
286
287 #
288 # If we're running gcc add '-D_U_="__attribute__((unused))"' to CFLAGS as well,
289 # so we can use _U_ to flag unused function arguments and not get warnings
290 # about them. Otherwise, add '-D_U_=""', so that _U_ used to flag an unused
291 # function argument will compile with non-GCC compilers.
292 #
293 if test "x$GCC" = "xyes" ; then
294   CFLAGS="-D_U_=\"__attribute__((unused))\" $CFLAGS"
295 else
296   CFLAGS="-D_U_=\"\" $CFLAGS"
297 fi
298
299 #
300 # If we're running gcc, will enable a barrier "stop on warning".
301 # This barrier is set for a very large part of the code. However, it is
302 # typically not set for "generated" code  (flex, ans2wrs, idl2wrs, ...)
303 #
304 warnings_as_errors_default="yes"
305 AC_MSG_CHECKING(whether we should treat compiler warnings as errors)
306 AC_ARG_ENABLE(warnings-as-errors,
307   AC_HELP_STRING( [--enable-warnings-as-errors],
308                   [Treat warnings as errors (only for gcc). @<:@default=yes@:>@]),
309 [
310   if test "x$GCC" = "xyes" -a "x$enableval" == "xyes" -a "x$wireshark_extra_gcc_flags" != "xyes"; then
311     with_warnings_as_errors="yes"
312     AC_MSG_RESULT(yes)
313   else
314     with_warnings_as_errors="no"
315     AC_MSG_RESULT(no)
316   fi
317 ],
318   if test "x$GCC" = "xyes" -a "x$wireshark_extra_gcc_flags" = "x" -a "x$warnings_as_errors_default" = "xyes"; then
319     with_warnings_as_errors="yes"
320     AC_MSG_RESULT(yes)
321   else
322     with_warnings_as_errors="no"
323     AC_MSG_RESULT(no)
324   fi
325 )
326 AM_CONDITIONAL(HAVE_WARNINGS_AS_ERRORS, test "x$with_warnings_as_errors" = "xyes")
327
328 #
329 # Add any platform-specific compiler flags needed.
330 #
331 AC_MSG_CHECKING(for platform-specific compiler flags)
332 if test "x$GCC" = "xyes" ; then
333         #
334         # GCC - do any platform-specific tweaking necessary.
335         #
336         case "$host_os" in
337         solaris*)
338                 # the X11 headers don't automatically include prototype info
339                 # and a lot don't include the return type
340                 CFLAGS="$CFLAGS -Wno-return-type -DFUNCPROTO=15"
341                 AC_MSG_RESULT(GCC on Solaris - added -Wno-return-type -DFUNCPROTO=15)
342                 ;;
343         darwin*)
344                 #
345                 # See comments above about Apple's lovely C compiler.
346                 #
347                 CFLAGS="-no-cpp-precomp $CFLAGS"
348                 AC_MSG_RESULT(Apple GCC - added -no-cpp-precomp)
349                 ;;
350         *)
351                 AC_MSG_RESULT(none needed)
352                 ;;
353         esac
354 else
355         #
356         # Not GCC - assume it's the vendor's compiler.
357         #
358         case "$host_os" in
359         hpux*)
360                 #
361                 # HP's ANSI C compiler; flags suggested by Jost Martin.
362                 # "-Ae" for ANSI C plus extensions such as "long long".
363                 # "+O2", for optimization.  XXX - works with "-g"?
364                 #
365                 CFLAGS="-Ae +O2 $CFLAGS"
366                 AC_MSG_RESULT(HP ANSI C compiler - added -Ae +O2)
367                 ;;
368         darwin*)
369                 #
370                 # It may be called "cc", but it's really a GCC derivative
371                 # with a problematic special precompiler and precompiled
372                 # headers; turn off the special precompiler, as some
373                 # apparently-legal code won't compile with its precompiled
374                 # headers.
375                 #
376                 CFLAGS="-no-cpp-precomp $CFLAGS"
377                 AC_MSG_RESULT(Apple GCC - added -no-cpp-precomp)
378                 ;;
379         *)
380                 AC_MSG_RESULT(none needed)
381                 ;;
382         esac
383 fi
384
385 #
386 # Add any platform-specific linker flags needed.
387 #
388 AC_MSG_CHECKING(for platform-specific linker flags)
389 case "$host_os" in
390 darwin*)
391         #
392         # Add -Wl,-single_module to the LDFLAGS used with shared
393         # libraries, to fix some error that show up in some cases;
394         # some Apple documentation recommends it for most shared
395         # libraries.
396         #
397         LDFLAGS_SHAREDLIB="-Wl,-single_module"
398         #
399         # Add -Wl,-search_paths_first to make sure that if we search
400         # directories A and B, in that order, for a given library, a
401         # non-shared version in directory A, rather than a shared
402         # version in directory B, is chosen (so we can use
403         # --with-pcap=/usr/local to force all programs to be linked
404         # with a static version installed in /usr/local/lib rather than
405         # the system version in /usr/lib).
406         #
407         LDFLAGS="-Wl,-search_paths_first $LDFLAGS"
408         AC_MSG_RESULT([Apple linker - added -Wl,-single_module and -Wl,-search_paths_first])
409         ;;
410 cygwin*)
411         #
412         # Shared libraries in cygwin/Win32 must never contain
413         # undefined symbols.
414         #
415         LDFLAGS="$LDFLAGS -no-undefined"
416         AC_MSG_RESULT(CygWin GNU ld - added -no-undefined)
417         ;;
418 *)
419         AC_MSG_RESULT(none needed)
420         ;;
421 esac
422 AC_SUBST(LDFLAGS_SHAREDLIB)
423
424 #
425 # On OS X, if we find the headers for Core Foundation, Launch Services,
426 # and Core Services, add -framework options to link with Application
427 # Services (of which Launch Services is a subframework), Core Foundation
428 # (required by the Launch Services APIs), and Core Services, so we can
429 # use them to launch a Web browser from the Help menu and to use
430 # Gestalt() to get the Mac OS X version number.
431 #
432 case "$host_os" in
433
434 darwin*)
435         AC_MSG_CHECKING([whether we can build with Core Foundation, Launch Services, and Core Services])
436         ac_save_LIBS="$LIBS"
437         ac_frameworks="-framework ApplicationServices -framework CoreFoundation -framework CoreServices"
438         LIBS="$LIBS $ac_frameworks"
439         AC_TRY_LINK(
440            [
441 #       include <CoreFoundation/CFBase.h>
442 #       include <CoreFoundation/CFString.h>
443 #       include <CoreFoundation/CFURL.h>
444 #       include <ApplicationServices/ApplicationServices.h>
445 #       include <CoreServices/CoreServices.h>
446            ],
447            [
448         CFStringRef url_CFString;
449         CFURLRef url_CFURL;
450         OSStatus status;
451         long os_version;
452
453         url_CFString = CFStringCreateWithCString(NULL, "", kCFStringEncodingASCII);
454         url_CFURL = CFURLCreateWithString(NULL, url_CFString, NULL);
455         status = LSOpenCFURLRef(url_CFURL, NULL);
456
457         Gestalt(gestaltSystemVersion, &os_version);
458            ],
459            ac_cv_can_use_osx_frameworks=yes,
460            ac_cv_can_use_osx_frameworks=no,
461            [echo $ac_n "cross compiling; assumed OK... $ac_c"])
462         if test "$ac_cv_can_use_osx_frameworks" = yes ; then
463                 AC_DEFINE(HAVE_OS_X_FRAMEWORKS, 1, [Define to 1 if you have OS X frameworks])
464                 FRAMEWORKS="$ac_frameworks"
465                 AC_MSG_RESULT(yes)
466         else
467                 AC_MSG_RESULT(no)
468         fi
469         LIBS="$ac_save_LIBS"
470         ;;
471 esac
472 AC_SUBST(FRAMEWORKS)
473
474 #
475 # If using $prefix we add "$prefix/include" to the include search path
476 # and "$prefix/lib" to the library search path.
477 #
478 if test "x$prefix" != "x" ; then
479         AC_MSG_CHECKING(whether to use $prefix for headers and libraries)
480         if test -d $prefix/include ; then
481                 AC_MSG_RESULT(yes)
482                 #
483                 # Arrange that we search for header files in "$prefix/include", as
484                 # various packages we use may have been installed under "$prefix/include".
485                 #
486                 CFLAGS="$CFLAGS -I$prefix/include"
487                 CPPFLAGS="$CPPFLAGS -I$prefix/include"
488
489                 #
490                 # Arrange that we search for libraries in "$prefix/lib".
491                 #
492                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, $prefix/lib)
493         else
494                 AC_MSG_RESULT(no)
495         fi
496 fi
497
498 dnl Look in /usr/local for header files and libraries ?
499 dnl XXX FIXME don't include /usr/local if it is already in the system
500 dnl search path as this causes gcc 3.2 on Linux to complain about a change
501 dnl of the system search order for includes
502 AC_ARG_ENABLE(usr-local,
503   AC_HELP_STRING( [--enable-usr-local],
504                   [look for headers and libs in /usr/local tree.  @<:@default=yes@:>@]),
505     ac_cv_enable_usr_local=$enableval,ac_cv_enable_usr_local=yes)
506
507 AC_MSG_CHECKING(whether to use /usr/local for headers and libraries)
508 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
509         AC_MSG_RESULT(yes)
510         #
511         # Arrange that we search for header files in the source directory
512         # and in its "wiretap" subdirectory, as well as in "/usr/local/include",
513         # as various packages we use ("libpcap", "zlib", "adns", "pcre")
514         # may have been installed under "/usr/local/include".
515         #
516         CFLAGS="$CFLAGS -I/usr/local/include"
517         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
518
519         #
520         # Arrange that we search for libraries in "/usr/local/lib".
521         #
522         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, /usr/local/lib)
523 else
524         AC_MSG_RESULT(no)
525 fi
526
527 #
528 # If we're running Solaris, and LD_LIBRARY_PATH is defined, add it as a
529 # link directory.
530 #
531 case "$host_os" in
532   solaris*)
533     AC_MSG_CHECKING(for LD_LIBRARY_PATH, since you appear to be running Solaris)
534     if test x$LD_LIBRARY_PATH != x ; then
535       LIBS="$LIBS -R$LD_LIBRARY_PATH"
536       AC_MSG_RESULT(yes -- added LD_LIBRARY_PATH to run-time linker path)
537     else
538       AC_MSG_RESULT(no -- this may be a problem in a few seconds)
539     fi
540   ;;
541 esac
542
543 #
544 # Check for versions of "sed" inadequate to handle, in libtool, a list
545 # of object files as large as the list in Wireshark.
546 #
547 # On Solaris, we check for "/bin/sed", "/usr/bin/sed", and "/usr/ucb/sed",
548 # as both "/usr/bin/sed" (which is also "/bin/sed", as "/bin" is just a
549 # symlink to "/usr/bin", but people may have "/bin" before "/usr/bin" in
550 # their search path) and "/usr/ucb/sed" are inadequate; "/usr/xpg4/bin/sed"
551 # is the only "sed" that comes with Solaris that can handle Wireshark.
552 #
553 # Add any checks here that are necessary for other OSes.
554 #
555 AC_WIRESHARK_GNU_SED_CHECK
556 if test "$HAVE_GNU_SED" = no ; then
557         case "$host_os" in
558         solaris*)
559                 AC_MSG_CHECKING(whether one of /usr/bin/sed or /bin/sed or /usr/ucb/sed will be used)
560                 case `which sed` in
561                         /bin/sed|/usr/bin/sed|/usr/ucb/sed)
562                         AC_MSG_RESULT(yes)
563                         AC_MSG_ERROR([change your path to search /usr/xpg4/bin or directory containing GNU sed before /usr/bin (and /bin and /usr/ucb)])
564                         ;;
565
566                         *)
567                         AC_MSG_RESULT(no)
568                         ;;
569                 esac
570                 ;;
571
572         *)
573                 :
574                 ;;
575         esac
576 fi
577
578 # Enable/disable tshark
579
580 AC_ARG_ENABLE(wireshark,
581   AC_HELP_STRING( [--enable-wireshark],
582                   [build GTK+-based wireshark.  @<:@default=yes, if GTK+ available@:>@]),
583     enable_wireshark=$enableval,enable_wireshark=yes)
584
585 AC_ARG_ENABLE(threads,
586   AC_HELP_STRING( [--enable-threads],
587                   [use threads in wireshark.  @<:@default=no@:>@]),
588     enable_threads=$enableval,enable_threads=no)
589 AM_CONDITIONAL(USE_THREADS, test x$enable_threads = xyes)
590
591 AC_ARG_ENABLE(profile-build,
592   AC_HELP_STRING( [--enable-profile-build],
593                   [build profile-ready binaries.  @<:@default=no@:>@]),
594     enable_profile_build=$enableval,enable_profile_build=no)
595 AM_CONDITIONAL(USE_PROFILE_BUILD, test x$enable_profile_build = xyes)
596 AC_MSG_CHECKING(if profile builds must be generated)
597 if test "x$enable_profile_build" = "xyes" ; then
598         if test "x$GCC" = "xyes" ; then
599                 AC_MSG_RESULT(yes)
600                 CFLAGS=" -pg $CFLAGS"
601         else
602                 AC_MSG_RESULT(no)
603                 echo "Building profile binaries currently only supported for GCC."
604         fi
605 else
606         AC_MSG_RESULT(no)
607 fi
608
609 # Create DATAFILE_DIR #define for config.h
610 datafiledir=$datadir/wireshark
611 datafiledir=`(
612     test "x$prefix" = xNONE && prefix=$ac_default_prefix
613     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
614     # Ugly hack, but I don't see how this problem can be solved
615     # properly that DATAFILE_DIR had a value starting with
616     # "${prefix}/" instead of e.g. "/usr/local/"
617     eval eval echo "$datafiledir"
618 )`
619 AC_DEFINE_UNQUOTED(DATAFILE_DIR,"$datafiledir", [Directory for data])
620
621 # GTK checks; we require GTK+ 2.4 or later.
622 # We don't add $GLIB_LIBS to LIBS, because we don't want to force all
623 # programs to be built with GTK+.
624 #
625 if test "x$enable_wireshark" = "xyes"; then
626         AM_PATH_GTK_2_0(2.4.0, CFLAGS="$CFLAGS $GTK_CFLAGS", GTK_OK=no, gthread)
627 else
628         GTK_OK=no
629 fi
630
631 # GLib checks
632 # This doesn't add GLIB_CFLAGS to CFLAGS, because AM_PATH_GTK will add
633 # GTK_CFLAGS to CFLAGS, and GTK_CFLAGS is a superset of CFLAGS.
634 # However, this means that both @GLIB_LIBS@ and @GTK_LIBS@ will be
635 # set when generating the Makefile, so we can make programs that require
636 # only GLib link with @GLIB_LIBS@ and make programs that require GTK+
637 # link with @GTK_LIBS@ (which includes @GLIB_LIBS@).
638 # We don't add $GLIB_LIBS to LIBS, because we don't want to force all
639 # programs to be built with GLib.
640 #
641 if test "$GTK_OK" = "no" ; then
642         #
643         # We don't have GTK+.
644         # If they didn't explicitly say "--disable-wireshark", fail (so
645         # that, unless they explicitly indicated that they don't want
646         # Wireshark, we stop so they know they won't be getting
647         # Wireshark unless they fix the GTK+ problem).
648         #
649         if test "x$enable_wireshark" = "xyes"; then
650                 AC_MSG_ERROR([GTK+ 2.4 or later isn't available, so Wireshark can't be compiled])
651         fi
652         wireshark_bin=""
653         wireshark_man=""
654         # Honor GLIB_CFLAGS
655         AM_PATH_GLIB_2_0(2.4.0, CFLAGS="$CFLAGS $GLIB_CFLAGS", AC_MSG_ERROR(GLib 2.4 or later distribution not found.), gmodule)
656
657 else
658         wireshark_bin="wireshark\$(EXEEXT)"
659         wireshark_man="wireshark.1"
660         wireshark_SUBDIRS="codecs gtk"
661         # Honor GLIB_CFLAGS
662         AM_PATH_GLIB_2_0(2.4.0, , AC_MSG_ERROR(GLib 2.4 or later distribution not found.), gmodule)
663 fi
664
665 #
666 # Check whether GLib modules are supported, to determine whether we
667 # can support plugins.
668 #
669 AC_MSG_CHECKING(whether GLib supports loadable modules)
670 ac_save_CFLAGS="$CFLAGS"
671 ac_save_LIBS="$LIBS"
672 CFLAGS="$CFLAGS $GLIB_CFLAGS"
673 LIBS="$GLIB_LIBS $LIBS"
674 AC_TRY_RUN([
675 #include <glib.h>
676 #include <gmodule.h>
677 #include <stdio.h>
678 #include <stdlib.h>
679
680 int
681 main ()
682 {
683   if (g_module_supported())
684     return 0;   /* success */
685   else
686     return 1;   /* failure */
687 }
688 ], ac_cv_glib_supports_modules=yes, ac_cv_glib_supports_modules=no,
689    [echo $ac_n "cross compiling; assumed OK... $ac_c"
690     ac_cv_glib_supports_modules=yes])
691 CFLAGS="$ac_save_CFLAGS"
692 LIBS="$ac_save_LIBS"
693 if test "$ac_cv_glib_supports_modules" = yes ; then
694   AC_MSG_RESULT(yes)
695   have_plugins=yes
696 else
697   AC_MSG_RESULT(no)
698   have_plugins=no
699 fi
700
701 #
702 # If we have <dlfcn.h>, check whether we can use dladdr to find a
703 # filename (hopefully, a full pathname, but no guarantees) for
704 # the executable.
705 #
706 if test "$ac_cv_header_dlfcn_h" = "yes"
707 then
708         AC_MSG_CHECKING(whether dladdr can be used to find the pathname of an executable)
709         ac_save_CFLAGS="$CFLAGS"
710         ac_save_LIBS="$LIBS"
711         CFLAGS="$CFLAGS $GLIB_CFLAGS"
712         LIBS="$GLIB_LIBS $LIBS"
713         AC_TRY_RUN([
714 #define _GNU_SOURCE     /* required on Linux, sigh */
715 #include <dlfcn.h>
716
717 int
718 main(void)
719 {
720         Dl_info info;
721
722         if (!dladdr((void *)main, &info))
723                 return 1;       /* failure */
724         return 0;               /* assume success */
725 }
726 ], ac_cv_dladdr_finds_executable_path=yes, ac_cv_dladdr_finds_executable_path=no,
727    [echo $ac_n "cross compiling; assumed OK... $ac_c"
728     ac_cv_dladdr_finds_executable_path=yes])
729         CFLAGS="$ac_save_CFLAGS"
730         LIBS="$ac_save_LIBS"
731         if test x$ac_cv_dladdr_finds_executable_path = xyes
732         then
733                 AC_DEFINE(DLADDR_FINDS_EXECUTABLE_PATH, 1, [Define if dladdr can be used to find the path of the executable])
734         fi
735         AC_MSG_RESULT($ac_cv_dladdr_finds_executable_path)
736 fi
737
738 dnl IGE Mac integration check
739 AC_MSG_CHECKING(whether to use IGE Mac integration functions)
740
741 AC_ARG_WITH(ige-mac-integration,
742   AC_HELP_STRING( [--with-ige-mac-integration],
743                   [use IGE Mac integration. (@<:@default=yes, if available@:>@]),
744 [
745     if test $withval = no
746     then
747         want_ige_mac_integration=no
748     else
749         want_ige_mac_integration=yes
750     fi
751 ],[
752     want_ige_mac_integration=yes
753 ])
754 if test "x$want_ige_mac_integration" = "xno" -o "x$no_gtk" = "xyes" ; then
755     AC_MSG_RESULT(no)
756 else
757     AC_MSG_RESULT(yes)
758     AC_WIRESHARK_IGE_MAC_INTEGRATION_CHECK
759 fi
760
761
762 AC_SUBST(wireshark_bin)
763 AC_SUBST(wireshark_man)
764
765
766 # Enable/disable tshark
767
768 AC_ARG_ENABLE(tshark,
769   AC_HELP_STRING( [--enable-tshark],
770                   [build tshark.  @<:@default=yes@:>@]),
771     tshark=$enableval,enable_tshark=yes)
772
773 if test "x$enable_tshark" = "xyes" ; then
774         tshark_bin="tshark\$(EXEEXT)"
775         tshark_man="tshark.1"
776         wiresharkfilter_man="wireshark-filter.4"
777 else
778         tshark_bin=""
779         tshark_man=""
780 fi
781 AC_SUBST(tshark_bin)
782 AC_SUBST(tshark_man)
783 AC_SUBST(wiresharkfilter_man)
784
785
786
787 # Enable/disable editcap
788
789 AC_ARG_ENABLE(editcap,
790   AC_HELP_STRING( [--enable-editcap],
791                   [build editcap.  @<:@default=yes@:>@]),
792     enable_editcap=$enableval,enable_editcap=yes)
793
794 if test "x$enable_editcap" = "xyes" ; then
795         editcap_bin="editcap\$(EXEEXT)"
796         editcap_man="editcap.1"
797 else
798         editcap_bin=""
799         editcap_man=""
800 fi
801 AC_SUBST(editcap_bin)
802 AC_SUBST(editcap_man)
803
804 # Enabling/disabling of dumpcap is done later (after we know if we have PCAP
805 # or not)
806
807 # Enable/disable capinfos
808
809 AC_ARG_ENABLE(capinfos,
810   AC_HELP_STRING( [--enable-capinfos],
811                   [build capinfos.  @<:@default=yes@:>@]),
812     enable_capinfos=$enableval,enable_capinfos=yes)
813
814 if test "x$enable_capinfos" = "xyes" ; then
815         capinfos_bin="capinfos\$(EXEEXT)"
816         capinfos_man="capinfos.1"
817 else
818         capinfos_bin=""
819         capinfos_man=""
820 fi
821 AC_SUBST(capinfos_bin)
822 AC_SUBST(capinfos_man)
823
824
825 # Enable/disable mergecap
826
827 AC_ARG_ENABLE(mergecap,
828   AC_HELP_STRING( [--enable-mergecap],
829                   [build mergecap.  @<:@default=yes@:>@]),
830     enable_mergecap=$enableval,enable_mergecap=yes)
831
832 if test "x$enable_mergecap" = "xyes" ; then
833         mergecap_bin="mergecap\$(EXEEXT)"
834         mergecap_man="mergecap.1"
835 else
836         mergecap_bin=""
837         mergecap_man=""
838 fi
839 AC_SUBST(mergecap_bin)
840 AC_SUBST(mergecap_man)
841
842
843 # Enable/disable text2pcap
844
845 AC_ARG_ENABLE(text2pcap,
846   AC_HELP_STRING( [--enable-text2pcap],
847                   [build text2pcap.  @<:@default=yes@:>@]),
848     text2pcap=$enableval,enable_text2pcap=yes)
849
850 if test "x$enable_text2pcap" = "xyes" ; then
851         text2pcap_bin="text2pcap\$(EXEEXT)"
852         text2pcap_man="text2pcap.1"
853 else
854         text2pcap_bin=""
855         text2pcap_man=""
856 fi
857 AC_SUBST(text2pcap_bin)
858 AC_SUBST(text2pcap_man)
859
860 # Enable/disable idl2wrs
861
862 AC_ARG_ENABLE(idl2wrs,
863   AC_HELP_STRING( [--enable-idl2wrs],
864                   [build idl2wrs.  @<:@default=yes@:>@]),
865     enable_idl2wrs=$enableval,enable_idl2wrs=yes)
866
867 if test "x$enable_idl2wrs" = "xyes" ; then
868         idl2wrs_bin="idl2wrs"
869         idl2wrs_man="idl2wrs.1"
870 else
871         idl2wrs_bin=""
872         idl2wrs_man=""
873 fi
874 AC_SUBST(idl2wrs_bin)
875 AC_SUBST(idl2wrs_man)
876
877
878 # Enable/disable dftest
879
880 AC_ARG_ENABLE(dftest,
881   AC_HELP_STRING( [--enable-dftest],
882                   [build dftest.  @<:@default=yes@:>@]),
883     enable_dftest=$enableval,enable_dftest=yes)
884
885 if test "x$enable_dftest" = "xyes" ; then
886         dftest_bin="dftest\$(EXEEXT)"
887 else
888         dftest_bin=""
889 fi
890 AC_SUBST(dftest_bin)
891
892
893 # Enable/disable randpkt
894
895 AC_ARG_ENABLE(randpkt,
896   AC_HELP_STRING( [--enable-randpkt],
897                   [build randpkt.  @<:@default=yes@:>@]),
898     enable_randpkt=$enableval,enable_randpkt=yes)
899
900 if test "x$enable_randpkt" = "xyes" ; then
901         randpkt_bin="randpkt\$(EXEEXT)"
902 else
903         randpkt_bin=""
904 fi
905 AC_SUBST(randpkt_bin)
906
907
908
909 dnl Checks for "gethostbyname()" - and "-lnsl", if we need it to get
910 dnl "gethostbyname()".
911 AC_WIRESHARK_GETHOSTBY_LIB_CHECK
912
913 dnl Checks for "connect()", used as a proxy for "socket()" - and
914 dnl "-lsocket", if we need it to get "connect()".
915 AC_WIRESHARK_SOCKET_LIB_CHECK
916
917 dnl pcap check
918 AC_MSG_CHECKING(whether to use libpcap for packet capture)
919
920 AC_ARG_WITH(pcap,
921   AC_HELP_STRING( [--with-pcap@<:@=DIR@:>@],
922                   [use libpcap for packet capturing.  @<:@default=yes@:>@]),
923 [
924         if test $withval = no
925         then
926                 want_pcap=no
927         elif test $withval = yes
928         then
929                 want_pcap=yes
930         else
931                 want_pcap=yes
932                 pcap_dir=$withval
933         fi
934 ],[
935         want_pcap=yes
936         pcap_dir=
937 ])
938 if test "x$want_pcap" = "xno" ; then
939         AC_MSG_RESULT(no)
940 else
941         AC_MSG_RESULT(yes)
942         AC_WIRESHARK_PCAP_CHECK
943 fi
944
945 # Enable/disable dumpcap
946
947 dnl dumpcap check
948 AC_MSG_CHECKING(whether to build dumpcap)
949
950 AC_ARG_ENABLE(dumpcap,
951   AC_HELP_STRING( [--enable-dumpcap],
952                   [build dumpcap.  @<:@default=yes@:>@]),
953     enable_dumpcap=$enableval,enable_dumpcap=yes)
954
955 if test "x$enable_dumpcap" = "xyes" ; then
956         if test "x$want_pcap" = "xno" ; then
957                 enable_dumpcap=no
958                 AC_MSG_RESULT(pcap not available - disabling dumpcap)
959         else
960                 AC_MSG_RESULT(yes)
961         fi
962 else
963         AC_MSG_RESULT(no)
964 fi
965
966 if test "x$enable_dumpcap" = "xyes" ; then
967         dumpcap_bin="dumpcap\$(EXEEXT)"
968         dumpcap_man="dumpcap.1"
969 else
970         dumpcap_bin=""
971         dumpcap_man=""
972 fi
973 AC_SUBST(dumpcap_bin)
974 AC_SUBST(dumpcap_man)
975
976 # Enable/disable rawshark
977
978 dnl rawshark check
979 AC_MSG_CHECKING(whether to build rawshark)
980
981 AC_ARG_ENABLE(rawshark,
982   AC_HELP_STRING( [--enable-rawshark],
983                   [build rawshark.  @<:@default=yes@:>@]),
984     rawshark=$enableval,enable_rawshark=yes)
985
986 if test "x$enable_rawshark" = "xyes" ; then
987         if test "x$want_pcap" = "xno" ; then
988                 enable_rawshark=no
989                 AC_MSG_RESULT(pcap not available - disabling rawshark)
990         else
991                 AC_MSG_RESULT(yes)
992         fi
993 else
994         AC_MSG_RESULT(no)
995 fi
996
997 if test "x$enable_rawshark" = "xyes" ; then
998         rawshark_bin="rawshark\$(EXEEXT)"
999         rawshark_man="rawshark.1"
1000 else
1001         rawshark_bin=""
1002         rawshark_man=""
1003 fi
1004 AC_SUBST(rawshark_bin)
1005 AC_SUBST(rawshark_man)
1006
1007
1008 dnl pcap remote check
1009 AC_MSG_CHECKING(whether to use libpcap remote capturing feature)
1010
1011 AC_ARG_WITH(pcap-remote,
1012 [  --with-pcap-remote        use libpcap remote capturing (requires libpcap)],
1013 [
1014     if test $withval = no
1015     then
1016         want_pcap_remote=no
1017     else
1018         want_pcap_remote=yes
1019     fi
1020 ],[
1021     want_pcap_remote=no
1022 ])
1023 if test "x$want_pcap_remote" = "xno" -o "x$want_pcap" = "xno" ; then
1024     AC_MSG_RESULT(no)
1025 else
1026     AC_MSG_RESULT(yes)
1027     AC_WIRESHARK_PCAP_REMOTE_CHECK
1028 fi
1029
1030 dnl zlib check
1031 AC_MSG_CHECKING(whether to use zlib for reading compressed capture files)
1032
1033 AC_ARG_WITH(zlib,
1034   AC_HELP_STRING( [--with-zlib@<:@=DIR@:>@],
1035                   [use zlib (located in directory DIR, if supplied) to read compressed data.  @<:@default=yes, if available@:>@]),
1036 [
1037         if test $withval = no
1038         then
1039                 want_zlib=no
1040         elif test $withval = yes
1041         then
1042                 want_zlib=yes
1043         else
1044                 want_zlib=yes
1045                 zlib_dir=$withval
1046         fi
1047 ],[
1048         #
1049         # Use zlib if it's present, otherwise don't.
1050         #
1051         want_zlib=ifavailable
1052         zlib_dir=
1053 ])
1054 if test "x$want_zlib" = "xno" ; then
1055         AC_MSG_RESULT(no)
1056 else
1057         AC_MSG_RESULT(yes)
1058         AC_WIRESHARK_ZLIB_CHECK
1059         if test "x$want_zlib" = "xno" ; then
1060                 AC_MSG_RESULT(zlib not found - disabling compressed capture file support)
1061         fi
1062 fi
1063
1064
1065 dnl pcre check
1066 AC_MSG_CHECKING(whether to use libpcre for regular expressions in dfilters)
1067
1068 AC_ARG_WITH(pcre,
1069   AC_HELP_STRING( [--with-pcre@<:@=DIR@:>@],
1070                   [use libpcre (located in directory DIR, if supplied) to use in dfilter regular expressions.  @<:@default=yes, if available@:>@]),
1071 [
1072         if test $withval = no
1073         then
1074                 want_pcre=no
1075         elif test $withval = yes
1076         then
1077                 want_pcre=yes
1078         else
1079                 want_pcre=yes
1080                 pcre_dir=$withval
1081         fi
1082 ],[
1083         #
1084         # Use libpcre if it's present, otherwise don't.
1085         #
1086         want_pcre=ifavailable
1087         pcre_dir=
1088 ])
1089 if test "x$want_pcre" = "xno" ; then
1090         AC_MSG_RESULT(no)
1091 else
1092         AC_MSG_RESULT(yes)
1093         AC_WIRESHARK_LIBPCRE_CHECK
1094         if test "x$want_pcre" = "xno" ; then
1095                 AC_MSG_RESULT(libpcre not found - disabling support for perl compatible regular expressions in dfilters)
1096         fi
1097 fi
1098
1099
1100 dnl lua check
1101 AC_MSG_CHECKING(whether to use liblua for the lua scripting plugin)
1102
1103 AC_ARG_WITH(lua,
1104   AC_HELP_STRING( [--with-lua@<:@=DIR@:>@],
1105                   [use liblua (located in directory DIR, if supplied) for the lua scripting plugin.  @<:@default=yes, if available@:>@]),
1106 [
1107         if test $withval = no
1108         then
1109                 want_lua=no
1110         elif test $withval = yes
1111         then
1112                 want_lua=yes
1113         else
1114                 want_lua=yes
1115                 lua_dir=$withval
1116         fi
1117 ],[
1118         #
1119         # Use liblua by default
1120         #
1121         want_lua=ifavailable
1122         lua_dir=
1123 ])
1124 if test "x$want_lua" = "xno" ; then
1125         AC_MSG_RESULT(no)
1126 else
1127         AC_MSG_RESULT(yes)
1128         AC_WIRESHARK_LIBLUA_CHECK
1129         if test "x$want_lua" = "xno" ; then
1130                 AC_MSG_RESULT(liblua not found - disabling support for the lua scripting plugin)
1131         fi
1132 fi
1133 AM_CONDITIONAL(HAVE_LIBLUA, test x$want_lua = xyes)
1134
1135
1136 dnl portaudio check
1137 AC_MSG_CHECKING(whether to use libportaudio for the rtp_player)
1138
1139 AC_ARG_WITH(portaudio,
1140   AC_HELP_STRING( [--with-portaudio@<:@=DIR@:>@],
1141                   [use libportaudio (located in directory DIR, if supplied) for the rtp_player.  @<:@default=yes, if available@:>@]),
1142 [
1143         if test $withval = no
1144         then
1145                 want_portaudio=no
1146         elif test $withval = yes
1147         then
1148                 want_portaudio=yes
1149         else
1150                 want_portaudio=yes
1151                 portaudio_dir=$withval
1152         fi
1153 ],[
1154         #
1155         # Use libportaudio by default
1156         #
1157         want_portaudio=ifavailable
1158         portaudio_dir=
1159 ])
1160 if test "x$want_portaudio" = "xno" ; then
1161         AC_MSG_RESULT(no)
1162 else
1163         AC_MSG_RESULT(yes)
1164         AC_WIRESHARK_LIBPORTAUDIO_CHECK
1165         if test "x$want_portaudio" = "xno" ; then
1166                 AC_MSG_RESULT(libportaudio not found - disabling support for the rtp_player)
1167         fi
1168 fi
1169 AM_CONDITIONAL(HAVE_LIBPORTAUDIO, test x$want_portaudio = xyes)
1170
1171
1172 dnl ipv6 check
1173 AC_ARG_ENABLE(ipv6,
1174   AC_HELP_STRING( [--enable-ipv6],
1175                   [use ipv6 name resolution, if available.  @<:@default=yes@:>@]),
1176     enable_ipv6=$enableval,enable_ipv6=yes)
1177
1178 AC_MSG_CHECKING(whether to enable ipv6 name resolution if available)
1179 if test "x$enable_ipv6" = "xno" ; then
1180         AC_MSG_RESULT(no)
1181 else
1182         AC_MSG_RESULT(yes)
1183         AC_WIRESHARK_IPV6_STACK
1184 fi
1185
1186
1187 dnl Check if dumpcap should be installed setuid
1188 AC_ARG_ENABLE(setuid-install,
1189   AC_HELP_STRING( [--enable-setuid-install],
1190                   [install dumpcap as setuid @<:@default=no@:>@]),
1191     enable_setuid_install=$enableval,enable_setuid_install=no)
1192
1193 AC_MSG_CHECKING(whether to install dumpcap setuid)
1194 if test "x$enable_setuid_install" = "xno" ; then
1195         AC_MSG_RESULT(no)
1196 else
1197         if test "x$enable_dumpcap" = "xno" ; then
1198                 AC_MSG_ERROR(Setuid install works only with dumpcap but dumpcap is disabled)
1199         else
1200                 AC_MSG_RESULT(yes)
1201         fi
1202 fi
1203
1204 AM_CONDITIONAL(SETUID_INSTALL, test x$enable_setuid_install = xyes)
1205 AC_CHECK_FUNCS(setresuid setresgid)
1206
1207 dnl libcap (not libpcap) check
1208 LIBCAP_LIBS=''
1209 AC_MSG_CHECKING(whether to use the libcap capabilities library)
1210
1211 AC_ARG_WITH(libcap,
1212   AC_HELP_STRING( [--with-libcap@<:@=DIR@:>@],
1213                   [use libcap (located in directory DIR, if supplied) for POSIX.1e capabilities management.   @<:@default=yes, if present@:>@]),
1214 [
1215 if   test "x$withval" = "xno";  then
1216         want_libcap=no
1217 elif test "x$withval" = "xyes"; then
1218         want_libcap=yes
1219 elif test -d "$withval"; then
1220         want_libcap=yes
1221         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1222 fi
1223 ])
1224 if test "x$with_libcap" = "xno" ; then
1225         AC_MSG_RESULT(no)
1226 else
1227         AC_MSG_RESULT(yes)
1228         AC_WIRESHARK_LIBCAP_CHECK
1229 fi
1230 AC_SUBST(LIBCAP_LIBS)
1231
1232 dnl Checks for header files.
1233 AC_CHECK_HEADERS(direct.h dirent.h fcntl.h grp.h inttypes.h netdb.h pwd.h stdarg.h stddef.h unistd.h)
1234 AC_CHECK_HEADERS(sys/ioctl.h sys/param.h sys/socket.h sys/sockio.h sys/stat.h sys/time.h sys/types.h sys/utsname.h sys/wait.h)
1235 AC_CHECK_HEADERS(netinet/in.h)
1236 AC_CHECK_HEADERS(arpa/inet.h arpa/nameser.h)
1237
1238 dnl SSL Check
1239 SSL_LIBS=''
1240 AC_MSG_CHECKING(whether to use SSL library)
1241
1242 AC_ARG_WITH(ssl,
1243   AC_HELP_STRING( [--with-ssl@<:@=DIR@:>@],
1244                   [use SSL crypto library (located in directory DIR, if supplied).   @<:@default=no@:>@]),
1245 [
1246 if test "x$withval" = "xno";  then
1247         want_ssl=no
1248 elif test "x$withval" = "xyes"; then
1249         want_ssl=yes
1250 elif test -d "$withval"; then
1251         want_ssl=yes
1252         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1253 fi
1254 ],[
1255         want_ssl=no
1256 ])
1257 if test "x$want_ssl" = "xyes"; then
1258         AC_MSG_RESULT(yes)
1259         AC_CHECK_LIB(crypto,EVP_md5,
1260             [
1261                 SSL_LIBS=-lcrypto
1262             ],
1263             [
1264                 AC_MSG_ERROR([SSL crypto library was requested, but is not available])
1265             ])
1266 else
1267         AC_MSG_RESULT(no)
1268 fi
1269 AC_SUBST(SSL_LIBS)
1270
1271 dnl kerberos check
1272 AC_MSG_CHECKING(whether to use kerberos)
1273
1274 AC_ARG_WITH(krb5,
1275   AC_HELP_STRING( [--with-krb5@<:@=DIR@:>@],
1276                   [use kerberos (located in directory DIR, if supplied) to use in kerberos dissection  @<:@default=yes@:>@]),
1277 [
1278         if test $withval = no
1279         then
1280                 want_krb5=no
1281         elif test $withval = yes
1282         then
1283                 want_krb5=yes
1284         else
1285                 want_krb5=yes
1286                 krb5_dir=$withval
1287         fi
1288 ],[
1289         #
1290         # Use kerberos if specified, otherwise don't.
1291         #
1292         want_krb5=ifavailable
1293         krb5_dir=
1294 ])
1295 if test "x$want_krb5" = "xno" ; then
1296         AC_MSG_RESULT(no)
1297 else
1298         AC_MSG_RESULT(yes)
1299         AC_WIRESHARK_KRB5_CHECK
1300 fi
1301
1302
1303 dnl c-ares Check
1304 C_ARES_LIBS=''
1305 AC_MSG_CHECKING(whether to use the c-ares library if available)
1306
1307 AC_ARG_WITH(c-ares,
1308   AC_HELP_STRING( [--with-c-ares@<:@=DIR@:>@],
1309                   [use c-ares (located in directory DIR, if supplied). Supersedes --with-adns.   @<:@default=yes, if present@:>@]),
1310 [
1311 if   test "x$withval" = "xno";  then
1312         want_c_ares=no
1313 elif test "x$withval" = "xyes"; then
1314         want_c_ares=yes
1315 elif test -d "$withval"; then
1316         want_c_ares=yes
1317         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1318 fi
1319 ])
1320 if test "x$want_c_ares" = "xno" ; then
1321         AC_MSG_RESULT(no)
1322 else
1323         AC_MSG_RESULT(yes)
1324         AC_WIRESHARK_C_ARES_CHECK
1325 fi
1326 AC_SUBST(C_ARES_LIBS)
1327
1328 dnl ADNS Check
1329 ADNS_LIBS=''
1330 AC_MSG_CHECKING(whether to use the GNU ADNS library if available)
1331
1332 AC_ARG_WITH(adns,
1333   AC_HELP_STRING( [--with-adns@<:@=DIR@:>@],
1334                   [use GNU ADNS (located in directory DIR, if supplied).   @<:@default=yes, if present@:>@]),
1335 [
1336 if   test "x$withval" = "xno";  then
1337         want_adns=no
1338 elif test "x$withval" = "xyes"; then
1339         want_adns=yes
1340 elif test -d "$withval"; then
1341         want_adns=yes
1342         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1343 fi
1344 ])
1345 if test "x$want_adns" = "xno" -o "x$have_good_c_ares" = "xyes" ; then
1346         AC_MSG_RESULT(no)
1347 else
1348         AC_MSG_RESULT(yes)
1349         AC_WIRESHARK_ADNS_CHECK
1350 fi
1351 AC_SUBST(ADNS_LIBS)
1352
1353 dnl GEOIP Check
1354 GEOIP_LIBS=''
1355 AC_MSG_CHECKING(whether to use the GeoIP IP address mapping library if available)
1356
1357 AC_ARG_WITH(geoip,
1358   AC_HELP_STRING( [--with-geoip@<:@=DIR@:>@],
1359                   [use GeoIP (located in directory DIR, if supplied).   @<:@default=yes, if present@:>@]),
1360 [
1361 if   test "x$withval" = "xno";  then
1362         want_geoip=no
1363 elif test "x$withval" = "xyes"; then
1364         want_geoip=yes
1365 elif test -d "$withval"; then
1366         want_geoip=yes
1367         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1368 fi
1369 ])
1370 if test "x$want_geoip" = "xno"; then
1371         AC_MSG_RESULT(no)
1372 else
1373         AC_MSG_RESULT(yes)
1374         AC_WIRESHARK_GEOIP_CHECK
1375 fi
1376 AC_SUBST(GEOIP_LIBS)
1377
1378 dnl Python devel Check
1379 AC_ARG_WITH(python,
1380     AC_HELP_STRING( [--with-python@<:@=DIR@:>@],
1381                     [use python interpretor (installed in DIR, if supplied). @<:@default=no@:>@ (EXPERIMENTAL)]),
1382 [
1383 pythondir='${libdir}/wireshark/python/${VERSION}'
1384 if test "x$withval" = "xno"; then
1385   want_python=no
1386 elif test "x$withval" != "xyes"; then
1387   pythondir="$withval"
1388   want_python=yes
1389   AC_WIRESHARK_PYTHON_CHECK
1390 else
1391   want_python=yes
1392   AC_WIRESHARK_PYTHON_CHECK
1393 fi
1394 ])
1395 AM_CONDITIONAL(HAVE_LIBPY, test x$want_python = xyes)
1396 AC_SUBST(pythondir)
1397
1398 #
1399 # Define WS_VAR_IMPORT appropriately for declarations of external
1400 # variables exported from dynamically-linked libraries.
1401 #
1402 AC_DEFINE(WS_VAR_IMPORT, extern, [Define as the string to precede external variable declarations in dynamically-linked libraries])
1403
1404 AC_ARG_ENABLE(airpcap,
1405   AC_HELP_STRING( [--enable-airpcap],
1406                   [use airpcap in wireshark.  @<:@default=no@:>@]),
1407   enable_airpcap=$enableval
1408   if test x$enable_airpcap != xno; then
1409         AC_DEFINE(HAVE_AIRPCAP, 1, [Enable AirPcap])
1410   fi
1411 )
1412 #
1413 # Define HAVE_AIRPDCAP
1414 # We'll want to remove this eventually.
1415 #
1416 AC_DEFINE(HAVE_AIRPDCAP, 1, [Enable AirPDcap (WPA/WPA2 decryption)])
1417
1418 dnl Checks for typedefs, structures, and compiler characteristics.
1419 # AC_C_CONST
1420
1421 # We need to know whether "struct sockaddr" has an "sa_len" member
1422 # for get_interface_list().
1423
1424 AC_WIRESHARK_STRUCT_SA_LEN
1425
1426 # We must know our byte order
1427 AC_C_BIGENDIAN
1428
1429 # Checks whether "-traditional" is needed when using "ioctl".
1430 # XXX - do we need this?
1431 AC_PROG_GCC_TRADITIONAL
1432
1433 GETOPT_C=""
1434 GETOPT_O=""
1435 AC_CHECK_FUNC(getopt,
1436   [GETOPT_O=""
1437    AC_DEFINE(HAVE_GETOPT_H, 1, [Define to 1 if you have the <getopt.h> header file.])
1438   ],
1439   GETOPT_O="wsgetopt.o"
1440 )
1441 if test "$ac_cv_func_getopt" = no ; then
1442   GETOPT_C="wsgetopt.c"
1443   GETOPT_O="wsgetopt.o"
1444 fi
1445 AC_SUBST(GETOPT_C)
1446 AC_SUBST(GETOPT_O)
1447
1448 AC_CHECK_FUNC(strerror, STRERROR_O="",
1449   [STRERROR_O="strerror.o"
1450    AC_DEFINE(NEED_STRERROR_H, 1, [Define if strerror.h needs to be included])
1451 ])
1452 if test "$ac_cv_func_strerror" = no ; then
1453   STRERROR_C="strerror.c"
1454   STRERROR_O="strerror.o"
1455 fi
1456 AC_SUBST(STRERROR_C)
1457 AC_SUBST(STRERROR_O)
1458
1459 AC_CHECK_FUNC(strncasecmp, STRNCASECMP_O="",
1460   STRNCASECMP_O="strncasecmp.o")
1461 if test "$ac_cv_func_strncasecmp" = no ; then
1462   STRNCASECMP_C="strncasecmp.c"
1463   STRNCASECMP_O="strncasecmp.o"
1464 fi
1465 AC_SUBST(STRNCASECMP_C)
1466 AC_SUBST(STRNCASECMP_O)
1467
1468 AC_CHECK_FUNCS(mkstemp mkdtemp)
1469
1470 #
1471 # XXX - if inet_aton isn't found, the build fails, with a complaint from
1472 # libtool about inet_aton.lo not being a valid libtool object.  We
1473 # probably have to handle it - and all the other replacement functions that
1474 # get built into libwireshark - differently.
1475 #
1476 AC_SEARCH_LIBS(inet_aton, [socket nsl], have_inet_aton=yes,
1477     have_inet_aton=no)
1478 if test "$have_inet_aton" = no; then
1479   INET_ATON_C="inet_aton.c"
1480   INET_ATON_O="inet_aton.o"
1481   INET_ATON_LO="inet_aton.lo"
1482   AC_DEFINE(NEED_INET_ATON_H, 1, [Define if inet/aton.h needs to be included])
1483 else
1484   INET_ATON_C=""
1485   INET_ATON_O=""
1486   INET_ATON_LO=""
1487 fi
1488 AC_SUBST(INET_ATON_C)
1489 AC_SUBST(INET_ATON_O)
1490 AC_SUBST(INET_ATON_LO)
1491
1492 AC_SEARCH_LIBS(inet_pton, [socket nsl], [
1493   dnl check for pre-BIND82 inet_pton() bug.
1494   AC_MSG_CHECKING(for broken inet_pton)
1495   AC_TRY_RUN([#include <sys/types.h>
1496 #include <sys/socket.h>
1497 #include <netinet/in.h>
1498 #include <arpa/inet.h>
1499 int main()
1500 {
1501 #ifdef AF_INET6
1502   char buf[16];
1503   /* this should return 0 (error) */
1504   return inet_pton(AF_INET6, "0:1:2:3:4:5:6:7:", buf);
1505 #else
1506   return 1;
1507 #endif
1508 }], [AC_MSG_RESULT(ok);
1509 have_inet_pton=yes], [AC_MSG_RESULT(broken);
1510 have_inet_pton=no], [AC_MSG_RESULT(cross compiling, assume it is broken);
1511 have_inet_pton=no])],
1512 have_inet_pton=no)
1513 if test "$have_inet_pton" = no; then
1514   INET_PTON_C="inet_pton.c"
1515   INET_PTON_O="inet_pton.o"
1516   INET_PTON_LO="inet_pton.lo"
1517 else
1518   INET_PTON_C=""
1519   INET_PTON_O=""
1520   INET_PTON_LO=""
1521 fi
1522 AC_SUBST(INET_PTON_C)
1523 AC_SUBST(INET_PTON_O)
1524 AC_SUBST(INET_PTON_LO)
1525
1526 AC_SEARCH_LIBS(inet_ntop, [socket nsl], [
1527   AC_MSG_CHECKING([for inet_ntop prototype])
1528   AC_TRY_COMPILE([#include <stdio.h>
1529 #include <sys/types.h>
1530 #include <sys/socket.h>
1531 #include <netinet/in.h>
1532 #include <arpa/inet.h>
1533
1534 extern const char *inet_ntop(int, const void *, char *, size_t);],, [
1535     AC_MSG_RESULT(yes)
1536     AC_DEFINE(HAVE_INET_NTOP_PROTO, 1,
1537     [Define if inet_ntop() prototype exists])], [
1538     AC_TRY_COMPILE([#include <stdio.h>
1539 #include <sys/types.h>
1540 #include <sys/socket.h>
1541 #include <netinet/in.h>
1542 #include <arpa/inet.h>
1543
1544 extern const char *inet_ntop(int, const void *, char *, socklen_t);],, [
1545       AC_MSG_RESULT(yes)
1546       AC_DEFINE(HAVE_INET_NTOP_PROTO, 1,
1547       [Define if inet_ntop() prototype exists])], [
1548       AC_MSG_RESULT(no)])])
1549   INET_NTOP_O=""
1550   INET_NTOP_LO=""], [
1551   INET_NTOP_C="inet_ntop.c"
1552   INET_NTOP_O="inet_ntop.o"
1553   INET_NTOP_LO="inet_ntop.lo"
1554   AC_DEFINE(NEED_INET_V6DEFS_H, 1,
1555   [Define if inet/v6defs.h needs to be included])])
1556 AC_SUBST(INET_NTOP_C)
1557 AC_SUBST(INET_NTOP_O)
1558 AC_SUBST(INET_NTOP_LO)
1559
1560 AC_CHECK_FUNC(strptime, STRPTIME_O="",
1561   [STRPTIME_O="strptime.o"
1562    AC_DEFINE(NEED_STRPTIME_H, 1, [Define if strptime.h needs to be included])
1563 ])
1564 if test "$ac_cv_func_strptime" = no ; then
1565   STRPTIME_C="strptime.c"
1566   STRPTIME_O="strptime.o"
1567 fi
1568 AC_SUBST(STRPTIME_C)
1569 AC_SUBST(STRPTIME_O)
1570
1571 AC_CHECK_FUNCS(getprotobynumber gethostbyname2)
1572 AC_CHECK_FUNCS(issetugid)
1573 AC_CHECK_FUNCS(mmap mprotect sysconf)
1574
1575 dnl blank for now, but will be used in future
1576 AC_SUBST(wireshark_SUBDIRS)
1577
1578 dnl
1579 dnl check whether plugins should be enabled and, if they should be,
1580 dnl check for plugins directory - stolen from Amanda's configure.in
1581 dnl
1582 dnl we don't wish to expand ${libdir} yet
1583 plugindir='${libdir}/wireshark/plugins/${VERSION}'
1584 AC_ARG_WITH(plugins,
1585   AC_HELP_STRING( [--with-plugins@<:@=DIR@:>@],
1586                   [support plugins (installed in DIR, if supplied).   @<:@default=yes, if possible@:>@]),
1587 [
1588   if test "x$withval" = "xno"; then
1589     have_plugins=no
1590   elif test "x$have_plugins" = "xno"; then
1591       AC_MSG_ERROR([GLib on this platform doesn't support loadable modules, so you can't enable plugins.])
1592   elif test "x$withval" != "xyes"; then
1593       plugindir="$withval"
1594   fi
1595 ])
1596 AM_CONDITIONAL(HAVE_PLUGINS, test "x$have_plugins" = "xyes")
1597 if test x$have_plugins = xyes
1598 then
1599   AC_DEFINE(HAVE_PLUGINS, 1, [Define if plugins are enabled])
1600 fi
1601 AC_SUBST(plugindir)
1602 CPPFLAGS="$CPPFLAGS '-DPLUGIN_DIR=\"\$(plugindir)\"'"
1603
1604 #
1605 # The plugin dissectors reside in ./plugins/PROTO/
1606 #
1607 PLUGIN_LIBS=""
1608 AC_SUBST(PLUGIN_LIBS)
1609
1610 dnl libtool defs
1611 #
1612 # Yes, AM_PROG_LIBTOOL is redundant with newer version(s) of some tool(s)
1613 # (autoconf?  automake?  libtool?) - with the newer version(s), it's
1614 # just an alias for AC_PROG_LIBTOOL, which is called earlier.
1615 #
1616 # With older version(s) of those tool(s), however, it's not just an
1617 # alias, and the configure scripts don't work without it.
1618 #
1619 AM_PROG_LIBTOOL
1620 AC_SUBST(LIBTOOL_DEPS)
1621
1622 AM_CONDITIONAL(ENABLE_STATIC, test x$enable_static = xyes)
1623 if test x$enable_static = xyes -a x$have_plugins = xyes
1624 then
1625   AC_DEFINE(ENABLE_STATIC, 1, [Link plugins statically into Wireshark])
1626 fi
1627 AC_SUBST(ENABLE_STATIC)
1628
1629 AC_ARG_ENABLE(new-packet-list,
1630   AC_HELP_STRING( [--enable-new-packet-list],
1631                   [use new packet list feature.  @<:@default=yes@:>@]),
1632                   new_packet_list=$enableval,new_packet_list=yes)
1633 AC_MSG_CHECKING(if new packet list is used);
1634 if test "x$new_packet_list" = "xyes" ; then
1635         AC_MSG_RESULT(yes)
1636         CFLAGS=" -DNEW_PACKET_LIST $CFLAGS"
1637 else
1638         AC_MSG_RESULT(no)
1639 fi
1640
1641 dnl Save the cacheable configure results to config.cache before recursing
1642 AC_CACHE_SAVE
1643
1644 sinclude(plugins/Custom.m4) dnl
1645 ifdef(_CUSTOM_AC_OUTPUT_,, define(_CUSTOM_AC_OUTPUT_, )) dnl
1646
1647 AM_CONFIG_HEADER(config.h)
1648 AC_OUTPUT(
1649   Makefile
1650   doxygen.cfg
1651   asn1/Makefile
1652   asn1/acp133/Makefile
1653   asn1/acse/Makefile
1654   asn1/ansi_map/Makefile
1655   asn1/ansi_tcap/Makefile
1656   asn1/camel/Makefile
1657   asn1/cdt/Makefile
1658   asn1/charging_ase/Makefile
1659   asn1/cmip/Makefile
1660   asn1/cmp/Makefile
1661   asn1/crmf/Makefile
1662   asn1/cms/Makefile
1663   asn1/dap/Makefile
1664   asn1/disp/Makefile
1665   asn1/dop/Makefile
1666   asn1/dsp/Makefile
1667   asn1/ess/Makefile
1668   asn1/ftam/Makefile
1669   asn1/gnm/Makefile
1670   asn1/goose/Makefile
1671   asn1/gsm_map/Makefile
1672   asn1/h225/Makefile
1673   asn1/h235/Makefile
1674   asn1/h245/Makefile
1675   asn1/h248/Makefile
1676   asn1/h282/Makefile
1677   asn1/h283/Makefile
1678   asn1/h323/Makefile
1679   asn1/h450/Makefile
1680   asn1/h450-ros/Makefile
1681   asn1/h460/Makefile
1682   asn1/h501/Makefile
1683   asn1/inap/Makefile
1684   asn1/ldap/Makefile
1685   asn1/logotypecertextn/Makefile
1686   asn1/lte-rrc/Makefile
1687   asn1/mms/Makefile
1688   asn1/mpeg-audio/Makefile
1689   asn1/mpeg-pes/Makefile
1690   asn1/nbap/Makefile
1691   asn1/ns_cert_exts/Makefile
1692   asn1/ocsp/Makefile
1693   asn1/p7/Makefile
1694   asn1/pcap/Makefile
1695   asn1/pkcs1/Makefile
1696   asn1/pkcs12/Makefile
1697   asn1/pkinit/Makefile
1698   asn1/pkix1explicit/Makefile
1699   asn1/pkix1implicit/Makefile
1700   asn1/pkixproxy/Makefile
1701   asn1/pkixqualified/Makefile
1702   asn1/pkixtsp/Makefile
1703   asn1/pres/Makefile
1704   asn1/q932/Makefile
1705   asn1/q932-ros/Makefile
1706   asn1/qsig/Makefile
1707   asn1/ranap/Makefile
1708   asn1/rnsap/Makefile
1709   asn1/ros/Makefile
1710   asn1/rrc/Makefile
1711   asn1/rrlp/Makefile
1712   asn1/rtse/Makefile
1713   asn1/s1ap/Makefile
1714   asn1/s4406/Makefile
1715   asn1/sabp/Makefile
1716   asn1/smrse/Makefile
1717   asn1/snmp/Makefile
1718   asn1/spnego/Makefile
1719   asn1/t125/Makefile
1720   asn1/t38/Makefile
1721   asn1/tcap/Makefile
1722   asn1/ulp/Makefile
1723   asn1/wlancertextn/Makefile
1724   asn1/x2ap/Makefile
1725   asn1/x411/Makefile
1726   asn1/x420/Makefile
1727   asn1/x509af/Makefile
1728   asn1/x509ce/Makefile
1729   asn1/x509if/Makefile
1730   asn1/x509sat/Makefile
1731   asn1/x721/Makefile
1732   doc/Makefile
1733   epan/Makefile
1734   epan/crc/Makefile
1735   epan/crypt/Makefile
1736   epan/doxygen.cfg
1737   epan/dfilter/Makefile
1738   epan/dissectors/Makefile
1739   epan/ftypes/Makefile
1740   epan/wslua/Makefile
1741   epan/wspython/Makefile
1742   codecs/Makefile
1743   gtk/Makefile
1744   gtk/doxygen.cfg
1745   help/Makefile
1746   packaging/Makefile
1747   packaging/macosx/Info.plist
1748   packaging/macosx/Makefile
1749   packaging/nsis/Makefile
1750   packaging/rpm/Makefile
1751   packaging/rpm/SPECS/Makefile
1752   packaging/rpm/SPECS/wireshark.spec
1753   packaging/svr4/Makefile
1754   packaging/svr4/checkinstall
1755   packaging/svr4/pkginfo
1756   plugins/Makefile
1757   plugins/asn1/Makefile
1758   plugins/docsis/Makefile
1759   plugins/ethercat/Makefile
1760   plugins/giop/Makefile
1761   plugins/gryphon/Makefile
1762   plugins/irda/Makefile
1763   plugins/m2m/Makefile
1764   plugins/mate/Makefile
1765   plugins/opcua/Makefile
1766   plugins/profinet/Makefile
1767   plugins/sercosiii/Makefile
1768   plugins/stats_tree/Makefile
1769   plugins/unistim/Makefile
1770   plugins/wimax/Makefile
1771   plugins/wimaxasncp/Makefile
1772   tools/Makefile
1773   tools/idl2wrs.sh
1774   tools/lemon/Makefile
1775   wiretap/Makefile
1776   wsutil/Makefile
1777   _CUSTOM_AC_OUTPUT_
1778   ,)
1779 dnl AC_CONFIG_FILES([tools/setuid-root.pl], [chmod +x tools/setuid-root.pl])
1780
1781
1782 # Pretty messages
1783
1784 if test "x$enable_setuid_install" = "xyes" ; then
1785         setuid_message="yes"
1786 else
1787         setuid_message="no"
1788 fi
1789
1790 if test "x$want_zlib" = "xno" ; then
1791         zlib_message="no"
1792 else
1793         zlib_message="yes"
1794 fi
1795
1796 if test "x$want_pcre" = "xno" ; then
1797         pcre_message="no"
1798 else
1799         pcre_message="yes"
1800 fi
1801
1802 if test "x$want_lua" = "xyes" ; then
1803         lua_message="yes"
1804 else
1805         lua_message="no"
1806 fi
1807
1808 if test "x$want_python" = "xyes"; then
1809         python_message="yes"
1810 else
1811         python_message="no"
1812 fi
1813
1814 if test "x$want_portaudio" = "xyes" ; then
1815         portaudio_message="yes"
1816 else
1817         portaudio_message="no"
1818 fi
1819
1820 if test "x$want_ssl" = "xno" ; then
1821         ssl_message="no"
1822 else
1823         ssl_message="yes"
1824 fi
1825
1826 if test "x$want_krb5" = "xno" ; then
1827         krb5_message="no"
1828 else
1829         krb5_message="yes ($ac_krb5_version)"
1830 fi
1831
1832 if test "x$have_good_c_ares" = "xyes" ; then
1833         c_ares_message="yes"
1834 else
1835         c_ares_message="no"
1836 fi
1837
1838 if test "x$have_good_adns" = "xyes" ; then
1839         adns_message="yes"
1840 else
1841         adns_message="no"
1842 fi
1843
1844 if test "x$have_good_libcap" = "xyes" ; then
1845         libcap_message="yes"
1846 else
1847         libcap_message="no"
1848 fi
1849
1850 if test "x$have_good_geoip" = "xyes" ; then
1851         geoip_message="yes"
1852 else
1853         geoip_message="no"
1854 fi
1855
1856 echo ""
1857 echo "The Wireshark package has been configured with the following options."
1858 echo "                    Build wireshark : $enable_wireshark"
1859 echo "                       Build tshark : $enable_tshark"
1860 echo "                     Build capinfos : $enable_capinfos"
1861 echo "                      Build editcap : $enable_editcap"
1862 echo "                      Build dumpcap : $enable_dumpcap"
1863 echo "                     Build mergecap : $enable_mergecap"
1864 echo "                    Build text2pcap : $enable_text2pcap"
1865 echo "                      Build idl2wrs : $enable_idl2wrs"
1866 echo "                      Build randpkt : $enable_randpkt"
1867 echo "                       Build dftest : $enable_dftest"
1868 echo "                     Build rawshark : $enable_rawshark"
1869 echo ""
1870 echo "             Install dumpcap setuid : $setuid_message"
1871 echo "                        Use plugins : $have_plugins"
1872 echo "                    Use lua library : $lua_message"
1873 echo "                 Use python binding : $python_message"
1874 echo "                   Build rtp_player : $portaudio_message"
1875 echo "                        Use threads : $enable_threads"
1876 echo "             Build profile binaries : $enable_profile_build"
1877 echo "                   Use pcap library : $want_pcap"
1878 echo "                   Use zlib library : $zlib_message"
1879 echo "                   Use pcre library : $pcre_message"
1880 echo "               Use kerberos library : $krb5_message"
1881 echo "                 Use c-ares library : $c_ares_message"
1882 echo "               Use GNU ADNS library : $adns_message"
1883 echo "                Use SMI MIB library : $libsmi_message"
1884 echo "             Use GNU crypto library : $gcrypt_message"
1885 echo "             Use SSL crypto library : $ssl_message"
1886 echo "           Use IPv6 name resolution : $enable_ipv6"
1887 echo "                 Use gnutls library : $tls_message"
1888 echo "     Use POSIX capabilities library : $libcap_message"
1889 echo "                  Use GeoIP library : $geoip_message"