acinclude.m4

   1 dnl Macros that test for specific features.
   2 dnl This file is part of the Autoconf packaging for Wireshark.
   3 dnl Copyright (C) 1998-2000 by Gerald Combs.
   4 dnl
   5 dnl $Id$
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2, or (at your option)
  10 dnl any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  20 dnl 02111-1307, USA.
  21 dnl
  22 dnl As a special exception, the Free Software Foundation gives unlimited
  23 dnl permission to copy, distribute and modify the configure scripts that
  24 dnl are the output of Autoconf.  You need not follow the terms of the GNU
  25 dnl General Public License when using or distributing such scripts, even
  26 dnl though portions of the text of Autoconf appear in them.  The GNU
  27 dnl General Public License (GPL) does govern all other use of the material
  28 dnl that constitutes the Autoconf program.
  29 dnl
  30 dnl Certain portions of the Autoconf source text are designed to be copied
  31 dnl (in certain cases, depending on the input) into the output of
  32 dnl Autoconf.  We call these the "data" portions.  The rest of the Autoconf
  33 dnl source text consists of comments plus executable code that decides which
  34 dnl of the data portions to output in any given case.  We call these
  35 dnl comments and executable code the "non-data" portions.  Autoconf never
  36 dnl copies any of the non-data portions into its output.
  37 dnl
  38 dnl This special exception to the GPL applies to versions of Autoconf
  39 dnl released by the Free Software Foundation.  When you make and
  40 dnl distribute a modified version of Autoconf, you may extend this special
  41 dnl exception to the GPL to apply to your modified version as well, *unless*
  42 dnl your modified version has the potential to copy into its output some
  43 dnl of the text that was the non-data portion of the version that you started
  44 dnl with.  (In other words, unless your change moves or copies text from
  45 dnl the non-data portions to the data portions.)  If your modification has
  46 dnl such potential, you must delete any notice of this special exception
  47 dnl to the GPL from your modified version.
  48 dnl
  49 dnl Written by David MacKenzie, with help from
  50 dnl Franc,ois Pinard, Karl Berry, Richard Pixley, Ian Lance Taylor,
  51 dnl Roland McGrath, Noah Friedman, david d zuhn, and many others.
  52
  53 #
  54 # AC_WIRESHARK_ADD_DASH_L
  55 #
  56 # Add to the variable specified as the first argument a "-L" flag for the
  57 # directory specified as the second argument, and, on Solaris, add a
  58 # "-R" flag for it as well.
  59 #
  60 # XXX - IRIX, and other OSes, may require some flag equivalent to
  61 # "-R" here.
  62 #
  63 AC_DEFUN([AC_WIRESHARK_ADD_DASH_L],
  64 [$1="$$1 -L$2"
  65 case "$host_os" in
  66   solaris*)
  67     $1="$$1 -R$2"
  68   ;;
  69 esac
  70 ])
  71
  72 #
  73 # AC_WIRESHARK_TIMEZONE_ABBREV
  74 #
  75
  76 AC_DEFUN([AC_WIRESHARK_TIMEZONE_ABBREV],
  77 [
  78   AC_CACHE_CHECK([for tm_zone in struct tm],
  79     ac_cv_wireshark_have_tm_zone,
  80     [
  81       AC_TRY_COMPILE(
  82         [#include <time.h>],
  83         [struct tm t; t.tm_zone;],
  84         ac_cv_wireshark_have_tm_zone=yes,
  85         ac_cv_wireshark_have_tm_zone=no)
  86     ])
  87   if test $ac_cv_wireshark_have_tm_zone = yes; then
  88     AC_DEFINE(HAVE_TM_ZONE, 1, [Define if tm_zone field exists in struct tm])
  89   else
  90     AC_CACHE_CHECK([for tzname],
  91       ac_cv_wireshark_have_tzname,
  92       [
  93         AC_TRY_LINK(
  94 [#include <time.h>
  95 #include <stdio.h>],
  96           [printf("%s", tzname[0]);],
  97           ac_cv_wireshark_have_tzname=yes,
  98           ac_cv_wireshark_have_tzname=no)
  99       ])
 100     if test $ac_cv_wireshark_have_tzname = yes; then
 101       AC_DEFINE(HAVE_TZNAME, 1, [Define if tzname array exists])
 102     fi
 103   fi
 104 ])
 105
 106
 107 #
 108 # AC_WIRESHARK_STRUCT_SA_LEN
 109 #
 110 dnl AC_STRUCT_ST_BLKSIZE extracted from the file in question,
 111 dnl "acspecific.m4" in GNU Autoconf 2.12, and turned into
 112 dnl AC_WIRESHARK_STRUCT_SA_LEN, which checks if "struct sockaddr"
 113 dnl has the 4.4BSD "sa_len" member, and defines HAVE_SA_LEN; that's
 114 dnl what's in this file.
 115 dnl Done by Guy Harris <guy@alum.mit.edu> on 1998-11-14.
 116
 117 dnl ### Checks for structure members
 118
 119 AC_DEFUN([AC_WIRESHARK_STRUCT_SA_LEN],
 120 [AC_CACHE_CHECK([for sa_len in struct sockaddr], ac_cv_wireshark_struct_sa_len,
 121 [AC_TRY_COMPILE([#include <sys/types.h>
 122 #include <sys/socket.h>], [struct sockaddr s; s.sa_len;],
 123 ac_cv_wireshark_struct_sa_len=yes, ac_cv_wireshark_struct_sa_len=no)])
 124 if test $ac_cv_wireshark_struct_sa_len = yes; then
 125   AC_DEFINE(HAVE_SA_LEN, 1, [Define if sa_len field exists in struct sockaddr])
 126 fi
 127 ])
 128
 129
 130 #
 131 # AC_WIRESHARK_IPV6_STACK
 132 #
 133 # By Jun-ichiro "itojun" Hagino, <itojun@iijlab.net>
 134 #
 135 AC_DEFUN([AC_WIRESHARK_IPV6_STACK],
 136 [
 137         v6type=unknown
 138         v6lib=none
 139
 140         AC_MSG_CHECKING([ipv6 stack type])
 141         for i in v6d toshiba kame inria zeta linux linux-glibc solaris8; do
 142                 case $i in
 143                 v6d)
 144                         AC_EGREP_CPP(yes, [
 145 #include </usr/local/v6/include/sys/types.h>
 146 #ifdef __V6D__
 147 yes
 148 #endif],
 149                                 [v6type=$i; v6lib=v6;
 150                                 v6libdir=/usr/local/v6/lib;
 151                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 152                         ;;
 153                 toshiba)
 154                         AC_EGREP_CPP(yes, [
 155 #include <sys/param.h>
 156 #ifdef _TOSHIBA_INET6
 157 yes
 158 #endif],
 159                                 [v6type=$i; v6lib=inet6;
 160                                 v6libdir=/usr/local/v6/lib;
 161                                 CFLAGS="-DINET6 $CFLAGS"])
 162                         ;;
 163                 kame)
 164                         AC_EGREP_CPP(yes, [
 165 #include <netinet/in.h>
 166 #ifdef __KAME__
 167 yes
 168 #endif],
 169                                 [v6type=$i; v6lib=inet6;
 170                                 v6libdir=/usr/local/v6/lib;
 171                                 CFLAGS="-DINET6 $CFLAGS"])
 172                         ;;
 173                 inria)
 174                         AC_EGREP_CPP(yes, [
 175 #include <netinet/in.h>
 176 #ifdef IPV6_INRIA_VERSION
 177 yes
 178 #endif],
 179                                 [v6type=$i; CFLAGS="-DINET6 $CFLAGS"])
 180                         ;;
 181                 zeta)
 182                         AC_EGREP_CPP(yes, [
 183 #include <sys/param.h>
 184 #ifdef _ZETA_MINAMI_INET6
 185 yes
 186 #endif],
 187                                 [v6type=$i; v6lib=inet6;
 188                                 v6libdir=/usr/local/v6/lib;
 189                                 CFLAGS="-DINET6 $CFLAGS"])
 190                         ;;
 191                 linux)
 192                         if test -d /usr/inet6; then
 193                                 v6type=$i
 194                                 v6lib=inet6
 195                                 v6libdir=/usr/inet6
 196                                 CFLAGS="-DINET6 $CFLAGS"
 197                         fi
 198                         ;;
 199                 linux-glibc)
 200                         AC_EGREP_CPP(yes, [
 201 #include <features.h>
 202 #if defined(__GLIBC__) && defined(__GLIBC_MINOR__)
 203 #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || __GLIBC__ > 2
 204 yes
 205 #endif
 206 #endif],
 207                         [v6type=$i; v6lib=inet6; CFLAGS="-DINET6 $CFLAGS"])
 208                         ;;
 209                 solaris8)
 210                         if test "`uname -s`" = "SunOS" && test "`uname -r`" = "5.8"; then
 211                                 v6type=$i
 212                                 v6lib=inet6
 213                                 [CFLAGS="-DINET6 -DSOLARIS8_INET6 $CFLAGS"]
 214                         fi
 215                         ;;
 216                 esac
 217                 if test "$v6type" != "unknown"; then
 218                         break
 219                 fi
 220         done
 221
 222         if test "$v6lib" != "none"; then
 223                 for dir in $v6libdir /usr/local/v6/lib /usr/local/lib; do
 224                         if test -d $dir -a -f $dir/lib$v6lib.a; then
 225                                 LIBS="-L$dir $LIBS -l$v6lib"
 226                                 break
 227                         fi
 228                 done
 229                 enable_ipv6="yes"
 230         else
 231                 enable_ipv6="no"
 232         fi
 233         AC_MSG_RESULT(["$v6type, $v6lib"])
 234 ])
 235
 236 #
 237 # AC_WIRESHARK_GETHOSTBY_LIB_CHECK
 238 #
 239 # Checks whether we need "-lnsl" to get "gethostby*()", which we use
 240 # in "resolv.c".
 241 #
 242 # Adapted from stuff in the AC_PATH_XTRA macro in "acspecific.m4" in
 243 # GNU Autoconf 2.13; the comment came from there.
 244 # Done by Guy Harris <guy@alum.mit.edu> on 2000-01-14.
 245 #
 246 AC_DEFUN([AC_WIRESHARK_GETHOSTBY_LIB_CHECK],
 247 [
 248     # msh@cis.ufl.edu says -lnsl (and -lsocket) are needed for his 386/AT,
 249     # to get the SysV transport functions.
 250     # chad@anasazi.com says the Pyramid MIS-ES running DC/OSx (SVR4)
 251     # needs -lnsl.
 252     # The nsl library prevents programs from opening the X display
 253     # on Irix 5.2, according to dickey@clark.net.
 254     AC_CHECK_FUNC(gethostbyname, ,
 255         AC_CHECK_LIB(nsl, gethostbyname, NSL_LIBS="-lnsl"))
 256     AC_SUBST(NSL_LIBS)
 257 ])
 258
 259 #
 260 # AC_WIRESHARK_SOCKET_LIB_CHECK
 261 #
 262 # Checks whether we need "-lsocket" to get "socket()", which is used
 263 # by libpcap on some platforms - and, in effect, "gethostby*()" on
 264 # most if not all platforms (so that it can use NIS or DNS or...
 265 # to look up host names).
 266 #
 267 # Adapted from stuff in the AC_PATH_XTRA macro in "acspecific.m4" in
 268 # GNU Autoconf 2.13; the comment came from there.
 269 # Done by Guy Harris <guy@alum.mit.edu> on 2000-01-14.
 270 #
 271 # We use "connect" because that's what AC_PATH_XTRA did.
 272 #
 273 AC_DEFUN([AC_WIRESHARK_SOCKET_LIB_CHECK],
 274 [
 275     # lieder@skyler.mavd.honeywell.com says without -lsocket,
 276     # socket/setsockopt and other routines are undefined under SCO ODT
 277     # 2.0.  But -lsocket is broken on IRIX 5.2 (and is not necessary
 278     # on later versions), says simon@lia.di.epfl.ch: it contains
 279     # gethostby* variants that don't use the nameserver (or something).
 280     # -lsocket must be given before -lnsl if both are needed.
 281     # We assume that if connect needs -lnsl, so does gethostbyname.
 282     AC_CHECK_FUNC(connect, ,
 283       AC_CHECK_LIB(socket, connect, SOCKET_LIBS="-lsocket",
 284                 AC_MSG_ERROR(Function 'socket' not found.), $NSL_LIBS))
 285     AC_SUBST(SOCKET_LIBS)
 286 ])
 287
 288 #
 289 # AC_WIRESHARK_BREAKLOOP_TRY_LINK
 290 #
 291 AC_DEFUN([AC_WIRESHARK_PCAP_BREAKLOOP_TRY_LINK],
 292 [
 293   AC_LINK_IFELSE(
 294   [
 295       AC_LANG_SOURCE(
 296       [[
 297 #       include <pcap.h>
 298         int main(void)
 299         {
 300           pcap_t  *pct = NULL;
 301           pcap_breakloop(pct);
 302           return 0;
 303         }
 304       ]])
 305   ],
 306   [
 307     ws_breakloop_compiled=yes
 308   ],
 309   [
 310     ws_breakloop_compiled=no
 311   ])
 312 ])
 313
 314
 315
 316 #
 317 # AC_WIRESHARK_PCAP_CHECK
 318 #
 319 AC_DEFUN([AC_WIRESHARK_PCAP_CHECK],
 320 [
 321         if test -z "$pcap_dir"
 322         then
 323           # Pcap header checks
 324           # XXX need to set a var AC_CHECK_HEADER(pcap.h,,)
 325
 326           #
 327           # The user didn't specify a directory in which libpcap resides.
 328           # First, look for a pcap-config script.
 329           #
 330           AC_PATH_PROG(PCAP_CONFIG, pcap-config)
 331
 332           if test -n "$PCAP_CONFIG" ; then
 333             #
 334             # Found it.
 335             #
 336             # Now check whether it's the libpcap 1.0 version, which
 337             # put a space after "-L" - on some platforms, that doesn't
 338             # work.
 339             #
 340             AC_MSG_CHECKING(for broken pcap-config)
 341             case "`\"$PCAP_CONFIG\" --libs`" in
 342
 343             "-L "*)
 344               #
 345               # Space after -L.  Pretend pcap-config doesn't exist.
 346               #
 347               AC_MSG_RESULT(yes)
 348               PCAP_CONFIG=""
 349               ;;
 350
 351             *)
 352               #
 353               # No space after -L.
 354               #
 355               AC_MSG_RESULT(no)
 356               ;;
 357             esac
 358           fi
 359           if test -n "$PCAP_CONFIG" ; then
 360             #
 361             # Found it, and it's usable; use it to get the include flags
 362             # for libpcap.
 363             #
 364             CFLAGS="$CFLAGS `\"$PCAP_CONFIG\" --cflags`"
 365             CPPFLAGS="$CPPFLAGS `\"$PCAP_CONFIG\" --cflags`"
 366           else
 367             #
 368             # Didn't find it; we have to look for libpcap ourselves.
 369             # We assume that the current library search path will work,
 370             # but we may have to look for the header in a "pcap"
 371             # subdirectory of "/usr/include" or "/usr/local/include",
 372             # as some systems apparently put "pcap.h" in a "pcap"
 373             # subdirectory, and we also check "$prefix/include" - and
 374             # "$prefix/include/pcap", in case $prefix is set to
 375             # "/usr/include" or "/usr/local/include".
 376             #
 377             # XXX - should we just add "$prefix/include" to the include
 378             # search path and "$prefix/lib" to the library search path?
 379             #
 380             AC_MSG_CHECKING(for extraneous pcap header directories)
 381             found_pcap_dir=""
 382             pcap_dir_list="/usr/include/pcap $prefix/include/pcap $prefix/include"
 383             if test "x$ac_cv_enable_usr_local" = "xyes" ; then
 384               pcap_dir_list="$pcap_dir_list /usr/local/include/pcap"
 385             fi
 386             for pcap_dir in $pcap_dir_list
 387             do
 388               if test -d $pcap_dir ; then
 389                 if test x$pcap_dir != x/usr/include -a x$pcap_dir != x/usr/local/include ; then
 390                     CFLAGS="$CFLAGS -I$pcap_dir"
 391                     CPPFLAGS="$CPPFLAGS -I$pcap_dir"
 392                 fi
 393                 found_pcap_dir=" $found_pcap_dir -I$pcap_dir"
 394                 break
 395               fi
 396             done
 397
 398             if test "$found_pcap_dir" != "" ; then
 399               AC_MSG_RESULT(found --$found_pcap_dir added to CFLAGS)
 400             else
 401               AC_MSG_RESULT(not found)
 402             fi
 403           fi
 404         else
 405           #
 406           # The user specified a directory in which libpcap resides,
 407           # so add the "include" subdirectory of that directory to
 408           # the include file search path and the "lib" subdirectory
 409           # of that directory to the library search path.
 410           #
 411           # XXX - if there's also a libpcap in a directory that's
 412           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 413           # make us find the version in the specified directory,
 414           # as the compiler and/or linker will search that other
 415           # directory before it searches the specified directory.
 416           #
 417           CFLAGS="$CFLAGS -I$pcap_dir/include"
 418           CPPFLAGS="$CPPFLAGS -I$pcap_dir/include"
 419           AC_WIRESHARK_ADD_DASH_L(LDFLAGS, $pcap_dir/lib)
 420         fi
 421
 422         # Pcap header check
 423         AC_CHECK_HEADER(pcap.h,,
 424             AC_MSG_ERROR([[Header file pcap.h not found; if you installed libpcap
 425 from source, did you also do \"make install-incl\", and if you installed a
 426 binary package of libpcap, is there also a developer's package of libpcap,
 427 and did you also install that package?]]))
 428
 429         if test -n "$PCAP_CONFIG" ; then
 430           #
 431           # We have pcap-config; we assume that means we have libpcap
 432           # installed and that pcap-config will tell us whatever
 433           # libraries libpcap needs.
 434           #
 435           if test x$enable_static = xyes; then
 436             PCAP_LIBS="`\"$PCAP_CONFIG\" --libs --static`"
 437           else
 438             PCAP_LIBS="`\"$PCAP_CONFIG\" --libs`"
 439           fi
 440           AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
 441         else
 442           #
 443           # Check to see if we find "pcap_open_live" in "-lpcap".
 444           # Also check for various additional libraries that libpcap might
 445           # require.
 446           #
 447           AC_CHECK_LIB(pcap, pcap_open_live,
 448             [
 449               PCAP_LIBS=-lpcap
 450               AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
 451             ], [
 452               ac_wireshark_extras_found=no
 453               ac_save_LIBS="$LIBS"
 454               for extras in "-lcfg -lodm" "-lpfring"
 455               do
 456                 AC_MSG_CHECKING([for pcap_open_live in -lpcap with $extras])
 457                 LIBS="-lpcap $extras"
 458                 #
 459                 # XXX - can't we use AC_CHECK_LIB here?
 460                 #
 461                 AC_TRY_LINK(
 462                     [
 463 #       include <pcap.h>
 464                     ],
 465                     [
 466         pcap_open_live(NULL, 0, 0, 0, NULL);
 467                     ],
 468                     [
 469                         ac_wireshark_extras_found=yes
 470                         AC_MSG_RESULT([yes])
 471                         PCAP_LIBS="-lpcap $extras"
 472                         AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
 473                     ],
 474                     [
 475                         AC_MSG_RESULT([no])
 476                     ])
 477                 if test x$ac_wireshark_extras_found = xyes
 478                 then
 479                     break
 480                 fi
 481               done
 482               if test x$ac_wireshark_extras_found = xno
 483               then
 484                 AC_MSG_ERROR([Can't link with library libpcap.])
 485               fi
 486               LIBS=$ac_save_LIBS
 487             ], $SOCKET_LIBS $NSL_LIBS)
 488         fi
 489         AC_SUBST(PCAP_LIBS)
 490
 491         #
 492         # Check whether various variables and functions are defined by
 493         # libpcap.
 494         #
 495         ac_save_LIBS="$LIBS"
 496         AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 497         LIBS="$PCAP_LIBS $SOCKET_LIBS $NSL_LIBS $LIBS"
 498         AC_TRY_LINK(
 499            [
 500 #       include <stdio.h>
 501         extern char *pcap_version;
 502            ],
 503            [
 504         printf ("%s\n", pcap_version);
 505            ],
 506            ac_cv_pcap_version_defined=yes,
 507            ac_cv_pcap_version_defined=no,
 508            [echo $ac_n "cross compiling; assumed OK... $ac_c"])
 509         if test "$ac_cv_pcap_version_defined" = yes ; then
 510                 AC_MSG_RESULT(yes)
 511                 AC_DEFINE(HAVE_PCAP_VERSION, 1, [Define if libpcap version is known])
 512         else
 513                 AC_MSG_RESULT(no)
 514         fi
 515         AC_CHECK_FUNCS(pcap_open_dead pcap_freecode)
 516         #
 517         # pcap_breakloop may be present in the library but not declared
 518         # in the pcap.h header file.  If it's not declared in the header
 519         # file, attempts to use it will get warnings, and, if we're
 520         # building with warnings treated as errors, that warning will
 521         # cause compilation to fail.
 522         #
 523         # We are therefore first testing whether the function is present
 524         # and then, if we're compiling with warnings as errors, testing
 525         # whether it is usable.  It is usable if it compiles without
 526         # a -Wimplicit warning (the "compile with warnings as errors"
 527         # option requires GCC). If it is not usable, we fail and tell
 528         # the user that the pcap.h header needs to be updated.
 529         #
 530         # Ceteris paribus, this should only happen with Mac OS X 10.3[.x] which
 531         # can have an up-to-date pcap library without the corresponding pcap
 532         # header.
 533         #
 534         # However, it might also happen on some others OSes with some erroneous
 535         # system manipulations where multiple versions of libcap might co-exist
 536         # e.g. hand made symbolic link from libpcap.so -> libpcap.so.0.8 but
 537         # having the pcap header version 0.7.
 538         #
 539         AC_MSG_CHECKING([whether pcap_breakloop is present])
 540         ac_CFLAGS_saved="$CFLAGS"
 541         AC_WIRESHARK_PCAP_BREAKLOOP_TRY_LINK
 542         if test "x$ws_breakloop_compiled" = "xyes"; then
 543           AC_MSG_RESULT(yes)
 544           AC_DEFINE(HAVE_PCAP_BREAKLOOP, 1, [Define if pcap_breakloop is known])
 545           if test "x$with_warnings_as_errors" = "xyes"; then
 546             AC_MSG_CHECKING([whether pcap_breakloop is usable])
 547             CFLAGS="$CFLAGS -Werror -Wimplicit"
 548             AC_WIRESHARK_PCAP_BREAKLOOP_TRY_LINK
 549             if test "x$ws_breakloop_compiled" = "xyes"; then
 550               AC_MSG_RESULT(yes)
 551             else
 552               AC_MSG_RESULT(no)
 553               AC_MSG_ERROR(
 554 [Your pcap library is more recent than your pcap header.
 555 As you are building with compiler warnings treated as errors, Wireshark
 556 won't be able to use functions not declared in that header.
 557 If you wish to build with compiler warnings treated as errors, You should
 558 install a newer version of the header file.])
 559             fi
 560             CFLAGS="$ac_CFLAGS_saved"
 561           fi
 562         else
 563           AC_MSG_RESULT(no)
 564         fi
 565
 566         #
 567         # Later versions of Mac OS X 10.3[.x] ship a pcap.h that
 568         # doesn't define pcap_if_t but ship an 0.8[.x] libpcap,
 569         # so the library has "pcap_findalldevs()", but pcap.h
 570         # doesn't define "pcap_if_t" so you can't actually *use*
 571         # "pcap_findalldevs()".
 572         #
 573         # That even appears to be true of systems shipped with
 574         # 10.3.4, so it doesn't appear only to be a case of
 575         # Software Update not updating header files.
 576         #
 577         # (You can work around this by installing the 0.8 header
 578         # files.)
 579         #
 580         AC_CACHE_CHECK([whether pcap_findalldevs is present and usable],
 581           [ac_cv_func_pcap_findalldevs],
 582           [
 583             AC_LINK_IFELSE(
 584               [
 585                 AC_LANG_SOURCE(
 586                   [[
 587                     #include <pcap.h>
 588                     main()
 589                     {
 590                       pcap_if_t *devpointer;
 591                       char errbuf[1];
 592
 593                       pcap_findalldevs(&devpointer, errbuf);
 594                     }
 595                   ]])
 596               ],
 597               [
 598                 ac_cv_func_pcap_findalldevs=yes
 599               ],
 600               [
 601                 ac_cv_func_pcap_findalldevs=no
 602               ])
 603           ])
 604         #
 605         # Don't check for other new routines that showed up after
 606         # "pcap_findalldevs()" if we don't have a usable
 607         # "pcap_findalldevs()", so we don't end up using them if the
 608         # "pcap.h" is crufty and old and doesn't declare them.
 609         #
 610         if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 611           AC_DEFINE(HAVE_PCAP_FINDALLDEVS, 1,
 612            [Define to 1 if you have the `pcap_findalldevs' function and a pcap.h that declares pcap_if_t.])
 613           AC_CHECK_FUNCS(pcap_datalink_val_to_name pcap_datalink_name_to_val)
 614           AC_CHECK_FUNCS(pcap_datalink_val_to_description)
 615           AC_CHECK_FUNCS(pcap_list_datalinks pcap_set_datalink pcap_lib_version)
 616           AC_CHECK_FUNCS(pcap_get_selectable_fd pcap_free_datalinks)
 617         fi
 618         LIBS="$ac_save_LIBS"
 619 ])
 620
 621 AC_DEFUN([AC_WIRESHARK_PCAP_REMOTE_CHECK],
 622 [
 623     ac_save_LIBS="$LIBS"
 624     LIBS="$PCAP_LIBS $SOCKET_LIBS $NSL_LIBS $LIBS"
 625     AC_DEFINE(HAVE_REMOTE, 1, [Define to 1 to enable remote
 626               capturing feature in WinPcap library])
 627     AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex pcap_createsrcstr)
 628     if test $ac_cv_func_pcap_open = "yes" -a \
 629             $ac_cv_func_pcap_findalldevs_ex = "yes" -a \
 630             $ac_cv_func_pcap_createsrcstr = "yes" ; then
 631         AC_DEFINE(HAVE_PCAP_REMOTE, 1,
 632             [Define to 1 if you have WinPcap remote capturing support and prefer to use these new API features.])
 633     fi
 634     AC_CHECK_FUNCS(pcap_setsampling)
 635     LIBS="$ac_save_LIBS"
 636 ])
 637
 638 #
 639 # AC_WIRESHARK_ZLIB_CHECK
 640 #
 641 AC_DEFUN([AC_WIRESHARK_ZLIB_CHECK],
 642 [
 643         if test "x$zlib_dir" != "x"
 644         then
 645           #
 646           # The user specified a directory in which zlib resides,
 647           # so add the "include" subdirectory of that directory to
 648           # the include file search path and the "lib" subdirectory
 649           # of that directory to the library search path.
 650           #
 651           # XXX - if there's also a zlib in a directory that's
 652           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 653           # make us find the version in the specified directory,
 654           # as the compiler and/or linker will search that other
 655           # directory before it searches the specified directory.
 656           #
 657           wireshark_save_CFLAGS="$CFLAGS"
 658           CFLAGS="$CFLAGS -I$zlib_dir/include"
 659           wireshark_save_CPPFLAGS="$CPPFLAGS"
 660           CPPFLAGS="$CPPFLAGS -I$zlib_dir/include"
 661           wireshark_save_LIBS="$LIBS"
 662           AC_WIRESHARK_ADD_DASH_L(LIBS, $zlib_dir/lib)
 663         fi
 664
 665         #
 666         # Make sure we have "zlib.h".  If we don't, it means we probably
 667         # don't have zlib, so don't use it.
 668         #
 669         AC_CHECK_HEADER(zlib.h,,
 670           [
 671             if test "x$zlib_dir" != "x"
 672             then
 673               #
 674               # The user used "--with-zlib=" to specify a directory
 675               # containing zlib, but we didn't find the header file
 676               # there; that either means they didn't specify the
 677               # right directory or are confused about whether zlib
 678               # is, in fact, installed.  Report the error and give up.
 679               #
 680               AC_MSG_ERROR([zlib header not found in directory specified in --with-zlib])
 681             else
 682               if test "x$want_zlib" = "xyes"
 683               then
 684                 #
 685                 # The user tried to force us to use the library, but we
 686                 # couldn't find the header file; report an error.
 687                 #
 688                 AC_MSG_ERROR(Header file zlib.h not found.)
 689               else
 690                 #
 691                 # We couldn't find the header file; don't use the
 692                 # library, as it's probably not present.
 693                 #
 694                 want_zlib=no
 695               fi
 696             fi
 697           ])
 698
 699         if test "x$want_zlib" != "xno"
 700         then
 701                 #
 702                 # Well, we at least have the zlib header file.
 703                 #
 704                 # Check for "gzgets()" in zlib, because we need it, but
 705                 # some older versions of zlib don't have it.  It appears
 706                 # from the zlib ChangeLog that any released version of zlib
 707                 # with "gzgets()" should have the other routines we
 708                 # depend on, such as "gzseek()", "gztell()", and "zError()".
 709                 #
 710                 # Another reason why we require "gzgets()" is that
 711                 # some versions of zlib that didn't have it, such
 712                 # as 1.0.8, had a bug in "gzseek()" that meant that it
 713                 # doesn't work correctly on uncompressed files; this
 714                 # means we cannot use version 1.0.8.  (Unfortunately,
 715                 # that's the version that comes with recent X11 source,
 716                 # and many people who install XFree86 on their Slackware
 717                 # boxes don't realize that they should configure it to
 718                 # use the native zlib rather than building and installing
 719                 # the crappy old version that comes with XFree86.)
 720                 #
 721                 # I.e., we can't just avoid using "gzgets()", as
 722                 # versions of zlib without "gzgets()" are likely to have
 723                 # a broken "gzseek()".
 724                 #
 725                 AC_CHECK_LIB(z, gzgets,
 726                 [
 727                         if test "x$zlib_dir" != "x"
 728                         then
 729                                 #
 730                                 # Put the "-I" and "-L" flags for zlib at
 731                                 # the beginning of CFLAGS, CPPFLAGS, and
 732                                 # LIBS.
 733                                 #
 734                                 LIBS=""
 735                                 AC_WIRESHARK_ADD_DASH_L(LIBS, $zlib_dir/lib)
 736                                 LIBS="$LIBS -lz $wireshark_save_LIBS"
 737                         else
 738                                 LIBS="-lz $LIBS"
 739                         fi
 740                         AC_DEFINE(HAVE_LIBZ, 1, [Define to use libz library])
 741                 ],[
 742                         if test "x$zlib_dir" != "x"
 743                         then
 744                                 #
 745                                 # Restore the versions of CFLAGS, CPPFLAGS,
 746                                 # and LIBS before we added the "-with-zlib="
 747                                 # directory, as we didn't actually find
 748                                 # zlib there, or didn't find a zlib that
 749                                 # contains gzgets there.
 750                                 #
 751                                 CFLAGS="$wireshark_save_CFLAGS"
 752                                 CPPFLAGS="$wireshark_save_CPPFLAGS"
 753                                 LIBS="$wireshark_save_LIBS"
 754                         fi
 755                         want_zlib=no
 756                 ])
 757         fi
 758
 759         if test "x$want_zlib" != "xno"
 760         then
 761                 #
 762                 # Well, we at least have the zlib header file and a zlib
 763                 # with "gzgets()".
 764                 #
 765                 # Now check for "gzgets()" in zlib when linking with the
 766                 # linker flags for GTK+ applications; people often grab
 767                 # XFree86 source and build and install it on their systems,
 768                 # and they appear sometimes to misconfigure XFree86 so that,
 769                 # even on systems with zlib, it assumes there is no zlib,
 770                 # so the XFree86 build process builds and installs its
 771                 # own zlib in the X11 library directory.
 772                 #
 773                 # The XFree86 zlib is an older version that lacks
 774                 # "gzgets()", and that's the zlib with which Wireshark
 775                 # gets linked, so the build of Wireshark fails.
 776                 #
 777                 ac_save_CFLAGS="$CFLAGS"
 778                 ac_save_LIBS="$LIBS"
 779                 CFLAGS="$CFLAGS $GTK_CFLAGS"
 780                 LIBS="$GTK_LIBS -lz $LIBS"
 781                 AC_MSG_CHECKING([for gzgets missing when linking with X11])
 782                 AC_TRY_LINK_FUNC(gzgets, AC_MSG_RESULT(no),
 783                   [
 784                     AC_MSG_RESULT(yes)
 785                     AC_MSG_ERROR(old zlib found when linking with X11 - get rid of old zlib.)
 786                   ])
 787                 CFLAGS="$ac_save_CFLAGS"
 788                 LIBS="$ac_save_LIBS"
 789         fi
 790 ])
 791
 792 #
 793 # AC_WIRESHARK_LIBPCRE_CHECK
 794 #
 795 AC_DEFUN([AC_WIRESHARK_LIBPCRE_CHECK],
 796 [
 797         if test "x$pcre_dir" != "x"
 798         then
 799           #
 800           # The user specified a directory in which libpcre resides,
 801           # so add the "include" subdirectory of that directory to
 802           # the include file search path and the "lib" subdirectory
 803           # of that directory to the library search path.
 804           #
 805           # XXX - if there's also a libpcre in a directory that's
 806           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 807           # make us find the version in the specified directory,
 808           # as the compiler and/or linker will search that other
 809           # directory before it searches the specified directory.
 810           #
 811           wireshark_save_CFLAGS="$CFLAGS"
 812           CFLAGS="$CFLAGS -I$pcre_dir/include"
 813           wireshark_save_CPPFLAGS="$CPPFLAGS"
 814           CPPFLAGS="$CPPFLAGS -I$pcre_dir/include"
 815           wireshark_save_LIBS="$LIBS"
 816           LIBS="$LIBS -lpcre"
 817           wireshark_save_LDFLAGS="$LDFLAGS"
 818           LDFLAGS="$LDFLAGS -L$pcre_dir/lib"
 819         fi
 820
 821         #
 822         # Make sure we have "pcre.h".  If we don't, it means we probably
 823         # don't have libpcre, so don't use it.
 824         #
 825         AC_CHECK_HEADER(pcre.h,,
 826           [
 827             if test "x$pcre_dir" != "x"
 828             then
 829               #
 830               # The user used "--with-pcre=" to specify a directory
 831               # containing libpcre, but we didn't find the header file
 832               # there; that either means they didn't specify the
 833               # right directory or are confused about whether libpcre
 834               # is, in fact, installed.  Report the error and give up.
 835               #
 836               AC_MSG_ERROR([libpcre header not found in directory specified in --with-pcre])
 837             else
 838               if test "x$want_pcre" = "xyes"
 839               then
 840                 #
 841                 # The user tried to force us to use the library, but we
 842                 # couldn't find the header file; report an error.
 843                 #
 844                 AC_MSG_ERROR(Header file pcre.h not found.)
 845               else
 846                 #
 847                 # We couldn't find the header file; don't use the
 848                 # library, as it's probably not present.
 849                 #
 850                 want_pcre=no
 851               fi
 852             fi
 853           ])
 854
 855         if test "x$want_pcre" != "xno"
 856         then
 857                 #
 858                 # Well, we at least have the pcre header file.
 859                 #
 860                 # We're only using standard functions from libpcre,
 861                 # so we don't need to perform extra checks.
 862                 #
 863                 AC_CHECK_LIB(pcre, pcre_compile,
 864                 [
 865                         if test "x$pcre_dir" != "x"
 866                         then
 867                                 #
 868                                 # Put the "-I" and "-L" flags for pcre at
 869                                 # the beginning of CFLAGS, CPPFLAGS,
 870                                 # LDFLAGS, and LIBS.
 871                                 #
 872                                 PCRE_LIBS="-L$pcre_dir/lib -lpcre $wireshark_save_LIBS"
 873                         else
 874                                 PCRE_LIBS="-lpcre"
 875                         fi
 876                         AC_DEFINE(HAVE_LIBPCRE, 1, [Define to use libpcre library])
 877                 ],[
 878                         if test "x$pcre_dir" != "x"
 879                         then
 880                                 #
 881                                 # Restore the versions of CFLAGS, CPPFLAGS,
 882                                 # LDFLAGS, and LIBS before we added the
 883                                 # "--with-pcre=" directory, as we didn't
 884                                 # actually find pcre there.
 885                                 #
 886                                 CFLAGS="$wireshark_save_CFLAGS"
 887                                 CPPFLAGS="$wireshark_save_CPPFLAGS"
 888                                 LDFLAGS="$wireshark_save_LDFLAGS"
 889                                 LIBS="$wireshark_save_LIBS"
 890                                 PCRE_LIBS=""
 891                         fi
 892                         want_pcre=no
 893                 ])
 894                 AC_SUBST(PCRE_LIBS)
 895         fi
 896 ])
 897
 898 #
 899 # AC_WIRESHARK_LIBLUA_CHECK
 900 #
 901 AC_DEFUN([AC_WIRESHARK_LIBLUA_CHECK],[
 902
 903         if test "x$lua_dir" != "x"
 904         then
 905                 #
 906                 # The user specified a directory in which liblua resides,
 907                 # so add the "include" subdirectory of that directory to
 908                 # the include file search path and the "lib" subdirectory
 909                 # of that directory to the library search path.
 910                 #
 911                 # XXX - if there's also a liblua in a directory that's
 912                 # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 913                 # make us find the version in the specified directory,
 914                 # as the compiler and/or linker will search that other
 915                 # directory before it searches the specified directory.
 916                 #
 917                 wireshark_save_CFLAGS="$CFLAGS"
 918                 CFLAGS="$CFLAGS -I$lua_dir/include"
 919                 wireshark_save_CPPFLAGS="$CPPFLAGS"
 920                 CPPFLAGS="$CPPFLAGS -I$lua_dir/include"
 921                 wireshark_save_LIBS="$LIBS"
 922                 LIBS="$LIBS -L$lua_dir/lib -llua -lm"
 923                 wireshark_save_LDFLAGS="$LDFLAGS"
 924                 LDFLAGS="$LDFLAGS -L$lua_dir/lib"
 925         else
 926                 #
 927                 # The user specified no directory in which liblua resides,
 928                 # so just add "-llua -lliblua" to the used libs.
 929                 #
 930                 wireshark_save_CFLAGS="$CFLAGS"
 931                 wireshark_save_CPPFLAGS="$CPPFLAGS"
 932                 wireshark_save_LDFLAGS="$LDFLAGS"
 933                 wireshark_save_LIBS="$LIBS"
 934                 LIBS="$LIBS -llua -lm"
 935         fi
 936
 937         #
 938         # Make sure we have "lua.h", "lualib.h" and "lauxlib.h".  If we don't, it means we probably
 939         # don't have liblua, so don't use it.
 940         #
 941         AC_CHECK_HEADERS(lua.h lualib.h lauxlib.h,,
 942         [
 943                 AC_CHECK_HEADERS(lua5.1/lua.h lua5.1/lualib.h lua5.1/lauxlib.h,
 944                 [
 945                         if test "x$lua_dir" != "x"
 946                         then
 947                                 LUA_INCLUDES="-I$lua_dir/include/lua5.1"
 948                         else
 949                                 #
 950                                 # The user didn't specify a directory in which liblua resides;
 951                                 # we must look for the headers in a "lua5.1" subdirectory of
 952                                 # "/usr/include", "/usr/local/include", or "$prefix/include"
 953                                 # as some systems apparently put the headers in a "lua5.1"
 954                                 # subdirectory.
 955                                 AC_MSG_CHECKING(for extraneous lua header directories)
 956                                 found_lua_dir=""
 957                                 lua_dir_list="/usr/include/lua5.1 $prefix/include/lua5.1"
 958                                 if test "x$ac_cv_enable_usr_local" = "xyes"
 959                                 then
 960                                         lua_dir_list="$lua_dir_list /usr/local/include/lua5.1"
 961                                 fi
 962                                 for lua_dir_ent in $lua_dir_list
 963                                 do
 964                                         if test -d $lua_dir_ent
 965                                         then
 966                                                 LUA_INCLUDES="-I$lua_dir_ent"
 967                                                 found_lua_dir="$lua_dir_ent"
 968                                                 break
 969                                         fi
 970                                 done
 971
 972                                 if test "x$found_lua_dir" != "x"
 973                                 then
 974                                         AC_MSG_RESULT(found -- $found_lua_dir)
 975                                 else
 976                                         AC_MSG_RESULT(not found)
 977                                         #
 978                                         # Restore the versions of CFLAGS, CPPFLAGS,
 979                                         # LDFLAGS, and LIBS before we added the
 980                                         # "--with-lua=" directory, as we didn't
 981                                         # actually find lua there.
 982                                         #
 983                                         CFLAGS="$wireshark_save_CFLAGS"
 984                                         CPPFLAGS="$wireshark_save_CPPFLAGS"
 985                                         LDFLAGS="$wireshark_save_LDFLAGS"
 986                                         LIBS="$wireshark_save_LIBS"
 987                                         LUA_LIBS=""
 988                                         if test "x$want_lua" = "xyes"
 989                                         then
 990                                                 # we found lua5.1/lua.h, but we don't know which include dir contains it
 991                                                 AC_MSG_ERROR(Header file lua.h was found as lua5.1/lua.h but we can't locate the include directory. Please set the DIR for the --with-lua configure parameter.)
 992                                         else
 993                                                 #
 994                                                 # We couldn't find the header file; don't use the
 995                                                 # library, as it's probably not present.
 996                                                 #
 997                                                 want_lua=no
 998                                         fi
 999                                 fi
1000                         fi
1001                 ],
1002                 [
1003                         #
1004                         # Restore the versions of CFLAGS, CPPFLAGS,
1005                         # LDFLAGS, and LIBS before we added the
1006                         # "--with-lua=" directory, as we didn't
1007                         # actually find lua there.
1008                         #
1009                         CFLAGS="$wireshark_save_CFLAGS"
1010                         CPPFLAGS="$wireshark_save_CPPFLAGS"
1011                         LDFLAGS="$wireshark_save_LDFLAGS"
1012                         LIBS="$wireshark_save_LIBS"
1013                         LUA_LIBS=""
1014                         if test "x$lua_dir" != "x"
1015                         then
1016                                 #
1017                                 # The user used "--with-lua=" to specify a directory
1018                                 # containing liblua, but we didn't find the header file
1019                                 # there; that either means they didn't specify the
1020                                 # right directory or are confused about whether liblua
1021                                 # is, in fact, installed.  Report the error and give up.
1022                                 #
1023                                 AC_MSG_ERROR([liblua header not found in directory specified in --with-lua])
1024                         else
1025                                 if test "x$want_lua" = "xyes"
1026                                 then
1027                                         #
1028                                         # The user tried to force us to use the library, but we
1029                                         # couldn't find the header file; report an error.
1030                                         #
1031                                         AC_MSG_ERROR(Header file lua.h not found.)
1032                                 else
1033                                         #
1034                                         # We couldn't find the header file; don't use the
1035                                         # library, as it's probably not present.
1036                                         #
1037                                         want_lua=no
1038                                 fi
1039                         fi
1040                 ])
1041         ])
1042
1043         if test "x$want_lua" != "xno"
1044         then
1045                 #
1046                 # Well, we at least have the lua header file.
1047                 #
1048                 # let's check if the libs are there
1049                 #
1050
1051                 # At least on Suse 9.3 systems, liblualib needs linking
1052                 # against libm.
1053                 LIBS="$LIBS $LUA_LIBS -lm"
1054
1055                 AC_CHECK_LIB(lua, luaL_register,
1056                 [
1057                     #
1058                     #  Lua 5.1 found
1059                     #
1060                         if test "x$lua_dir" != "x"
1061                         then
1062                                 #
1063                                 # Put the "-I" and "-L" flags for lua at
1064                                 # the beginning of CFLAGS, CPPFLAGS,
1065                                 # LDFLAGS, and LIBS.
1066                                 #
1067                                 LUA_LIBS="-L$lua_dir/lib -llua -lm"
1068                                 LUA_INCLUDES="-I$lua_dir/include"
1069                         else
1070                                 LUA_LIBS="-llua -lm"
1071                                 LUA_INCLUDES=""
1072                         fi
1073                         AC_DEFINE(HAVE_LUA_5_1, 1, [Define to use Lua 5.1])
1074                         want_lua=yes
1075
1076                 ],[
1077                         #
1078                         # We could not find the libs, maybe we have version number in the lib name
1079                         #
1080
1081                         LIBS="$wireshark_save_LIBS -llua5.1 -lm"
1082
1083                         AC_CHECK_LIB(lua5.1, luaL_register,
1084                         [
1085                             #
1086                             #  Lua 5.1 found
1087                             #
1088                             LUA_LIBS=" -llua5.1 -lm"
1089                             AC_DEFINE(HAVE_LUA_5_1, 1, [Define to use Lua 5.1])
1090                             want_lua=yes
1091                         ],[
1092                                 #
1093                                 # Restore the versions of CFLAGS, CPPFLAGS,
1094                                 # LDFLAGS, and LIBS before we added the
1095                                 # "--with-lua=" directory, as we didn't
1096                                 # actually find lua there.
1097                                 #
1098                                 CFLAGS="$wireshark_save_CFLAGS"
1099                                 CPPFLAGS="$wireshark_save_CPPFLAGS"
1100                                 LDFLAGS="$wireshark_save_LDFLAGS"
1101                                 LIBS="$wireshark_save_LIBS"
1102                                 LUA_LIBS=""
1103                                 # User requested --with-lua but it isn't available
1104                                 if test "x$want_lua" = "xyes"
1105                                 then
1106                                         AC_MSG_ERROR(Linking with liblua failed.)
1107                                 fi
1108                                 want_lua=no
1109                         ])
1110                 ])
1111
1112         CFLAGS="$wireshark_save_CFLAGS"
1113         CPPFLAGS="$wireshark_save_CPPFLAGS"
1114         LDFLAGS="$wireshark_save_LDFLAGS"
1115         LIBS="$wireshark_save_LIBS"
1116         AC_SUBST(LUA_LIBS)
1117         AC_SUBST(LUA_INCLUDES)
1118
1119         fi
1120 ])
1121
1122 #
1123 # AC_WIRESHARK_LIBPORTAUDIO_CHECK
1124 #
1125 AC_DEFUN([AC_WIRESHARK_LIBPORTAUDIO_CHECK],[
1126
1127         if test "x$portaudio_dir" != "x"
1128         then
1129                 #
1130                 # The user specified a directory in which libportaudio
1131                 # resides, so add the "include" subdirectory of that directory to
1132                 # the include file search path and the "lib" subdirectory
1133                 # of that directory to the library search path.
1134                 #
1135                 # XXX - if there's also a libportaudio in a directory that's
1136                 # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
1137                 # make us find the version in the specified directory,
1138                 # as the compiler and/or linker will search that other
1139                 # directory before it searches the specified directory.
1140                 #
1141                 wireshark_save_CFLAGS="$CFLAGS"
1142                 CFLAGS="$CFLAGS -I$portaudio_dir/include"
1143                 wireshark_save_CPPFLAGS="$CPPFLAGS"
1144                 CPPFLAGS="$CPPFLAGS -I$portaudio_dir/include"
1145                 wireshark_save_LIBS="$LIBS"
1146                 LIBS="$LIBS -L$portaudio_dir/lib -lportaudio"
1147                 wireshark_save_LDFLAGS="$LDFLAGS"
1148                 LDFLAGS="$LDFLAGS -L$portaudio_dir/lib"
1149         else
1150                 #
1151                 # The user specified no directory in which libportaudio resides,
1152                 # so just add "-lportaudio" to the used libs.
1153                 #
1154                 wireshark_save_CFLAGS="$CFLAGS"
1155                 wireshark_save_CPPFLAGS="$CPPFLAGS"
1156                 wireshark_save_LDFLAGS="$LDFLAGS"
1157                 wireshark_save_LIBS="$LIBS"
1158                 LIBS="$LIBS -lportaudio"
1159         fi
1160
1161         #
1162         # Make sure we have "portaudio.h".  If we don't, it means we probably
1163         # don't have libportaudio, so don't use it.
1164         #
1165         AC_CHECK_HEADERS(portaudio.h,,
1166         [
1167                 if test "x$portaudio_dir" != "x"
1168                 then
1169                         #
1170                         # The user used "--with-portaudio=" to specify a directory
1171                         # containing libportaudio, but we didn't find the header file
1172                         # there; that either means they didn't specify the
1173                         # right directory or are confused about whether libportaudio
1174                         # is, in fact, installed.  Report the error and give up.
1175                         #
1176                         AC_MSG_ERROR([libportaudio header not found in directory specified in --with-portaudio])
1177                 else
1178                         CFLAGS="$wireshark_save_CFLAGS"
1179                         CPPFLAGS="$wireshark_save_CPPFLAGS"
1180                         LDFLAGS="$wireshark_save_LDFLAGS"
1181                         LIBS="$wireshark_save_LIBS"
1182                         PORTAUDIO_LIBS=""
1183                         if test "x$want_portaudio" = "xyes"
1184                         then
1185                                 #
1186                                 # The user tried to force us to use the library, but we
1187                                 # couldn't find the header file; report an error.
1188                                 #
1189                                 AC_MSG_ERROR(Header file portaudio.h not found.)
1190                         else
1191                                 #
1192                                 # We couldn't find the header file; don't use the
1193                                 # library, as it's probably not present.
1194                                 #
1195                                 want_portaudio=no
1196                         fi
1197                 fi
1198         ])
1199
1200         #
1201         # Check whether we have the right version of portaudio
1202         #
1203         if test "x$want_portaudio" != "xno"
1204         then
1205                 AC_CHECK_TYPE(PortAudioStream,
1206                 AC_DEFINE(PORTAUDIO_API_1, 1, [Define if we are using version of of the Portaudio library API]),
1207                 ,
1208                 [#include <portaudio.h>])
1209         fi
1210
1211         if test "x$want_portaudio" != "xno"
1212         then
1213                 #
1214                 # Well, we at least have the portaudio header file.
1215                 #
1216                 # let's check if the libs are there
1217                 #
1218
1219                 AC_CHECK_LIB(portaudio, Pa_Initialize,
1220                 [
1221                         if test "x$portaudio_dir" != "x"
1222                         then
1223                                 #
1224                                 # Put the "-I" and "-L" flags for portaudio at
1225                                 # the beginning of CFLAGS, CPPFLAGS,
1226                                 # LDFLAGS, and LIBS.
1227                                 #
1228                                 PORTAUDIO_LIBS="-L$portaudio_dir/lib -lportaudio"
1229                                 PORTAUDIO_INCLUDES="-I$portaudio_dir/include"
1230                         else
1231                                 PORTAUDIO_LIBS="-lportaudio"
1232                                 PORTAUDIO_INCLUDES=""
1233                         fi
1234                         AC_DEFINE(HAVE_LIBPORTAUDIO, 1, [Define to use libportaudio library])
1235                         want_portaudio=yes
1236                 ],[
1237                         #
1238                         # Restore the versions of CFLAGS, CPPFLAGS,
1239                         # LDFLAGS, and LIBS before we added the
1240                         # "--with-portaudio=" directory, as we didn't
1241                         # actually find portaudio there.
1242                         #
1243                         CFLAGS="$wireshark_save_CFLAGS"
1244                         CPPFLAGS="$wireshark_save_CPPFLAGS"
1245                         LDFLAGS="$wireshark_save_LDFLAGS"
1246                         LIBS="$wireshark_save_LIBS"
1247                         PORTAUDIO_LIBS=""
1248                         # User requested --with-portaudio but it isn't available
1249                         if test "x$want_portaudio" = "xyes"
1250                         then
1251                                 AC_MSG_ERROR(Linking with libportaudio failed.)
1252                         fi
1253                         want_portaudio=no
1254                 ])
1255
1256         CFLAGS="$wireshark_save_CFLAGS"
1257         CPPFLAGS="$wireshark_save_CPPFLAGS"
1258         LDFLAGS="$wireshark_save_LDFLAGS"
1259         LIBS="$wireshark_save_LIBS"
1260         AC_SUBST(PORTAUDIO_LIBS)
1261         AC_SUBST(PORTAUDIO_INCLUDES)
1262
1263         fi
1264 ])
1265
1266 #
1267 # AC_WIRESHARK_RPM_CHECK
1268 # Looks for the rpm program, and checks to see if we can redefine "_topdir".
1269 #
1270 AC_DEFUN([AC_WIRESHARK_RPM_CHECK],
1271 [
1272         AC_CHECK_PROG(ac_cv_wireshark_have_rpm, rpm, "yes", "no")
1273         if test "x$ac_cv_wireshark_have_rpm" = "xyes"; then
1274                 rpm --define '_topdir /tmp' > /dev/null 2>&1
1275                 AC_MSG_CHECKING(to see if we can redefine _topdir)
1276                 if test $? -eq 0 ; then
1277                         AC_MSG_RESULT(yes)
1278                         HAVE_RPM=yes
1279                 else
1280                         AC_MSG_RESULT(no.  You'll have to build packages manually.)
1281                         HAVE_RPM=no
1282                 fi
1283         fi
1284 ])
1285
1286 #
1287 # AC_WIRESHARK_GNU_SED_CHECK
1288 # Checks if GNU sed is the first sed in PATH.
1289 #
1290 AC_DEFUN([AC_WIRESHARK_GNU_SED_CHECK],
1291 [
1292         AC_MSG_CHECKING(for GNU sed as first sed in PATH)
1293         if  ( sh -c "sed --version" </dev/null 2> /dev/null | grep "GNU sed" 2>&1 > /dev/null ) ;  then
1294                 AC_MSG_RESULT(yes)
1295                 HAVE_GNU_SED=yes
1296         else
1297                 AC_MSG_RESULT(no)
1298                 HAVE_GNU_SED=no
1299         fi
1300 ])
1301
1302 #
1303 # AC_WIRESHARK_C_ARES_CHECK
1304 #
1305 AC_DEFUN([AC_WIRESHARK_C_ARES_CHECK],
1306 [
1307         want_c_ares=defaultyes
1308
1309         if test "x$want_c_ares" = "xdefaultyes"; then
1310                 want_c_ares=yes
1311                 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
1312                         withval=/usr/local
1313                         if test -d "$withval"; then
1314                                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1315                         fi
1316                 fi
1317         fi
1318
1319         if test "x$want_c_ares" = "xyes"; then
1320                 AC_CHECK_LIB(cares, ares_init,
1321                   [
1322                     C_ARES_LIBS=-lcares
1323                 AC_DEFINE(HAVE_C_ARES, 1, [Define to use c-ares library])
1324                 have_good_c_ares=yes
1325                   ],, $SOCKET_LIBS $NSL_LIBS
1326                 )
1327         else
1328                 AC_MSG_RESULT(not required)
1329         fi
1330 ])
1331
1332
1333 #
1334 # AC_WIRESHARK_ADNS_CHECK
1335 #
1336 AC_DEFUN([AC_WIRESHARK_ADNS_CHECK],
1337 [
1338         want_adns=defaultyes
1339
1340         if test "x$want_adns" = "xdefaultyes"; then
1341                 want_adns=yes
1342                 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
1343                         withval=/usr/local
1344                         if test -d "$withval"; then
1345                                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1346                         fi
1347                 fi
1348         fi
1349
1350         if test "x$want_adns" = "xyes"; then
1351                 AC_CHECK_LIB(adns, adns_init,
1352                   [
1353                     ADNS_LIBS=-ladns
1354                 AC_DEFINE(HAVE_GNU_ADNS, 1, [Define to use GNU ADNS library])
1355                 have_good_adns=yes
1356                   ],, $SOCKET_LIBS $NSL_LIBS
1357                 )
1358         else
1359                 AC_MSG_RESULT(not required)
1360         fi
1361 ])
1362
1363
1364 #
1365 # AC_WIRESHARK_LIBCAP_CHECK
1366 #
1367 AC_DEFUN([AC_WIRESHARK_LIBCAP_CHECK],
1368 [
1369         want_libcap=defaultyes
1370
1371         if test "x$want_libcap" = "xdefaultyes"; then
1372                 want_libcap=yes
1373                 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
1374                         withval=/usr/local
1375                         if test -d "$withval"; then
1376                                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1377                         fi
1378                 fi
1379         fi
1380
1381         if test "x$want_libcap" = "xyes"; then
1382                 AC_CHECK_LIB(cap, cap_set_flag,
1383                   [
1384                     LIBCAP_LIBS=-lcap
1385                 AC_DEFINE(HAVE_LIBCAP, 1, [Define to use the libcap library])
1386                 have_good_libcap=yes
1387                   ],,
1388                 )
1389         else
1390                 AC_MSG_RESULT(not required)
1391         fi
1392 ])
1393
1394
1395 #
1396 # AC_WIRESHARK_KRB5_CHECK
1397 #
1398 AC_DEFUN([AC_WIRESHARK_KRB5_CHECK],
1399 [
1400         wireshark_save_CFLAGS="$CFLAGS"
1401         wireshark_save_CPPFLAGS="$CPPFLAGS"
1402         if test "x$krb5_dir" != "x"
1403         then
1404           #
1405           # The user specified a directory in which kerberos resides,
1406           # so add the "include" subdirectory of that directory to
1407           # the include file search path and the "lib" subdirectory
1408           # of that directory to the library search path.
1409           #
1410           # XXX - if there's also a kerberos in a directory that's
1411           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
1412           # make us find the version in the specified directory,
1413           # as the compiler and/or linker will search that other
1414           # directory before it searches the specified directory.
1415           #
1416           CFLAGS="$CFLAGS -I$krb5_dir/include"
1417           CPPFLAGS="$CPPFLAGS -I$krb5_dir/include"
1418           ac_heimdal_version=`grep heimdal $krb5_dir/include/krb5.h | head -n 1 | sed 's/^.*heimdal.*$/HEIMDAL/'`
1419           ac_mit_version=`grep 'Massachusetts Institute of Technology' $krb5_dir/include/krb5.h | head -n 1 | sed 's/^.*Massachusetts Institute of Technology.*$/MIT/'`
1420           ac_krb5_version="$ac_heimdal_version$ac_mit_version"
1421           if test "x$ac_krb5_version" = "xHEIMDAL"
1422               KRB5_LIBS="-L$krb5_dir/lib -lkrb5 -lasn1 $SSL_LIBS -lroken -lcrypt"
1423           then
1424               KRB5_LIBS="-L$krb5_dir/lib -lkrb5 -lk5crypto -lcom_err"
1425           fi
1426           if test "x$ac_krb5_version" = "xMIT"
1427           then
1428             AC_DEFINE(HAVE_MIT_KERBEROS, 1, [Define to use MIT kerberos])
1429           fi
1430         else
1431           AC_PATH_PROG(KRB5_CONFIG, krb5-config)
1432           if test -x "$KRB5_CONFIG"
1433           then
1434             KRB5_FLAGS=`"$KRB5_CONFIG" --cflags`
1435             KRB5_LIBS=`"$KRB5_CONFIG" --libs`
1436             CFLAGS="$CFLAGS $KRB5_FLAGS"
1437             CPPFLAGS="$CPPFLAGS $KRB5_FLAGS"
1438             #
1439             # If -lcrypto is in KRB5_FLAGS, we require it to build
1440             # with Heimdal/MIT.  We don't want to built with it by
1441             # default, due to annoying license incompatibilities
1442             # between the OpenSSL license and the GPL, so:
1443             #
1444             #   if SSL_LIBS is set to a non-empty string, we
1445             #   remove -lcrypto from KRB5_LIBS and replace
1446             #   it with SSL_LIBS;
1447             #
1448             #   if SSL_LIBS is not set to a non-empty string
1449             #   we fail with an appropriate error message.
1450             #
1451             case "$KRB5_LIBS" in
1452             *-lcrypto*)
1453                 if test ! -z "$SSL_LIBS"
1454                 then
1455                     KRB5_LIBS=`echo $KRB5_LIBS | sed 's/-lcrypto//'`
1456                     KRB5_LIBS="$KRB5_LIBS $SSL_LIBS"
1457                 else
1458                     AC_MSG_ERROR([Kerberos library requires -lcrypto but --with-ssl not specified])
1459                 fi
1460                 ;;
1461             esac
1462             ac_krb5_version=`"$KRB5_CONFIG" --version | head -n 1 | sed -e 's/^.*heimdal.*$/HEIMDAL/' -e 's/^Kerberos .*$/MIT/' -e 's/^Solaris Kerberos .*$/MIT/'`
1463           fi
1464         fi
1465
1466         #
1467         # Make sure we have "krb5.h".  If we don't, it means we probably
1468         # don't have kerberos, so don't use it.
1469         #
1470         AC_CHECK_HEADER(krb5.h,,
1471           [
1472             if test "x$krb5_dir" != "x"
1473             then
1474               #
1475               # The user used "--with-krb5=" to specify a directory
1476               # containing kerberos, but we didn't find the header file
1477               # there; that either means they didn't specify the
1478               # right directory or are confused about whether kerberos
1479               # is, in fact, installed.  Report the error and give up.
1480               #
1481               AC_MSG_ERROR([kerberos header not found in directory specified in --with-krb5])
1482             else
1483               if test "x$want_krb5" = "xyes"
1484               then
1485                 #
1486                 # The user tried to force us to use the library, but we
1487                 # couldn't find the header file; report an error.
1488                 #
1489                 AC_MSG_ERROR(Header file krb5.h not found.)
1490               else
1491                 #
1492                 # We couldn't find the header file; don't use the
1493                 # library, as it's probably not present.
1494                 #
1495                 want_krb5=no
1496                 AC_MSG_RESULT(No Heimdal or MIT header found - disabling dissection for some kerberos data in packet decoding)
1497               fi
1498             fi
1499           ])
1500
1501         if test "x$want_krb5" != "xno"
1502         then
1503             #
1504             # Well, we at least have the krb5 header file.
1505             # Check whether this is Heimdal or MIT.
1506             #
1507             AC_MSG_CHECKING(whether the Kerberos library is Heimdal or MIT)
1508             if test "x$ac_krb5_version" = "xHEIMDAL" -o "x$ac_krb5_version" = "xMIT"
1509             then
1510                 #
1511                 # Yes.
1512                 # Check whether we have krb5_kt_resolve - and whether
1513                 # we need to link with -lresolv when linking with
1514                 # the Kerberos library.
1515                 #
1516                 AC_MSG_RESULT($ac_krb5_version)
1517                 wireshark_save_LIBS="$LIBS"
1518                 found_krb5_kt_resolve=no
1519                 for extras in "" "-lresolv"
1520                 do
1521                     LIBS="$KRB5_LIBS $extras"
1522                     if test -z "$extras"
1523                     then
1524                         AC_MSG_CHECKING([whether $ac_krb5_version includes krb5_kt_resolve])
1525                     else
1526                         AC_MSG_CHECKING([whether $ac_krb5_version includes krb5_kt_resolve (linking with $extras)])
1527                     fi
1528                     AC_TRY_LINK(
1529                         [
1530                         ],
1531                         [
1532                             krb5_kt_resolve();
1533                         ],
1534                         [
1535                             #
1536                             # We found "krb5_kt_resolve()", and required
1537                             # the libraries in extras as well.
1538                             #
1539                             AC_MSG_RESULT(yes)
1540                             KRB5_LIBS="$LIBS"
1541                             AC_DEFINE(HAVE_KERBEROS, 1, [Define to use kerberos])
1542                             if test "x$ac_krb5_version" = "xHEIMDAL"
1543                             then
1544                                 AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1, [Define to use heimdal kerberos])
1545                             elif test "x$ac_krb5_version" = "xMIT"
1546                             then
1547                                 AC_DEFINE(HAVE_MIT_KERBEROS, 1, [Define to use MIT kerberos])
1548                             fi
1549                             found_krb5_kt_resolve=yes
1550                             break
1551                         ],
1552                         [
1553                             AC_MSG_RESULT(no)
1554                         ])
1555                 done
1556                 if test "$found_krb5_kt_resolve" = no
1557                 then
1558                     #
1559                     # We didn't find "krb5_kt_resolve()" in the
1560                     # Kerberos library, even when we tried linking
1561                     # with -lresolv; we can't link with kerberos.
1562                     #
1563                     if test "x$want_krb5" = "xyes"
1564                     then
1565                         #
1566                         # The user tried to force us to use the library,
1567                         # but we can't do so; report an error.
1568                         #
1569                         AC_MSG_ERROR(Usable $ac_krb5_version not found)
1570                     else
1571                         #
1572                         # Restore the versions of CFLAGS and CPPFLAGS
1573                         # from before we added the flags for Kerberos.
1574                         #
1575                         AC_MSG_RESULT(Usable $ac_krb5_version not found - disabling dissection for some kerberos data in packet decoding)
1576                         CFLAGS="$wireshark_save_CFLAGS"
1577                         CPPFLAGS="$wireshark_save_CPPFLAGS"
1578                         KRB5_LIBS=""
1579                         want_krb5=no
1580                     fi
1581                 else
1582                     #
1583                     # We can link with Kerberos; see whether krb5.h
1584                     # defines KEYTYPE_ARCFOUR_56 (where "defines" means
1585                     # "as a #define or as an enum member).
1586                     #
1587                     AC_MSG_CHECKING([whether krb5.h defines KEYTYPE_ARCFOUR_56])
1588                     AC_COMPILE_IFELSE(
1589                       [
1590                         AC_LANG_SOURCE(
1591                           [[
1592                             #include <krb5.h>
1593                             #include <stdio.h>
1594
1595                             main()
1596                             {
1597                               printf("%u\n", KEYTYPE_ARCFOUR_56);
1598                             }
1599                           ]])
1600                       ],
1601                       [
1602                         AC_MSG_RESULT(yes)
1603                         AC_DEFINE(HAVE_KEYTYPE_ARCFOUR_56, 1, [Define if krb5.h defines KEYTYPE_ARCFOUR_56])
1604                       ],
1605                       [
1606                         AC_MSG_RESULT(no)
1607                       ])
1608                 fi
1609                 LIBS="$wireshark_save_LIBS"
1610             else
1611                 #
1612                 # It's not Heimdal or MIT.
1613                 #
1614                 AC_MSG_RESULT(no)
1615                 if test "x$want_krb5" = "xyes"
1616                 then
1617                     #
1618                     # The user tried to force us to use the library,
1619                     # but we can't do so; report an error.
1620                     #
1621                     AC_MSG_ERROR(Kerberos not found)
1622                 else
1623                     #
1624                     # Restore the versions of CFLAGS and CPPFLAGS
1625                     # from before we added the flags for Kerberos.
1626                     #
1627                     AC_MSG_RESULT(Kerberos not found - disabling dissection for some kerberos data in packet decoding)
1628                     CFLAGS="$wireshark_save_CFLAGS"
1629                     CPPFLAGS="$wireshark_save_CPPFLAGS"
1630                     KRB5_LIBS=""
1631                     want_krb5=no
1632                 fi
1633             fi
1634         else
1635             #
1636             # The user asked us not to use Kerberos, or they didn't
1637             # say whether they wanted us to use it but we found
1638             # that we couldn't.
1639             #
1640             # Restore the versions of CFLAGS and CPPFLAGS
1641             # from before we added the flags for Kerberos.
1642             #
1643             CFLAGS="$wireshark_save_CFLAGS"
1644             CPPFLAGS="$wireshark_save_CPPFLAGS"
1645             KRB5_LIBS=""
1646             want_krb5=no
1647         fi
1648         AC_SUBST(KRB5_LIBS)
1649 ])
1650
1651 #
1652 # AC_WIRESHARK_GEOIP_CHECK
1653 #
1654 AC_DEFUN([AC_WIRESHARK_GEOIP_CHECK],
1655 [
1656         want_geoip=defaultyes
1657
1658         if test "x$want_geoip" = "xdefaultyes"; then
1659                 want_geoip=yes
1660                 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
1661                         withval=/usr/local
1662                         if test -d "$withval"; then
1663                                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1664                         fi
1665                 fi
1666         fi
1667
1668         if test "x$want_geoip" = "xyes"; then
1669                 AC_CHECK_LIB(GeoIP, GeoIP_new,
1670                   [
1671                     GEOIP_LIBS=-lGeoIP
1672                 AC_DEFINE(HAVE_GEOIP, 1, [Define to use GeoIP library])
1673                 have_good_geoip=yes
1674                   ],,
1675                 )
1676         else
1677                 AC_MSG_RESULT(not required)
1678         fi
1679 ])
1680
1681 #AC_WIRESHARK_GCC_LDFLAGS_CHECK
1682 #
1683 # $1 : ldflag(s) to test
1684 #
1685 # The macro first determines if the compiler is GCC. Then compile with the
1686 # defined ldflags. The defined flags are added to LDFLAGS only if the
1687 # compilation succeeds.
1688 #
1689 AC_DEFUN([AC_WIRESHARK_GCC_LDFLAGS_CHECK],
1690 [GCC_OPTION="$1"
1691 AC_MSG_CHECKING(whether we can add $GCC_OPTION to LDFLAGS)
1692 if test "x$GCC" != "x"; then
1693   LDFLAGS_saved="$CFLAGS"
1694   LDFLAGS="$LDFLAGS $GCC_OPTION"
1695   AC_LINK_IFELSE([
1696     AC_LANG_SOURCE([[
1697                 main() { return; }
1698                   ]])],
1699                   [
1700                     AC_MSG_RESULT(yes)
1701                   ],
1702                   [
1703                     AC_MSG_RESULT(no)
1704                     LDFLAGS="$LDFLAGS_saved"
1705                   ])
1706 else
1707   AC_MSG_RESULT(no)
1708 fi
1709 ])
1710
1711 #
1712 # AC_WIRESHARK_GCC_CFLAGS_CHECK
1713 #
1714 # $1 : cflags to test
1715 #
1716 # The macro first determines if the compiler is GCC. Then compile with the
1717 # defined cflags. The defined flags are added to CFLAGS only if the compilation
1718 # succeeds.
1719 #
1720 AC_DEFUN([AC_WIRESHARK_GCC_CFLAGS_CHECK],
1721 [GCC_OPTION="$1"
1722 AC_MSG_CHECKING(whether we can add $GCC_OPTION to CFLAGS)
1723 if test "x$GCC" != "x"; then
1724   CFLAGS_saved="$CFLAGS"
1725   CFLAGS="$CFLAGS $GCC_OPTION"
1726   AC_COMPILE_IFELSE([
1727     AC_LANG_SOURCE([[
1728                       int foo;
1729                   ]])],
1730                   [
1731                     AC_MSG_RESULT(yes)
1732                   ],
1733                   [
1734                     AC_MSG_RESULT(no)
1735                     CFLAGS="$CFLAGS_saved"
1736                   ])
1737 else
1738   AC_MSG_RESULT(no)
1739 fi
1740 ])
1741
1742 #
1743 # AC_WIRESHARK_IGE_MAC_INTEGRATION_CHECK
1744 #
1745 # Checks for the presence of OS X integration functions in the GTK+ framework
1746 # or as a separate library.
1747 #
1748 # http://developer.imendio.com/projects/gtk-macosx/integration
1749 #
1750 AC_DEFUN([AC_WIRESHARK_IGE_MAC_INTEGRATION_CHECK],
1751 [
1752         ac_save_CFLAGS="$CFLAGS"
1753         ac_save_LIBS="$LIBS"
1754         CFLAGS="$CFLAGS $GTK_CFLAGS"
1755         LIBS="$GTK_LIBS $LIBS"
1756         AC_CHECK_LIB(Gtk, ige_mac_menu_set_menu_bar,
1757         [
1758                 AC_DEFINE(HAVE_IGE_MAC_INTEGRATION, 1,
1759                         [Define to 1 if the the Gtk+ framework or a separate library inclues the Imendio IGE Mac OS X Integration functions.])
1760                 have_ige_mac=yes
1761                 # We don't want gtk stuff in LIBS (which is reset below) so
1762                 # manually set GTK_LIBS (which is more appropriate)
1763                 GTK_LIBS="$GTK_LIBS -lGtk"
1764         ])
1765
1766         if test x$have_ige_mac == x
1767         then
1768                 AC_CHECK_LIB(igemacintegration, ige_mac_menu_set_menu_bar,
1769                 [
1770                         AC_DEFINE(HAVE_IGE_MAC_INTEGRATION, 1,
1771                                 [Define to 1 if the the Gtk+ framework or a separate library inclues the Imendio IGE Mac OS X Integration functions.])
1772                         # We don't want gtk stuff in LIBS (which is reset below) so
1773                         # manually set GTK_LIBS (which is more appropriate)
1774                         GTK_LIBS="$GTK_LIBS -ligemacintegration"
1775                 ])
1776         fi
1777         CFLAGS="$ac_save_CFLAGS"
1778         LIBS="$ac_save_LIBS"
1779 ])
1780
1781 #
1782 # AC_WIRESHARK_PYTHON_CHECK
1783 #
1784 # Check whether python devel package is present
1785 #
1786 AC_DEFUN([AC_WIRESHARK_PYTHON_CHECK],
1787   [
1788     #
1789     # Checking whether we have a python devel environment available
1790     #
1791 #  AC_CACHE_CHECK([checking python devel package], ac_cv_wireshark_python_devel,
1792 #    [
1793     AC_CHECK_PROG([ac_ws_python_config], [python-config], "yes", "no")
1794     if test ac_ws_python_config = "no"; then
1795       ac_cv_wireshark_python_devel = "no"
1796     else
1797       AC_MSG_CHECKING([python devel])
1798       ac_save_ws_cflags=$CFLAGS
1799       ac_save_ws_libs=$LIBS
1800       CFLAGS=$(python-config --includes)
1801       LIBS=$(python-config --ldflags)
1802       AC_COMPILE_IFELSE(
1803         [
1804           AC_LANG_PROGRAM(
1805             [[#include <Python.h>]],
1806             [[Py_Initialiaze();]]
1807           )
1808         ],
1809         [
1810           #
1811           # Compilation successful, we have python devel available
1812           #
1813           ac_cv_wireshark_python_devel=yes
1814           PY_LIBS=$LIBS
1815           PY_CFLAGS=$CFLAGS
1816           AC_SUBST(PY_LIBS)
1817           AC_SUBST(PY_CFLAGS)
1818           CFLAGS="$ac_save_ws_cflags"
1819           LIBS="$ac_save_ws_libs"
1820           AC_DEFINE(HAVE_PYTHON, 1, [Define if python devel package available])
1821           AC_MSG_RESULT([yes])
1822         ],
1823         [
1824           #
1825           # Compilation unsuccessful, python devel not available
1826           #
1827           ac_cv_wireshark_python_devel=no
1828           CFLAGS=$ac_save_ws_cflags
1829           LIBS=$ac_save_ws_libs
1830           AC_MSG_RESULT([no])
1831         ])
1832     fi
1833 #    ])
1834 ])