acinclude.m4

   1 dnl Macros that test for specific features.
   2 dnl This file is part of the Autoconf packaging for Wireshark.
   3 dnl Copyright (C) 1998-2000 by Gerald Combs.
   4 dnl
   5 dnl $Id$
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2, or (at your option)
  10 dnl any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  20 dnl 02111-1307, USA.
  21 dnl
  22 dnl As a special exception, the Free Software Foundation gives unlimited
  23 dnl permission to copy, distribute and modify the configure scripts that
  24 dnl are the output of Autoconf.  You need not follow the terms of the GNU
  25 dnl General Public License when using or distributing such scripts, even
  26 dnl though portions of the text of Autoconf appear in them.  The GNU
  27 dnl General Public License (GPL) does govern all other use of the material
  28 dnl that constitutes the Autoconf program.
  29 dnl
  30 dnl Certain portions of the Autoconf source text are designed to be copied
  31 dnl (in certain cases, depending on the input) into the output of
  32 dnl Autoconf.  We call these the "data" portions.  The rest of the Autoconf
  33 dnl source text consists of comments plus executable code that decides which
  34 dnl of the data portions to output in any given case.  We call these
  35 dnl comments and executable code the "non-data" portions.  Autoconf never
  36 dnl copies any of the non-data portions into its output.
  37 dnl
  38 dnl This special exception to the GPL applies to versions of Autoconf
  39 dnl released by the Free Software Foundation.  When you make and
  40 dnl distribute a modified version of Autoconf, you may extend this special
  41 dnl exception to the GPL to apply to your modified version as well, *unless*
  42 dnl your modified version has the potential to copy into its output some
  43 dnl of the text that was the non-data portion of the version that you started
  44 dnl with.  (In other words, unless your change moves or copies text from
  45 dnl the non-data portions to the data portions.)  If your modification has
  46 dnl such potential, you must delete any notice of this special exception
  47 dnl to the GPL from your modified version.
  48 dnl
  49 dnl Written by David MacKenzie, with help from
  50 dnl Franc,ois Pinard, Karl Berry, Richard Pixley, Ian Lance Taylor,
  51 dnl Roland McGrath, Noah Friedman, david d zuhn, and many others.
  52
  53 #
  54 # AC_WIRESHARK_ADD_DASH_L
  55 #
  56 # Add to the variable specified as the first argument a "-L" flag for the
  57 # directory specified as the second argument, and, on Solaris, add a
  58 # "-R" flag for it as well.
  59 #
  60 # XXX - IRIX, and other OSes, may require some flag equivalent to
  61 # "-R" here.
  62 #
  63 AC_DEFUN([AC_WIRESHARK_ADD_DASH_L],
  64 [$1="$$1 -L$2"
  65 case "$host_os" in
  66   solaris*)
  67     $1="$$1 -R$2"
  68   ;;
  69 esac
  70 ])
  71
  72 #
  73 # AC_WIRESHARK_TIMEZONE_ABBREV
  74 #
  75
  76 AC_DEFUN([AC_WIRESHARK_TIMEZONE_ABBREV],
  77 [
  78   AC_CACHE_CHECK([for tm_zone in struct tm],
  79     ac_cv_wireshark_have_tm_zone,
  80     [
  81       AC_TRY_COMPILE(
  82         [#include <time.h>],
  83         [struct tm t; t.tm_zone;],
  84         ac_cv_wireshark_have_tm_zone=yes,
  85         ac_cv_wireshark_have_tm_zone=no)
  86     ])
  87   if test $ac_cv_wireshark_have_tm_zone = yes; then
  88     AC_DEFINE(HAVE_TM_ZONE, 1, [Define if tm_zone field exists in struct tm])
  89   else
  90     AC_CACHE_CHECK([for tzname],
  91       ac_cv_wireshark_have_tzname,
  92       [
  93         AC_TRY_LINK(
  94 [#include <time.h>
  95 #include <stdio.h>],
  96           [printf("%s", tzname[0]);],
  97           ac_cv_wireshark_have_tzname=yes,
  98           ac_cv_wireshark_have_tzname=no)
  99       ])
 100     if test $ac_cv_wireshark_have_tzname = yes; then
 101       AC_DEFINE(HAVE_TZNAME, 1, [Define if tzname array exists])
 102     fi
 103   fi
 104 ])
 105
 106
 107 #
 108 # AC_WIRESHARK_STRUCT_SA_LEN
 109 #
 110 dnl AC_STRUCT_ST_BLKSIZE extracted from the file in question,
 111 dnl "acspecific.m4" in GNU Autoconf 2.12, and turned into
 112 dnl AC_WIRESHARK_STRUCT_SA_LEN, which checks if "struct sockaddr"
 113 dnl has the 4.4BSD "sa_len" member, and defines HAVE_SA_LEN; that's
 114 dnl what's in this file.
 115 dnl Done by Guy Harris <guy@alum.mit.edu> on 1998-11-14.
 116
 117 dnl ### Checks for structure members
 118
 119 AC_DEFUN([AC_WIRESHARK_STRUCT_SA_LEN],
 120 [AC_CACHE_CHECK([for sa_len in struct sockaddr], ac_cv_wireshark_struct_sa_len,
 121 [AC_TRY_COMPILE([#include <sys/types.h>
 122 #include <sys/socket.h>], [struct sockaddr s; s.sa_len;],
 123 ac_cv_wireshark_struct_sa_len=yes, ac_cv_wireshark_struct_sa_len=no)])
 124 if test $ac_cv_wireshark_struct_sa_len = yes; then
 125   AC_DEFINE(HAVE_SA_LEN, 1, [Define if sa_len field exists in struct sockaddr])
 126 fi
 127 ])
 128
 129
 130 #
 131 # AC_WIRESHARK_IPV6_STACK
 132 #
 133 # By Jun-ichiro "itojun" Hagino, <itojun@iijlab.net>
 134 #
 135 AC_DEFUN([AC_WIRESHARK_IPV6_STACK],
 136 [
 137         v6type=unknown
 138         v6lib=none
 139
 140         AC_MSG_CHECKING([ipv6 stack type])
 141         for i in v6d toshiba kame inria zeta linux linux-glibc solaris8; do
 142                 case $i in
 143                 v6d)
 144                         AC_EGREP_CPP(yes, [
 145 #include </usr/local/v6/include/sys/types.h>
 146 #ifdef __V6D__
 147 yes
 148 #endif],
 149                                 [v6type=$i; v6lib=v6;
 150                                 v6libdir=/usr/local/v6/lib;
 151                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 152                         ;;
 153                 toshiba)
 154                         AC_EGREP_CPP(yes, [
 155 #include <sys/param.h>
 156 #ifdef _TOSHIBA_INET6
 157 yes
 158 #endif],
 159                                 [v6type=$i; v6lib=inet6;
 160                                 v6libdir=/usr/local/v6/lib;
 161                                 CFLAGS="-DINET6 $CFLAGS"])
 162                         ;;
 163                 kame)
 164                         AC_EGREP_CPP(yes, [
 165 #include <netinet/in.h>
 166 #ifdef __KAME__
 167 yes
 168 #endif],
 169                                 [v6type=$i; v6lib=inet6;
 170                                 v6libdir=/usr/local/v6/lib;
 171                                 CFLAGS="-DINET6 $CFLAGS"])
 172                         ;;
 173                 inria)
 174                         AC_EGREP_CPP(yes, [
 175 #include <netinet/in.h>
 176 #ifdef IPV6_INRIA_VERSION
 177 yes
 178 #endif],
 179                                 [v6type=$i; CFLAGS="-DINET6 $CFLAGS"])
 180                         ;;
 181                 zeta)
 182                         AC_EGREP_CPP(yes, [
 183 #include <sys/param.h>
 184 #ifdef _ZETA_MINAMI_INET6
 185 yes
 186 #endif],
 187                                 [v6type=$i; v6lib=inet6;
 188                                 v6libdir=/usr/local/v6/lib;
 189                                 CFLAGS="-DINET6 $CFLAGS"])
 190                         ;;
 191                 linux)
 192                         if test -d /usr/inet6; then
 193                                 v6type=$i
 194                                 v6lib=inet6
 195                                 v6libdir=/usr/inet6
 196                                 CFLAGS="-DINET6 $CFLAGS"
 197                         fi
 198                         ;;
 199                 linux-glibc)
 200                         AC_EGREP_CPP(yes, [
 201 #include <features.h>
 202 #if defined(__GLIBC__) && defined(__GLIBC_MINOR__)
 203 #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || __GLIBC__ > 2
 204 yes
 205 #endif
 206 #endif],
 207                         [v6type=$i; v6lib=inet6; CFLAGS="-DINET6 $CFLAGS"])
 208                         ;;
 209                 solaris8)
 210                         if test "`uname -s`" = "SunOS" && test "`uname -r`" = "5.8"; then
 211                                 v6type=$i
 212                                 v6lib=inet6
 213                                 [CFLAGS="-DINET6 -DSOLARIS8_INET6 $CFLAGS"]
 214                         fi
 215                         ;;
 216                 esac
 217                 if test "$v6type" != "unknown"; then
 218                         break
 219                 fi
 220         done
 221
 222         if test "$v6lib" != "none"; then
 223                 for dir in $v6libdir /usr/local/v6/lib /usr/local/lib; do
 224                         if test -d $dir -a -f $dir/lib$v6lib.a; then
 225                                 LIBS="-L$dir $LIBS -l$v6lib"
 226                                 break
 227                         fi
 228                 done
 229                 enable_ipv6="yes"
 230         else
 231                 enable_ipv6="no"
 232         fi
 233         AC_MSG_RESULT(["$v6type, $v6lib"])
 234 ])
 235
 236 #
 237 # AC_WIRESHARK_GETHOSTBY_LIB_CHECK
 238 #
 239 # Checks whether we need "-lnsl" to get "gethostby*()", which we use
 240 # in "resolv.c".
 241 #
 242 # Adapted from stuff in the AC_PATH_XTRA macro in "acspecific.m4" in
 243 # GNU Autoconf 2.13; the comment came from there.
 244 # Done by Guy Harris <guy@alum.mit.edu> on 2000-01-14.
 245 #
 246 AC_DEFUN([AC_WIRESHARK_GETHOSTBY_LIB_CHECK],
 247 [
 248     # msh@cis.ufl.edu says -lnsl (and -lsocket) are needed for his 386/AT,
 249     # to get the SysV transport functions.
 250     # chad@anasazi.com says the Pyramid MIS-ES running DC/OSx (SVR4)
 251     # needs -lnsl.
 252     # The nsl library prevents programs from opening the X display
 253     # on Irix 5.2, according to dickey@clark.net.
 254     AC_CHECK_FUNC(gethostbyname, ,
 255         AC_CHECK_LIB(nsl, gethostbyname, NSL_LIBS="-lnsl"))
 256     AC_SUBST(NSL_LIBS)
 257 ])
 258
 259 #
 260 # AC_WIRESHARK_SOCKET_LIB_CHECK
 261 #
 262 # Checks whether we need "-lsocket" to get "socket()", which is used
 263 # by libpcap on some platforms - and, in effect, "gethostby*()" on
 264 # most if not all platforms (so that it can use NIS or DNS or...
 265 # to look up host names).
 266 #
 267 # Adapted from stuff in the AC_PATH_XTRA macro in "acspecific.m4" in
 268 # GNU Autoconf 2.13; the comment came from there.
 269 # Done by Guy Harris <guy@alum.mit.edu> on 2000-01-14.
 270 #
 271 # We use "connect" because that's what AC_PATH_XTRA did.
 272 #
 273 AC_DEFUN([AC_WIRESHARK_SOCKET_LIB_CHECK],
 274 [
 275     # lieder@skyler.mavd.honeywell.com says without -lsocket,
 276     # socket/setsockopt and other routines are undefined under SCO ODT
 277     # 2.0.  But -lsocket is broken on IRIX 5.2 (and is not necessary
 278     # on later versions), says simon@lia.di.epfl.ch: it contains
 279     # gethostby* variants that don't use the nameserver (or something).
 280     # -lsocket must be given before -lnsl if both are needed.
 281     # We assume that if connect needs -lnsl, so does gethostbyname.
 282     AC_CHECK_FUNC(connect, ,
 283       AC_CHECK_LIB(socket, connect, SOCKET_LIBS="-lsocket",
 284                 AC_MSG_ERROR(Function 'socket' not found.), $NSL_LIBS))
 285     AC_SUBST(SOCKET_LIBS)
 286 ])
 287
 288 #
 289 # AC_WIRESHARK_BREAKLOOP_TRY_LINK
 290 #
 291 AC_DEFUN([AC_WIRESHARK_PCAP_BREAKLOOP_TRY_LINK],
 292 [
 293   AC_LINK_IFELSE(
 294   [
 295       AC_LANG_SOURCE(
 296       [[
 297 #       include <pcap.h>
 298         int main(void)
 299         {
 300           pcap_t  *pct = NULL;
 301           pcap_breakloop(pct);
 302           return 0;
 303         }
 304       ]])
 305   ],
 306   [
 307     ws_breakloop_compiled=yes
 308   ],
 309   [
 310     ws_breakloop_compiled=no
 311   ])
 312 ])
 313
 314
 315
 316 #
 317 # AC_WIRESHARK_PCAP_CHECK
 318 #
 319 AC_DEFUN([AC_WIRESHARK_PCAP_CHECK],
 320 [
 321         if test -z "$pcap_dir"
 322         then
 323           # Pcap header checks
 324           # XXX need to set a var AC_CHECK_HEADER(pcap.h,,)
 325
 326           #
 327           # The user didn't specify a directory in which libpcap resides.
 328           # First, look for a pcap-config script.
 329           #
 330           AC_PATH_PROG(PCAP_CONFIG, pcap-config)
 331
 332           if test -n "$PCAP_CONFIG" ; then
 333             #
 334             # Found it.
 335             #
 336             # Now check whether it's the libpcap 1.0 version, which
 337             # put a space after "-L" - on some platforms, that doesn't
 338             # work.
 339             #
 340             AC_MSG_CHECKING(for broken pcap-config)
 341             case "`\"$PCAP_CONFIG\" --libs`" in
 342
 343             "-L "*)
 344               #
 345               # Space after -L.  Pretend pcap-config doesn't exist.
 346               #
 347               AC_MSG_RESULT(yes)
 348               PCAP_CONFIG=""
 349               ;;
 350
 351             *)
 352               #
 353               # No space after -L.
 354               #
 355               AC_MSG_RESULT(no)
 356               ;;
 357             esac
 358           fi
 359           if test -n "$PCAP_CONFIG" ; then
 360             #
 361             # Found it, and it's usable; use it to get the include flags
 362             # for libpcap.
 363             #
 364             CFLAGS="$CFLAGS `\"$PCAP_CONFIG\" --cflags`"
 365             CPPFLAGS="$CPPFLAGS `\"$PCAP_CONFIG\" --cflags`"
 366           else
 367             #
 368             # Didn't find it; we have to look for libpcap ourselves.
 369             # We assume that the current library search path will work,
 370             # but we may have to look for the header in a "pcap"
 371             # subdirectory of "/usr/include" or "/usr/local/include",
 372             # as some systems apparently put "pcap.h" in a "pcap"
 373             # subdirectory, and we also check "$prefix/include" - and
 374             # "$prefix/include/pcap", in case $prefix is set to
 375             # "/usr/include" or "/usr/local/include".
 376             #
 377             # XXX - should we just add "$prefix/include" to the include
 378             # search path and "$prefix/lib" to the library search path?
 379             #
 380             AC_MSG_CHECKING(for extraneous pcap header directories)
 381             found_pcap_dir=""
 382             pcap_dir_list="/usr/include/pcap $prefix/include/pcap $prefix/include"
 383             if test "x$ac_cv_enable_usr_local" = "xyes" ; then
 384               pcap_dir_list="$pcap_dir_list /usr/local/include/pcap"
 385             fi
 386             for pcap_dir in $pcap_dir_list
 387             do
 388               if test -d $pcap_dir ; then
 389                 if test x$pcap_dir != x/usr/include -a x$pcap_dir != x/usr/local/include ; then
 390                     CFLAGS="$CFLAGS -I$pcap_dir"
 391                     CPPFLAGS="$CPPFLAGS -I$pcap_dir"
 392                 fi
 393                 found_pcap_dir=" $found_pcap_dir -I$pcap_dir"
 394                 break
 395               fi
 396             done
 397
 398             if test "$found_pcap_dir" != "" ; then
 399               AC_MSG_RESULT(found --$found_pcap_dir added to CFLAGS)
 400             else
 401               AC_MSG_RESULT(not found)
 402             fi
 403           fi
 404         else
 405           #
 406           # The user specified a directory in which libpcap resides,
 407           # so add the "include" subdirectory of that directory to
 408           # the include file search path and the "lib" subdirectory
 409           # of that directory to the library search path.
 410           #
 411           # XXX - if there's also a libpcap in a directory that's
 412           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 413           # make us find the version in the specified directory,
 414           # as the compiler and/or linker will search that other
 415           # directory before it searches the specified directory.
 416           #
 417           CFLAGS="$CFLAGS -I$pcap_dir/include"
 418           CPPFLAGS="$CPPFLAGS -I$pcap_dir/include"
 419           AC_WIRESHARK_ADD_DASH_L(LDFLAGS, $pcap_dir/lib)
 420         fi
 421
 422         # Pcap header check
 423         AC_CHECK_HEADER(pcap.h,,
 424             AC_MSG_ERROR([[Header file pcap.h not found; if you installed libpcap
 425 from source, did you also do \"make install-incl\", and if you installed a
 426 binary package of libpcap, is there also a developer's package of libpcap,
 427 and did you also install that package?]]))
 428
 429         if test -n "$PCAP_CONFIG" ; then
 430           #
 431           # We have pcap-config; we assume that means we have libpcap
 432           # installed and that pcap-config will tell us whatever
 433           # libraries libpcap needs.
 434           #
 435           if test x$enable_static = xyes; then
 436             PCAP_LIBS="`\"$PCAP_CONFIG\" --libs --static`"
 437           else
 438             PCAP_LIBS="`\"$PCAP_CONFIG\" --libs`"
 439           fi
 440           AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
 441         else
 442           #
 443           # Check to see if we find "pcap_open_live" in "-lpcap".
 444           # Also check for various additional libraries that libpcap might
 445           # require.
 446           #
 447           AC_CHECK_LIB(pcap, pcap_open_live,
 448             [
 449               PCAP_LIBS=-lpcap
 450               AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
 451             ], [
 452               ac_wireshark_extras_found=no
 453               ac_save_LIBS="$LIBS"
 454               for extras in "-lcfg -lodm" "-lpfring"
 455               do
 456                 AC_MSG_CHECKING([for pcap_open_live in -lpcap with $extras])
 457                 LIBS="-lpcap $extras"
 458                 #
 459                 # XXX - can't we use AC_CHECK_LIB here?
 460                 #
 461                 AC_TRY_LINK(
 462                     [
 463 #       include <pcap.h>
 464                     ],
 465                     [
 466         pcap_open_live(NULL, 0, 0, 0, NULL);
 467                     ],
 468                     [
 469                         ac_wireshark_extras_found=yes
 470                         AC_MSG_RESULT([yes])
 471                         PCAP_LIBS="-lpcap $extras"
 472                         AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
 473                     ],
 474                     [
 475                         AC_MSG_RESULT([no])
 476                     ])
 477                 if test x$ac_wireshark_extras_found = xyes
 478                 then
 479                     break
 480                 fi
 481               done
 482               if test x$ac_wireshark_extras_found = xno
 483               then
 484                 AC_MSG_ERROR([Can't link with library libpcap.])
 485               fi
 486               LIBS=$ac_save_LIBS
 487             ], $SOCKET_LIBS $NSL_LIBS)
 488         fi
 489         AC_SUBST(PCAP_LIBS)
 490
 491         #
 492         # Check whether various variables and functions are defined by
 493         # libpcap.
 494         #
 495         ac_save_LIBS="$LIBS"
 496         AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 497         LIBS="$PCAP_LIBS $SOCKET_LIBS $NSL_LIBS $LIBS"
 498         AC_TRY_LINK(
 499            [
 500 #       include <stdio.h>
 501         extern char *pcap_version;
 502            ],
 503            [
 504         printf ("%s\n", pcap_version);
 505            ],
 506            ac_cv_pcap_version_defined=yes,
 507            ac_cv_pcap_version_defined=no,
 508            [echo $ac_n "cross compiling; assumed OK... $ac_c"])
 509         if test "$ac_cv_pcap_version_defined" = yes ; then
 510                 AC_MSG_RESULT(yes)
 511                 AC_DEFINE(HAVE_PCAP_VERSION, 1, [Define if libpcap version is known])
 512         else
 513                 AC_MSG_RESULT(no)
 514         fi
 515         AC_CHECK_FUNCS(pcap_open_dead pcap_freecode)
 516         #
 517         # pcap_breakloop may be present in the library but not declared
 518         # in the pcap.h header file.  If it's not declared in the header
 519         # file, attempts to use it will get warnings, and, if we're
 520         # building with warnings treated as errors, that warning will
 521         # cause compilation to fail.
 522         #
 523         # We are therefore first testing whether the function is present
 524         # and then, if we're compiling with warnings as errors, testing
 525         # whether it is usable.  It is usable if it compiles without
 526         # a -Wimplicit warning (the "compile with warnings as errors"
 527         # option requires GCC). If it is not usable, we fail and tell
 528         # the user that the pcap.h header needs to be updated.
 529         #
 530         # Ceteris paribus, this should only happen with Mac OS X 10.3[.x] which
 531         # can have an up-to-date pcap library without the corresponding pcap
 532         # header.
 533         #
 534         # However, it might also happen on some others OSes with some erroneous
 535         # system manipulations where multiple versions of libcap might co-exist
 536         # e.g. hand made symbolic link from libpcap.so -> libpcap.so.0.8 but
 537         # having the pcap header version 0.7.
 538         #
 539         AC_MSG_CHECKING([whether pcap_breakloop is present])
 540         ac_CFLAGS_saved="$CFLAGS"
 541         AC_WIRESHARK_PCAP_BREAKLOOP_TRY_LINK
 542         if test "x$ws_breakloop_compiled" = "xyes"; then
 543           AC_MSG_RESULT(yes)
 544           AC_DEFINE(HAVE_PCAP_BREAKLOOP, 1, [Define if pcap_breakloop is known])
 545           if test "x$with_warnings_as_errors" = "xyes"; then
 546             AC_MSG_CHECKING([whether pcap_breakloop is usable])
 547             CFLAGS="$CFLAGS -Werror -Wimplicit"
 548             AC_WIRESHARK_PCAP_BREAKLOOP_TRY_LINK
 549             if test "x$ws_breakloop_compiled" = "xyes"; then
 550               AC_MSG_RESULT(yes)
 551             else
 552               AC_MSG_RESULT(no)
 553               AC_MSG_ERROR(
 554 [Your pcap library is more recent than your pcap header.
 555 As you are building with compiler warnings treated as errors, Wireshark
 556 won't be able to use functions not declared in that header.
 557 If you wish to build with compiler warnings treated as errors, You should
 558 install a newer version of the header file.])
 559             fi
 560             CFLAGS="$ac_CFLAGS_saved"
 561           fi
 562         else
 563           AC_MSG_RESULT(no)
 564         fi
 565
 566         #
 567         # Later versions of Mac OS X 10.3[.x] ship a pcap.h that
 568         # doesn't define pcap_if_t but ship an 0.8[.x] libpcap,
 569         # so the library has "pcap_findalldevs()", but pcap.h
 570         # doesn't define "pcap_if_t" so you can't actually *use*
 571         # "pcap_findalldevs()".
 572         #
 573         # That even appears to be true of systems shipped with
 574         # 10.3.4, so it doesn't appear only to be a case of
 575         # Software Update not updating header files.
 576         #
 577         # (You can work around this by installing the 0.8 header
 578         # files.)
 579         #
 580         AC_CACHE_CHECK([whether pcap_findalldevs is present and usable],
 581           [ac_cv_func_pcap_findalldevs],
 582           [
 583             AC_LINK_IFELSE(
 584               [
 585                 AC_LANG_SOURCE(
 586                   [[
 587                     #include <pcap.h>
 588                     main()
 589                     {
 590                       pcap_if_t *devpointer;
 591                       char errbuf[1];
 592
 593                       pcap_findalldevs(&devpointer, errbuf);
 594                     }
 595                   ]])
 596               ],
 597               [
 598                 ac_cv_func_pcap_findalldevs=yes
 599               ],
 600               [
 601                 ac_cv_func_pcap_findalldevs=no
 602               ])
 603           ])
 604         #
 605         # Don't check for other new routines that showed up after
 606         # "pcap_findalldevs()" if we don't have a usable
 607         # "pcap_findalldevs()", so we don't end up using them if the
 608         # "pcap.h" is crufty and old and doesn't declare them.
 609         #
 610         if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 611           AC_DEFINE(HAVE_PCAP_FINDALLDEVS, 1,
 612            [Define to 1 if you have the `pcap_findalldevs' function and a pcap.h that declares pcap_if_t.])
 613           AC_CHECK_FUNCS(pcap_datalink_val_to_name pcap_datalink_name_to_val)
 614           AC_CHECK_FUNCS(pcap_datalink_val_to_description)
 615           AC_CHECK_FUNCS(pcap_list_datalinks pcap_set_datalink pcap_lib_version)
 616           AC_CHECK_FUNCS(pcap_get_selectable_fd pcap_free_datalinks)
 617           AC_CHECK_FUNCS(pcap_create bpf_image)
 618         fi
 619         LIBS="$ac_save_LIBS"
 620 ])
 621
 622 AC_DEFUN([AC_WIRESHARK_PCAP_REMOTE_CHECK],
 623 [
 624     ac_save_LIBS="$LIBS"
 625     LIBS="$PCAP_LIBS $SOCKET_LIBS $NSL_LIBS $LIBS"
 626     AC_DEFINE(HAVE_REMOTE, 1, [Define to 1 to enable remote
 627               capturing feature in WinPcap library])
 628     AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex pcap_createsrcstr)
 629     if test $ac_cv_func_pcap_open = "yes" -a \
 630             $ac_cv_func_pcap_findalldevs_ex = "yes" -a \
 631             $ac_cv_func_pcap_createsrcstr = "yes" ; then
 632         AC_DEFINE(HAVE_PCAP_REMOTE, 1,
 633             [Define to 1 if you have WinPcap remote capturing support and prefer to use these new API features.])
 634     fi
 635     AC_CHECK_FUNCS(pcap_setsampling)
 636     LIBS="$ac_save_LIBS"
 637 ])
 638
 639 #
 640 # AC_WIRESHARK_ZLIB_CHECK
 641 #
 642 AC_DEFUN([AC_WIRESHARK_ZLIB_CHECK],
 643 [
 644         if test "x$zlib_dir" != "x"
 645         then
 646           #
 647           # The user specified a directory in which zlib resides,
 648           # so add the "include" subdirectory of that directory to
 649           # the include file search path and the "lib" subdirectory
 650           # of that directory to the library search path.
 651           #
 652           # XXX - if there's also a zlib in a directory that's
 653           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 654           # make us find the version in the specified directory,
 655           # as the compiler and/or linker will search that other
 656           # directory before it searches the specified directory.
 657           #
 658           wireshark_save_CFLAGS="$CFLAGS"
 659           CFLAGS="$CFLAGS -I$zlib_dir/include"
 660           wireshark_save_CPPFLAGS="$CPPFLAGS"
 661           CPPFLAGS="$CPPFLAGS -I$zlib_dir/include"
 662           wireshark_save_LIBS="$LIBS"
 663           AC_WIRESHARK_ADD_DASH_L(LIBS, $zlib_dir/lib)
 664         fi
 665
 666         #
 667         # Make sure we have "zlib.h".  If we don't, it means we probably
 668         # don't have zlib, so don't use it.
 669         #
 670         AC_CHECK_HEADER(zlib.h,,
 671           [
 672             if test "x$zlib_dir" != "x"
 673             then
 674               #
 675               # The user used "--with-zlib=" to specify a directory
 676               # containing zlib, but we didn't find the header file
 677               # there; that either means they didn't specify the
 678               # right directory or are confused about whether zlib
 679               # is, in fact, installed.  Report the error and give up.
 680               #
 681               AC_MSG_ERROR([zlib header not found in directory specified in --with-zlib])
 682             else
 683               if test "x$want_zlib" = "xyes"
 684               then
 685                 #
 686                 # The user tried to force us to use the library, but we
 687                 # couldn't find the header file; report an error.
 688                 #
 689                 AC_MSG_ERROR(Header file zlib.h not found.)
 690               else
 691                 #
 692                 # We couldn't find the header file; don't use the
 693                 # library, as it's probably not present.
 694                 #
 695                 want_zlib=no
 696               fi
 697             fi
 698           ])
 699
 700         if test "x$want_zlib" != "xno"
 701         then
 702                 #
 703                 # Well, we at least have the zlib header file.
 704                 # We link with zlib to support uncompression of
 705                 # gzipped network traffic, e.g. in an HTTP request
 706                 # or response body.
 707                 #
 708                 if test "x$zlib_dir" != "x"
 709                 then
 710                         #
 711                         # Put the "-I" and "-L" flags for zlib at
 712                         # the beginning of CFLAGS, CPPFLAGS, and
 713                         # LIBS.
 714                         #
 715                         LIBS=""
 716                         AC_WIRESHARK_ADD_DASH_L(LIBS, $zlib_dir/lib)
 717                         LIBS="$LIBS -lz $wireshark_save_LIBS"
 718                 else
 719                         LIBS="-lz $LIBS"
 720                 fi
 721                 AC_DEFINE(HAVE_LIBZ, 1, [Define to use libz library])
 722
 723                 #
 724                 # Check for "inflatePrime()" in zlib, which we need
 725                 # in order to read compressed capture files.
 726                 #
 727                 AC_CHECK_FUNCS(inflatePrime)
 728
 729                 if test "x$ac_cv_func_inflatePrime" = "xyes" ; then
 730                         #
 731                         # Now check for "inflatePrime()" in zlib when
 732                         # linking with the linker flags for GTK+
 733                         # applications; people often grab XFree86 source
 734                         # and build and install it on their systems,
 735                         # and they appear sometimes to misconfigure
 736                         # XFree86 so that, even on systems with zlib,
 737                         # it assumes there is no zlib, so the XFree86
 738                         # build process builds and installs its
 739                         # own zlib in the X11 library directory.
 740                         #
 741                         # The zlib in at least some versions of XFree86
 742                         # is an older version that may lack "inflatePrime()",
 743                         # and that's the zlib with which Wireshark gets
 744                         # linked, so the build of Wireshark fails.
 745                         #
 746                         AC_MSG_CHECKING([for inflatePrime missing when linking with X11])
 747                         AC_TRY_LINK_FUNC(inflatePrime, AC_MSG_RESULT(no),
 748                           [
 749                             AC_MSG_RESULT(yes)
 750                             AC_MSG_ERROR(old zlib found when linking with X11 - get rid of old zlib.)
 751                           ])
 752                 fi
 753         else
 754                 #
 755                 # Restore the versions of CFLAGS, CPPFLAGS,
 756                 # and LIBS before we added the "-with-zlib="
 757                 # directory, as we didn't actually find
 758                 # zlib there.
 759                 #
 760                 CFLAGS="$wireshark_save_CFLAGS"
 761                 CPPFLAGS="$wireshark_save_CPPFLAGS"
 762                 LIBS="$wireshark_save_LIBS"
 763                 want_zlib=no
 764         fi
 765 ])
 766
 767 #
 768 # AC_WIRESHARK_LIBLUA_CHECK
 769 #
 770 AC_DEFUN([AC_WIRESHARK_LIBLUA_CHECK],[
 771
 772         if test "x$lua_dir" != "x"
 773         then
 774                 #
 775                 # The user specified a directory in which liblua resides,
 776                 # so add the "include" subdirectory of that directory to
 777                 # the include file search path and the "lib" subdirectory
 778                 # of that directory to the library search path.
 779                 #
 780                 # XXX - if there's also a liblua in a directory that's
 781                 # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 782                 # make us find the version in the specified directory,
 783                 # as the compiler and/or linker will search that other
 784                 # directory before it searches the specified directory.
 785                 #
 786                 wireshark_save_CFLAGS="$CFLAGS"
 787                 CFLAGS="$CFLAGS -I$lua_dir/include"
 788                 wireshark_save_CPPFLAGS="$CPPFLAGS"
 789                 CPPFLAGS="$CPPFLAGS -I$lua_dir/include"
 790                 wireshark_save_LIBS="$LIBS"
 791                 LIBS="$LIBS -L$lua_dir/lib -llua -lm"
 792                 wireshark_save_LDFLAGS="$LDFLAGS"
 793                 LDFLAGS="$LDFLAGS -L$lua_dir/lib"
 794         else
 795                 #
 796                 # The user specified no directory in which liblua resides,
 797                 # so just add "-llua -lliblua" to the used libs.
 798                 #
 799                 wireshark_save_CFLAGS="$CFLAGS"
 800                 wireshark_save_CPPFLAGS="$CPPFLAGS"
 801                 wireshark_save_LDFLAGS="$LDFLAGS"
 802                 wireshark_save_LIBS="$LIBS"
 803                 LIBS="$LIBS -llua -lm"
 804         fi
 805
 806         #
 807         # Make sure we have "lua.h", "lualib.h" and "lauxlib.h".  If we don't, it means we probably
 808         # don't have liblua, so don't use it.
 809         #
 810         AC_CHECK_HEADERS(lua.h lualib.h lauxlib.h,,
 811         [
 812                 AC_CHECK_HEADERS(lua5.1/lua.h lua5.1/lualib.h lua5.1/lauxlib.h,
 813                 [
 814                         if test "x$lua_dir" != "x"
 815                         then
 816                                 LUA_INCLUDES="-I$lua_dir/include/lua5.1"
 817                         else
 818                                 #
 819                                 # The user didn't specify a directory in which liblua resides;
 820                                 # we must look for the headers in a "lua5.1" subdirectory of
 821                                 # "/usr/include", "/usr/local/include", or "$prefix/include"
 822                                 # as some systems apparently put the headers in a "lua5.1"
 823                                 # subdirectory.
 824                                 AC_MSG_CHECKING(for extraneous lua header directories)
 825                                 found_lua_dir=""
 826                                 lua_dir_list="/usr/include/lua5.1 $prefix/include/lua5.1"
 827                                 if test "x$ac_cv_enable_usr_local" = "xyes"
 828                                 then
 829                                         lua_dir_list="$lua_dir_list /usr/local/include/lua5.1"
 830                                 fi
 831                                 for lua_dir_ent in $lua_dir_list
 832                                 do
 833                                         if test -d $lua_dir_ent
 834                                         then
 835                                                 LUA_INCLUDES="-I$lua_dir_ent"
 836                                                 found_lua_dir="$lua_dir_ent"
 837                                                 break
 838                                         fi
 839                                 done
 840
 841                                 if test "x$found_lua_dir" != "x"
 842                                 then
 843                                         AC_MSG_RESULT(found -- $found_lua_dir)
 844                                 else
 845                                         AC_MSG_RESULT(not found)
 846                                         #
 847                                         # Restore the versions of CFLAGS, CPPFLAGS,
 848                                         # LDFLAGS, and LIBS before we added the
 849                                         # "--with-lua=" directory, as we didn't
 850                                         # actually find lua there.
 851                                         #
 852                                         CFLAGS="$wireshark_save_CFLAGS"
 853                                         CPPFLAGS="$wireshark_save_CPPFLAGS"
 854                                         LDFLAGS="$wireshark_save_LDFLAGS"
 855                                         LIBS="$wireshark_save_LIBS"
 856                                         LUA_LIBS=""
 857                                         if test "x$want_lua" = "xyes"
 858                                         then
 859                                                 # we found lua5.1/lua.h, but we don't know which include dir contains it
 860                                                 AC_MSG_ERROR(Header file lua.h was found as lua5.1/lua.h but we can't locate the include directory. Please set the DIR for the --with-lua configure parameter.)
 861                                         else
 862                                                 #
 863                                                 # We couldn't find the header file; don't use the
 864                                                 # library, as it's probably not present.
 865                                                 #
 866                                                 want_lua=no
 867                                         fi
 868                                 fi
 869                         fi
 870                 ],
 871                 [
 872                         #
 873                         # Restore the versions of CFLAGS, CPPFLAGS,
 874                         # LDFLAGS, and LIBS before we added the
 875                         # "--with-lua=" directory, as we didn't
 876                         # actually find lua there.
 877                         #
 878                         CFLAGS="$wireshark_save_CFLAGS"
 879                         CPPFLAGS="$wireshark_save_CPPFLAGS"
 880                         LDFLAGS="$wireshark_save_LDFLAGS"
 881                         LIBS="$wireshark_save_LIBS"
 882                         LUA_LIBS=""
 883                         if test "x$lua_dir" != "x"
 884                         then
 885                                 #
 886                                 # The user used "--with-lua=" to specify a directory
 887                                 # containing liblua, but we didn't find the header file
 888                                 # there; that either means they didn't specify the
 889                                 # right directory or are confused about whether liblua
 890                                 # is, in fact, installed.  Report the error and give up.
 891                                 #
 892                                 AC_MSG_ERROR([liblua header not found in directory specified in --with-lua])
 893                         else
 894                                 if test "x$want_lua" = "xyes"
 895                                 then
 896                                         #
 897                                         # The user tried to force us to use the library, but we
 898                                         # couldn't find the header file; report an error.
 899                                         #
 900                                         AC_MSG_ERROR(Header file lua.h not found.)
 901                                 else
 902                                         #
 903                                         # We couldn't find the header file; don't use the
 904                                         # library, as it's probably not present.
 905                                         #
 906                                         want_lua=no
 907                                 fi
 908                         fi
 909                 ])
 910         ])
 911
 912         if test "x$want_lua" != "xno"
 913         then
 914                 #
 915                 # Well, we at least have the lua header file.
 916                 #
 917                 # let's check if the libs are there
 918                 #
 919
 920                 # At least on Suse 9.3 systems, liblualib needs linking
 921                 # against libm.
 922                 LIBS="$LIBS $LUA_LIBS -lm"
 923
 924                 AC_CHECK_LIB(lua, luaL_register,
 925                 [
 926                     #
 927                     #  Lua 5.1 found
 928                     #
 929                         if test "x$lua_dir" != "x"
 930                         then
 931                                 #
 932                                 # Put the "-I" and "-L" flags for lua at
 933                                 # the beginning of CFLAGS, CPPFLAGS,
 934                                 # LDFLAGS, and LIBS.
 935                                 #
 936                                 LUA_LIBS="-L$lua_dir/lib -llua -lm"
 937                                 LUA_INCLUDES="-I$lua_dir/include"
 938                         else
 939                                 LUA_LIBS="-llua -lm"
 940                                 LUA_INCLUDES=""
 941                         fi
 942                         AC_DEFINE(HAVE_LUA_5_1, 1, [Define to use Lua 5.1])
 943                         want_lua=yes
 944
 945                 ],[
 946                         #
 947                         # We could not find the libs, maybe we have version number in the lib name
 948                         #
 949
 950                         LIBS="$wireshark_save_LIBS -llua5.1 -lm"
 951
 952                         AC_CHECK_LIB(lua5.1, luaL_register,
 953                         [
 954                             #
 955                             #  Lua 5.1 found
 956                             #
 957                             LUA_LIBS=" -llua5.1 -lm"
 958                             AC_DEFINE(HAVE_LUA_5_1, 1, [Define to use Lua 5.1])
 959                             want_lua=yes
 960                         ],[
 961                                 #
 962                                 # Restore the versions of CFLAGS, CPPFLAGS,
 963                                 # LDFLAGS, and LIBS before we added the
 964                                 # "--with-lua=" directory, as we didn't
 965                                 # actually find lua there.
 966                                 #
 967                                 CFLAGS="$wireshark_save_CFLAGS"
 968                                 CPPFLAGS="$wireshark_save_CPPFLAGS"
 969                                 LDFLAGS="$wireshark_save_LDFLAGS"
 970                                 LIBS="$wireshark_save_LIBS"
 971                                 LUA_LIBS=""
 972                                 # User requested --with-lua but it isn't available
 973                                 if test "x$want_lua" = "xyes"
 974                                 then
 975                                         AC_MSG_ERROR(Linking with liblua failed.)
 976                                 fi
 977                                 want_lua=no
 978                         ])
 979                 ])
 980
 981         CFLAGS="$wireshark_save_CFLAGS"
 982         CPPFLAGS="$wireshark_save_CPPFLAGS"
 983         LDFLAGS="$wireshark_save_LDFLAGS"
 984         LIBS="$wireshark_save_LIBS"
 985         AC_SUBST(LUA_LIBS)
 986         AC_SUBST(LUA_INCLUDES)
 987
 988         fi
 989 ])
 990
 991 #
 992 # AC_WIRESHARK_LIBPORTAUDIO_CHECK
 993 #
 994 AC_DEFUN([AC_WIRESHARK_LIBPORTAUDIO_CHECK],[
 995
 996         if test "x$portaudio_dir" != "x"
 997         then
 998                 #
 999                 # The user specified a directory in which libportaudio
1000                 # resides, so add the "include" subdirectory of that directory to
1001                 # the include file search path and the "lib" subdirectory
1002                 # of that directory to the library search path.
1003                 #
1004                 # XXX - if there's also a libportaudio in a directory that's
1005                 # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
1006                 # make us find the version in the specified directory,
1007                 # as the compiler and/or linker will search that other
1008                 # directory before it searches the specified directory.
1009                 #
1010                 wireshark_save_CFLAGS="$CFLAGS"
1011                 CFLAGS="$CFLAGS -I$portaudio_dir/include"
1012                 wireshark_save_CPPFLAGS="$CPPFLAGS"
1013                 CPPFLAGS="$CPPFLAGS -I$portaudio_dir/include"
1014                 wireshark_save_LIBS="$LIBS"
1015                 LIBS="$LIBS -L$portaudio_dir/lib -lportaudio"
1016                 wireshark_save_LDFLAGS="$LDFLAGS"
1017                 LDFLAGS="$LDFLAGS -L$portaudio_dir/lib"
1018         else
1019                 #
1020                 # The user specified no directory in which libportaudio resides,
1021                 # so just add "-lportaudio" to the used libs.
1022                 #
1023                 wireshark_save_CFLAGS="$CFLAGS"
1024                 wireshark_save_CPPFLAGS="$CPPFLAGS"
1025                 wireshark_save_LDFLAGS="$LDFLAGS"
1026                 wireshark_save_LIBS="$LIBS"
1027                 LIBS="$LIBS -lportaudio"
1028         fi
1029
1030         #
1031         # Make sure we have "portaudio.h".  If we don't, it means we probably
1032         # don't have libportaudio, so don't use it.
1033         #
1034         AC_CHECK_HEADERS(portaudio.h,,
1035         [
1036                 if test "x$portaudio_dir" != "x"
1037                 then
1038                         #
1039                         # The user used "--with-portaudio=" to specify a directory
1040                         # containing libportaudio, but we didn't find the header file
1041                         # there; that either means they didn't specify the
1042                         # right directory or are confused about whether libportaudio
1043                         # is, in fact, installed.  Report the error and give up.
1044                         #
1045                         AC_MSG_ERROR([libportaudio header not found in directory specified in --with-portaudio])
1046                 else
1047                         CFLAGS="$wireshark_save_CFLAGS"
1048                         CPPFLAGS="$wireshark_save_CPPFLAGS"
1049                         LDFLAGS="$wireshark_save_LDFLAGS"
1050                         LIBS="$wireshark_save_LIBS"
1051                         PORTAUDIO_LIBS=""
1052                         if test "x$want_portaudio" = "xyes"
1053                         then
1054                                 #
1055                                 # The user tried to force us to use the library, but we
1056                                 # couldn't find the header file; report an error.
1057                                 #
1058                                 AC_MSG_ERROR(Header file portaudio.h not found.)
1059                         else
1060                                 #
1061                                 # We couldn't find the header file; don't use the
1062                                 # library, as it's probably not present.
1063                                 #
1064                                 want_portaudio=no
1065                         fi
1066                 fi
1067         ])
1068
1069         #
1070         # Check whether we have the right version of portaudio
1071         #
1072         if test "x$want_portaudio" != "xno"
1073         then
1074                 AC_CHECK_TYPE(PortAudioStream,
1075                 AC_DEFINE(PORTAUDIO_API_1, 1, [Define if we are using version of of the Portaudio library API]),
1076                 ,
1077                 [#include <portaudio.h>])
1078         fi
1079
1080         if test "x$want_portaudio" != "xno"
1081         then
1082                 #
1083                 # Well, we at least have the portaudio header file.
1084                 #
1085                 # let's check if the libs are there
1086                 #
1087
1088                 AC_CHECK_LIB(portaudio, Pa_Initialize,
1089                 [
1090                         if test "x$portaudio_dir" != "x"
1091                         then
1092                                 #
1093                                 # Put the "-I" and "-L" flags for portaudio at
1094                                 # the beginning of CFLAGS, CPPFLAGS,
1095                                 # LDFLAGS, and LIBS.
1096                                 #
1097                                 PORTAUDIO_LIBS="-L$portaudio_dir/lib -lportaudio"
1098                                 PORTAUDIO_INCLUDES="-I$portaudio_dir/include"
1099                         else
1100                                 PORTAUDIO_LIBS="-lportaudio"
1101                                 PORTAUDIO_INCLUDES=""
1102                         fi
1103                         AC_DEFINE(HAVE_LIBPORTAUDIO, 1, [Define to use libportaudio library])
1104                         want_portaudio=yes
1105                 ],[
1106                         #
1107                         # Restore the versions of CFLAGS, CPPFLAGS,
1108                         # LDFLAGS, and LIBS before we added the
1109                         # "--with-portaudio=" directory, as we didn't
1110                         # actually find portaudio there.
1111                         #
1112                         CFLAGS="$wireshark_save_CFLAGS"
1113                         CPPFLAGS="$wireshark_save_CPPFLAGS"
1114                         LDFLAGS="$wireshark_save_LDFLAGS"
1115                         LIBS="$wireshark_save_LIBS"
1116                         PORTAUDIO_LIBS=""
1117                         # User requested --with-portaudio but it isn't available
1118                         if test "x$want_portaudio" = "xyes"
1119                         then
1120                                 AC_MSG_ERROR(Linking with libportaudio failed.)
1121                         fi
1122                         want_portaudio=no
1123                 ])
1124
1125         CFLAGS="$wireshark_save_CFLAGS"
1126         CPPFLAGS="$wireshark_save_CPPFLAGS"
1127         LDFLAGS="$wireshark_save_LDFLAGS"
1128         LIBS="$wireshark_save_LIBS"
1129         AC_SUBST(PORTAUDIO_LIBS)
1130         AC_SUBST(PORTAUDIO_INCLUDES)
1131
1132         fi
1133 ])
1134
1135 #
1136 # AC_WIRESHARK_RPM_CHECK
1137 # Looks for the rpm program, and checks to see if we can redefine "_topdir".
1138 #
1139 AC_DEFUN([AC_WIRESHARK_RPM_CHECK],
1140 [
1141         AC_CHECK_PROG(ac_cv_wireshark_have_rpm, rpm, "yes", "no")
1142         if test "x$ac_cv_wireshark_have_rpm" = "xyes"; then
1143                 rpm --define '_topdir /tmp' > /dev/null 2>&1
1144                 AC_MSG_CHECKING(to see if we can redefine _topdir)
1145                 if test $? -eq 0 ; then
1146                         AC_MSG_RESULT(yes)
1147                         HAVE_RPM=yes
1148                 else
1149                         AC_MSG_RESULT(no.  You'll have to build packages manually.)
1150                         HAVE_RPM=no
1151                 fi
1152         fi
1153 ])
1154
1155 #
1156 # AC_WIRESHARK_GNU_SED_CHECK
1157 # Checks if GNU sed is the first sed in PATH.
1158 #
1159 AC_DEFUN([AC_WIRESHARK_GNU_SED_CHECK],
1160 [
1161         AC_MSG_CHECKING(for GNU sed as first sed in PATH)
1162         if  ( sh -c "sed --version" </dev/null 2> /dev/null | grep "GNU sed" 2>&1 > /dev/null ) ;  then
1163                 AC_MSG_RESULT(yes)
1164                 HAVE_GNU_SED=yes
1165         else
1166                 AC_MSG_RESULT(no)
1167                 HAVE_GNU_SED=no
1168         fi
1169 ])
1170
1171 #
1172 # AC_WIRESHARK_C_ARES_CHECK
1173 #
1174 AC_DEFUN([AC_WIRESHARK_C_ARES_CHECK],
1175 [
1176         want_c_ares=defaultyes
1177
1178         if test "x$want_c_ares" = "xdefaultyes"; then
1179                 want_c_ares=yes
1180                 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
1181                         withval=/usr/local
1182                         if test -d "$withval"; then
1183                                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1184                         fi
1185                 fi
1186         fi
1187
1188         if test "x$want_c_ares" = "xyes"; then
1189                 AC_CHECK_LIB(cares, ares_init,
1190                   [
1191                     C_ARES_LIBS=-lcares
1192                 AC_DEFINE(HAVE_C_ARES, 1, [Define to use c-ares library])
1193                 have_good_c_ares=yes
1194                   ],, $SOCKET_LIBS $NSL_LIBS
1195                 )
1196         else
1197                 AC_MSG_RESULT(not required)
1198         fi
1199 ])
1200
1201
1202 #
1203 # AC_WIRESHARK_ADNS_CHECK
1204 #
1205 AC_DEFUN([AC_WIRESHARK_ADNS_CHECK],
1206 [
1207         want_adns=defaultyes
1208
1209         if test "x$want_adns" = "xdefaultyes"; then
1210                 want_adns=yes
1211                 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
1212                         withval=/usr/local
1213                         if test -d "$withval"; then
1214                                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1215                         fi
1216                 fi
1217         fi
1218
1219         if test "x$want_adns" = "xyes"; then
1220                 AC_CHECK_LIB(adns, adns_init,
1221                   [
1222                     ADNS_LIBS=-ladns
1223                 AC_DEFINE(HAVE_GNU_ADNS, 1, [Define to use GNU ADNS library])
1224                 have_good_adns=yes
1225                   ],, $SOCKET_LIBS $NSL_LIBS
1226                 )
1227         else
1228                 AC_MSG_RESULT(not required)
1229         fi
1230 ])
1231
1232
1233 #
1234 # AC_WIRESHARK_LIBCAP_CHECK
1235 #
1236 AC_DEFUN([AC_WIRESHARK_LIBCAP_CHECK],
1237 [
1238         want_libcap=defaultyes
1239
1240         if test "x$want_libcap" = "xdefaultyes"; then
1241                 want_libcap=yes
1242                 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
1243                         withval=/usr/local
1244                         if test -d "$withval"; then
1245                                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1246                         fi
1247                 fi
1248         fi
1249
1250         if test "x$want_libcap" = "xyes"; then
1251                 AC_CHECK_LIB(cap, cap_set_flag,
1252                   [
1253                     LIBCAP_LIBS=-lcap
1254                 AC_DEFINE(HAVE_LIBCAP, 1, [Define to use the libcap library])
1255                 have_good_libcap=yes
1256                   ],,
1257                 )
1258         else
1259                 AC_MSG_RESULT(not required)
1260         fi
1261 ])
1262
1263
1264 #
1265 # AC_WIRESHARK_KRB5_CHECK
1266 #
1267 AC_DEFUN([AC_WIRESHARK_KRB5_CHECK],
1268 [
1269         wireshark_save_CFLAGS="$CFLAGS"
1270         wireshark_save_CPPFLAGS="$CPPFLAGS"
1271         if test "x$krb5_dir" != "x"
1272         then
1273           #
1274           # The user specified a directory in which kerberos resides,
1275           # so add the "include" subdirectory of that directory to
1276           # the include file search path and the "lib" subdirectory
1277           # of that directory to the library search path.
1278           #
1279           # XXX - if there's also a kerberos in a directory that's
1280           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
1281           # make us find the version in the specified directory,
1282           # as the compiler and/or linker will search that other
1283           # directory before it searches the specified directory.
1284           #
1285           CFLAGS="$CFLAGS -I$krb5_dir/include"
1286           CPPFLAGS="$CPPFLAGS -I$krb5_dir/include"
1287           ac_heimdal_version=`grep heimdal $krb5_dir/include/krb5.h | head -n 1 | sed 's/^.*heimdal.*$/HEIMDAL/'`
1288           # MIT Kerberos moved krb5.h to krb5/krb5.h starting with release 1.5
1289           ac_mit_version_olddir=`grep 'Massachusetts Institute of Technology' $krb5_dir/include/krb5.h | head -n 1 | sed 's/^.*Massachusetts Institute of Technology.*$/MIT/'`
1290           ac_mit_version_newdir=`grep 'Massachusetts Institute of Technology' $krb5_dir/include/krb5/krb5.h | head -n 1 | sed 's/^.*Massachusetts Institute of Technology.*$/MIT/'`
1291           ac_krb5_version="$ac_heimdal_version$ac_mit_version_olddir$ac_mit_version_newdir"
1292           if test "x$ac_krb5_version" = "xHEIMDAL"
1293               KRB5_LIBS="-L$krb5_dir/lib -lkrb5 -lasn1 $SSL_LIBS -lroken -lcrypt"
1294           then
1295               KRB5_LIBS="-L$krb5_dir/lib -lkrb5 -lk5crypto -lcom_err"
1296           fi
1297           if test "x$ac_krb5_version" = "xMIT"
1298           then
1299             AC_DEFINE(HAVE_MIT_KERBEROS, 1, [Define to use MIT kerberos])
1300           fi
1301         else
1302           AC_PATH_PROG(KRB5_CONFIG, krb5-config)
1303           if test -x "$KRB5_CONFIG"
1304           then
1305             KRB5_FLAGS=`"$KRB5_CONFIG" --cflags`
1306             KRB5_LIBS=`"$KRB5_CONFIG" --libs`
1307             CFLAGS="$CFLAGS $KRB5_FLAGS"
1308             CPPFLAGS="$CPPFLAGS $KRB5_FLAGS"
1309             #
1310             # If -lcrypto is in KRB5_FLAGS, we require it to build
1311             # with Heimdal/MIT.  We don't want to built with it by
1312             # default, due to annoying license incompatibilities
1313             # between the OpenSSL license and the GPL, so:
1314             #
1315             #   if SSL_LIBS is set to a non-empty string, we
1316             #   remove -lcrypto from KRB5_LIBS and replace
1317             #   it with SSL_LIBS;
1318             #
1319             #   if SSL_LIBS is not set to a non-empty string
1320             #   we fail with an appropriate error message.
1321             #
1322             case "$KRB5_LIBS" in
1323             *-lcrypto*)
1324                 if test ! -z "$SSL_LIBS"
1325                 then
1326                     KRB5_LIBS=`echo $KRB5_LIBS | sed 's/-lcrypto//'`
1327                     KRB5_LIBS="$KRB5_LIBS $SSL_LIBS"
1328                 else
1329                     AC_MSG_ERROR([Kerberos library requires -lcrypto but --with-ssl not specified])
1330                 fi
1331                 ;;
1332             esac
1333             ac_krb5_version=`"$KRB5_CONFIG" --version | head -n 1 | sed -e 's/^.*heimdal.*$/HEIMDAL/' -e 's/^Kerberos .*$/MIT/' -e 's/^Solaris Kerberos .*$/MIT/'`
1334           fi
1335         fi
1336
1337         #
1338         # Make sure we have "krb5.h".  If we don't, it means we probably
1339         # don't have kerberos, so don't use it.
1340         #
1341         AC_CHECK_HEADER(krb5.h,,
1342           [
1343             if test "x$krb5_dir" != "x"
1344             then
1345               #
1346               # The user used "--with-krb5=" to specify a directory
1347               # containing kerberos, but we didn't find the header file
1348               # there; that either means they didn't specify the
1349               # right directory or are confused about whether kerberos
1350               # is, in fact, installed.  Report the error and give up.
1351               #
1352               AC_MSG_ERROR([kerberos header not found in directory specified in --with-krb5])
1353             else
1354               if test "x$want_krb5" = "xyes"
1355               then
1356                 #
1357                 # The user tried to force us to use the library, but we
1358                 # couldn't find the header file; report an error.
1359                 #
1360                 AC_MSG_ERROR(Header file krb5.h not found.)
1361               else
1362                 #
1363                 # We couldn't find the header file; don't use the
1364                 # library, as it's probably not present.
1365                 #
1366                 want_krb5=no
1367                 AC_MSG_RESULT(No Heimdal or MIT header found - disabling dissection for some kerberos data in packet decoding)
1368               fi
1369             fi
1370           ])
1371
1372         if test "x$want_krb5" != "xno"
1373         then
1374             #
1375             # Well, we at least have the krb5 header file.
1376             # Check whether this is Heimdal or MIT.
1377             #
1378             AC_MSG_CHECKING(whether the Kerberos library is Heimdal or MIT)
1379             if test "x$ac_krb5_version" = "xHEIMDAL" -o "x$ac_krb5_version" = "xMIT"
1380             then
1381                 #
1382                 # Yes.
1383                 # Check whether we have krb5_kt_resolve - and whether
1384                 # we need to link with -lresolv when linking with
1385                 # the Kerberos library.
1386                 #
1387                 AC_MSG_RESULT($ac_krb5_version)
1388                 wireshark_save_LIBS="$LIBS"
1389                 found_krb5_kt_resolve=no
1390                 for extras in "" "-lresolv"
1391                 do
1392                     LIBS="$KRB5_LIBS $extras"
1393                     if test -z "$extras"
1394                     then
1395                         AC_MSG_CHECKING([whether $ac_krb5_version includes krb5_kt_resolve])
1396                     else
1397                         AC_MSG_CHECKING([whether $ac_krb5_version includes krb5_kt_resolve (linking with $extras)])
1398                     fi
1399                     AC_TRY_LINK(
1400                         [
1401                         ],
1402                         [
1403                             krb5_kt_resolve();
1404                         ],
1405                         [
1406                             #
1407                             # We found "krb5_kt_resolve()", and required
1408                             # the libraries in extras as well.
1409                             #
1410                             AC_MSG_RESULT(yes)
1411                             KRB5_LIBS="$LIBS"
1412                             AC_DEFINE(HAVE_KERBEROS, 1, [Define to use kerberos])
1413                             if test "x$ac_krb5_version" = "xHEIMDAL"
1414                             then
1415                                 AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1, [Define to use heimdal kerberos])
1416                             elif test "x$ac_krb5_version" = "xMIT"
1417                             then
1418                                 AC_DEFINE(HAVE_MIT_KERBEROS, 1, [Define to use MIT kerberos])
1419                             fi
1420                             found_krb5_kt_resolve=yes
1421                             break
1422                         ],
1423                         [
1424                             AC_MSG_RESULT(no)
1425                         ])
1426                 done
1427                 if test "$found_krb5_kt_resolve" = no
1428                 then
1429                     #
1430                     # We didn't find "krb5_kt_resolve()" in the
1431                     # Kerberos library, even when we tried linking
1432                     # with -lresolv; we can't link with kerberos.
1433                     #
1434                     if test "x$want_krb5" = "xyes"
1435                     then
1436                         #
1437                         # The user tried to force us to use the library,
1438                         # but we can't do so; report an error.
1439                         #
1440                         AC_MSG_ERROR(Usable $ac_krb5_version not found)
1441                     else
1442                         #
1443                         # Restore the versions of CFLAGS and CPPFLAGS
1444                         # from before we added the flags for Kerberos.
1445                         #
1446                         AC_MSG_RESULT(Usable $ac_krb5_version not found - disabling dissection for some kerberos data in packet decoding)
1447                         CFLAGS="$wireshark_save_CFLAGS"
1448                         CPPFLAGS="$wireshark_save_CPPFLAGS"
1449                         KRB5_LIBS=""
1450                         want_krb5=no
1451                     fi
1452                 else
1453                     #
1454                     # We can link with Kerberos; see whether krb5.h
1455                     # defines KEYTYPE_ARCFOUR_56 (where "defines" means
1456                     # "as a #define or as an enum member).
1457                     #
1458                     AC_MSG_CHECKING([whether krb5.h defines KEYTYPE_ARCFOUR_56])
1459                     AC_COMPILE_IFELSE(
1460                       [
1461                         AC_LANG_SOURCE(
1462                           [[
1463                             #include <krb5.h>
1464                             #include <stdio.h>
1465
1466                             main()
1467                             {
1468                               printf("%u\n", KEYTYPE_ARCFOUR_56);
1469                             }
1470                           ]])
1471                       ],
1472                       [
1473                         AC_MSG_RESULT(yes)
1474                         AC_DEFINE(HAVE_KEYTYPE_ARCFOUR_56, 1, [Define if krb5.h defines KEYTYPE_ARCFOUR_56])
1475                       ],
1476                       [
1477                         AC_MSG_RESULT(no)
1478                       ])
1479                 fi
1480                 LIBS="$wireshark_save_LIBS"
1481             else
1482                 #
1483                 # It's not Heimdal or MIT.
1484                 #
1485                 AC_MSG_RESULT(no)
1486                 if test "x$want_krb5" = "xyes"
1487                 then
1488                     #
1489                     # The user tried to force us to use the library,
1490                     # but we can't do so; report an error.
1491                     #
1492                     AC_MSG_ERROR(Kerberos not found)
1493                 else
1494                     #
1495                     # Restore the versions of CFLAGS and CPPFLAGS
1496                     # from before we added the flags for Kerberos.
1497                     #
1498                     AC_MSG_RESULT(Kerberos not found - disabling dissection for some kerberos data in packet decoding)
1499                     CFLAGS="$wireshark_save_CFLAGS"
1500                     CPPFLAGS="$wireshark_save_CPPFLAGS"
1501                     KRB5_LIBS=""
1502                     want_krb5=no
1503                 fi
1504             fi
1505         else
1506             #
1507             # The user asked us not to use Kerberos, or they didn't
1508             # say whether they wanted us to use it but we found
1509             # that we couldn't.
1510             #
1511             # Restore the versions of CFLAGS and CPPFLAGS
1512             # from before we added the flags for Kerberos.
1513             #
1514             CFLAGS="$wireshark_save_CFLAGS"
1515             CPPFLAGS="$wireshark_save_CPPFLAGS"
1516             KRB5_LIBS=""
1517             want_krb5=no
1518         fi
1519         AC_SUBST(KRB5_LIBS)
1520 ])
1521
1522 #
1523 # AC_WIRESHARK_GEOIP_CHECK
1524 #
1525 AC_DEFUN([AC_WIRESHARK_GEOIP_CHECK],
1526 [
1527         want_geoip=defaultyes
1528
1529         if test "x$want_geoip" = "xdefaultyes"; then
1530                 want_geoip=yes
1531                 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
1532                         withval=/usr/local
1533                         if test -d "$withval"; then
1534                                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1535                         fi
1536                 fi
1537         fi
1538
1539         if test "x$want_geoip" = "xyes"; then
1540                 AC_CHECK_LIB(GeoIP, GeoIP_new,
1541                   [
1542                     GEOIP_LIBS=-lGeoIP
1543                 AC_DEFINE(HAVE_GEOIP, 1, [Define to use GeoIP library])
1544                 have_good_geoip=yes
1545                   ],,
1546                 )
1547         else
1548                 AC_MSG_RESULT(not required)
1549         fi
1550 ])
1551
1552 #AC_WIRESHARK_LDFLAGS_CHECK
1553 #
1554 # $1 : ldflag(s) to test
1555 #
1556 # The macro first determines if the compiler supports "-Wl,{option}" to
1557 # pass options through to the linker. Then it attempts to compile with
1558 # the defined ldflags. The defined flags are added to LDFLAGS only if
1559 # the compilation succeeds.
1560 #
1561 AC_DEFUN([AC_WIRESHARK_LDFLAGS_CHECK],
1562 [GCC_OPTION="$1"
1563 AC_MSG_CHECKING(whether we can add $GCC_OPTION to LDFLAGS)
1564 if test "x$ac_supports_W_linker_passthrough" = "xyes"; then
1565   LDFLAGS_saved="$LDFLAGS"
1566   LDFLAGS="$LDFLAGS $GCC_OPTION"
1567   AC_LINK_IFELSE([
1568     AC_LANG_SOURCE([[
1569                 main() { return; }
1570                   ]])],
1571                   [
1572                     AC_MSG_RESULT(yes)
1573                   ],
1574                   [
1575                     AC_MSG_RESULT(no)
1576                     LDFLAGS="$LDFLAGS_saved"
1577                   ])
1578 else
1579   AC_MSG_RESULT(no)
1580 fi
1581 ])
1582
1583 #
1584 # AC_WIRESHARK_GCC_CFLAGS_CHECK
1585 #
1586 # $1 : cflags to test
1587 #
1588 # The macro first determines if the compiler supports GCC-style flags.
1589 # Then it attempts to compile with the defined cflags.  The defined
1590 # flags are added to CFLAGS only if the compilation succeeds.
1591 #
1592 # We do this because not all such options are necessarily supported by
1593 # the version of the particular compiler we're using.
1594 #
1595 # NOTE: clang, by default, only warns about unknown -W options.
1596 # If we're using clang, we turn on -Werror=unknown-warning-option
1597 # so that it fails if we pass it a -W option it doesn't know about
1598 # but doesn't fail for any other warning that the test program might
1599 # produce.
1600 #
1601 AC_DEFUN([AC_WIRESHARK_GCC_CFLAGS_CHECK],
1602 [GCC_OPTION="$1"
1603 AC_MSG_CHECKING(whether we can add $GCC_OPTION to CFLAGS)
1604 if test "x$ac_supports_gcc_flags" = "xyes" ; then
1605   CFLAGS_saved="$CFLAGS"
1606   CFLAGS="$CFLAGS $GCC_OPTION"
1607   if test "x$CC" = "xclang" ; then
1608     CFLAGS="$CFLAGS -Werror=unknown-warning-option"
1609   fi
1610   AC_COMPILE_IFELSE([
1611     AC_LANG_SOURCE([[
1612                       int foo;
1613                   ]])],
1614                   [
1615                     AC_MSG_RESULT(yes)
1616                   ],
1617                   [
1618                     AC_MSG_RESULT(no)
1619                     CFLAGS="$CFLAGS_saved"
1620                   ])
1621 else
1622   AC_MSG_RESULT(no)
1623 fi
1624 ])
1625
1626 #
1627 # AC_WIRESHARK_OSX_INTEGRATION_CHECK
1628 #
1629 # Checks for the presence of OS X integration functions in the GTK+ framework
1630 # or as a separate library.
1631 #
1632 # http://sourceforge.net/apps/trac/gtk-osx/wiki/Integrate
1633 #
1634 # http://live.gnome.org/GTK%2B/OSX/Integration
1635 #    for the old Carbon-based integration functions
1636 #
1637 # http://gtk-osx.sourceforge.net/ige-mac-integration/
1638 #    for the new Cocoa-based integration functions
1639 #
1640 AC_DEFUN([AC_WIRESHARK_OSX_INTEGRATION_CHECK],
1641 [
1642         ac_save_CFLAGS="$CFLAGS"
1643         ac_save_LIBS="$LIBS"
1644         CFLAGS="$CFLAGS $GTK_CFLAGS"
1645         LIBS="$GTK_LIBS $LIBS"
1646
1647         #
1648         # Check for the new integration functions in a -ligemacintegration
1649         # library.
1650         #
1651         AC_CHECK_LIB(igemacintegration, gtk_osxapplication_set_menu_bar,
1652         [
1653                 AC_DEFINE(HAVE_GTKOSXAPPLICATION, 1,
1654                         [Define to 1 if -ligemacintegration includes the GtkOSXApplication Integration functions.])
1655                 have_ige_mac=yes
1656                 # We don't want gtk stuff in LIBS (which is reset below) so
1657                 # manually set GTK_LIBS (which is more appropriate)
1658                 GTK_LIBS="$GTK_LIBS -ligemacintegration"
1659         ])
1660
1661         if test x$have_ige_mac = x
1662         then
1663                 #
1664                 # Not found - check for the old integration functions in
1665                 # the Gtk framework.
1666                 #
1667                 AC_CHECK_LIB(Gtk, ige_mac_menu_set_menu_bar,
1668                 [
1669                         AC_DEFINE(HAVE_IGE_MAC_INTEGRATION, 1,
1670                                 [Define to 1 if the the Gtk+ framework or a separate library includes the Imendio IGE Mac OS X Integration functions.])
1671                         have_ige_mac=yes
1672                         # We don't want gtk stuff in LIBS (which is reset below) so
1673                         # manually set GTK_LIBS (which is more appropriate)
1674                         GTK_LIBS="$GTK_LIBS -lGtk"
1675                 ])
1676         fi
1677
1678         if test x$have_ige_mac = x
1679         then
1680                 #
1681                 # Not found - check for the old integration functions in
1682                 # a -ligemacintegration library.
1683                 #
1684                 AC_CHECK_LIB(igemacintegration, ige_mac_menu_set_menu_bar,
1685                 [
1686                         AC_DEFINE(HAVE_IGE_MAC_INTEGRATION, 1,
1687                                 [Define to 1 if the the Gtk+ framework or a separate library includes the Imendio IGE Mac OS X Integration functions.])
1688                         have_ige_mac=yes
1689                         # We don't want gtk stuff in LIBS (which is reset below) so
1690                         # manually set GTK_LIBS (which is more appropriate)
1691                         GTK_LIBS="$GTK_LIBS -ligemacintegration"
1692                 ])
1693         fi
1694         CFLAGS="$ac_save_CFLAGS"
1695         LIBS="$ac_save_LIBS"
1696 ])
1697
1698 #
1699 # AC_WIRESHARK_PYTHON_CHECK
1700 #
1701 # Check whether python devel package is present
1702 #
1703 AC_DEFUN([AC_WIRESHARK_PYTHON_CHECK],
1704   [
1705     #
1706     # Checking whether we have a python devel environment available
1707     #
1708 #  AC_CACHE_CHECK([checking python devel package], ac_cv_wireshark_python_devel,
1709 #    [
1710     AC_CHECK_PROG([ac_ws_python_config], python-config, "yes", "no")
1711     if test "x$ac_ws_python_config" = "xno"; then
1712       ac_cv_wireshark_python_devel=no
1713         if test "x$want_python" = "xyes"
1714         then
1715             #
1716             # The user tried to force us to use Python, but we
1717             # couldn't find the python-config tool; report an error.
1718             #
1719             AC_MSG_ERROR("python-config not found")
1720         fi
1721         #
1722         # Set want_python to no, so we report that we aren't using
1723         # the Python interpreter.
1724         #
1725         want_python=no
1726     else
1727       AC_MSG_CHECKING([python devel])
1728       ac_save_ws_cflags=$CFLAGS
1729       ac_save_ws_libs=$LIBS
1730       CFLAGS=$(python-config --includes)
1731       LIBS=$(python-config --ldflags)
1732       AC_COMPILE_IFELSE(
1733         [
1734           AC_LANG_PROGRAM(
1735             [[#include <Python.h>]],
1736             [[Py_Initialiaze();]]
1737           )
1738         ],
1739         [
1740           #
1741           # Compilation successful, we have python devel available
1742           #
1743           ac_cv_wireshark_python_devel=yes
1744           PY_LIBS=$LIBS
1745           PY_CFLAGS=$CFLAGS
1746           AC_SUBST(PY_LIBS)
1747           AC_SUBST(PY_CFLAGS)
1748           CFLAGS="$ac_save_ws_cflags"
1749           LIBS="$ac_save_ws_libs"
1750           AC_DEFINE(HAVE_PYTHON, 1, [Define if python devel package available])
1751           AC_MSG_RESULT([yes])
1752         ],
1753         [
1754           #
1755           # Compilation unsuccessful, python devel not available
1756           #
1757           ac_cv_wireshark_python_devel=no
1758           CFLAGS=$ac_save_ws_cflags
1759           LIBS=$ac_save_ws_libs
1760           if test "x$want_python" = "xyes"
1761           then
1762             #
1763             # The user tried to force us to use Python, but we
1764             # couldn't compile the test program; report an error.
1765             #
1766             AC_MSG_ERROR("Python test program failed compilation")
1767           fi
1768           AC_MSG_RESULT([no])
1769           #
1770           # Set want_python to no, so we report that we aren't using
1771           # the Python interpreter.
1772           #
1773           want_python=no
1774         ])
1775     fi
1776 #    ])
1777 ])