acinclude.m4

   1 dnl Macros that test for specific features.
   2 dnl This file is part of the Autoconf packaging for Ethereal.
   3 dnl Copyright (C) 1998-2000 by Gerald Combs.
   4 dnl
   5 dnl $Id$
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2, or (at your option)
  10 dnl any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  20 dnl 02111-1307, USA.
  21 dnl
  22 dnl As a special exception, the Free Software Foundation gives unlimited
  23 dnl permission to copy, distribute and modify the configure scripts that
  24 dnl are the output of Autoconf.  You need not follow the terms of the GNU
  25 dnl General Public License when using or distributing such scripts, even
  26 dnl though portions of the text of Autoconf appear in them.  The GNU
  27 dnl General Public License (GPL) does govern all other use of the material
  28 dnl that constitutes the Autoconf program.
  29 dnl
  30 dnl Certain portions of the Autoconf source text are designed to be copied
  31 dnl (in certain cases, depending on the input) into the output of
  32 dnl Autoconf.  We call these the "data" portions.  The rest of the Autoconf
  33 dnl source text consists of comments plus executable code that decides which
  34 dnl of the data portions to output in any given case.  We call these
  35 dnl comments and executable code the "non-data" portions.  Autoconf never
  36 dnl copies any of the non-data portions into its output.
  37 dnl
  38 dnl This special exception to the GPL applies to versions of Autoconf
  39 dnl released by the Free Software Foundation.  When you make and
  40 dnl distribute a modified version of Autoconf, you may extend this special
  41 dnl exception to the GPL to apply to your modified version as well, *unless*
  42 dnl your modified version has the potential to copy into its output some
  43 dnl of the text that was the non-data portion of the version that you started
  44 dnl with.  (In other words, unless your change moves or copies text from
  45 dnl the non-data portions to the data portions.)  If your modification has
  46 dnl such potential, you must delete any notice of this special exception
  47 dnl to the GPL from your modified version.
  48 dnl
  49 dnl Written by David MacKenzie, with help from
  50 dnl Franc,ois Pinard, Karl Berry, Richard Pixley, Ian Lance Taylor,
  51 dnl Roland McGrath, Noah Friedman, david d zuhn, and many others.
  52
  53 #
  54 # AC_ETHEREAL_ADD_DASH_L
  55 #
  56 # Add to the variable specified as the first argument a "-L" flag for the
  57 # directory specified as the second argument, and, on Solaris, add a
  58 # "-R" flag for it as well.
  59 #
  60 # XXX - IRIX, and other OSes, may require some flag equivalent to
  61 # "-R" here.
  62 #
  63 AC_DEFUN([AC_ETHEREAL_ADD_DASH_L],
  64 [$1="$$1 -L$2"
  65 case "$host_os" in
  66   solaris*)
  67     $1="$$1 -R$2"
  68   ;;
  69 esac
  70 ])
  71
  72
  73 #
  74 # AC_ETHEREAL_STRUCT_SA_LEN
  75 #
  76 dnl AC_STRUCT_ST_BLKSIZE extracted from the file in question,
  77 dnl "acspecific.m4" in GNU Autoconf 2.12, and turned into
  78 dnl AC_ETHEREAL_STRUCT_SA_LEN, which checks if "struct sockaddr"
  79 dnl has the 4.4BSD "sa_len" member, and defines HAVE_SA_LEN; that's
  80 dnl what's in this file.
  81 dnl Done by Guy Harris <guy@alum.mit.edu> on 1998-11-14.
  82
  83 dnl ### Checks for structure members
  84
  85 AC_DEFUN([AC_ETHEREAL_STRUCT_SA_LEN],
  86 [AC_CACHE_CHECK([for sa_len in struct sockaddr], ac_cv_ethereal_struct_sa_len,
  87 [AC_TRY_COMPILE([#include <sys/types.h>
  88 #include <sys/socket.h>], [struct sockaddr s; s.sa_len;],
  89 ac_cv_ethereal_struct_sa_len=yes, ac_cv_ethereal_struct_sa_len=no)])
  90 if test $ac_cv_ethereal_struct_sa_len = yes; then
  91   AC_DEFINE(HAVE_SA_LEN, 1, [Define if sa_len field exists in struct sockaddr])
  92 fi
  93 ])
  94
  95
  96 dnl
  97 dnl Check whether a given format can be used to print 64-bit integers
  98 dnl
  99 AC_DEFUN([AC_ETHEREAL_CHECK_64BIT_FORMAT],
 100 [
 101   AC_MSG_CHECKING([whether %$1x can be used to format 64-bit integers])
 102   AC_RUN_IFELSE(
 103     [
 104       AC_LANG_SOURCE(
 105         [[
 106 #         ifdef HAVE_INTTYPES_H
 107           #include <inttypes.h>
 108 #         endif
 109           #include <glibconfig.h>
 110           #include <stdio.h>
 111           #include <sys/types.h>
 112
 113           main()
 114           {
 115             guint64 t = 1;
 116             char strbuf[16+1];
 117             sprintf(strbuf, "%016$1x", t << 32);
 118             if (strcmp(strbuf, "0000000100000000") == 0)
 119               exit(0);
 120             else
 121               exit(1);
 122           }
 123         ]])
 124     ],
 125     [
 126       AC_DEFINE(PRId64, "$1d", [Format for printing 64-bit signed decimal numbers])
 127       AC_DEFINE(PRIo64, "$1o", [Format for printing 64-bit unsigned octal numbers])
 128       AC_DEFINE(PRIx64, "$1x", [Format for printing 64-bit unsigned hexadecimal numbers])
 129       AC_DEFINE(PRIu64, "$1u", [Format for printing 64-bit unsigned decimal numbers])
 130       AC_MSG_RESULT(yes)
 131     ],
 132     [
 133       AC_MSG_RESULT(no)
 134       $2
 135     ])
 136 ])
 137
 138 #
 139 # AC_ETHEREAL_IPV6_STACK
 140 #
 141 # By Jun-ichiro "itojun" Hagino, <itojun@iijlab.net>
 142 #
 143 AC_DEFUN([AC_ETHEREAL_IPV6_STACK],
 144 [
 145         v6type=unknown
 146         v6lib=none
 147
 148         AC_MSG_CHECKING([ipv6 stack type])
 149         for i in v6d toshiba kame inria zeta linux linux-glibc solaris8; do
 150                 case $i in
 151                 v6d)
 152                         AC_EGREP_CPP(yes, [
 153 #include </usr/local/v6/include/sys/types.h>
 154 #ifdef __V6D__
 155 yes
 156 #endif],
 157                                 [v6type=$i; v6lib=v6;
 158                                 v6libdir=/usr/local/v6/lib;
 159                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 160                         ;;
 161                 toshiba)
 162                         AC_EGREP_CPP(yes, [
 163 #include <sys/param.h>
 164 #ifdef _TOSHIBA_INET6
 165 yes
 166 #endif],
 167                                 [v6type=$i; v6lib=inet6;
 168                                 v6libdir=/usr/local/v6/lib;
 169                                 CFLAGS="-DINET6 $CFLAGS"])
 170                         ;;
 171                 kame)
 172                         AC_EGREP_CPP(yes, [
 173 #include <netinet/in.h>
 174 #ifdef __KAME__
 175 yes
 176 #endif],
 177                                 [v6type=$i; v6lib=inet6;
 178                                 v6libdir=/usr/local/v6/lib;
 179                                 CFLAGS="-DINET6 $CFLAGS"])
 180                         ;;
 181                 inria)
 182                         AC_EGREP_CPP(yes, [
 183 #include <netinet/in.h>
 184 #ifdef IPV6_INRIA_VERSION
 185 yes
 186 #endif],
 187                                 [v6type=$i; CFLAGS="-DINET6 $CFLAGS"])
 188                         ;;
 189                 zeta)
 190                         AC_EGREP_CPP(yes, [
 191 #include <sys/param.h>
 192 #ifdef _ZETA_MINAMI_INET6
 193 yes
 194 #endif],
 195                                 [v6type=$i; v6lib=inet6;
 196                                 v6libdir=/usr/local/v6/lib;
 197                                 CFLAGS="-DINET6 $CFLAGS"])
 198                         ;;
 199                 linux)
 200                         if test -d /usr/inet6; then
 201                                 v6type=$i
 202                                 v6lib=inet6
 203                                 v6libdir=/usr/inet6
 204                                 CFLAGS="-DINET6 $CFLAGS"
 205                         fi
 206                         ;;
 207                 linux-glibc)
 208                         AC_EGREP_CPP(yes, [
 209 #include <features.h>
 210 #if defined(__GLIBC__) && defined(__GLIBC_MINOR__)
 211 #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || __GLIBC__ > 2
 212 yes
 213 #endif
 214 #endif],
 215                         [v6type=$i; v6lib=inet6; CFLAGS="-DINET6 $CFLAGS"])
 216                         ;;
 217                 solaris8)
 218                         if test "`uname -s`" = "SunOS" && test "`uname -r`" = "5.8"; then
 219                                 v6type=$i
 220                                 v6lib=inet6
 221                                 [CFLAGS="-DINET6 -DSOLARIS8_INET6 $CFLAGS"]
 222                         fi
 223                         ;;
 224                 esac
 225                 if test "$v6type" != "unknown"; then
 226                         break
 227                 fi
 228         done
 229
 230         if test "$v6lib" != "none"; then
 231                 for dir in $v6libdir /usr/local/v6/lib /usr/local/lib; do
 232                         if test -d $dir -a -f $dir/lib$v6lib.a; then
 233                                 LIBS="-L$dir $LIBS -l$v6lib"
 234                                 break
 235                         fi
 236                 done
 237                 enable_ipv6="yes"
 238         else
 239                 enable_ipv6="no"
 240         fi
 241         AC_MSG_RESULT(["$v6type, $v6lib"])
 242 ])
 243
 244 #
 245 # AC_ETHEREAL_GETHOSTBY_LIB_CHECK
 246 #
 247 # Checks whether we need "-lnsl" to get "gethostby*()", which we use
 248 # in "resolv.c".
 249 #
 250 # Adapted from stuff in the AC_PATH_XTRA macro in "acspecific.m4" in
 251 # GNU Autoconf 2.13; the comment came from there.
 252 # Done by Guy Harris <guy@alum.mit.edu> on 2000-01-14.
 253 #
 254 AC_DEFUN([AC_ETHEREAL_GETHOSTBY_LIB_CHECK],
 255 [
 256     # msh@cis.ufl.edu says -lnsl (and -lsocket) are needed for his 386/AT,
 257     # to get the SysV transport functions.
 258     # chad@anasazi.com says the Pyramid MIS-ES running DC/OSx (SVR4)
 259     # needs -lnsl.
 260     # The nsl library prevents programs from opening the X display
 261     # on Irix 5.2, according to dickey@clark.net.
 262     AC_CHECK_FUNC(gethostbyname, ,
 263         AC_CHECK_LIB(nsl, gethostbyname, NSL_LIBS="-lnsl"))
 264     AC_SUBST(NSL_LIBS)
 265 ])
 266
 267 #
 268 # AC_ETHEREAL_SOCKET_LIB_CHECK
 269 #
 270 # Checks whether we need "-lsocket" to get "socket()", which is used
 271 # by libpcap on some platforms - and, in effect, "gethostby*()" on
 272 # most if not all platforms (so that it can use NIS or DNS or...
 273 # to look up host names).
 274 #
 275 # Adapted from stuff in the AC_PATH_XTRA macro in "acspecific.m4" in
 276 # GNU Autoconf 2.13; the comment came from there.
 277 # Done by Guy Harris <guy@alum.mit.edu> on 2000-01-14.
 278 #
 279 # We use "connect" because that's what AC_PATH_XTRA did.
 280 #
 281 AC_DEFUN([AC_ETHEREAL_SOCKET_LIB_CHECK],
 282 [
 283     # lieder@skyler.mavd.honeywell.com says without -lsocket,
 284     # socket/setsockopt and other routines are undefined under SCO ODT
 285     # 2.0.  But -lsocket is broken on IRIX 5.2 (and is not necessary
 286     # on later versions), says simon@lia.di.epfl.ch: it contains
 287     # gethostby* variants that don't use the nameserver (or something).
 288     # -lsocket must be given before -lnsl if both are needed.
 289     # We assume that if connect needs -lnsl, so does gethostbyname.
 290     AC_CHECK_FUNC(connect, ,
 291       AC_CHECK_LIB(socket, connect, SOCKET_LIBS="-lsocket",
 292                 AC_MSG_ERROR(Function 'socket' not found.), $NSL_LIBS))
 293     AC_SUBST(SOCKET_LIBS)
 294 ])
 295
 296 #
 297 # AC_ETHEREAL_PCAP_CHECK
 298 #
 299 AC_DEFUN([AC_ETHEREAL_PCAP_CHECK],
 300 [
 301         if test -z "$pcap_dir"
 302         then
 303           # Pcap header checks
 304           # XXX need to set a var AC_CHECK_HEADER(pcap.h,,)
 305
 306           #
 307           # The user didn't specify a directory in which libpcap resides;
 308           # we assume that the current library search path will work,
 309           # but we may have to look for the header in a "pcap"
 310           # subdirectory of "/usr/include" or "/usr/local/include",
 311           # as some systems apparently put "pcap.h" in a "pcap"
 312           # subdirectory, and we also check "$prefix/include" - and
 313           # "$prefix/include/pcap", in case $prefix is set to
 314           # "/usr/include" or "/usr/local/include".
 315           #
 316           # XXX - should we just add "$prefix/include" to the include
 317           # search path and "$prefix/lib" to the library search path?
 318           #
 319           AC_MSG_CHECKING(for extraneous pcap header directories)
 320           found_pcap_dir=""
 321           pcap_dir_list="/usr/include/pcap $prefix/include/pcap $prefix/include"
 322           if test "x$ac_cv_enable_usr_local" = "xyes" ; then
 323             pcap_dir_list="$pcap_dir_list /usr/local/include/pcap"
 324           fi
 325           for pcap_dir in $pcap_dir_list
 326           do
 327             if test -d $pcap_dir ; then
 328                 if test x$pcap_dir != x/usr/include -a x$pcap_dir != x/usr/local/include ; then
 329                     CFLAGS="$CFLAGS -I$pcap_dir"
 330                     CPPFLAGS="$CPPFLAGS -I$pcap_dir"
 331                 fi
 332                 found_pcap_dir=" $found_pcap_dir -I$pcap_dir"
 333                 break
 334             fi
 335           done
 336
 337           if test "$found_pcap_dir" != "" ; then
 338             AC_MSG_RESULT(found --$found_pcap_dir added to CFLAGS)
 339           else
 340             AC_MSG_RESULT(not found)
 341           fi
 342         else
 343           #
 344           # The user specified a directory in which libpcap resides,
 345           # so add the "include" subdirectory of that directory to
 346           # the include file search path and the "lib" subdirectory
 347           # of that directory to the library search path.
 348           #
 349           # XXX - if there's also a libpcap in a directory that's
 350           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 351           # make us find the version in the specified directory,
 352           # as the compiler and/or linker will search that other
 353           # directory before it searches the specified directory.
 354           #
 355           CFLAGS="$CFLAGS -I$pcap_dir/include"
 356           CPPFLAGS="$CPPFLAGS -I$pcap_dir/include"
 357           AC_ETHEREAL_ADD_DASH_L(LDFLAGS, $pcap_dir/lib)
 358         fi
 359
 360         # Pcap header check
 361         AC_CHECK_HEADER(pcap.h,,
 362             AC_MSG_ERROR([[Header file pcap.h not found; if you installed libpcap
 363 from source, did you also do \"make install-incl\", and if you installed a
 364 binary package of libpcap, is there also a developer's package of libpcap,
 365 and did you also install that package?]]))
 366
 367         #
 368         # Check to see if we find "pcap_open_live" in "-lpcap".
 369         #
 370         AC_CHECK_LIB(pcap, pcap_open_live,
 371           [
 372             PCAP_LIBS=-lpcap
 373             AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
 374           ], [
 375             AC_MSG_CHECKING([for pcap_open_live in -lpcap -lcfg -lodm])
 376             ac_save_LIBS="$LIBS"
 377             LIBS="-lpcap -lcfg -lodm"
 378             AC_TRY_LINK(
 379                 [
 380 #       include <pcap.h>
 381                 ],
 382                 [
 383         pcap_open_live(NULL, 0, 0, 0, NULL);
 384                 ],
 385                 [
 386                 AC_MSG_RESULT([yes])
 387                 PCAP_LIBS="-lpcap -lcfg -lodm"
 388                 AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
 389                 ],
 390                 [
 391                 AC_MSG_RESULT([no])
 392                 AC_MSG_ERROR([Library libpcap not found.])
 393                 ])
 394             LIBS=$ac_save_LIBS
 395           ], $SOCKET_LIBS $NSL_LIBS)
 396         AC_SUBST(PCAP_LIBS)
 397
 398         #
 399         # Check whether various variables and functions are defined by
 400         # libpcap.
 401         #
 402         ac_save_LIBS="$LIBS"
 403         AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 404         LIBS="$PCAP_LIBS $SOCKET_LIBS $NSL_LIBS $LIBS"
 405         AC_TRY_LINK(
 406            [
 407 #       include <stdio.h>
 408         extern char *pcap_version;
 409            ],
 410            [
 411         printf ("%s\n", pcap_version);
 412            ],
 413            ac_cv_pcap_version_defined=yes,
 414            ac_cv_pcap_version_defined=no,
 415            [echo $ac_n "cross compiling; assumed OK... $ac_c"])
 416         if test "$ac_cv_pcap_version_defined" = yes ; then
 417                 AC_MSG_RESULT(yes)
 418                 AC_DEFINE(HAVE_PCAP_VERSION, 1, [Define if libpcap version is known])
 419         else
 420                 AC_MSG_RESULT(no)
 421         fi
 422         AC_CHECK_FUNCS(pcap_open_dead)
 423         #
 424         # Later versions of Mac OS X 10.3[.x] ship a pcap.h that
 425         # doesn't define pcap_if_t but ship an 0.8[.x] libpcap,
 426         # so the library has "pcap_findalldevs()", but pcap.h
 427         # doesn't define "pcap_if_t" so you can't actually *use*
 428         # "pcap_findalldevs()".
 429         #
 430         # That even appears to be true of systems shipped with
 431         # 10.3.4, so it doesn't appear only to be a case of
 432         # Software Update not updating header files.
 433         #
 434         # (You can work around this by installing the 0.8 header
 435         # files.)
 436         #
 437         AC_CACHE_CHECK([whether pcap_findalldevs is present and usable],
 438           [ac_cv_func_pcap_findalldevs],
 439           [
 440             AC_LINK_IFELSE(
 441               [
 442                 AC_LANG_SOURCE(
 443                   [[
 444                     #include <pcap.h>
 445                     main()
 446                     {
 447                       pcap_if_t *devpointer;
 448                       char errbuf[1];
 449
 450                       pcap_findalldevs(&devpointer, errbuf);
 451                     }
 452                   ]])
 453               ],
 454               [
 455                 ac_cv_func_pcap_findalldevs=yes
 456               ],
 457               [
 458                 ac_cv_func_pcap_findalldevs=no
 459               ])
 460           ])
 461         #
 462         # Don't check for other new routines that showed up after
 463         # "pcap_findalldevs()" if we don't have a usable
 464         # "pcap_findalldevs()", so we don't end up using them if the
 465         # "pcap.h" is crufty and old and doesn't declare them.
 466         #
 467         if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 468           AC_DEFINE(HAVE_PCAP_FINDALLDEVS, 1,
 469            [Define to 1 if you have the `pcap_findalldevs' function and a pcap.h that declares pcap_if_t.])
 470           AC_CHECK_FUNCS(pcap_datalink_val_to_name pcap_datalink_name_to_val)
 471           AC_CHECK_FUNCS(pcap_list_datalinks pcap_set_datalink pcap_lib_version)
 472         fi
 473         LIBS="$ac_save_LIBS"
 474 ])
 475
 476 #
 477 # AC_ETHEREAL_ZLIB_CHECK
 478 #
 479 AC_DEFUN([AC_ETHEREAL_ZLIB_CHECK],
 480 [
 481         if test "x$zlib_dir" != "x"
 482         then
 483           #
 484           # The user specified a directory in which zlib resides,
 485           # so add the "include" subdirectory of that directory to
 486           # the include file search path and the "lib" subdirectory
 487           # of that directory to the library search path.
 488           #
 489           # XXX - if there's also a zlib in a directory that's
 490           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 491           # make us find the version in the specified directory,
 492           # as the compiler and/or linker will search that other
 493           # directory before it searches the specified directory.
 494           #
 495           ethereal_save_CFLAGS="$CFLAGS"
 496           CFLAGS="$CFLAGS -I$zlib_dir/include"
 497           ethereal_save_CPPFLAGS="$CPPFLAGS"
 498           CPPFLAGS="$CPPFLAGS -I$zlib_dir/include"
 499           ethereal_save_LIBS="$LIBS"
 500           AC_ETHEREAL_ADD_DASH_L(LIBS, $zlib_dir/lib)
 501         fi
 502
 503         #
 504         # Make sure we have "zlib.h".  If we don't, it means we probably
 505         # don't have zlib, so don't use it.
 506         #
 507         AC_CHECK_HEADER(zlib.h,,
 508           [
 509             if test "x$zlib_dir" != "x"
 510             then
 511               #
 512               # The user used "--with-zlib=" to specify a directory
 513               # containing zlib, but we didn't find the header file
 514               # there; that either means they didn't specify the
 515               # right directory or are confused about whether zlib
 516               # is, in fact, installed.  Report the error and give up.
 517               #
 518               AC_MSG_ERROR([zlib header not found in directory specified in --with-zlib])
 519             else
 520               if test "x$want_zlib" = "xyes"
 521               then
 522                 #
 523                 # The user tried to force us to use the library, but we
 524                 # couldn't find the header file; report an error.
 525                 #
 526                 AC_MSG_ERROR(Header file zlib.h not found.)
 527               else
 528                 #
 529                 # We couldn't find the header file; don't use the
 530                 # library, as it's probably not present.
 531                 #
 532                 want_zlib=no
 533               fi
 534             fi
 535           ])
 536
 537         if test "x$want_zlib" != "xno"
 538         then
 539                 #
 540                 # Well, we at least have the zlib header file.
 541                 #
 542                 # Check for "gzgets()" in zlib, because we need it, but
 543                 # some older versions of zlib don't have it.  It appears
 544                 # from the zlib ChangeLog that any released version of zlib
 545                 # with "gzgets()" should have the other routines we
 546                 # depend on, such as "gzseek()", "gztell()", and "zError()".
 547                 #
 548                 # Another reason why we require "gzgets()" is that
 549                 # some versions of zlib that didn't have it, such
 550                 # as 1.0.8, had a bug in "gzseek()" that meant that it
 551                 # doesn't work correctly on uncompressed files; this
 552                 # means we cannot use version 1.0.8.  (Unfortunately,
 553                 # that's the version that comes with recent X11 source,
 554                 # and many people who install XFree86 on their Slackware
 555                 # boxes don't realize that they should configure it to
 556                 # use the native zlib rather than building and installing
 557                 # the crappy old version that comes with XFree86.)
 558                 #
 559                 # I.e., we can't just avoid using "gzgets()", as
 560                 # versions of zlib without "gzgets()" are likely to have
 561                 # a broken "gzseek()".
 562                 #
 563                 AC_CHECK_LIB(z, gzgets,
 564                 [
 565                         if test "x$zlib_dir" != "x"
 566                         then
 567                                 #
 568                                 # Put the "-I" and "-L" flags for zlib at
 569                                 # the beginning of CFLAGS, CPPFLAGS, and
 570                                 # LIBS.
 571                                 #
 572                                 LIBS=""
 573                                 AC_ETHEREAL_ADD_DASH_L(LIBS, $zlib_dir/lib)
 574                                 LIBS="$LIBS -lz $ethereal_save_LIBS"
 575                         else
 576                                 LIBS="-lz $LIBS"
 577                         fi
 578                         AC_DEFINE(HAVE_LIBZ, 1, [Define to use libz library])
 579                 ],[
 580                         if test "x$zlib_dir" != "x"
 581                         then
 582                                 #
 583                                 # Restore the versions of CFLAGS, CPPFLAGS,
 584                                 # and LIBS before we added the "-with-zlib="
 585                                 # directory, as we didn't actually find
 586                                 # zlib there, or didn't find a zlib that
 587                                 # contains gzgets there.
 588                                 #
 589                                 CFLAGS="$ethereal_save_CFLAGS"
 590                                 CPPFLAGS="$ethereal_save_CPPFLAGS"
 591                                 LIBS="$ethereal_save_LIBS"
 592                         fi
 593                         want_zlib=no
 594                 ])
 595         fi
 596
 597         if test "x$want_zlib" != "xno"
 598         then
 599                 #
 600                 # Well, we at least have the zlib header file and a zlib
 601                 # with "gzgets()".
 602                 #
 603                 # Now check for "gzgets()" in zlib when linking with the
 604                 # linker flags for GTK+ applications; people often grab
 605                 # XFree86 source and build and install it on their systems,
 606                 # and they appear sometimes to misconfigure XFree86 so that,
 607                 # even on systems with zlib, it assumes there is no zlib,
 608                 # so the XFree86 build process builds and installs its
 609                 # own zlib in the X11 library directory.
 610                 #
 611                 # The XFree86 zlib is an older version that lacks
 612                 # "gzgets()", and that's the zlib with which Ethereal
 613                 # gets linked, so the build of Ethereal fails.
 614                 #
 615                 ac_save_CFLAGS="$CFLAGS"
 616                 ac_save_LIBS="$LIBS"
 617                 CFLAGS="$CFLAGS $GTK_CFLAGS"
 618                 LIBS="$GTK_LIBS -lz $LIBS"
 619                 AC_MSG_CHECKING([for gzgets missing when linking with X11])
 620                 AC_TRY_LINK_FUNC(gzgets, AC_MSG_RESULT(no),
 621                   [
 622                     AC_MSG_RESULT(yes)
 623                     AC_MSG_ERROR(old zlib found when linking with X11 - get rid of old zlib.)
 624                   ])
 625                 CFLAGS="$ac_save_CFLAGS"
 626                 LIBS="$ac_save_LIBS"
 627         fi
 628 ])
 629
 630 #
 631 # AC_ETHEREAL_LIBPCRE_CHECK
 632 #
 633 AC_DEFUN([AC_ETHEREAL_LIBPCRE_CHECK],
 634 [
 635         if test "x$pcre_dir" != "x"
 636         then
 637           #
 638           # The user specified a directory in which libpcre resides,
 639           # so add the "include" subdirectory of that directory to
 640           # the include file search path and the "lib" subdirectory
 641           # of that directory to the library search path.
 642           #
 643           # XXX - if there's also a libpcre in a directory that's
 644           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 645           # make us find the version in the specified directory,
 646           # as the compiler and/or linker will search that other
 647           # directory before it searches the specified directory.
 648           #
 649           ethereal_save_CFLAGS="$CFLAGS"
 650           CFLAGS="$CFLAGS -I$pcre_dir/include"
 651           ethereal_save_CPPFLAGS="$CPPFLAGS"
 652           CPPFLAGS="$CPPFLAGS -I$pcre_dir/include"
 653           ethereal_save_LIBS="$LIBS"
 654           LIBS="$LIBS -lpcre"
 655           ethereal_save_LDFLAGS="$LDFLAGS"
 656           LDFLAGS="$LDFLAGS -L$pcre_dir/lib"
 657         fi
 658
 659         #
 660         # Make sure we have "pcre.h".  If we don't, it means we probably
 661         # don't have libpcre, so don't use it.
 662         #
 663         AC_CHECK_HEADER(pcre.h,,
 664           [
 665             if test "x$pcre_dir" != "x"
 666             then
 667               #
 668               # The user used "--with-pcre=" to specify a directory
 669               # containing libpcre, but we didn't find the header file
 670               # there; that either means they didn't specify the
 671               # right directory or are confused about whether libpcre
 672               # is, in fact, installed.  Report the error and give up.
 673               #
 674               AC_MSG_ERROR([libpcre header not found in directory specified in --with-pcre])
 675             else
 676               if test "x$want_pcre" = "xyes"
 677               then
 678                 #
 679                 # The user tried to force us to use the library, but we
 680                 # couldn't find the header file; report an error.
 681                 #
 682                 AC_MSG_ERROR(Header file pcre.h not found.)
 683               else
 684                 #
 685                 # We couldn't find the header file; don't use the
 686                 # library, as it's probably not present.
 687                 #
 688                 want_pcre=no
 689               fi
 690             fi
 691           ])
 692
 693         if test "x$want_pcre" != "xno"
 694         then
 695                 #
 696                 # Well, we at least have the pcre header file.
 697                 #
 698                 # We're only using standard functions from libpcre,
 699                 # so we don't need to perform extra checks.
 700                 #
 701                 AC_CHECK_LIB(pcre, pcre_compile,
 702                 [
 703                         if test "x$pcre_dir" != "x"
 704                         then
 705                                 #
 706                                 # Put the "-I" and "-L" flags for pcre at
 707                                 # the beginning of CFLAGS, CPPFLAGS,
 708                                 # LDFLAGS, and LIBS.
 709                                 #
 710                                 PCRE_LIBS="-L$pcre_dir/lib -lpcre $ethereal_save_LIBS"
 711                         else
 712                                 PCRE_LIBS="-lpcre"
 713                         fi
 714                         AC_DEFINE(HAVE_LIBPCRE, 1, [Define to use libpcre library])
 715                 ],[
 716                         if test "x$pcre_dir" != "x"
 717                         then
 718                                 #
 719                                 # Restore the versions of CFLAGS, CPPFLAGS,
 720                                 # LDFLAGS, and LIBS before we added the
 721                                 # "--with-pcre=" directory, as we didn't
 722                                 # actually find pcre there.
 723                                 #
 724                                 CFLAGS="$ethereal_save_CFLAGS"
 725                                 CPPFLAGS="$ethereal_save_CPPFLAGS"
 726                                 LDFLAGS="$ethereal_save_LDFLAGS"
 727                                 LIBS="$ethereal_save_LIBS"
 728                                 PCRE_LIBS=""
 729                         fi
 730                         want_pcre=no
 731                 ])
 732                 AC_SUBST(PCRE_LIBS)
 733         fi
 734 ])
 735
 736 #
 737 # AC_ETHEREAL_UCDSNMP_CHECK
 738 #
 739 AC_DEFUN([AC_ETHEREAL_UCDSNMP_CHECK],
 740 [
 741         if test "x$ucdsnmp_dir" != "x"
 742         then
 743                 #
 744                 # The user specified a directory in which UCD SNMP resides,
 745                 # so add the "include" subdirectory of that directory to
 746                 # the include file search path and the "lib" subdirectory
 747                 # of that directory to the library search path.
 748                 #
 749                 # XXX - if there's also a libpcap in a directory that's
 750                 # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 751                 # make us find the version in the specified directory,
 752                 # as the compiler and/or linker will search that other
 753                 # directory before it searches the specified directory.
 754                 #
 755                 CFLAGS="$CFLAGS -I$ucdsnmp_dir/include"
 756                 CPPFLAGS="$CPPFLAGS -I$ucdsnmp_dir/include"
 757                 AC_ETHEREAL_ADD_DASH_L(LDFLAGS, $ucdsnmp_dir/lib)
 758         fi
 759
 760         #
 761         # Check for one of the UCD SNMP header files we include,
 762         # to see whether we have UCD SNMP installed.
 763         #
 764         AC_CHECK_HEADER(ucd-snmp/ucd-snmp-config.h,
 765         [
 766                 #
 767                 # UCD SNMP or Net-SNMP might require various helper
 768                 # libraries on various platforms, such as "-ldes425"
 769                 # in "/usr/kerberos/lib" on some versions of Red
 770                 # Hat Linux, or "-lkstat" on Solaris.
 771                 #
 772                 # It might also require "-lcrypto" on some platforms;
 773                 # if the user didn't specify --with-ssl, we check
 774                 # whether it would have made a difference and, if so,
 775                 # we tell the user that they needed to request it.
 776                 # (There are annoying licensing issues with it and
 777                 # GPL'ed code, so we don't include it by default.)
 778                 #
 779                 # XXX - autoconf really needs a way to test for
 780                 # a given routine in a given library *and* to test
 781                 # whether additional "-L"/"-R"/whatever flags are
 782                 # needed *before* the "-l" flag for the library
 783                 # and to test whether additional libraries are
 784                 # needed after the library *and* to cache all that
 785                 # information.
 786                 #
 787                 ethereal_save_LIBS="$LIBS"
 788                 found_sprint_realloc_objid=no
 789                 for extras in "" "-L/usr/kerberos/lib -ldes425" "-lkstat"
 790                 do
 791                         LIBS="-lsnmp $extras $SOCKET_LIBS $NSL_LIBS $SSL_LIBS"
 792                         if test -z "$extras"
 793                         then
 794                                 AC_MSG_CHECKING([whether UCD SNMP includes sprint_realloc_objid])
 795                         else
 796                                 AC_MSG_CHECKING([whether UCD SNMP includes sprint_realloc_objid (linking with $extras)])
 797                         fi
 798                         AC_TRY_LINK(
 799                             [
 800                             ],
 801                             [
 802                                 sprint_realloc_objid();
 803                             ],
 804                             [
 805                                 #
 806                                 # We found "sprint_realloc_objid()",
 807                                 # and required the libraries in
 808                                 # extras as well.
 809                                 #
 810                                 AC_MSG_RESULT(yes)
 811                                 SNMP_LIBS="-lsnmp $extras"; break;
 812                                 found_sprint_realloc_objid=yes
 813                                 break
 814                             ],
 815                             [
 816                                 #
 817                                 # The link failed.  If they didn't ask
 818                                 # for SSL, try linking with -lcrypto
 819                                 # as well, and if *that* succeeds,
 820                                 # tell them they'll need to specify
 821                                 # --want-ssl.
 822                                 #
 823                                 AC_MSG_RESULT(no)
 824                                 if test "x$want_ssl" = "xno"
 825                                 then
 826                                         LIBS="$LIBS -lcrypto"
 827                                         AC_TRY_LINK(
 828                                             [
 829                                             ],
 830                                             [
 831                                                 sprint_realloc_objid();
 832                                             ],
 833                                             [
 834                                                 #
 835                                                 # It worked with -lcrypto; tell
 836                                                 # them they'll need to specify
 837                                                 # --with-ssl.
 838                                                 #
 839                                                 AC_MSG_ERROR([UCD SNMP requires -lcrypto but --with-ssl not specified])
 840                                             ])
 841                                 fi
 842                             ])
 843                 done
 844                 LIBS="$ethereal_save_LIBS"
 845
 846                 #
 847                 # If we didn't find "sprint_realloc_objid()", fail.
 848                 # Either the user needs a newer version of UCD SNMP
 849                 # with "sprint_realloc_objid()", or they may need to
 850                 # specify "--with-ssl".
 851                 #
 852                 if test "$found_snmp_sprint_realloc_objid" = no; then
 853                     AC_MSG_ERROR([UCD SNMP header files found, but sprint_realloc_objid not found in SNMP library.])
 854                 fi
 855
 856                 #
 857                 # We found it, so we have UCD SNMP.
 858                 #
 859                 AC_DEFINE(HAVE_UCD_SNMP, 1, [Define to enable support for UCD-SNMP])
 860                 have_ucd_snmp="yes"
 861         ],[
 862                 #
 863                 # No, we don't have it.
 864                 # If the user explicitly asked for UCD SNMP, fail,
 865                 # otherwise just don't use the UCD SNMP library.
 866                 #
 867                 if test "x$want_ucdsnmp" = "xyes" ; then
 868                         AC_MSG_ERROR(Header file ucd-snmp/snmp.h not found.)
 869                 fi
 870         ])
 871 ])
 872
 873 #
 874 # AC_ETHEREAL_RPM_CHECK
 875 # Looks for the rpm program, and checks to see if we can redefine "_topdir".
 876 #
 877 AC_DEFUN([AC_ETHEREAL_RPM_CHECK],
 878 [
 879         AC_CHECK_PROG(ac_cv_ethereal_have_rpm, rpm, "yes", "no")
 880         if test "x$ac_cv_ethereal_have_rpm" = "xyes"; then
 881                 rpm --define '_topdir /tmp' > /dev/null 2>&1
 882                 AC_MSG_CHECKING(to see if we can redefine _topdir)
 883                 if test $? -eq 0 ; then
 884                         AC_MSG_RESULT(yes)
 885                         HAVE_RPM=yes
 886                 else
 887                         AC_MSG_RESULT(no.  You'll have to build packages manually.)
 888                         HAVE_RPM=no
 889                 fi
 890         fi
 891 ])
 892
 893 #
 894 # AC_ETHEREAL_GNU_SED_CHECK
 895 # Checks if GNU sed is the first sed in PATH.
 896 #
 897 AC_DEFUN([AC_ETHEREAL_GNU_SED_CHECK],
 898 [
 899         AC_MSG_CHECKING(for GNU sed as first sed in PATH)
 900         if  ( sh -c "sed --version" </dev/null 2> /dev/null | grep "GNU sed" 2>&1 > /dev/null ) ;  then
 901                 AC_MSG_RESULT(yes)
 902                 HAVE_GNU_SED=yes
 903         else
 904                 AC_MSG_RESULT(no)
 905                 HAVE_GNU_SED=no
 906         fi
 907 ])
 908
 909 #
 910 # AC_ETHEREAL_ADNS_CHECK
 911 #
 912 AC_DEFUN([AC_ETHEREAL_ADNS_CHECK],
 913 [
 914         want_adns=defaultyes
 915
 916         AC_ARG_WITH(adns,
 917 changequote(<<, >>)dnl
 918 <<  --with-adns[=DIR]       use GNU ADNS (located in directory DIR, if supplied).   [default=yes, if present]>>,
 919 changequote([, ])dnl
 920         [
 921         if   test "x$withval" = "xno";  then
 922                 want_adns=no
 923         elif test "x$withval" = "xyes"; then
 924                 want_adns=yes
 925         elif test -d "$withval"; then
 926                 want_adns=yes
 927                 AC_ETHEREAL_ADD_DASH_L(LDFLAGS, ${withval}/lib)
 928         fi
 929         ])
 930
 931         if test "x$want_adns" = "xdefaultyes"; then
 932                 want_adns=yes
 933                 withval=/usr/local
 934                 if test -d "$withval"; then
 935                         AC_ETHEREAL_ADD_DASH_L(LDFLAGS, ${withval}/lib)
 936                 fi
 937         fi
 938
 939         if test "x$want_adns" = "xyes"; then
 940                 AC_CHECK_LIB(adns, adns_init,
 941                   [
 942                     ADNS_LIBS=-ladns
 943                 AC_DEFINE(HAVE_GNU_ADNS, 1, [Define to use GNU ADNS library])
 944                 have_good_adns=yes
 945                   ],, $SOCKET_LIBS $NSL_LIBS
 946                 )
 947         else
 948                 AC_MSG_RESULT(not required)
 949         fi
 950 ])
 951
 952
 953 #
 954 # AC_ETHEREAL_KRB5_CHECK
 955 #
 956 AC_DEFUN([AC_ETHEREAL_KRB5_CHECK],
 957 [
 958         ethereal_save_CFLAGS="$CFLAGS"
 959         ethereal_save_CPPFLAGS="$CPPFLAGS"
 960         if test "x$krb5_dir" != "x"
 961         then
 962           #
 963           # The user specified a directory in which kerberos resides,
 964           # so add the "include" subdirectory of that directory to
 965           # the include file search path and the "lib" subdirectory
 966           # of that directory to the library search path.
 967           #
 968           # XXX - if there's also a kerberos in a directory that's
 969           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 970           # make us find the version in the specified directory,
 971           # as the compiler and/or linker will search that other
 972           # directory before it searches the specified directory.
 973           #
 974           CFLAGS="$CFLAGS -I$krb5_dir/include"
 975           CPPFLAGS="$CPPFLAGS -I$krb5_dir/include"
 976           ac_heimdal_version=`grep heimdal $krb5_dir/include/krb5.h | head -n 1 | sed 's/^.*heimdal.*$/HEIMDAL/'`
 977           ac_mit_version=`grep 'Massachusetts Institute of Technology' $krb5_dir/include/krb5.h | head -n 1 | sed 's/^.*Massachusetts Institute of Technology.*$/MIT/'`
 978           ac_krb5_version="$ac_heimdal_version$ac_mit_version"
 979           if test "x$ac_krb5_version" = "xHEIMDAL"
 980               KRB5_LIBS="-L$krb5_dir/lib -lkrb5 -lasn1 $SSL_LIBS -lroken -lcrypt"
 981           then
 982               KRB5_LIBS="-L$krb5_dir/lib -lkrb5 -lk5crypto -lcom_err"
 983           fi
 984           if test "x$ac_krb5_version" = "xMIT"
 985           then
 986           AC_DEFINE(HAVE_MIT_KERBEROS, 1, [Define to use MIT kerberos])
 987           fi
 988         else
 989           AC_PATH_PROG(KRB5_CONFIG, krb5-config)
 990           if test -x "$KRB5_CONFIG"
 991           then
 992             KRB5_FLAGS=`"$KRB5_CONFIG" --cflags`
 993             KRB5_LIBS=`"$KRB5_CONFIG" --libs`
 994             CFLAGS="$CFLAGS $KRB5_FLAGS"
 995             CPPFLAGS="$CPPFLAGS $KRB5_FLAGS"
 996             #
 997             # If -lcrypto is in KRB5_FLAGS, we require it to build
 998             # with Heimdal/MIT.  We don't want to built with it by
 999             # default, due to annoying license incompatibilities
1000             # between the OpenSSL license and the GPL, so:
1001             #
1002             #   if SSL_LIBS is set to a non-empty string, we
1003             #   remove -lcrypto from KRB5_LIBS and replace
1004             #   it with SSL_LIBS;
1005             #
1006             #   if SSL_LIBS is not set to a non-empty string
1007             #   we fail with an appropriate error message.
1008             #
1009             case "$KRB5_LIBS" in
1010             *-lcrypto*)
1011                 if test ! -z "$SSL_LIBS"
1012                 then
1013                     KRB5_LIBS=`echo $KRB5_LIBS | sed 's/-lcrypto//'`
1014                     KRB5_LIBS="$KRB5_LIBS $SSL_LIBS"
1015                 else
1016                     AC_MSG_ERROR([Kerberos library requires -lcrypto but --with-ssl not specified])
1017                 fi
1018                 ;;
1019             esac
1020             ac_krb5_version=`"$KRB5_CONFIG" --version | head -n 1 | sed -e 's/^.*heimdal.*$/HEIMDAL/' -e 's/^Kerberos .*$/MIT/'`
1021           fi
1022         fi
1023
1024         #
1025         # Make sure we have "krb5.h".  If we don't, it means we probably
1026         # don't have kerberos, so don't use it.
1027         #
1028         AC_CHECK_HEADER(krb5.h,,
1029           [
1030             if test "x$krb5_dir" != "x"
1031             then
1032               #
1033               # The user used "--with-krb5=" to specify a directory
1034               # containing kerberos, but we didn't find the header file
1035               # there; that either means they didn't specify the
1036               # right directory or are confused about whether kerberos
1037               # is, in fact, installed.  Report the error and give up.
1038               #
1039               AC_MSG_ERROR([kerberos header not found in directory specified in --with-krb5])
1040             else
1041               if test "x$want_krb5" = "xyes"
1042               then
1043                 #
1044                 # The user tried to force us to use the library, but we
1045                 # couldn't find the header file; report an error.
1046                 #
1047                 AC_MSG_ERROR(Header file krb5.h not found.)
1048               else
1049                 #
1050                 # We couldn't find the header file; don't use the
1051                 # library, as it's probably not present.
1052                 #
1053                 want_krb5=no
1054                 AC_MSG_RESULT(No Heimdal or MIT header found - disabling dissection for some kerberos data in packet decoding)
1055               fi
1056             fi
1057           ])
1058
1059         if test "x$want_krb5" != "xno"
1060         then
1061             #
1062             # Well, we at least have the krb5 header file.
1063             # Check whether this is Heimdal or MIT.
1064             #
1065             AC_MSG_CHECKING(whether the Kerberos library is Heimdal or MIT)
1066             if test "x$ac_krb5_version" = "xHEIMDAL" -o "x$ac_krb5_version" = "xMIT"
1067             then
1068                 #
1069                 # Yes.
1070                 # Check whether we have krb5_kt_resolve - and whether
1071                 # we need to link with -lresolv when linking with
1072                 # the Kerberos library.
1073                 #
1074                 AC_MSG_RESULT($ac_krb5_version)
1075                 ethereal_save_LIBS="$LIBS"
1076                 found_krb5_kt_resolve=no
1077                 for extras in "" "-lresolv"
1078                 do
1079                     LIBS="$KRB5_LIBS $extras"
1080                     if test -z "$extras"
1081                     then
1082                         AC_MSG_CHECKING([whether $ac_krb5_version includes krb5_kt_resolve])
1083                     else
1084                         AC_MSG_CHECKING([whether $ac_krb5_version includes krb5_kt_resolve (linking with $extras)])
1085                     fi
1086                     AC_TRY_LINK(
1087                         [
1088                         ],
1089                         [
1090                             krb5_kt_resolve();
1091                         ],
1092                         [
1093                             #
1094                             # We found "krb5_kt_resolve()", and required
1095                             # the libraries in extras as well.
1096                             #
1097                             AC_MSG_RESULT(yes)
1098                             KRB5_LIBS="$LIBS"
1099                             AC_DEFINE(HAVE_KERBEROS, 1, [Define to use kerberos])
1100                             if test "x$ac_krb5_version" = "xHEIMDAL"
1101                             then
1102                                 AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1, [Define to use heimdal kerberos])
1103                             fi
1104                             if test "x$ac_krb5_version" = "xMIT"
1105                             then
1106                                 AC_DEFINE(HAVE_MIT_KERBEROS, 1, [Define to use MIT kerberos])
1107                             fi
1108                             found_krb5_kt_resolve=yes
1109                             break
1110                         ],
1111                         [
1112                             AC_MSG_RESULT(no)
1113                         ])
1114                 done
1115                 if test "$found_krb5_kt_resolve" = no
1116                 then
1117                     #
1118                     # We didn't find "krb5_kt_resolve()" in the
1119                     # Kerberos library, even when we tried linking
1120                     # with -lresolv; we can't link with kerberos.
1121                     #
1122                     if test "x$want_krb5" = "xyes"
1123                     then
1124                         #
1125                         # The user tried to force us to use the library,
1126                         # but we can't do so; report an error.
1127                         #
1128                         AC_MSG_ERROR(Usable $ac_krb5_version not found)
1129                     else
1130                         #
1131                         # Restore the versions of CFLAGS and CPPFLAGS
1132                         # from before we added the flags for Kerberos.
1133                         #
1134                         AC_MSG_RESULT(Usable $ac_krb5_version not found - disabling dissection for some kerberos data in packet decoding)
1135                         CFLAGS="$ethereal_save_CFLAGS"
1136                         CPPFLAGS="$ethereal_save_CPPFLAGS"
1137                         KRB5_LIBS=""
1138                         want_krb5=no
1139                     fi
1140                 fi
1141                 LIBS="$ethereal_save_LIBS"
1142             else
1143                 #
1144                 # It's not Heimdal or MIT.
1145                 #
1146                 AC_MSG_RESULT(no)
1147                 if test "x$want_krb5" = "xyes"
1148                 then
1149                     #
1150                     # The user tried to force us to use the library,
1151                     # but we can't do so; report an error.
1152                     #
1153                     AC_MSG_ERROR(Kerberos not found)
1154                 else
1155                     #
1156                     # Restore the versions of CFLAGS and CPPFLAGS
1157                     # from before we added the flags for Kerberos.
1158                     #
1159                     AC_MSG_RESULT(Kerberos not found - disabling dissection for some kerberos data in packet decoding)
1160                     CFLAGS="$ethereal_save_CFLAGS"
1161                     CPPFLAGS="$ethereal_save_CPPFLAGS"
1162                     KRB5_LIBS=""
1163                     want_krb5=no
1164                 fi
1165             fi
1166         else
1167             #
1168             # The user asked us not to use Kerberos, or they didn't
1169             # say whether they wanted us to use it but we found
1170             # that we couldn't.
1171             #
1172             # Restore the versions of CFLAGS and CPPFLAGS
1173             # from before we added the flags for Kerberos.
1174             #
1175             CFLAGS="$ethereal_save_CFLAGS"
1176             CPPFLAGS="$ethereal_save_CPPFLAGS"
1177             KRB5_LIBS=""
1178             want_krb5=no
1179         fi
1180         AC_SUBST(KRB5_LIBS)
1181 ])
1182