acinclude.m4

   1 dnl Macros that test for specific features.
   2 dnl This file is part of the Autoconf packaging for Ethereal.
   3 dnl Copyright (C) 1998-2000 by Gerald Combs.
   4 dnl
   5 dnl $Id: acinclude.m4,v 1.46 2002/10/25 03:13:07 guy Exp $
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2, or (at your option)
  10 dnl any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  20 dnl 02111-1307, USA.
  21 dnl
  22 dnl As a special exception, the Free Software Foundation gives unlimited
  23 dnl permission to copy, distribute and modify the configure scripts that
  24 dnl are the output of Autoconf.  You need not follow the terms of the GNU
  25 dnl General Public License when using or distributing such scripts, even
  26 dnl though portions of the text of Autoconf appear in them.  The GNU
  27 dnl General Public License (GPL) does govern all other use of the material
  28 dnl that constitutes the Autoconf program.
  29 dnl
  30 dnl Certain portions of the Autoconf source text are designed to be copied
  31 dnl (in certain cases, depending on the input) into the output of
  32 dnl Autoconf.  We call these the "data" portions.  The rest of the Autoconf
  33 dnl source text consists of comments plus executable code that decides which
  34 dnl of the data portions to output in any given case.  We call these
  35 dnl comments and executable code the "non-data" portions.  Autoconf never
  36 dnl copies any of the non-data portions into its output.
  37 dnl
  38 dnl This special exception to the GPL applies to versions of Autoconf
  39 dnl released by the Free Software Foundation.  When you make and
  40 dnl distribute a modified version of Autoconf, you may extend this special
  41 dnl exception to the GPL to apply to your modified version as well, *unless*
  42 dnl your modified version has the potential to copy into its output some
  43 dnl of the text that was the non-data portion of the version that you started
  44 dnl with.  (In other words, unless your change moves or copies text from
  45 dnl the non-data portions to the data portions.)  If your modification has
  46 dnl such potential, you must delete any notice of this special exception
  47 dnl to the GPL from your modified version.
  48 dnl
  49 dnl Written by David MacKenzie, with help from
  50 dnl Franc,ois Pinard, Karl Berry, Richard Pixley, Ian Lance Taylor,
  51 dnl Roland McGrath, Noah Friedman, david d zuhn, and many others.
  52
  53 #
  54 # AC_ETHEREAL_ADD_DASH_L
  55 #
  56 # Add to the variable specified as the first argument a "-L" flag for the
  57 # directory specified as the second argument, and, on Solaris, add a
  58 # "-R" flag for it as well.
  59 #
  60 # XXX - IRIX, and other OSes, may require some flag equivalent to
  61 # "-R" here.
  62 #
  63 AC_DEFUN(AC_ETHEREAL_ADD_DASH_L,
  64 [$1="$$1 -L$2"
  65 case "$host_os" in
  66   solaris*)
  67     $1="$$1 -R$2"
  68   ;;
  69 esac
  70 ])
  71
  72
  73 #
  74 # AC_ETHEREAL_STRUCT_SA_LEN
  75 #
  76 dnl AC_STRUCT_ST_BLKSIZE extracted from the file in question,
  77 dnl "acspecific.m4" in GNU Autoconf 2.12, and turned into
  78 dnl AC_ETHEREAL_STRUCT_SA_LEN, which checks if "struct sockaddr"
  79 dnl has the 4.4BSD "sa_len" member, and defines HAVE_SA_LEN; that's
  80 dnl what's in this file.
  81 dnl Done by Guy Harris <guy@alum.mit.edu> on 1998-11-14.
  82
  83 dnl ### Checks for structure members
  84
  85 AC_DEFUN(AC_ETHEREAL_STRUCT_SA_LEN,
  86 [AC_CACHE_CHECK([for sa_len in struct sockaddr], ac_cv_ethereal_struct_sa_len,
  87 [AC_TRY_COMPILE([#include <sys/types.h>
  88 #include <sys/socket.h>], [struct sockaddr s; s.sa_len;],
  89 ac_cv_ethereal_struct_sa_len=yes, ac_cv_ethereal_struct_sa_len=no)])
  90 if test $ac_cv_ethereal_struct_sa_len = yes; then
  91   AC_DEFINE(HAVE_SA_LEN)
  92 fi
  93 ])
  94
  95 #
  96 # AC_ETHEREAL_IPV6_STACK
  97 #
  98 # By Jun-ichiro "itojun" Hagino, <itojun@iijlab.net>
  99 #
 100 AC_DEFUN(AC_ETHEREAL_IPV6_STACK,
 101 [
 102         v6type=unknown
 103         v6lib=none
 104
 105         AC_MSG_CHECKING([ipv6 stack type])
 106         for i in v6d toshiba kame inria zeta linux linux-glibc solaris8; do
 107                 case $i in
 108                 v6d)
 109                         AC_EGREP_CPP(yes, [
 110 #include </usr/local/v6/include/sys/types.h>
 111 #ifdef __V6D__
 112 yes
 113 #endif],
 114                                 [v6type=$i; v6lib=v6;
 115                                 v6libdir=/usr/local/v6/lib;
 116                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 117                         ;;
 118                 toshiba)
 119                         AC_EGREP_CPP(yes, [
 120 #include <sys/param.h>
 121 #ifdef _TOSHIBA_INET6
 122 yes
 123 #endif],
 124                                 [v6type=$i; v6lib=inet6;
 125                                 v6libdir=/usr/local/v6/lib;
 126                                 CFLAGS="-DINET6 $CFLAGS"])
 127                         ;;
 128                 kame)
 129                         AC_EGREP_CPP(yes, [
 130 #include <netinet/in.h>
 131 #ifdef __KAME__
 132 yes
 133 #endif],
 134                                 [v6type=$i; v6lib=inet6;
 135                                 v6libdir=/usr/local/v6/lib;
 136                                 CFLAGS="-DINET6 $CFLAGS"])
 137                         ;;
 138                 inria)
 139                         AC_EGREP_CPP(yes, [
 140 #include <netinet/in.h>
 141 #ifdef IPV6_INRIA_VERSION
 142 yes
 143 #endif],
 144                                 [v6type=$i; CFLAGS="-DINET6 $CFLAGS"])
 145                         ;;
 146                 zeta)
 147                         AC_EGREP_CPP(yes, [
 148 #include <sys/param.h>
 149 #ifdef _ZETA_MINAMI_INET6
 150 yes
 151 #endif],
 152                                 [v6type=$i; v6lib=inet6;
 153                                 v6libdir=/usr/local/v6/lib;
 154                                 CFLAGS="-DINET6 $CFLAGS"])
 155                         ;;
 156                 linux)
 157                         if test -d /usr/inet6; then
 158                                 v6type=$i
 159                                 v6lib=inet6
 160                                 v6libdir=/usr/inet6
 161                                 CFLAGS="-DINET6 $CFLAGS"
 162                         fi
 163                         ;;
 164                 linux-glibc)
 165                         AC_EGREP_CPP(yes, [
 166 #include <features.h>
 167 #if defined(__GLIBC__) && defined(__GLIBC_MINOR__)
 168 #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || __GLIBC__ > 2
 169 yes
 170 #endif
 171 #endif],
 172                         [v6type=$i; v6lib=inet6; CFLAGS="-DINET6 $CFLAGS"])
 173                         ;;
 174                 solaris8)
 175                         if test "`uname -s`" = "SunOS" && test "`uname -r`" = "5.8"; then
 176                                 v6type=$i
 177                                 v6lib=inet6
 178                                 [CFLAGS="-DINET6 -DSOLARIS8_INET6 $CFLAGS"]
 179                         fi
 180                         ;;
 181                 esac
 182                 if test "$v6type" != "unknown"; then
 183                         break
 184                 fi
 185         done
 186
 187         if test "$v6lib" != "none"; then
 188                 for dir in $v6libdir /usr/local/v6/lib /usr/local/lib; do
 189                         if test -d $dir -a -f $dir/lib$v6lib.a; then
 190                                 LIBS="-L$dir $LIBS -l$v6lib"
 191                                 break
 192                         fi
 193                 done
 194                 enable_ipv6="yes"
 195         else
 196                 enable_ipv6="no"
 197         fi
 198         AC_MSG_RESULT(["$v6type, $v6lib"])
 199 ])
 200
 201 #
 202 # AC_ETHEREAL_GETHOSTBY_LIB_CHECK
 203 #
 204 # Checks whether we need "-lnsl" to get "gethostby*()", which we use
 205 # in "resolv.c".
 206 #
 207 # Adapted from stuff in the AC_PATH_XTRA macro in "acspecific.m4" in
 208 # GNU Autoconf 2.13; the comment came from there.
 209 # Done by Guy Harris <guy@alum.mit.edu> on 2000-01-14.
 210 #
 211 AC_DEFUN(AC_ETHEREAL_GETHOSTBY_LIB_CHECK,
 212 [
 213     # msh@cis.ufl.edu says -lnsl (and -lsocket) are needed for his 386/AT,
 214     # to get the SysV transport functions.
 215     # chad@anasazi.com says the Pyramid MIS-ES running DC/OSx (SVR4)
 216     # needs -lnsl.
 217     # The nsl library prevents programs from opening the X display
 218     # on Irix 5.2, according to dickey@clark.net.
 219     AC_CHECK_FUNC(gethostbyname, ,
 220         AC_CHECK_LIB(nsl, gethostbyname, NSL_LIBS="-lnsl"))
 221     AC_SUBST(NSL_LIBS)
 222 ])
 223
 224 #
 225 # AC_ETHEREAL_SOCKET_LIB_CHECK
 226 #
 227 # Checks whether we need "-lsocket" to get "socket()", which is used
 228 # by libpcap on some platforms - and, in effect, "gethostby*()" on
 229 # most if not all platforms (so that it can use NIS or DNS or...
 230 # to look up host names).
 231 #
 232 # Adapted from stuff in the AC_PATH_XTRA macro in "acspecific.m4" in
 233 # GNU Autoconf 2.13; the comment came from there.
 234 # Done by Guy Harris <guy@alum.mit.edu> on 2000-01-14.
 235 #
 236 # We use "connect" because that's what AC_PATH_XTRA did.
 237 #
 238 AC_DEFUN(AC_ETHEREAL_SOCKET_LIB_CHECK,
 239 [
 240     # lieder@skyler.mavd.honeywell.com says without -lsocket,
 241     # socket/setsockopt and other routines are undefined under SCO ODT
 242     # 2.0.  But -lsocket is broken on IRIX 5.2 (and is not necessary
 243     # on later versions), says simon@lia.di.epfl.ch: it contains
 244     # gethostby* variants that don't use the nameserver (or something).
 245     # -lsocket must be given before -lnsl if both are needed.
 246     # We assume that if connect needs -lnsl, so does gethostbyname.
 247     AC_CHECK_FUNC(connect, ,
 248       AC_CHECK_LIB(socket, connect, SOCKET_LIBS="-lsocket",
 249                 AC_MSG_ERROR(Function 'socket' not found.), $NSL_LIBS))
 250     AC_SUBST(SOCKET_LIBS)
 251 ])
 252
 253 #
 254 # AC_ETHEREAL_PCAP_CHECK
 255 #
 256 AC_DEFUN(AC_ETHEREAL_PCAP_CHECK,
 257 [
 258         if test -z "$pcap_dir"
 259         then
 260           #
 261           # The user didn't specify a directory in which libpcap resides;
 262           # we assume that the current library search path will work,
 263           # but we may have to look for the header in a "pcap"
 264           # subdirectory of "/usr/include" or "/usr/local/include",
 265           # as some systems apparently put "pcap.h" in a "pcap"
 266           # subdirectory, and we also check "$prefix/include".
 267           #
 268           # XXX - should we just add "$prefix/include" to the include
 269           # search path and "$prefix/lib" to the library search path?
 270           #
 271           AC_MSG_CHECKING(for extraneous pcap header directories)
 272           found_pcap_dir=""
 273           for pcap_dir in /usr/include/pcap /usr/local/include/pcap $prefix/include
 274           do
 275             if test -d $pcap_dir ; then
 276                 if test x$pcap_dir != x/usr/include; then
 277                     CFLAGS="$CFLAGS -I$pcap_dir"
 278                     CPPFLAGS="$CPPFLAGS -I$pcap_dir"
 279                 fi
 280                 found_pcap_dir=" $found_pcap_dir -I$pcap_dir"
 281             fi
 282           done
 283
 284           if test "$found_pcap_dir" != "" ; then
 285             AC_MSG_RESULT(found --$found_pcap_dir added to CFLAGS)
 286           else
 287             AC_MSG_RESULT(not found)
 288           fi
 289         else
 290           #
 291           # The user specified a directory in which libpcap resides,
 292           # so add the "include" subdirectory of that directory to
 293           # the include file search path and the "lib" subdirectory
 294           # of that directory to the library search path.
 295           #
 296           # XXX - if there's also a libpcap in a directory that's
 297           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 298           # make us find the version in the specified directory,
 299           # as the compiler and/or linker will search that other
 300           # directory before it searches the specified directory.
 301           #
 302           CFLAGS="$CFLAGS -I$pcap_dir/include"
 303           CPPFLAGS="$CPPFLAGS -I$pcap_dir/include"
 304           AC_ETHEREAL_ADD_DASH_L(LDFLAGS, $pcap_dir/lib)
 305         fi
 306
 307         # Pcap header checks
 308         AC_CHECK_HEADER(net/bpf.h,,
 309             AC_MSG_ERROR([[Header file net/bpf.h not found; if you installed libpcap from source, did you also do \"make install-incl\"?]]))
 310         AC_CHECK_HEADER(pcap.h,, AC_MSG_ERROR(Header file pcap.h not found.))
 311
 312         #
 313         # Check to see if we find "pcap_open_live" in "-lpcap".
 314         #
 315         AC_CHECK_LIB(pcap, pcap_open_live,
 316           [
 317             PCAP_LIBS=-lpcap
 318             AC_DEFINE(HAVE_LIBPCAP)
 319           ], AC_MSG_ERROR(Library libpcap not found.),
 320           $SOCKET_LIBS $NSL_LIBS)
 321         AC_SUBST(PCAP_LIBS)
 322 ])
 323
 324 #
 325 # AC_ETHEREAL_PCAP_VERSION_CHECK
 326 #
 327 # Check whether "pcap_version" is defined by libpcap.
 328 #
 329 AC_DEFUN(AC_ETHEREAL_PCAP_VERSION_CHECK,
 330 [
 331         AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 332         ac_save_LIBS="$LIBS"
 333         LIBS="$PCAP_LIBS $SOCKET_LIBS $NSL_LIBS $LIBS"
 334         AC_TRY_LINK([],
 335            [
 336 char *
 337 return_pcap_version(void)
 338 {
 339         extern char pcap_version[];
 340
 341         return pcap_version;
 342 }
 343            ],
 344            ac_cv_pcap_version_defined=yes,
 345            ac_cv_pcap_version_defined=no,
 346            [echo $ac_n "cross compiling; assumed OK... $ac_c"])
 347         LIBS="$ac_save_LIBS"
 348         if test "$ac_cv_pcap_version_defined" = yes ; then
 349                 AC_MSG_RESULT(yes)
 350                 AC_DEFINE(HAVE_PCAP_VERSION)
 351         else
 352                 AC_MSG_RESULT(no)
 353         fi
 354 ])
 355
 356 #
 357 # AC_ETHEREAL_ZLIB_CHECK
 358 #
 359 AC_DEFUN(AC_ETHEREAL_ZLIB_CHECK,
 360 [
 361         if test "x$zlib_dir" != "x"
 362         then
 363           #
 364           # The user specified a directory in which zlib resides,
 365           # so add the "include" subdirectory of that directory to
 366           # the include file search path and the "lib" subdirectory
 367           # of that directory to the library search path.
 368           #
 369           # XXX - if there's also a zlib in a directory that's
 370           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 371           # make us find the version in the specified directory,
 372           # as the compiler and/or linker will search that other
 373           # directory before it searches the specified directory.
 374           #
 375           ethereal_save_CFLAGS="$CFLAGS"
 376           CFLAGS="$CFLAGS -I$zlib_dir/include"
 377           ethereal_save_CPPLAGS="$CPPLAGS"
 378           CPPFLAGS="$CPPFLAGS -I$zlib_dir/include"
 379           ethereal_save_LIBS="$LIBS"
 380           AC_ETHEREAL_ADD_DASH_L(LIBS, $zlib_dir/lib)
 381         fi
 382
 383         #
 384         # Make sure we have "zlib.h".  If we don't, it means we probably
 385         # don't have zlib, so don't use it.
 386         #
 387         AC_CHECK_HEADER(zlib.h,,
 388           [
 389             if test "x$zlib_dir" != "x"
 390             then
 391               #
 392               # The user used "--with-zlib=" to specify a directory
 393               # containing zlib, but we didn't find the header file
 394               # there; that either means they didn't specify the
 395               # right directory or are confused about whether zlib
 396               # is, in fact, installed.  Report the error and give up.
 397               #
 398               AC_MSG_ERROR([zlib header not found in directory specified in --with-zlib])
 399             else
 400               if test "x$want_zlib" = "xyes"
 401               then
 402                 #
 403                 # The user tried to force us to use the library, but we
 404                 # couldn't find the header file; report an error.
 405                 #
 406                 AC_MSG_ERROR(Header file zlib.h not found.)
 407               else
 408                 #
 409                 # We couldn't find the header file; don't use the
 410                 # library, as it's probably not present.
 411                 #
 412                 want_zlib=no
 413               fi
 414             fi
 415           ])
 416
 417         if test "x$want_zlib" != "xno"
 418         then
 419                 #
 420                 # Well, we at least have the zlib header file.
 421                 #
 422                 # Check for "gzgets()" in zlib, because we need it, but
 423                 # some older versions of zlib don't have it.  It appears
 424                 # from the zlib ChangeLog that any released version of zlib
 425                 # with "gzgets()" should have the other routines we
 426                 # depend on, such as "gzseek()", "gztell()", and "zError()".
 427                 #
 428                 # Another reason why we require "gzgets()" is that
 429                 # some versions of zlib that didn't have it, such
 430                 # as 1.0.8, had a bug in "gzseek()" that meant that it
 431                 # doesn't work correctly on uncompressed files; this
 432                 # means we cannot use version 1.0.8.  (Unfortunately,
 433                 # that's the version that comes with recent X11 source,
 434                 # and many people who install XFree86 on their Slackware
 435                 # boxes don't realize that they should configure it to
 436                 # use the native zlib rather than building and installing
 437                 # the crappy old version that comes with XFree86.)
 438                 #
 439                 # I.e., we can't just avoid using "gzgets()", as
 440                 # versions of zlib without "gzgets()" are likely to have
 441                 # a broken "gzseek()".
 442                 #
 443                 AC_CHECK_LIB(z, gzgets,
 444                 [
 445                         if test "x$zlib_dir" != "x"
 446                         then
 447                                 #
 448                                 # Put the "-I" and "-L" flags for zlib at
 449                                 # the beginning of CFLAGS, CPPFLAGS, and
 450                                 # LIBS.
 451                                 #
 452                                 LIBS=""
 453                                 AC_ETHEREAL_ADD_DASH_L(LIBS, $zlib_dir/lib)
 454                                 LIBS="$LIBS -lz $ethereal_save_LIBS"
 455                         else
 456                                 LIBS="-lz $LIBS"
 457                         fi
 458                         AC_DEFINE(HAVE_LIBZ)
 459                 ],[
 460                         if test "x$zlib_dir" != "x"
 461                         then
 462                                 #
 463                                 # Restore the versions of CFLAGS, CPPFLAGS,
 464                                 # and LIBS before we added the "-with-zlib="
 465                                 # directory, as we didn't actually find
 466                                 # zlib there, or didn't find a zlib that
 467                                 # contains gzgets there.
 468                                 #
 469                                 CFLAGS="$ethereal_save_CFLAGS"
 470                                 CPPFLAGS="$ethereal_save_CPPLAGS"
 471                                 LIBS="$ethereal_save_LIBS"
 472                         fi
 473                         want_zlib=no
 474                 ])
 475         fi
 476
 477         if test "x$want_zlib" != "xno"
 478         then
 479                 #
 480                 # Well, we at least have the zlib header file and a zlib
 481                 # with "gzgets()".
 482                 #
 483                 # Now check for "gzgets()" in zlib when linking with the
 484                 # linker flags for GTK+ applications; people often grab
 485                 # XFree86 source and build and install it on their systems,
 486                 # and they appear sometimes to misconfigure XFree86 so that,
 487                 # even on systems with zlib, it assumes there is no zlib,
 488                 # so the XFree86 build process builds and installs its
 489                 # own zlib in the X11 library directory.
 490                 #
 491                 # The XFree86 zlib is an older version that lacks
 492                 # "gzgets()", and that's the zlib with which Ethereal
 493                 # gets linked, so the build of Ethereal fails.
 494                 #
 495                 ac_save_CFLAGS="$CFLAGS"
 496                 ac_save_LIBS="$LIBS"
 497                 CFLAGS="$CFLAGS $GTK_CFLAGS"
 498                 LIBS="$GTK_LIBS -lz $LIBS"
 499                 AC_MSG_CHECKING([for gzgets missing when linking with X11])
 500                 AC_TRY_LINK_FUNC(gzgets, AC_MSG_RESULT(no),
 501                   [
 502                     AC_MSG_RESULT(yes)
 503                     AC_MSG_ERROR(old zlib found when linking with X11 - get rid of old zlib.)
 504                   ])
 505                 CFLAGS="$ac_save_CFLAGS"
 506                 LIBS="$ac_save_LIBS"
 507         fi
 508 ])
 509
 510 #
 511 # AC_ETHEREAL_UCDSNMP_CHECK
 512 #
 513 AC_DEFUN(AC_ETHEREAL_UCDSNMP_CHECK,
 514 [
 515         if test "x$ucdsnmp_dir" != "x"
 516         then
 517                 #
 518                 # The user specified a directory in which UCD SNMP resides,
 519                 # so add the "include" subdirectory of that directory to
 520                 # the include file search path and the "lib" subdirectory
 521                 # of that directory to the library search path.
 522                 #
 523                 # XXX - if there's also a libpcap in a directory that's
 524                 # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 525                 # make us find the version in the specified directory,
 526                 # as the compiler and/or linker will search that other
 527                 # directory before it searches the specified directory.
 528                 #
 529                 CFLAGS="$CFLAGS -I$ucdsnmp_dir/include"
 530                 CPPFLAGS="$CPPFLAGS -I$ucdsnmp_dir/include"
 531                 AC_ETHEREAL_ADD_DASH_L(LDFLAGS, $ucdsnmp_dir/lib)
 532         fi
 533
 534         #
 535         # Check for the UCD SNMP header file, to see whether we
 536         # have UCD SNMP installed.
 537         #
 538         AC_CHECK_HEADER(ucd-snmp/snmp.h,
 539         [
 540                 #
 541                 # UCD SNMP may require "-lkstat" on Solaris, sigh.
 542                 # XXX - it may also require "-lcrypto" on some platforms;
 543                 # we should check for that as well, rather than requiring
 544                 # users to explicitly indicate whether it's required.
 545                 #
 546                 AC_CHECK_LIB(snmp, sprint_realloc_objid,
 547                   SNMP_LIBS=-lsnmp,
 548                   [
 549                     #
 550                     # Throw away the cached "we didn't find it" answer.
 551                     #
 552                     unset ac_cv_lib_snmp_sprint_realloc_objid
 553                     AC_CHECK_LIB(snmp, sprint_realloc_objid,
 554                       [
 555                         #
 556                         # Throw away the cached "we found it" answer, so
 557                         # that if we rerun "configure", we don't just blow
 558                         # off this check and blithely assume that we don't
 559                         # need "-lkstat".
 560                         #
 561                         # XXX - autoconf really needs a way to test for
 562                         # a given routine in a given library *and* to test
 563                         # whether additional "-L"/"-R"/whatever flags are
 564                         # needed *before* the "-l" flag for the library
 565                         # and to test whether additional libraries are
 566                         # needed after the library *and* to cache all that
 567                         # information.
 568                         #
 569                         unset ac_cv_lib_snmp_sprint_realloc_objid
 570                         SNMP_LIBS="-lsnmp -lkstat"
 571                       ],,$SOCKET_LIBS $NSL_LIBS $SSL_LIBS -lkstat
 572                     )
 573                   ], $SOCKET_LIBS $NSL_LIBS $SSL_LIBS
 574                 )
 575
 576                 #
 577                 # If we didn't find "sprint_realloc_objid()", fail.
 578                 # Either the user needs a newer version of UCD SNMP
 579                 # with "sprint_realloc_objid()", or they may need to
 580                 # specify "--with-ssl".
 581                 #
 582                 if test "$ac_cv_lib_snmp_sprint_realloc_objid" = no; then
 583                     AC_MSG_ERROR([UCD SNMP header files found, but sprint_realloc_objid not found in SNMP library.])
 584                 fi
 585
 586                 #
 587                 # We found it, so we have UCD SNMP.
 588                 #
 589                 AC_DEFINE(HAVE_UCD_SNMP)
 590         ],[
 591                 #
 592                 # No, we don't have it.
 593                 # If the user explicitly asked for UCD SNMP, fail,
 594                 # otherwise just don't use the UCD SNMP library.
 595                 #
 596                 if test "x$want_ucdsnmp" = "xyes" ; then
 597                         AC_MSG_ERROR(Header file ucd-snmp/snmp.h not found.)
 598                 fi
 599         ])
 600 ])
 601
 602 #
 603 # AC_ETHEREAL_SSL_CHECK
 604 #
 605 AC_DEFUN(AC_ETHEREAL_SSL_CHECK,
 606 [
 607         want_ssl=defaultyes
 608
 609         AC_ARG_WITH(ssl,
 610         [  --with-ssl=DIR          use SSL crypto library, located in directory DIR.], [
 611         if   test "x$withval" = "xno";  then
 612                 want_ssl=no
 613         elif test "x$withval" = "xyes"; then
 614                 want_ssl=yes
 615         elif test -d "$withval"; then
 616                 want_ssl=yes
 617                 AC_ETHEREAL_ADD_DASH_L(LDFLAGS, ${withval}/lib)
 618         fi
 619         ])
 620
 621         if test "x$want_ssl" = "xdefaultyes"; then
 622                 want_ssl=yes
 623                 withval=/usr/local/ssl
 624                 if test -d "$withval"; then
 625                         AC_ETHEREAL_ADD_DASH_L(LDFLAGS, ${withval}/lib)
 626                 fi
 627         fi
 628
 629         if test "x$want_ssl" = "xyes"; then
 630                 AC_CHECK_LIB(crypto, EVP_md5,
 631                   [
 632                     SSL_LIBS=-lcrypto
 633                   ],,
 634                 )
 635         else
 636                 AC_MSG_RESULT(not required)
 637         fi
 638 ])
 639
 640 #
 641 # AC_ETHEREAL_RPM_CHECK
 642 # Looks for the rpm program, and checks to see if we can redefine "_topdir".
 643 #
 644 AC_DEFUN(AC_ETHEREAL_RPM_CHECK,
 645 [
 646         AC_CHECK_PROG(ac_cv_ethereal_have_rpm, rpm, "yes", "no")
 647         if test "x$ac_cv_ethereal_have_rpm" = "xyes"; then
 648                 rpm --define '_topdir /tmp' > /dev/null 2>&1
 649                 AC_MSG_CHECKING(to see if we can redefine _topdir)
 650                 if test $? -eq 0 ; then
 651                         AC_MSG_RESULT(yes)
 652                         HAVE_RPM=yes
 653                 else
 654                         AC_MSG_RESULT(no.  You'll have to build packages manually.)
 655                         HAVE_RPM=no
 656                 fi
 657         fi
 658 ])
 659
 660 #
 661 # AC_ETHEREAL_GNU_SED_CHECK
 662 # Checks if GNU sed is the first sed in PATH.
 663 #
 664 AC_DEFUN([AC_ETHEREAL_GNU_SED_CHECK],
 665 [
 666         AC_MSG_CHECKING(for GNU sed as first sed in PATH)
 667         if  ( sh -c "sed --version" </dev/null 2> /dev/null | grep "GNU sed" 2>&1 > /dev/null ) ;  then
 668                 AC_MSG_RESULT(yes)
 669                 HAVE_GNU_SED=yes
 670         else
 671                 AC_MSG_RESULT(no)
 672                 HAVE_GNU_SED=no
 673         fi
 674 ])