acinclude.m4

   1 dnl Macros that test for specific features.
   2 dnl This file is part of the Autoconf packaging for Wireshark.
   3 dnl Copyright (C) 1998-2000 by Gerald Combs.
   4 dnl
   5 dnl $Id$
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2, or (at your option)
  10 dnl any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  20 dnl 02111-1307, USA.
  21 dnl
  22 dnl As a special exception, the Free Software Foundation gives unlimited
  23 dnl permission to copy, distribute and modify the configure scripts that
  24 dnl are the output of Autoconf.  You need not follow the terms of the GNU
  25 dnl General Public License when using or distributing such scripts, even
  26 dnl though portions of the text of Autoconf appear in them.  The GNU
  27 dnl General Public License (GPL) does govern all other use of the material
  28 dnl that constitutes the Autoconf program.
  29 dnl
  30 dnl Certain portions of the Autoconf source text are designed to be copied
  31 dnl (in certain cases, depending on the input) into the output of
  32 dnl Autoconf.  We call these the "data" portions.  The rest of the Autoconf
  33 dnl source text consists of comments plus executable code that decides which
  34 dnl of the data portions to output in any given case.  We call these
  35 dnl comments and executable code the "non-data" portions.  Autoconf never
  36 dnl copies any of the non-data portions into its output.
  37 dnl
  38 dnl This special exception to the GPL applies to versions of Autoconf
  39 dnl released by the Free Software Foundation.  When you make and
  40 dnl distribute a modified version of Autoconf, you may extend this special
  41 dnl exception to the GPL to apply to your modified version as well, *unless*
  42 dnl your modified version has the potential to copy into its output some
  43 dnl of the text that was the non-data portion of the version that you started
  44 dnl with.  (In other words, unless your change moves or copies text from
  45 dnl the non-data portions to the data portions.)  If your modification has
  46 dnl such potential, you must delete any notice of this special exception
  47 dnl to the GPL from your modified version.
  48 dnl
  49 dnl Written by David MacKenzie, with help from
  50 dnl Franc,ois Pinard, Karl Berry, Richard Pixley, Ian Lance Taylor,
  51 dnl Roland McGrath, Noah Friedman, david d zuhn, and many others.
  52
  53 #
  54 # AC_WIRESHARK_ADD_DASH_L
  55 #
  56 # Add to the variable specified as the first argument a "-L" flag for the
  57 # directory specified as the second argument, and, on Solaris, add a
  58 # "-R" flag for it as well.
  59 #
  60 # XXX - IRIX, and other OSes, may require some flag equivalent to
  61 # "-R" here.
  62 #
  63 AC_DEFUN([AC_WIRESHARK_ADD_DASH_L],
  64 [$1="$$1 -L$2"
  65 case "$host_os" in
  66   solaris*)
  67     $1="$$1 -R$2"
  68   ;;
  69 esac
  70 ])
  71
  72
  73 #
  74 # AC_WIRESHARK_STRUCT_SA_LEN
  75 #
  76 dnl AC_STRUCT_ST_BLKSIZE extracted from the file in question,
  77 dnl "acspecific.m4" in GNU Autoconf 2.12, and turned into
  78 dnl AC_WIRESHARK_STRUCT_SA_LEN, which checks if "struct sockaddr"
  79 dnl has the 4.4BSD "sa_len" member, and defines HAVE_SA_LEN; that's
  80 dnl what's in this file.
  81 dnl Done by Guy Harris <guy@alum.mit.edu> on 1998-11-14.
  82
  83 dnl ### Checks for structure members
  84
  85 AC_DEFUN([AC_WIRESHARK_STRUCT_SA_LEN],
  86 [AC_CACHE_CHECK([for sa_len in struct sockaddr], ac_cv_wireshark_struct_sa_len,
  87 [AC_TRY_COMPILE([#include <sys/types.h>
  88 #include <sys/socket.h>], [struct sockaddr s; s.sa_len;],
  89 ac_cv_wireshark_struct_sa_len=yes, ac_cv_wireshark_struct_sa_len=no)])
  90 if test $ac_cv_wireshark_struct_sa_len = yes; then
  91   AC_DEFINE(HAVE_SA_LEN, 1, [Define if sa_len field exists in struct sockaddr])
  92 fi
  93 ])
  94
  95
  96 #
  97 # AC_WIRESHARK_IPV6_STACK
  98 #
  99 # By Jun-ichiro "itojun" Hagino, <itojun@iijlab.net>
 100 #
 101 AC_DEFUN([AC_WIRESHARK_IPV6_STACK],
 102 [
 103         v6type=unknown
 104         v6lib=none
 105
 106         AC_MSG_CHECKING([ipv6 stack type])
 107         for i in v6d toshiba kame inria zeta linux linux-glibc solaris8; do
 108                 case $i in
 109                 v6d)
 110                         AC_EGREP_CPP(yes, [
 111 #include </usr/local/v6/include/sys/types.h>
 112 #ifdef __V6D__
 113 yes
 114 #endif],
 115                                 [v6type=$i; v6lib=v6;
 116                                 v6libdir=/usr/local/v6/lib;
 117                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 118                         ;;
 119                 toshiba)
 120                         AC_EGREP_CPP(yes, [
 121 #include <sys/param.h>
 122 #ifdef _TOSHIBA_INET6
 123 yes
 124 #endif],
 125                                 [v6type=$i; v6lib=inet6;
 126                                 v6libdir=/usr/local/v6/lib;
 127                                 CFLAGS="-DINET6 $CFLAGS"])
 128                         ;;
 129                 kame)
 130                         AC_EGREP_CPP(yes, [
 131 #include <netinet/in.h>
 132 #ifdef __KAME__
 133 yes
 134 #endif],
 135                                 [v6type=$i; v6lib=inet6;
 136                                 v6libdir=/usr/local/v6/lib;
 137                                 CFLAGS="-DINET6 $CFLAGS"])
 138                         ;;
 139                 inria)
 140                         AC_EGREP_CPP(yes, [
 141 #include <netinet/in.h>
 142 #ifdef IPV6_INRIA_VERSION
 143 yes
 144 #endif],
 145                                 [v6type=$i; CFLAGS="-DINET6 $CFLAGS"])
 146                         ;;
 147                 zeta)
 148                         AC_EGREP_CPP(yes, [
 149 #include <sys/param.h>
 150 #ifdef _ZETA_MINAMI_INET6
 151 yes
 152 #endif],
 153                                 [v6type=$i; v6lib=inet6;
 154                                 v6libdir=/usr/local/v6/lib;
 155                                 CFLAGS="-DINET6 $CFLAGS"])
 156                         ;;
 157                 linux)
 158                         if test -d /usr/inet6; then
 159                                 v6type=$i
 160                                 v6lib=inet6
 161                                 v6libdir=/usr/inet6
 162                                 CFLAGS="-DINET6 $CFLAGS"
 163                         fi
 164                         ;;
 165                 linux-glibc)
 166                         AC_EGREP_CPP(yes, [
 167 #include <features.h>
 168 #if defined(__GLIBC__) && defined(__GLIBC_MINOR__)
 169 #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || __GLIBC__ > 2
 170 yes
 171 #endif
 172 #endif],
 173                         [v6type=$i; v6lib=inet6; CFLAGS="-DINET6 $CFLAGS"])
 174                         ;;
 175                 solaris8)
 176                         if test "`uname -s`" = "SunOS" && test "`uname -r`" = "5.8"; then
 177                                 v6type=$i
 178                                 v6lib=inet6
 179                                 [CFLAGS="-DINET6 -DSOLARIS8_INET6 $CFLAGS"]
 180                         fi
 181                         ;;
 182                 esac
 183                 if test "$v6type" != "unknown"; then
 184                         break
 185                 fi
 186         done
 187
 188         if test "$v6lib" != "none"; then
 189                 for dir in $v6libdir /usr/local/v6/lib /usr/local/lib; do
 190                         if test -d $dir -a -f $dir/lib$v6lib.a; then
 191                                 LIBS="-L$dir $LIBS -l$v6lib"
 192                                 break
 193                         fi
 194                 done
 195                 enable_ipv6="yes"
 196         else
 197                 enable_ipv6="no"
 198         fi
 199         AC_MSG_RESULT(["$v6type, $v6lib"])
 200 ])
 201
 202 #
 203 # AC_WIRESHARK_GETHOSTBY_LIB_CHECK
 204 #
 205 # Checks whether we need "-lnsl" to get "gethostby*()", which we use
 206 # in "resolv.c".
 207 #
 208 # Adapted from stuff in the AC_PATH_XTRA macro in "acspecific.m4" in
 209 # GNU Autoconf 2.13; the comment came from there.
 210 # Done by Guy Harris <guy@alum.mit.edu> on 2000-01-14.
 211 #
 212 AC_DEFUN([AC_WIRESHARK_GETHOSTBY_LIB_CHECK],
 213 [
 214     # msh@cis.ufl.edu says -lnsl (and -lsocket) are needed for his 386/AT,
 215     # to get the SysV transport functions.
 216     # chad@anasazi.com says the Pyramid MIS-ES running DC/OSx (SVR4)
 217     # needs -lnsl.
 218     # The nsl library prevents programs from opening the X display
 219     # on Irix 5.2, according to dickey@clark.net.
 220     AC_CHECK_FUNC(gethostbyname, ,
 221         AC_CHECK_LIB(nsl, gethostbyname, NSL_LIBS="-lnsl"))
 222     AC_SUBST(NSL_LIBS)
 223 ])
 224
 225 #
 226 # AC_WIRESHARK_SOCKET_LIB_CHECK
 227 #
 228 # Checks whether we need "-lsocket" to get "socket()", which is used
 229 # by libpcap on some platforms - and, in effect, "gethostby*()" on
 230 # most if not all platforms (so that it can use NIS or DNS or...
 231 # to look up host names).
 232 #
 233 # Adapted from stuff in the AC_PATH_XTRA macro in "acspecific.m4" in
 234 # GNU Autoconf 2.13; the comment came from there.
 235 # Done by Guy Harris <guy@alum.mit.edu> on 2000-01-14.
 236 #
 237 # We use "connect" because that's what AC_PATH_XTRA did.
 238 #
 239 AC_DEFUN([AC_WIRESHARK_SOCKET_LIB_CHECK],
 240 [
 241     # lieder@skyler.mavd.honeywell.com says without -lsocket,
 242     # socket/setsockopt and other routines are undefined under SCO ODT
 243     # 2.0.  But -lsocket is broken on IRIX 5.2 (and is not necessary
 244     # on later versions), says simon@lia.di.epfl.ch: it contains
 245     # gethostby* variants that don't use the nameserver (or something).
 246     # -lsocket must be given before -lnsl if both are needed.
 247     # We assume that if connect needs -lnsl, so does gethostbyname.
 248     AC_CHECK_FUNC(connect, ,
 249       AC_CHECK_LIB(socket, connect, SOCKET_LIBS="-lsocket",
 250                 AC_MSG_ERROR(Function 'socket' not found.), $NSL_LIBS))
 251     AC_SUBST(SOCKET_LIBS)
 252 ])
 253
 254 #
 255 # AC_WIRESHARK_BREAKLOOP_TRY_LINK
 256 #
 257 AC_DEFUN([AC_WIRESHARK_PCAP_BREAKLOOP_TRY_LINK],
 258 [
 259   AC_LINK_IFELSE(
 260   [
 261       AC_LANG_SOURCE(
 262       [[
 263 #       include <pcap.h>
 264         int main(void)
 265         {
 266           pcap_t  *pct = NULL;
 267           pcap_breakloop(pct);
 268           return 0;
 269         }
 270       ]])
 271   ],
 272   [
 273     ws_breakloop_compiled=yes
 274   ],
 275   [
 276     ws_breakloop_compiled=no
 277   ])
 278 ])
 279
 280
 281
 282 #
 283 # AC_WIRESHARK_PCAP_CHECK
 284 #
 285 AC_DEFUN([AC_WIRESHARK_PCAP_CHECK],
 286 [
 287         if test -z "$pcap_dir"
 288         then
 289           # Pcap header checks
 290           # XXX need to set a var AC_CHECK_HEADER(pcap.h,,)
 291
 292           #
 293           # The user didn't specify a directory in which libpcap resides;
 294           # we assume that the current library search path will work,
 295           # but we may have to look for the header in a "pcap"
 296           # subdirectory of "/usr/include" or "/usr/local/include",
 297           # as some systems apparently put "pcap.h" in a "pcap"
 298           # subdirectory, and we also check "$prefix/include" - and
 299           # "$prefix/include/pcap", in case $prefix is set to
 300           # "/usr/include" or "/usr/local/include".
 301           #
 302           # XXX - should we just add "$prefix/include" to the include
 303           # search path and "$prefix/lib" to the library search path?
 304           #
 305           AC_MSG_CHECKING(for extraneous pcap header directories)
 306           found_pcap_dir=""
 307           pcap_dir_list="/usr/include/pcap $prefix/include/pcap $prefix/include"
 308           if test "x$ac_cv_enable_usr_local" = "xyes" ; then
 309             pcap_dir_list="$pcap_dir_list /usr/local/include/pcap"
 310           fi
 311           for pcap_dir in $pcap_dir_list
 312           do
 313             if test -d $pcap_dir ; then
 314                 if test x$pcap_dir != x/usr/include -a x$pcap_dir != x/usr/local/include ; then
 315                     CFLAGS="$CFLAGS -I$pcap_dir"
 316                     CPPFLAGS="$CPPFLAGS -I$pcap_dir"
 317                 fi
 318                 found_pcap_dir=" $found_pcap_dir -I$pcap_dir"
 319                 break
 320             fi
 321           done
 322
 323           if test "$found_pcap_dir" != "" ; then
 324             AC_MSG_RESULT(found --$found_pcap_dir added to CFLAGS)
 325           else
 326             AC_MSG_RESULT(not found)
 327           fi
 328         else
 329           #
 330           # The user specified a directory in which libpcap resides,
 331           # so add the "include" subdirectory of that directory to
 332           # the include file search path and the "lib" subdirectory
 333           # of that directory to the library search path.
 334           #
 335           # XXX - if there's also a libpcap in a directory that's
 336           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 337           # make us find the version in the specified directory,
 338           # as the compiler and/or linker will search that other
 339           # directory before it searches the specified directory.
 340           #
 341           CFLAGS="$CFLAGS -I$pcap_dir/include"
 342           CPPFLAGS="$CPPFLAGS -I$pcap_dir/include"
 343           AC_WIRESHARK_ADD_DASH_L(LDFLAGS, $pcap_dir/lib)
 344         fi
 345
 346         # Pcap header check
 347         AC_CHECK_HEADER(pcap.h,,
 348             AC_MSG_ERROR([[Header file pcap.h not found; if you installed libpcap
 349 from source, did you also do \"make install-incl\", and if you installed a
 350 binary package of libpcap, is there also a developer's package of libpcap,
 351 and did you also install that package?]]))
 352
 353         #
 354         # Check to see if we find "pcap_open_live" in "-lpcap".
 355         # Also check for various additional libraries that libpcap might
 356         # require.
 357         #
 358         AC_CHECK_LIB(pcap, pcap_open_live,
 359           [
 360             PCAP_LIBS=-lpcap
 361             AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
 362           ], [
 363             ac_wireshark_extras_found=no
 364             ac_save_LIBS="$LIBS"
 365             for extras in "-lcfg -lodm" "-lpfring"
 366             do
 367                 AC_MSG_CHECKING([for pcap_open_live in -lpcap with $extras])
 368                 LIBS="-lpcap $extras"
 369                 #
 370                 # XXX - can't we use AC_CHECK_LIB here?
 371                 #
 372                 AC_TRY_LINK(
 373                     [
 374 #       include <pcap.h>
 375                     ],
 376                     [
 377         pcap_open_live(NULL, 0, 0, 0, NULL);
 378                     ],
 379                     [
 380                         ac_wireshark_extras_found=yes
 381                         AC_MSG_RESULT([yes])
 382                         PCAP_LIBS="-lpcap $extras"
 383                         AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
 384                     ],
 385                     [
 386                         AC_MSG_RESULT([no])
 387                     ])
 388                 if test x$ac_wireshark_extras_found = xyes
 389                 then
 390                     break
 391                 fi
 392             done
 393             if test x$ac_wireshark_extras_found = xno
 394             then
 395                 AC_MSG_ERROR([Can't link with library libpcap.])
 396             fi
 397             LIBS=$ac_save_LIBS
 398           ], $SOCKET_LIBS $NSL_LIBS)
 399         AC_SUBST(PCAP_LIBS)
 400
 401         #
 402         # Check whether various variables and functions are defined by
 403         # libpcap.
 404         #
 405         ac_save_LIBS="$LIBS"
 406         AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 407         LIBS="$PCAP_LIBS $SOCKET_LIBS $NSL_LIBS $LIBS"
 408         AC_TRY_LINK(
 409            [
 410 #       include <stdio.h>
 411         extern char *pcap_version;
 412            ],
 413            [
 414         printf ("%s\n", pcap_version);
 415            ],
 416            ac_cv_pcap_version_defined=yes,
 417            ac_cv_pcap_version_defined=no,
 418            [echo $ac_n "cross compiling; assumed OK... $ac_c"])
 419         if test "$ac_cv_pcap_version_defined" = yes ; then
 420                 AC_MSG_RESULT(yes)
 421                 AC_DEFINE(HAVE_PCAP_VERSION, 1, [Define if libpcap version is known])
 422         else
 423                 AC_MSG_RESULT(no)
 424         fi
 425         AC_CHECK_FUNCS(pcap_open_dead pcap_freecode)
 426         #
 427         # pcap_breakloop may be present in the library but not declared
 428         # in the pcap.h header file.  If it's not declared in the header
 429         # file, attempts to use it will get warnings, and, if we're
 430         # building with warnings treated as errors, that warning will
 431         # cause compilation to fail.
 432         #
 433         # We are therefore first testing whether the function is present
 434         # and then, if we're compiling with warnings as errors, testing
 435         # whether it is usable.  It is usable if it compiles without
 436         # a -Wimplicit warning (the "compile with warnings as errors"
 437         # option requires GCC). If it is not usable, we fail and tell
 438         # the user that the pcap.h header needs to be updated.
 439         #
 440         # Ceteris paribus, this should only happen with Mac OS X 10.3[.x] which
 441         # can have an up-to-date pcap library without the corresponding pcap
 442         # header.
 443         #
 444         # However, it might also happen on some others OSes with some erroneous
 445         # system manipulations where multiple versions of libcap might co-exist
 446         # e.g. hand made symbolic link from libpcap.so -> libpcap.so.0.8 but
 447         # having the pcap header version 0.7.
 448         #
 449         AC_MSG_CHECKING([whether pcap_breakloop is present])
 450         ac_CFLAGS_saved="$CFLAGS"
 451         AC_WIRESHARK_PCAP_BREAKLOOP_TRY_LINK
 452         if test "x$ws_breakloop_compiled" = "xyes"; then
 453           AC_MSG_RESULT(yes)
 454           AC_DEFINE(HAVE_PCAP_BREAKLOOP, 1, [Define if pcap_breakloop is known])
 455           if test "x$with_warnings_as_errors" = "xyes"; then
 456             AC_MSG_CHECKING([whether pcap_breakloop is usable])
 457             CFLAGS="$CFLAGS -Werror -Wimplicit"
 458             AC_WIRESHARK_PCAP_BREAKLOOP_TRY_LINK
 459             if test "x$ws_breakloop_compiled" = "xyes"; then
 460               AC_MSG_RESULT(yes)
 461             else
 462               AC_MSG_RESULT(no)
 463               AC_MSG_ERROR(
 464 [Your pcap library is more recent than your pcap header.
 465 As you are building with compiler warnings treated as errors, Wireshark
 466 won't be able to use functions not declared in that header.
 467 If you wish to build with compiler warnings treated as errors, You should
 468 install a newer version of the header file.])
 469             fi
 470             CFLAGS="$ac_CFLAGS_saved"
 471           fi
 472         else
 473           AC_MSG_RESULT(no)
 474         fi
 475
 476         #
 477         # Later versions of Mac OS X 10.3[.x] ship a pcap.h that
 478         # doesn't define pcap_if_t but ship an 0.8[.x] libpcap,
 479         # so the library has "pcap_findalldevs()", but pcap.h
 480         # doesn't define "pcap_if_t" so you can't actually *use*
 481         # "pcap_findalldevs()".
 482         #
 483         # That even appears to be true of systems shipped with
 484         # 10.3.4, so it doesn't appear only to be a case of
 485         # Software Update not updating header files.
 486         #
 487         # (You can work around this by installing the 0.8 header
 488         # files.)
 489         #
 490         AC_CACHE_CHECK([whether pcap_findalldevs is present and usable],
 491           [ac_cv_func_pcap_findalldevs],
 492           [
 493             AC_LINK_IFELSE(
 494               [
 495                 AC_LANG_SOURCE(
 496                   [[
 497                     #include <pcap.h>
 498                     main()
 499                     {
 500                       pcap_if_t *devpointer;
 501                       char errbuf[1];
 502
 503                       pcap_findalldevs(&devpointer, errbuf);
 504                     }
 505                   ]])
 506               ],
 507               [
 508                 ac_cv_func_pcap_findalldevs=yes
 509               ],
 510               [
 511                 ac_cv_func_pcap_findalldevs=no
 512               ])
 513           ])
 514         #
 515         # Don't check for other new routines that showed up after
 516         # "pcap_findalldevs()" if we don't have a usable
 517         # "pcap_findalldevs()", so we don't end up using them if the
 518         # "pcap.h" is crufty and old and doesn't declare them.
 519         #
 520         if test $ac_cv_func_pcap_findalldevs = "yes" ; then
 521           AC_DEFINE(HAVE_PCAP_FINDALLDEVS, 1,
 522            [Define to 1 if you have the `pcap_findalldevs' function and a pcap.h that declares pcap_if_t.])
 523           AC_CHECK_FUNCS(pcap_datalink_val_to_name pcap_datalink_name_to_val)
 524           AC_CHECK_FUNCS(pcap_list_datalinks pcap_set_datalink pcap_lib_version)
 525           AC_CHECK_FUNCS(pcap_get_selectable_fd pcap_free_datalinks)
 526         fi
 527         LIBS="$ac_save_LIBS"
 528 ])
 529
 530 AC_DEFUN([AC_WIRESHARK_PCAP_REMOTE_CHECK],
 531 [
 532     ac_save_LIBS="$LIBS"
 533     LIBS="$PCAP_LIBS $SOCKET_LIBS $NSL_LIBS $LIBS"
 534     AC_DEFINE(HAVE_REMOTE, 1, [Define to 1 to enable remote
 535               capturing feature in WinPcap library])
 536     AC_CHECK_FUNCS(pcap_open pcap_findalldevs_ex pcap_createsrcstr)
 537     if test $ac_cv_func_pcap_open = "yes" -a \
 538             $ac_cv_func_pcap_findalldevs_ex = "yes" -a \
 539             $ac_cv_func_pcap_createsrcstr = "yes" ; then
 540         AC_DEFINE(HAVE_PCAP_REMOTE, 1,
 541             [Define to 1 if you have WinPcap remote capturing support and prefer to use these new API features.])
 542     fi
 543     AC_CHECK_FUNCS(pcap_setsampling)
 544     LIBS="$ac_save_LIBS"
 545 ])
 546
 547 #
 548 # AC_WIRESHARK_ZLIB_CHECK
 549 #
 550 AC_DEFUN([AC_WIRESHARK_ZLIB_CHECK],
 551 [
 552         if test "x$zlib_dir" != "x"
 553         then
 554           #
 555           # The user specified a directory in which zlib resides,
 556           # so add the "include" subdirectory of that directory to
 557           # the include file search path and the "lib" subdirectory
 558           # of that directory to the library search path.
 559           #
 560           # XXX - if there's also a zlib in a directory that's
 561           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 562           # make us find the version in the specified directory,
 563           # as the compiler and/or linker will search that other
 564           # directory before it searches the specified directory.
 565           #
 566           wireshark_save_CFLAGS="$CFLAGS"
 567           CFLAGS="$CFLAGS -I$zlib_dir/include"
 568           wireshark_save_CPPFLAGS="$CPPFLAGS"
 569           CPPFLAGS="$CPPFLAGS -I$zlib_dir/include"
 570           wireshark_save_LIBS="$LIBS"
 571           AC_WIRESHARK_ADD_DASH_L(LIBS, $zlib_dir/lib)
 572         fi
 573
 574         #
 575         # Make sure we have "zlib.h".  If we don't, it means we probably
 576         # don't have zlib, so don't use it.
 577         #
 578         AC_CHECK_HEADER(zlib.h,,
 579           [
 580             if test "x$zlib_dir" != "x"
 581             then
 582               #
 583               # The user used "--with-zlib=" to specify a directory
 584               # containing zlib, but we didn't find the header file
 585               # there; that either means they didn't specify the
 586               # right directory or are confused about whether zlib
 587               # is, in fact, installed.  Report the error and give up.
 588               #
 589               AC_MSG_ERROR([zlib header not found in directory specified in --with-zlib])
 590             else
 591               if test "x$want_zlib" = "xyes"
 592               then
 593                 #
 594                 # The user tried to force us to use the library, but we
 595                 # couldn't find the header file; report an error.
 596                 #
 597                 AC_MSG_ERROR(Header file zlib.h not found.)
 598               else
 599                 #
 600                 # We couldn't find the header file; don't use the
 601                 # library, as it's probably not present.
 602                 #
 603                 want_zlib=no
 604               fi
 605             fi
 606           ])
 607
 608         if test "x$want_zlib" != "xno"
 609         then
 610                 #
 611                 # Well, we at least have the zlib header file.
 612                 #
 613                 # Check for "gzgets()" in zlib, because we need it, but
 614                 # some older versions of zlib don't have it.  It appears
 615                 # from the zlib ChangeLog that any released version of zlib
 616                 # with "gzgets()" should have the other routines we
 617                 # depend on, such as "gzseek()", "gztell()", and "zError()".
 618                 #
 619                 # Another reason why we require "gzgets()" is that
 620                 # some versions of zlib that didn't have it, such
 621                 # as 1.0.8, had a bug in "gzseek()" that meant that it
 622                 # doesn't work correctly on uncompressed files; this
 623                 # means we cannot use version 1.0.8.  (Unfortunately,
 624                 # that's the version that comes with recent X11 source,
 625                 # and many people who install XFree86 on their Slackware
 626                 # boxes don't realize that they should configure it to
 627                 # use the native zlib rather than building and installing
 628                 # the crappy old version that comes with XFree86.)
 629                 #
 630                 # I.e., we can't just avoid using "gzgets()", as
 631                 # versions of zlib without "gzgets()" are likely to have
 632                 # a broken "gzseek()".
 633                 #
 634                 AC_CHECK_LIB(z, gzgets,
 635                 [
 636                         if test "x$zlib_dir" != "x"
 637                         then
 638                                 #
 639                                 # Put the "-I" and "-L" flags for zlib at
 640                                 # the beginning of CFLAGS, CPPFLAGS, and
 641                                 # LIBS.
 642                                 #
 643                                 LIBS=""
 644                                 AC_WIRESHARK_ADD_DASH_L(LIBS, $zlib_dir/lib)
 645                                 LIBS="$LIBS -lz $wireshark_save_LIBS"
 646                         else
 647                                 LIBS="-lz $LIBS"
 648                         fi
 649                         AC_DEFINE(HAVE_LIBZ, 1, [Define to use libz library])
 650                 ],[
 651                         if test "x$zlib_dir" != "x"
 652                         then
 653                                 #
 654                                 # Restore the versions of CFLAGS, CPPFLAGS,
 655                                 # and LIBS before we added the "-with-zlib="
 656                                 # directory, as we didn't actually find
 657                                 # zlib there, or didn't find a zlib that
 658                                 # contains gzgets there.
 659                                 #
 660                                 CFLAGS="$wireshark_save_CFLAGS"
 661                                 CPPFLAGS="$wireshark_save_CPPFLAGS"
 662                                 LIBS="$wireshark_save_LIBS"
 663                         fi
 664                         want_zlib=no
 665                 ])
 666         fi
 667
 668         if test "x$want_zlib" != "xno"
 669         then
 670                 #
 671                 # Well, we at least have the zlib header file and a zlib
 672                 # with "gzgets()".
 673                 #
 674                 # Now check for "gzgets()" in zlib when linking with the
 675                 # linker flags for GTK+ applications; people often grab
 676                 # XFree86 source and build and install it on their systems,
 677                 # and they appear sometimes to misconfigure XFree86 so that,
 678                 # even on systems with zlib, it assumes there is no zlib,
 679                 # so the XFree86 build process builds and installs its
 680                 # own zlib in the X11 library directory.
 681                 #
 682                 # The XFree86 zlib is an older version that lacks
 683                 # "gzgets()", and that's the zlib with which Wireshark
 684                 # gets linked, so the build of Wireshark fails.
 685                 #
 686                 ac_save_CFLAGS="$CFLAGS"
 687                 ac_save_LIBS="$LIBS"
 688                 CFLAGS="$CFLAGS $GTK_CFLAGS"
 689                 LIBS="$GTK_LIBS -lz $LIBS"
 690                 AC_MSG_CHECKING([for gzgets missing when linking with X11])
 691                 AC_TRY_LINK_FUNC(gzgets, AC_MSG_RESULT(no),
 692                   [
 693                     AC_MSG_RESULT(yes)
 694                     AC_MSG_ERROR(old zlib found when linking with X11 - get rid of old zlib.)
 695                   ])
 696                 CFLAGS="$ac_save_CFLAGS"
 697                 LIBS="$ac_save_LIBS"
 698         fi
 699 ])
 700
 701 #
 702 # AC_WIRESHARK_LIBPCRE_CHECK
 703 #
 704 AC_DEFUN([AC_WIRESHARK_LIBPCRE_CHECK],
 705 [
 706         if test "x$pcre_dir" != "x"
 707         then
 708           #
 709           # The user specified a directory in which libpcre resides,
 710           # so add the "include" subdirectory of that directory to
 711           # the include file search path and the "lib" subdirectory
 712           # of that directory to the library search path.
 713           #
 714           # XXX - if there's also a libpcre in a directory that's
 715           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 716           # make us find the version in the specified directory,
 717           # as the compiler and/or linker will search that other
 718           # directory before it searches the specified directory.
 719           #
 720           wireshark_save_CFLAGS="$CFLAGS"
 721           CFLAGS="$CFLAGS -I$pcre_dir/include"
 722           wireshark_save_CPPFLAGS="$CPPFLAGS"
 723           CPPFLAGS="$CPPFLAGS -I$pcre_dir/include"
 724           wireshark_save_LIBS="$LIBS"
 725           LIBS="$LIBS -lpcre"
 726           wireshark_save_LDFLAGS="$LDFLAGS"
 727           LDFLAGS="$LDFLAGS -L$pcre_dir/lib"
 728         fi
 729
 730         #
 731         # Make sure we have "pcre.h".  If we don't, it means we probably
 732         # don't have libpcre, so don't use it.
 733         #
 734         AC_CHECK_HEADER(pcre.h,,
 735           [
 736             if test "x$pcre_dir" != "x"
 737             then
 738               #
 739               # The user used "--with-pcre=" to specify a directory
 740               # containing libpcre, but we didn't find the header file
 741               # there; that either means they didn't specify the
 742               # right directory or are confused about whether libpcre
 743               # is, in fact, installed.  Report the error and give up.
 744               #
 745               AC_MSG_ERROR([libpcre header not found in directory specified in --with-pcre])
 746             else
 747               if test "x$want_pcre" = "xyes"
 748               then
 749                 #
 750                 # The user tried to force us to use the library, but we
 751                 # couldn't find the header file; report an error.
 752                 #
 753                 AC_MSG_ERROR(Header file pcre.h not found.)
 754               else
 755                 #
 756                 # We couldn't find the header file; don't use the
 757                 # library, as it's probably not present.
 758                 #
 759                 want_pcre=no
 760               fi
 761             fi
 762           ])
 763
 764         if test "x$want_pcre" != "xno"
 765         then
 766                 #
 767                 # Well, we at least have the pcre header file.
 768                 #
 769                 # We're only using standard functions from libpcre,
 770                 # so we don't need to perform extra checks.
 771                 #
 772                 AC_CHECK_LIB(pcre, pcre_compile,
 773                 [
 774                         if test "x$pcre_dir" != "x"
 775                         then
 776                                 #
 777                                 # Put the "-I" and "-L" flags for pcre at
 778                                 # the beginning of CFLAGS, CPPFLAGS,
 779                                 # LDFLAGS, and LIBS.
 780                                 #
 781                                 PCRE_LIBS="-L$pcre_dir/lib -lpcre $wireshark_save_LIBS"
 782                         else
 783                                 PCRE_LIBS="-lpcre"
 784                         fi
 785                         AC_DEFINE(HAVE_LIBPCRE, 1, [Define to use libpcre library])
 786                 ],[
 787                         if test "x$pcre_dir" != "x"
 788                         then
 789                                 #
 790                                 # Restore the versions of CFLAGS, CPPFLAGS,
 791                                 # LDFLAGS, and LIBS before we added the
 792                                 # "--with-pcre=" directory, as we didn't
 793                                 # actually find pcre there.
 794                                 #
 795                                 CFLAGS="$wireshark_save_CFLAGS"
 796                                 CPPFLAGS="$wireshark_save_CPPFLAGS"
 797                                 LDFLAGS="$wireshark_save_LDFLAGS"
 798                                 LIBS="$wireshark_save_LIBS"
 799                                 PCRE_LIBS=""
 800                         fi
 801                         want_pcre=no
 802                 ])
 803                 AC_SUBST(PCRE_LIBS)
 804         fi
 805 ])
 806
 807 #
 808 # AC_WIRESHARK_LIBLUA_CHECK
 809 #
 810 AC_DEFUN([AC_WIRESHARK_LIBLUA_CHECK],[
 811
 812         if test "x$lua_dir" != "x"
 813         then
 814                 #
 815                 # The user specified a directory in which liblua resides,
 816                 # so add the "include" subdirectory of that directory to
 817                 # the include file search path and the "lib" subdirectory
 818                 # of that directory to the library search path.
 819                 #
 820                 # XXX - if there's also a liblua in a directory that's
 821                 # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 822                 # make us find the version in the specified directory,
 823                 # as the compiler and/or linker will search that other
 824                 # directory before it searches the specified directory.
 825                 #
 826                 wireshark_save_CFLAGS="$CFLAGS"
 827                 CFLAGS="$CFLAGS -I$lua_dir/include"
 828                 wireshark_save_CPPFLAGS="$CPPFLAGS"
 829                 CPPFLAGS="$CPPFLAGS -I$lua_dir/include"
 830                 wireshark_save_LIBS="$LIBS"
 831                 LIBS="$LIBS -L$lua_dir/lib -llua -lm"
 832                 wireshark_save_LDFLAGS="$LDFLAGS"
 833                 LDFLAGS="$LDFLAGS -L$lua_dir/lib"
 834         else
 835                 #
 836                 # The user specified no directory in which liblua resides,
 837                 # so just add "-llua -lliblua" to the used libs.
 838                 #
 839                 wireshark_save_CFLAGS="$CFLAGS"
 840                 wireshark_save_CPPFLAGS="$CPPFLAGS"
 841                 wireshark_save_LDFLAGS="$LDFLAGS"
 842                 wireshark_save_LIBS="$LIBS"
 843                 LIBS="$LIBS -llua -lm"
 844         fi
 845
 846         #
 847         # Make sure we have "lua.h", "lualib.h" and "lauxlib.h".  If we don't, it means we probably
 848         # don't have liblua, so don't use it.
 849         #
 850         AC_CHECK_HEADERS(lua.h lualib.h lauxlib.h,,
 851         [
 852                 AC_CHECK_HEADERS(lua5.1/lua.h lua5.1/lualib.h lua5.1/lauxlib.h,
 853                 [
 854                         if test "x$lua_dir" != "x"
 855                         then
 856                                 LUA_INCLUDES="-I$lua_dir/include/lua5.1"
 857                         else
 858                                 # we found lua5.1/lua.h, but we don't know which include dir contains it
 859                                 AC_MSG_ERROR(Header file lua.h was found as lua5.1/lua.h but we can't use it. Please set the PATH for the --with-lua configure parameter. \n probably it is /usr.)
 860                         fi
 861
 862                 ],
 863                 [
 864                         if test "x$lua_dir" != "x"
 865                         then
 866                                 #
 867                                 # The user used "--with-lua=" to specify a directory
 868                                 # containing liblua, but we didn't find the header file
 869                                 # there; that either means they didn't specify the
 870                                 # right directory or are confused about whether liblua
 871                                 # is, in fact, installed.  Report the error and give up.
 872                                 #
 873                                 AC_MSG_ERROR([liblua header not found in directory specified in --with-lua])
 874                         else
 875                                 if test "x$want_lua" = "xyes"
 876                                 then
 877                                         #
 878                                         # The user tried to force us to use the library, but we
 879                                         # couldn't find the header file; report an error.
 880                                         #
 881                                         AC_MSG_ERROR(Header file lua.h not found.)
 882                                 else
 883                                         #
 884                                         # We couldn't find the header file; don't use the
 885                                         # library, as it's probably not present.
 886                                         #
 887                                         want_lua=no
 888                                 fi
 889                         fi
 890                 ])
 891         ])
 892
 893         if test "x$want_lua" != "xno"
 894         then
 895                 #
 896                 # Well, we at least have the lua header file.
 897                 #
 898                 # let's check if the libs are there
 899                 #
 900
 901                 # At least on Suse 9.3 systems, liblualib needs linking
 902                 # against libm.
 903                 LIBS="$LIBS $LUA_LIBS -lm"
 904
 905                 AC_CHECK_LIB(lua, luaL_register,
 906                 [
 907                     #
 908                     #  Lua 5.1 found
 909                     #
 910                         if test "x$lua_dir" != "x"
 911                         then
 912                                 #
 913                                 # Put the "-I" and "-L" flags for lua at
 914                                 # the beginning of CFLAGS, CPPFLAGS,
 915                                 # LDFLAGS, and LIBS.
 916                                 #
 917                                 LUA_LIBS="-L$lua_dir/lib -llua -lm"
 918                                 LUA_INCLUDES="-I$lua_dir/include"
 919                         else
 920                                 LUA_LIBS="-llua -lm"
 921                                 LUA_INCLUDES=""
 922                         fi
 923                         AC_DEFINE(HAVE_LUA_5_1, 1, [Define to use Lua 5.1])
 924
 925                 ],[
 926                         #
 927                         # We could not find the libs, maybe we have version number in the lib name
 928                         #
 929
 930                         LIBS="$wireshark_save_LIBS -llua5.1 -lm"
 931
 932                         AC_CHECK_LIB(lua5.1, luaL_register,
 933                         [
 934                             #
 935                             #  Lua 5.1 found
 936                             #
 937                             AC_DEFINE(HAVE_LUA_5_1, 1, [Define to use Lua 5.1])
 938                             LUA_LIBS=" -llua5.1 -lm"
 939                         ],[
 940                                 #
 941                                 # Restore the versions of CFLAGS, CPPFLAGS,
 942                                 # LDFLAGS, and LIBS before we added the
 943                                 # "--with-lua=" directory, as we didn't
 944                                 # actually find lua there.
 945                                 #
 946                                 CFLAGS="$wireshark_save_CFLAGS"
 947                                 CPPFLAGS="$wireshark_save_CPPFLAGS"
 948                                 LDFLAGS="$wireshark_save_LDFLAGS"
 949                                 LIBS="$wireshark_save_LIBS"
 950                                 LUA_LIBS=""
 951                                 # User requested --with-lua but it isn't available
 952                                 if test "x$want_lua" = "xyes"
 953                                 then
 954                                         AC_MSG_ERROR(Linking with liblua failed.)
 955                                 fi
 956                                 want_lua=no
 957                         ])
 958                 ])
 959
 960         CFLAGS="$wireshark_save_CFLAGS"
 961         CPPFLAGS="$wireshark_save_CPPFLAGS"
 962         LDFLAGS="$wireshark_save_LDFLAGS"
 963         LIBS="$wireshark_save_LIBS"
 964         AC_SUBST(LUA_LIBS)
 965         AC_SUBST(LUA_INCLUDES)
 966
 967         fi
 968 ])
 969
 970 #
 971 # AC_WIRESHARK_LIBPORTAUDIO_CHECK
 972 #
 973 AC_DEFUN([AC_WIRESHARK_LIBPORTAUDIO_CHECK],[
 974
 975         if test "x$portaudio_dir" != "x"
 976         then
 977                 #
 978                 # The user specified a directory in which libportaudio
 979                 # resides, so add the "include" subdirectory of that directory to
 980                 # the include file search path and the "lib" subdirectory
 981                 # of that directory to the library search path.
 982                 #
 983                 # XXX - if there's also a libportaudio in a directory that's
 984                 # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 985                 # make us find the version in the specified directory,
 986                 # as the compiler and/or linker will search that other
 987                 # directory before it searches the specified directory.
 988                 #
 989                 wireshark_save_CFLAGS="$CFLAGS"
 990                 CFLAGS="$CFLAGS -I$portaudio_dir/include"
 991                 wireshark_save_CPPFLAGS="$CPPFLAGS"
 992                 CPPFLAGS="$CPPFLAGS -I$portaudio_dir/include"
 993                 wireshark_save_LIBS="$LIBS"
 994                 LIBS="$LIBS -L$portaudio_dir/lib -lportaudio"
 995                 wireshark_save_LDFLAGS="$LDFLAGS"
 996                 LDFLAGS="$LDFLAGS -L$portaudio_dir/lib"
 997         else
 998                 #
 999                 # The user specified no directory in which libportaudio resides,
1000                 # so just add "-lportaudio" to the used libs.
1001                 #
1002                 wireshark_save_CFLAGS="$CFLAGS"
1003                 wireshark_save_CPPFLAGS="$CPPFLAGS"
1004                 wireshark_save_LDFLAGS="$LDFLAGS"
1005                 wireshark_save_LIBS="$LIBS"
1006                 LIBS="$LIBS -lportaudio"
1007         fi
1008
1009         #
1010         # Make sure we have "portaudio.h".  If we don't, it means we probably
1011         # don't have libportaudio, so don't use it.
1012         #
1013         AC_CHECK_HEADERS(portaudio.h,,
1014         [
1015                 if test "x$portaudio_dir" != "x"
1016                 then
1017                         #
1018                         # The user used "--with-portaudio=" to specify a directory
1019                         # containing libportaudio, but we didn't find the header file
1020                         # there; that either means they didn't specify the
1021                         # right directory or are confused about whether libportaudio
1022                         # is, in fact, installed.  Report the error and give up.
1023                         #
1024                         AC_MSG_ERROR([libportaudio header not found in directory specified in --with-portaudio])
1025                 else
1026                         CFLAGS="$wireshark_save_CFLAGS"
1027                         CPPFLAGS="$wireshark_save_CPPFLAGS"
1028                         LDFLAGS="$wireshark_save_LDFLAGS"
1029                         LIBS="$wireshark_save_LIBS"
1030                         PORTAUDIO_LIBS=""
1031                         if test "x$want_portaudio" = "xyes"
1032                         then
1033                                 #
1034                                 # The user tried to force us to use the library, but we
1035                                 # couldn't find the header file; report an error.
1036                                 #
1037                                 AC_MSG_ERROR(Header file portaudio.h not found.)
1038                         else
1039                                 #
1040                                 # We couldn't find the header file; don't use the
1041                                 # library, as it's probably not present.
1042                                 #
1043                                 want_portaudio=no
1044                         fi
1045                 fi
1046         ])
1047
1048         #
1049         # Check whether we have the right version of portaudio
1050         #
1051         if test "x$want_portaudio" != "xno"
1052         then
1053                 AC_CHECK_TYPE(PortAudioStream,
1054                 AC_DEFINE(PORTAUDIO_API_1, 1, [Define if we are using version of of the Portaudio library API]),
1055                 ,
1056                 [#include <portaudio.h>])
1057         fi
1058
1059         if test "x$want_portaudio" != "xno"
1060         then
1061                 #
1062                 # Well, we at least have the portaudio header file.
1063                 #
1064                 # let's check if the libs are there
1065                 #
1066
1067                 AC_CHECK_LIB(portaudio, Pa_Initialize,
1068                 [
1069                         if test "x$portaudio_dir" != "x"
1070                         then
1071                                 #
1072                                 # Put the "-I" and "-L" flags for portaudio at
1073                                 # the beginning of CFLAGS, CPPFLAGS,
1074                                 # LDFLAGS, and LIBS.
1075                                 #
1076                                 PORTAUDIO_LIBS="-L$portaudio_dir/lib -lportaudio"
1077                                 PORTAUDIO_INCLUDES="-I$portaudio_dir/include"
1078                         else
1079                                 PORTAUDIO_LIBS="-lportaudio"
1080                                 PORTAUDIO_INCLUDES=""
1081                         fi
1082                         AC_DEFINE(HAVE_LIBPORTAUDIO, 1, [Define to use libportaudio library])
1083                         want_portaudio=yes
1084                 ],[
1085                         #
1086                         # Restore the versions of CFLAGS, CPPFLAGS,
1087                         # LDFLAGS, and LIBS before we added the
1088                         # "--with-portaudio=" directory, as we didn't
1089                         # actually find portaudio there.
1090                         #
1091                         CFLAGS="$wireshark_save_CFLAGS"
1092                         CPPFLAGS="$wireshark_save_CPPFLAGS"
1093                         LDFLAGS="$wireshark_save_LDFLAGS"
1094                         LIBS="$wireshark_save_LIBS"
1095                         PORTAUDIO_LIBS=""
1096                         # User requested --with-portaudio but it isn't available
1097                         if test "x$want_portaudio" = "xyes"
1098                         then
1099                                 AC_MSG_ERROR(Linking with libportaudio failed.)
1100                         fi
1101                         want_portaudio=no
1102                 ])
1103
1104         CFLAGS="$wireshark_save_CFLAGS"
1105         CPPFLAGS="$wireshark_save_CPPFLAGS"
1106         LDFLAGS="$wireshark_save_LDFLAGS"
1107         LIBS="$wireshark_save_LIBS"
1108         AC_SUBST(PORTAUDIO_LIBS)
1109         AC_SUBST(PORTAUDIO_INCLUDES)
1110
1111         fi
1112 ])
1113
1114 #
1115 # AC_WIRESHARK_RPM_CHECK
1116 # Looks for the rpm program, and checks to see if we can redefine "_topdir".
1117 #
1118 AC_DEFUN([AC_WIRESHARK_RPM_CHECK],
1119 [
1120         AC_CHECK_PROG(ac_cv_wireshark_have_rpm, rpm, "yes", "no")
1121         if test "x$ac_cv_wireshark_have_rpm" = "xyes"; then
1122                 rpm --define '_topdir /tmp' > /dev/null 2>&1
1123                 AC_MSG_CHECKING(to see if we can redefine _topdir)
1124                 if test $? -eq 0 ; then
1125                         AC_MSG_RESULT(yes)
1126                         HAVE_RPM=yes
1127                 else
1128                         AC_MSG_RESULT(no.  You'll have to build packages manually.)
1129                         HAVE_RPM=no
1130                 fi
1131         fi
1132 ])
1133
1134 #
1135 # AC_WIRESHARK_GNU_SED_CHECK
1136 # Checks if GNU sed is the first sed in PATH.
1137 #
1138 AC_DEFUN([AC_WIRESHARK_GNU_SED_CHECK],
1139 [
1140         AC_MSG_CHECKING(for GNU sed as first sed in PATH)
1141         if  ( sh -c "sed --version" </dev/null 2> /dev/null | grep "GNU sed" 2>&1 > /dev/null ) ;  then
1142                 AC_MSG_RESULT(yes)
1143                 HAVE_GNU_SED=yes
1144         else
1145                 AC_MSG_RESULT(no)
1146                 HAVE_GNU_SED=no
1147         fi
1148 ])
1149
1150 #
1151 # AC_WIRESHARK_C_ARES_CHECK
1152 #
1153 AC_DEFUN([AC_WIRESHARK_C_ARES_CHECK],
1154 [
1155         want_c_ares=defaultyes
1156
1157         if test "x$want_c_ares" = "xdefaultyes"; then
1158                 want_c_ares=yes
1159                 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
1160                         withval=/usr/local
1161                         if test -d "$withval"; then
1162                                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1163                         fi
1164                 fi
1165         fi
1166
1167         if test "x$want_c_ares" = "xyes"; then
1168                 AC_CHECK_LIB(cares, ares_init,
1169                   [
1170                     C_ARES_LIBS=-lcares
1171                 AC_DEFINE(HAVE_C_ARES, 1, [Define to use c-ares library])
1172                 have_good_c_ares=yes
1173                   ],, $SOCKET_LIBS $NSL_LIBS
1174                 )
1175         else
1176                 AC_MSG_RESULT(not required)
1177         fi
1178 ])
1179
1180
1181 #
1182 # AC_WIRESHARK_ADNS_CHECK
1183 #
1184 AC_DEFUN([AC_WIRESHARK_ADNS_CHECK],
1185 [
1186         want_adns=defaultyes
1187
1188         if test "x$want_adns" = "xdefaultyes"; then
1189                 want_adns=yes
1190                 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
1191                         withval=/usr/local
1192                         if test -d "$withval"; then
1193                                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1194                         fi
1195                 fi
1196         fi
1197
1198         if test "x$want_adns" = "xyes"; then
1199                 AC_CHECK_LIB(adns, adns_init,
1200                   [
1201                     ADNS_LIBS=-ladns
1202                 AC_DEFINE(HAVE_GNU_ADNS, 1, [Define to use GNU ADNS library])
1203                 have_good_adns=yes
1204                   ],, $SOCKET_LIBS $NSL_LIBS
1205                 )
1206         else
1207                 AC_MSG_RESULT(not required)
1208         fi
1209 ])
1210
1211
1212 #
1213 # AC_WIRESHARK_LIBCAP_CHECK
1214 #
1215 AC_DEFUN([AC_WIRESHARK_LIBCAP_CHECK],
1216 [
1217         want_libcap=defaultyes
1218
1219         if test "x$want_libcap" = "xdefaultyes"; then
1220                 want_libcap=yes
1221                 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
1222                         withval=/usr/local
1223                         if test -d "$withval"; then
1224                                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1225                         fi
1226                 fi
1227         fi
1228
1229         if test "x$want_libcap" = "xyes"; then
1230                 AC_CHECK_LIB(cap, cap_set_flag,
1231                   [
1232                     LIBCAP_LIBS=-lcap
1233                 AC_DEFINE(HAVE_LIBCAP, 1, [Define to use the libcap library])
1234                 have_good_libcap=yes
1235                   ],,
1236                 )
1237         else
1238                 AC_MSG_RESULT(not required)
1239         fi
1240 ])
1241
1242
1243 #
1244 # AC_WIRESHARK_KRB5_CHECK
1245 #
1246 AC_DEFUN([AC_WIRESHARK_KRB5_CHECK],
1247 [
1248         wireshark_save_CFLAGS="$CFLAGS"
1249         wireshark_save_CPPFLAGS="$CPPFLAGS"
1250         if test "x$krb5_dir" != "x"
1251         then
1252           #
1253           # The user specified a directory in which kerberos resides,
1254           # so add the "include" subdirectory of that directory to
1255           # the include file search path and the "lib" subdirectory
1256           # of that directory to the library search path.
1257           #
1258           # XXX - if there's also a kerberos in a directory that's
1259           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
1260           # make us find the version in the specified directory,
1261           # as the compiler and/or linker will search that other
1262           # directory before it searches the specified directory.
1263           #
1264           CFLAGS="$CFLAGS -I$krb5_dir/include"
1265           CPPFLAGS="$CPPFLAGS -I$krb5_dir/include"
1266           ac_heimdal_version=`grep heimdal $krb5_dir/include/krb5.h | head -n 1 | sed 's/^.*heimdal.*$/HEIMDAL/'`
1267           ac_mit_version=`grep 'Massachusetts Institute of Technology' $krb5_dir/include/krb5.h | head -n 1 | sed 's/^.*Massachusetts Institute of Technology.*$/MIT/'`
1268           ac_krb5_version="$ac_heimdal_version$ac_mit_version"
1269           if test "x$ac_krb5_version" = "xHEIMDAL"
1270               KRB5_LIBS="-L$krb5_dir/lib -lkrb5 -lasn1 $SSL_LIBS -lroken -lcrypt"
1271           then
1272               KRB5_LIBS="-L$krb5_dir/lib -lkrb5 -lk5crypto -lcom_err"
1273           fi
1274           if test "x$ac_krb5_version" = "xMIT"
1275           then
1276             AC_DEFINE(HAVE_MIT_KERBEROS, 1, [Define to use MIT kerberos])
1277           fi
1278         else
1279           AC_PATH_PROG(KRB5_CONFIG, krb5-config)
1280           if test -x "$KRB5_CONFIG"
1281           then
1282             KRB5_FLAGS=`"$KRB5_CONFIG" --cflags`
1283             KRB5_LIBS=`"$KRB5_CONFIG" --libs`
1284             CFLAGS="$CFLAGS $KRB5_FLAGS"
1285             CPPFLAGS="$CPPFLAGS $KRB5_FLAGS"
1286             #
1287             # If -lcrypto is in KRB5_FLAGS, we require it to build
1288             # with Heimdal/MIT.  We don't want to built with it by
1289             # default, due to annoying license incompatibilities
1290             # between the OpenSSL license and the GPL, so:
1291             #
1292             #   if SSL_LIBS is set to a non-empty string, we
1293             #   remove -lcrypto from KRB5_LIBS and replace
1294             #   it with SSL_LIBS;
1295             #
1296             #   if SSL_LIBS is not set to a non-empty string
1297             #   we fail with an appropriate error message.
1298             #
1299             case "$KRB5_LIBS" in
1300             *-lcrypto*)
1301                 if test ! -z "$SSL_LIBS"
1302                 then
1303                     KRB5_LIBS=`echo $KRB5_LIBS | sed 's/-lcrypto//'`
1304                     KRB5_LIBS="$KRB5_LIBS $SSL_LIBS"
1305                 else
1306                     AC_MSG_ERROR([Kerberos library requires -lcrypto but --with-ssl not specified])
1307                 fi
1308                 ;;
1309             esac
1310             ac_krb5_version=`"$KRB5_CONFIG" --version | head -n 1 | sed -e 's/^.*heimdal.*$/HEIMDAL/' -e 's/^Kerberos .*$/MIT/'`
1311           fi
1312         fi
1313
1314         #
1315         # Make sure we have "krb5.h".  If we don't, it means we probably
1316         # don't have kerberos, so don't use it.
1317         #
1318         AC_CHECK_HEADER(krb5.h,,
1319           [
1320             if test "x$krb5_dir" != "x"
1321             then
1322               #
1323               # The user used "--with-krb5=" to specify a directory
1324               # containing kerberos, but we didn't find the header file
1325               # there; that either means they didn't specify the
1326               # right directory or are confused about whether kerberos
1327               # is, in fact, installed.  Report the error and give up.
1328               #
1329               AC_MSG_ERROR([kerberos header not found in directory specified in --with-krb5])
1330             else
1331               if test "x$want_krb5" = "xyes"
1332               then
1333                 #
1334                 # The user tried to force us to use the library, but we
1335                 # couldn't find the header file; report an error.
1336                 #
1337                 AC_MSG_ERROR(Header file krb5.h not found.)
1338               else
1339                 #
1340                 # We couldn't find the header file; don't use the
1341                 # library, as it's probably not present.
1342                 #
1343                 want_krb5=no
1344                 AC_MSG_RESULT(No Heimdal or MIT header found - disabling dissection for some kerberos data in packet decoding)
1345               fi
1346             fi
1347           ])
1348
1349         if test "x$want_krb5" != "xno"
1350         then
1351             #
1352             # Well, we at least have the krb5 header file.
1353             # Check whether this is Heimdal or MIT.
1354             #
1355             AC_MSG_CHECKING(whether the Kerberos library is Heimdal or MIT)
1356             if test "x$ac_krb5_version" = "xHEIMDAL" -o "x$ac_krb5_version" = "xMIT"
1357             then
1358                 #
1359                 # Yes.
1360                 # Check whether we have krb5_kt_resolve - and whether
1361                 # we need to link with -lresolv when linking with
1362                 # the Kerberos library.
1363                 #
1364                 AC_MSG_RESULT($ac_krb5_version)
1365                 wireshark_save_LIBS="$LIBS"
1366                 found_krb5_kt_resolve=no
1367                 for extras in "" "-lresolv"
1368                 do
1369                     LIBS="$KRB5_LIBS $extras"
1370                     if test -z "$extras"
1371                     then
1372                         AC_MSG_CHECKING([whether $ac_krb5_version includes krb5_kt_resolve])
1373                     else
1374                         AC_MSG_CHECKING([whether $ac_krb5_version includes krb5_kt_resolve (linking with $extras)])
1375                     fi
1376                     AC_TRY_LINK(
1377                         [
1378                         ],
1379                         [
1380                             krb5_kt_resolve();
1381                         ],
1382                         [
1383                             #
1384                             # We found "krb5_kt_resolve()", and required
1385                             # the libraries in extras as well.
1386                             #
1387                             AC_MSG_RESULT(yes)
1388                             KRB5_LIBS="$LIBS"
1389                             AC_DEFINE(HAVE_KERBEROS, 1, [Define to use kerberos])
1390                             if test "x$ac_krb5_version" = "xHEIMDAL"
1391                             then
1392                                 AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1, [Define to use heimdal kerberos])
1393                             elif test "x$ac_krb5_version" = "xMIT"
1394                             then
1395                                 AC_DEFINE(HAVE_MIT_KERBEROS, 1, [Define to use MIT kerberos])
1396                             fi
1397                             found_krb5_kt_resolve=yes
1398                             break
1399                         ],
1400                         [
1401                             AC_MSG_RESULT(no)
1402                         ])
1403                 done
1404                 if test "$found_krb5_kt_resolve" = no
1405                 then
1406                     #
1407                     # We didn't find "krb5_kt_resolve()" in the
1408                     # Kerberos library, even when we tried linking
1409                     # with -lresolv; we can't link with kerberos.
1410                     #
1411                     if test "x$want_krb5" = "xyes"
1412                     then
1413                         #
1414                         # The user tried to force us to use the library,
1415                         # but we can't do so; report an error.
1416                         #
1417                         AC_MSG_ERROR(Usable $ac_krb5_version not found)
1418                     else
1419                         #
1420                         # Restore the versions of CFLAGS and CPPFLAGS
1421                         # from before we added the flags for Kerberos.
1422                         #
1423                         AC_MSG_RESULT(Usable $ac_krb5_version not found - disabling dissection for some kerberos data in packet decoding)
1424                         CFLAGS="$wireshark_save_CFLAGS"
1425                         CPPFLAGS="$wireshark_save_CPPFLAGS"
1426                         KRB5_LIBS=""
1427                         want_krb5=no
1428                     fi
1429                 else
1430                     #
1431                     # We can link with Kerberos; see whether krb5.h
1432                     # defines KEYTYPE_ARCFOUR_56 (where "defines" means
1433                     # "as a #define or as an enum member).
1434                     #
1435                     AC_MSG_CHECKING([whether krb5.h defines KEYTYPE_ARCFOUR_56])
1436                     AC_COMPILE_IFELSE(
1437                       [
1438                         AC_LANG_SOURCE(
1439                           [[
1440                             #include <krb5.h>
1441                             #include <stdio.h>
1442
1443                             main()
1444                             {
1445                               printf("%u\n", KEYTYPE_ARCFOUR_56);
1446                             }
1447                           ]])
1448                       ],
1449                       [
1450                         AC_MSG_RESULT(yes)
1451                         AC_DEFINE(HAVE_KEYTYPE_ARCFOUR_56, 1, [Define if krb5.h defines KEYTYPE_ARCFOUR_56])
1452                       ],
1453                       [
1454                         AC_MSG_RESULT(no)
1455                       ])
1456                 fi
1457                 LIBS="$wireshark_save_LIBS"
1458             else
1459                 #
1460                 # It's not Heimdal or MIT.
1461                 #
1462                 AC_MSG_RESULT(no)
1463                 if test "x$want_krb5" = "xyes"
1464                 then
1465                     #
1466                     # The user tried to force us to use the library,
1467                     # but we can't do so; report an error.
1468                     #
1469                     AC_MSG_ERROR(Kerberos not found)
1470                 else
1471                     #
1472                     # Restore the versions of CFLAGS and CPPFLAGS
1473                     # from before we added the flags for Kerberos.
1474                     #
1475                     AC_MSG_RESULT(Kerberos not found - disabling dissection for some kerberos data in packet decoding)
1476                     CFLAGS="$wireshark_save_CFLAGS"
1477                     CPPFLAGS="$wireshark_save_CPPFLAGS"
1478                     KRB5_LIBS=""
1479                     want_krb5=no
1480                 fi
1481             fi
1482         else
1483             #
1484             # The user asked us not to use Kerberos, or they didn't
1485             # say whether they wanted us to use it but we found
1486             # that we couldn't.
1487             #
1488             # Restore the versions of CFLAGS and CPPFLAGS
1489             # from before we added the flags for Kerberos.
1490             #
1491             CFLAGS="$wireshark_save_CFLAGS"
1492             CPPFLAGS="$wireshark_save_CPPFLAGS"
1493             KRB5_LIBS=""
1494             want_krb5=no
1495         fi
1496         AC_SUBST(KRB5_LIBS)
1497 ])
1498
1499 #
1500 # AC_WIRESHARK_GEOIP_CHECK
1501 #
1502 AC_DEFUN([AC_WIRESHARK_GEOIP_CHECK],
1503 [
1504         want_geoip=defaultyes
1505
1506         if test "x$want_geoip" = "xdefaultyes"; then
1507                 want_geoip=yes
1508                 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
1509                         withval=/usr/local
1510                         if test -d "$withval"; then
1511                                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1512                         fi
1513                 fi
1514         fi
1515
1516         if test "x$want_geoip" = "xyes"; then
1517                 AC_CHECK_LIB(GeoIP, GeoIP_new,
1518                   [
1519                     GEOIP_LIBS=-lGeoIP
1520                 AC_DEFINE(HAVE_GEOIP, 1, [Define to use GeoIP library])
1521                 have_good_geoip=yes
1522                   ],,
1523                 )
1524         else
1525                 AC_MSG_RESULT(not required)
1526         fi
1527 ])
1528
1529 #
1530 # AC_WIRESHARK_GCC_CFLAGS_CHECK
1531 #
1532 # $1 : cflags to test
1533 #
1534 # The macro first determines if the compiler is GCC. Then compile with the
1535 # defined cflags. The defined flags are added to CFLAGS only if the compilation
1536 # succeeds.
1537 #
1538 AC_DEFUN([AC_WIRESHARK_GCC_CFLAGS_CHECK],
1539 [GCC_OPTION="$1"
1540 AC_MSG_CHECKING(whether we can add $GCC_OPTION to CFLAGS)
1541 if test "x$GCC" != "x"; then
1542   CFLAGS_saved="$CFLAGS"
1543   CFLAGS="$CFLAGS $GCC_OPTION"
1544   AC_COMPILE_IFELSE([
1545     AC_LANG_SOURCE([[
1546                       int foo;
1547                   ]])],
1548                   [
1549                     AC_MSG_RESULT(yes)
1550                   ],
1551                   [
1552                     AC_MSG_RESULT(no)
1553                     CFLAGS="$CFLAGS_saved"
1554                   ])
1555 else
1556   AC_MSG_RESULT(no)
1557 fi
1558 ])
1559
1560 #
1561 # AC_WIRESHARK_IGE_MAC_INTEGRATION_CHECK
1562 #
1563 # Checks for the presence of OS X integration functions in the GTK+ framework
1564 # or as a separate library.
1565 #
1566 # http://developer.imendio.com/projects/gtk-macosx/integration
1567 #
1568 AC_DEFUN([AC_WIRESHARK_IGE_MAC_INTEGRATION_CHECK],
1569 [
1570         ac_save_CFLAGS="$CFLAGS"
1571         ac_save_LIBS="$LIBS"
1572         CFLAGS="$CFLAGS $GTK_CFLAGS"
1573         LIBS="$GTK_LIBS $LIBS"
1574         AC_SEARCH_LIBS(ige_mac_menu_set_menu_bar, Gtk igemacintegration,
1575         [
1576                 AC_DEFINE(HAVE_IGE_MAC_INTEGRATION, 1,
1577                         [Define to 1 if the the Gtk+ framework or a separate library inclues the Imendio IGE Mac OS X Integration functions.])
1578         ])
1579 ])
1580
1581