autofoo will fail on systems that lack libgcrypt.m4.
[obnox/wireshark/wip.git] / acinclude.m4
1 dnl Macros that test for specific features.
2 dnl This file is part of the Autoconf packaging for Wireshark.
3 dnl Copyright (C) 1998-2000 by Gerald Combs.
4 dnl
5 dnl $Id$
6 dnl
7 dnl This program is free software; you can redistribute it and/or modify
8 dnl it under the terms of the GNU General Public License as published by
9 dnl the Free Software Foundation; either version 2, or (at your option)
10 dnl any later version.
11 dnl
12 dnl This program is distributed in the hope that it will be useful,
13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 dnl GNU General Public License for more details.
16 dnl
17 dnl You should have received a copy of the GNU General Public License
18 dnl along with this program; if not, write to the Free Software
19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
20 dnl 02111-1307, USA.
21 dnl
22 dnl As a special exception, the Free Software Foundation gives unlimited
23 dnl permission to copy, distribute and modify the configure scripts that
24 dnl are the output of Autoconf.  You need not follow the terms of the GNU
25 dnl General Public License when using or distributing such scripts, even
26 dnl though portions of the text of Autoconf appear in them.  The GNU
27 dnl General Public License (GPL) does govern all other use of the material
28 dnl that constitutes the Autoconf program.
29 dnl
30 dnl Certain portions of the Autoconf source text are designed to be copied
31 dnl (in certain cases, depending on the input) into the output of
32 dnl Autoconf.  We call these the "data" portions.  The rest of the Autoconf
33 dnl source text consists of comments plus executable code that decides which
34 dnl of the data portions to output in any given case.  We call these
35 dnl comments and executable code the "non-data" portions.  Autoconf never
36 dnl copies any of the non-data portions into its output.
37 dnl
38 dnl This special exception to the GPL applies to versions of Autoconf
39 dnl released by the Free Software Foundation.  When you make and
40 dnl distribute a modified version of Autoconf, you may extend this special
41 dnl exception to the GPL to apply to your modified version as well, *unless*
42 dnl your modified version has the potential to copy into its output some
43 dnl of the text that was the non-data portion of the version that you started
44 dnl with.  (In other words, unless your change moves or copies text from
45 dnl the non-data portions to the data portions.)  If your modification has
46 dnl such potential, you must delete any notice of this special exception
47 dnl to the GPL from your modified version.
48 dnl
49 dnl Written by David MacKenzie, with help from
50 dnl Franc,ois Pinard, Karl Berry, Richard Pixley, Ian Lance Taylor,
51 dnl Roland McGrath, Noah Friedman, david d zuhn, and many others.
52
53 #
54 # AC_WIRESHARK_ADD_DASH_L
55 #
56 # Add to the variable specified as the first argument a "-L" flag for the
57 # directory specified as the second argument, and, on Solaris, add a
58 # "-R" flag for it as well.
59 #
60 # XXX - IRIX, and other OSes, may require some flag equivalent to
61 # "-R" here.
62 #
63 AC_DEFUN([AC_WIRESHARK_ADD_DASH_L],
64 [$1="$$1 -L$2"
65 case "$host_os" in
66   solaris*)
67     $1="$$1 -R$2"
68   ;;
69 esac
70 ])
71
72
73 #
74 # AC_WIRESHARK_STRUCT_SA_LEN
75 #
76 dnl AC_STRUCT_ST_BLKSIZE extracted from the file in question,
77 dnl "acspecific.m4" in GNU Autoconf 2.12, and turned into
78 dnl AC_WIRESHARK_STRUCT_SA_LEN, which checks if "struct sockaddr"
79 dnl has the 4.4BSD "sa_len" member, and defines HAVE_SA_LEN; that's
80 dnl what's in this file.
81 dnl Done by Guy Harris <guy@alum.mit.edu> on 1998-11-14. 
82
83 dnl ### Checks for structure members
84
85 AC_DEFUN([AC_WIRESHARK_STRUCT_SA_LEN],
86 [AC_CACHE_CHECK([for sa_len in struct sockaddr], ac_cv_wireshark_struct_sa_len,
87 [AC_TRY_COMPILE([#include <sys/types.h>
88 #include <sys/socket.h>], [struct sockaddr s; s.sa_len;],
89 ac_cv_wireshark_struct_sa_len=yes, ac_cv_wireshark_struct_sa_len=no)])
90 if test $ac_cv_wireshark_struct_sa_len = yes; then
91   AC_DEFINE(HAVE_SA_LEN, 1, [Define if sa_len field exists in struct sockaddr])
92 fi
93 ])
94
95
96 dnl
97 dnl Check whether a given format can be used to print 64-bit integers
98 dnl
99 AC_DEFUN([AC_WIRESHARK_CHECK_64BIT_FORMAT],
100 [
101   AC_MSG_CHECKING([whether %$1x can be used to format 64-bit integers])
102   AC_RUN_IFELSE(
103     [
104       AC_LANG_SOURCE(
105         [[
106 #         ifdef HAVE_INTTYPES_H
107           #include <inttypes.h>
108 #         endif
109           #include <glibconfig.h>
110           #include <stdio.h>
111           #include <sys/types.h>
112
113           main()
114           {
115             guint64 t = 1;
116             char strbuf[16+1];
117             sprintf(strbuf, "%016$1x", t << 32);
118             if (strcmp(strbuf, "0000000100000000") == 0)
119               exit(0);
120             else
121               exit(1);
122           }
123         ]])
124     ],
125     [
126       AC_DEFINE(PRId64, "$1d", [Format for printing 64-bit signed decimal numbers])
127       AC_DEFINE(PRIo64, "$1o", [Format for printing 64-bit unsigned octal numbers])
128       AC_DEFINE(PRIx64, "$1x", [Format for printing 64-bit unsigned hexadecimal numbers (lower-case)])
129       AC_DEFINE(PRIX64, "$1X", [Format for printing 64-bit unsigned hexadecimal numbers (upper-case)])
130       AC_DEFINE(PRIu64, "$1u", [Format for printing 64-bit unsigned decimal numbers])
131       AC_MSG_RESULT(yes)
132     ],
133     [
134       AC_MSG_RESULT(no)
135       $2
136     ])
137 ])
138
139 #
140 # AC_WIRESHARK_IPV6_STACK
141 #
142 # By Jun-ichiro "itojun" Hagino, <itojun@iijlab.net>
143 #
144 AC_DEFUN([AC_WIRESHARK_IPV6_STACK],
145 [
146         v6type=unknown
147         v6lib=none
148
149         AC_MSG_CHECKING([ipv6 stack type])
150         for i in v6d toshiba kame inria zeta linux linux-glibc solaris8; do
151                 case $i in
152                 v6d)
153                         AC_EGREP_CPP(yes, [
154 #include </usr/local/v6/include/sys/types.h>
155 #ifdef __V6D__
156 yes
157 #endif],
158                                 [v6type=$i; v6lib=v6;
159                                 v6libdir=/usr/local/v6/lib;
160                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
161                         ;;
162                 toshiba)
163                         AC_EGREP_CPP(yes, [
164 #include <sys/param.h>
165 #ifdef _TOSHIBA_INET6
166 yes
167 #endif],
168                                 [v6type=$i; v6lib=inet6;
169                                 v6libdir=/usr/local/v6/lib;
170                                 CFLAGS="-DINET6 $CFLAGS"])
171                         ;;
172                 kame)
173                         AC_EGREP_CPP(yes, [
174 #include <netinet/in.h>
175 #ifdef __KAME__
176 yes
177 #endif],
178                                 [v6type=$i; v6lib=inet6;
179                                 v6libdir=/usr/local/v6/lib;
180                                 CFLAGS="-DINET6 $CFLAGS"])
181                         ;;
182                 inria)
183                         AC_EGREP_CPP(yes, [
184 #include <netinet/in.h>
185 #ifdef IPV6_INRIA_VERSION
186 yes
187 #endif],
188                                 [v6type=$i; CFLAGS="-DINET6 $CFLAGS"])
189                         ;;
190                 zeta)
191                         AC_EGREP_CPP(yes, [
192 #include <sys/param.h>
193 #ifdef _ZETA_MINAMI_INET6
194 yes
195 #endif],
196                                 [v6type=$i; v6lib=inet6;
197                                 v6libdir=/usr/local/v6/lib;
198                                 CFLAGS="-DINET6 $CFLAGS"])
199                         ;;
200                 linux)
201                         if test -d /usr/inet6; then
202                                 v6type=$i
203                                 v6lib=inet6
204                                 v6libdir=/usr/inet6
205                                 CFLAGS="-DINET6 $CFLAGS"
206                         fi
207                         ;;
208                 linux-glibc)
209                         AC_EGREP_CPP(yes, [
210 #include <features.h>
211 #if defined(__GLIBC__) && defined(__GLIBC_MINOR__)
212 #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || __GLIBC__ > 2
213 yes
214 #endif
215 #endif],
216                         [v6type=$i; v6lib=inet6; CFLAGS="-DINET6 $CFLAGS"])
217                         ;;
218                 solaris8)
219                         if test "`uname -s`" = "SunOS" && test "`uname -r`" = "5.8"; then
220                                 v6type=$i
221                                 v6lib=inet6
222                                 [CFLAGS="-DINET6 -DSOLARIS8_INET6 $CFLAGS"]
223                         fi
224                         ;; 
225                 esac
226                 if test "$v6type" != "unknown"; then
227                         break
228                 fi
229         done
230
231         if test "$v6lib" != "none"; then
232                 for dir in $v6libdir /usr/local/v6/lib /usr/local/lib; do
233                         if test -d $dir -a -f $dir/lib$v6lib.a; then
234                                 LIBS="-L$dir $LIBS -l$v6lib"
235                                 break
236                         fi
237                 done
238                 enable_ipv6="yes"
239         else
240                 enable_ipv6="no"
241         fi
242         AC_MSG_RESULT(["$v6type, $v6lib"])
243 ])
244
245 #
246 # AC_WIRESHARK_GETHOSTBY_LIB_CHECK
247 #
248 # Checks whether we need "-lnsl" to get "gethostby*()", which we use
249 # in "resolv.c".
250 #
251 # Adapted from stuff in the AC_PATH_XTRA macro in "acspecific.m4" in
252 # GNU Autoconf 2.13; the comment came from there.
253 # Done by Guy Harris <guy@alum.mit.edu> on 2000-01-14. 
254 #
255 AC_DEFUN([AC_WIRESHARK_GETHOSTBY_LIB_CHECK],
256 [
257     # msh@cis.ufl.edu says -lnsl (and -lsocket) are needed for his 386/AT,
258     # to get the SysV transport functions.
259     # chad@anasazi.com says the Pyramid MIS-ES running DC/OSx (SVR4)
260     # needs -lnsl.
261     # The nsl library prevents programs from opening the X display
262     # on Irix 5.2, according to dickey@clark.net.
263     AC_CHECK_FUNC(gethostbyname, ,
264         AC_CHECK_LIB(nsl, gethostbyname, NSL_LIBS="-lnsl"))
265     AC_SUBST(NSL_LIBS)
266 ])
267
268 #
269 # AC_WIRESHARK_SOCKET_LIB_CHECK
270 #
271 # Checks whether we need "-lsocket" to get "socket()", which is used
272 # by libpcap on some platforms - and, in effect, "gethostby*()" on
273 # most if not all platforms (so that it can use NIS or DNS or...
274 # to look up host names).
275 #
276 # Adapted from stuff in the AC_PATH_XTRA macro in "acspecific.m4" in
277 # GNU Autoconf 2.13; the comment came from there.
278 # Done by Guy Harris <guy@alum.mit.edu> on 2000-01-14. 
279 #
280 # We use "connect" because that's what AC_PATH_XTRA did.
281 #
282 AC_DEFUN([AC_WIRESHARK_SOCKET_LIB_CHECK],
283 [
284     # lieder@skyler.mavd.honeywell.com says without -lsocket,
285     # socket/setsockopt and other routines are undefined under SCO ODT
286     # 2.0.  But -lsocket is broken on IRIX 5.2 (and is not necessary
287     # on later versions), says simon@lia.di.epfl.ch: it contains
288     # gethostby* variants that don't use the nameserver (or something).
289     # -lsocket must be given before -lnsl if both are needed.
290     # We assume that if connect needs -lnsl, so does gethostbyname.
291     AC_CHECK_FUNC(connect, ,
292       AC_CHECK_LIB(socket, connect, SOCKET_LIBS="-lsocket",
293                 AC_MSG_ERROR(Function 'socket' not found.), $NSL_LIBS))
294     AC_SUBST(SOCKET_LIBS)
295 ])
296
297 #
298 # AC_WIRESHARK_PCAP_CHECK
299 #
300 AC_DEFUN([AC_WIRESHARK_PCAP_CHECK],
301 [
302         if test -z "$pcap_dir"
303         then
304           # Pcap header checks
305           # XXX need to set a var AC_CHECK_HEADER(pcap.h,,)
306
307           #
308           # The user didn't specify a directory in which libpcap resides;
309           # we assume that the current library search path will work,
310           # but we may have to look for the header in a "pcap"
311           # subdirectory of "/usr/include" or "/usr/local/include",
312           # as some systems apparently put "pcap.h" in a "pcap"
313           # subdirectory, and we also check "$prefix/include" - and
314           # "$prefix/include/pcap", in case $prefix is set to
315           # "/usr/include" or "/usr/local/include".
316           #
317           # XXX - should we just add "$prefix/include" to the include
318           # search path and "$prefix/lib" to the library search path?
319           #
320           AC_MSG_CHECKING(for extraneous pcap header directories)
321           found_pcap_dir=""
322           pcap_dir_list="/usr/include/pcap $prefix/include/pcap $prefix/include"
323           if test "x$ac_cv_enable_usr_local" = "xyes" ; then
324             pcap_dir_list="$pcap_dir_list /usr/local/include/pcap"
325           fi
326           for pcap_dir in $pcap_dir_list
327           do
328             if test -d $pcap_dir ; then
329                 if test x$pcap_dir != x/usr/include -a x$pcap_dir != x/usr/local/include ; then
330                     CFLAGS="$CFLAGS -I$pcap_dir"
331                     CPPFLAGS="$CPPFLAGS -I$pcap_dir"
332                 fi
333                 found_pcap_dir=" $found_pcap_dir -I$pcap_dir"
334                 break
335             fi
336           done
337
338           if test "$found_pcap_dir" != "" ; then
339             AC_MSG_RESULT(found --$found_pcap_dir added to CFLAGS)
340           else
341             AC_MSG_RESULT(not found)
342           fi
343         else
344           #
345           # The user specified a directory in which libpcap resides,
346           # so add the "include" subdirectory of that directory to
347           # the include file search path and the "lib" subdirectory
348           # of that directory to the library search path.
349           #
350           # XXX - if there's also a libpcap in a directory that's
351           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
352           # make us find the version in the specified directory,
353           # as the compiler and/or linker will search that other
354           # directory before it searches the specified directory.
355           #
356           CFLAGS="$CFLAGS -I$pcap_dir/include"
357           CPPFLAGS="$CPPFLAGS -I$pcap_dir/include"
358           AC_WIRESHARK_ADD_DASH_L(LDFLAGS, $pcap_dir/lib)
359         fi
360
361         # Pcap header check
362         AC_CHECK_HEADER(pcap.h,, 
363             AC_MSG_ERROR([[Header file pcap.h not found; if you installed libpcap
364 from source, did you also do \"make install-incl\", and if you installed a
365 binary package of libpcap, is there also a developer's package of libpcap,
366 and did you also install that package?]]))
367
368         #
369         # Check to see if we find "pcap_open_live" in "-lpcap".
370         # Also check for various additional libraries that libpcap might
371         # require.
372         #
373         AC_CHECK_LIB(pcap, pcap_open_live,
374           [
375             PCAP_LIBS=-lpcap
376             AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
377           ], [
378             ac_wireshark_extras_found=no
379             ac_save_LIBS="$LIBS"
380             for extras in "-lcfg -lodm" "-lpfring"
381             do
382                 AC_MSG_CHECKING([for pcap_open_live in -lpcap with $extras])
383                 LIBS="-lpcap $extras"
384                 #
385                 # XXX - can't we use AC_CHECK_LIB here?
386                 #
387                 AC_TRY_LINK(
388                     [
389 #       include <pcap.h>
390                     ],
391                     [
392         pcap_open_live(NULL, 0, 0, 0, NULL);
393                     ],
394                     [
395                         ac_wireshark_extras_found=yes
396                         AC_MSG_RESULT([yes])
397                         PCAP_LIBS="-lpcap $extras"
398                         AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
399                     ],
400                     [
401                         AC_MSG_RESULT([no])
402                     ])
403                 if test x$ac_wireshark_extras_found = xyes
404                 then
405                     break
406                 fi
407             done
408             if test x$ac_wireshark_extras_found = xno
409             then
410                 AC_MSG_ERROR([Can't link with library libpcap.])
411             fi
412             LIBS=$ac_save_LIBS
413           ], $SOCKET_LIBS $NSL_LIBS)
414         AC_SUBST(PCAP_LIBS)
415
416         #
417         # Check whether various variables and functions are defined by
418         # libpcap.
419         #
420         ac_save_LIBS="$LIBS"
421         AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
422         LIBS="$PCAP_LIBS $SOCKET_LIBS $NSL_LIBS $LIBS"
423         AC_TRY_LINK(
424            [
425 #       include <stdio.h>
426         extern char *pcap_version;
427            ],
428            [
429         printf ("%s\n", pcap_version);
430            ],
431            ac_cv_pcap_version_defined=yes,
432            ac_cv_pcap_version_defined=no,
433            [echo $ac_n "cross compiling; assumed OK... $ac_c"])
434         if test "$ac_cv_pcap_version_defined" = yes ; then
435                 AC_MSG_RESULT(yes)
436                 AC_DEFINE(HAVE_PCAP_VERSION, 1, [Define if libpcap version is known])
437         else
438                 AC_MSG_RESULT(no)
439         fi
440         AC_CHECK_FUNCS(pcap_open_dead pcap_freecode pcap_breakloop)
441         #
442         # Later versions of Mac OS X 10.3[.x] ship a pcap.h that
443         # doesn't define pcap_if_t but ship an 0.8[.x] libpcap,
444         # so the library has "pcap_findalldevs()", but pcap.h
445         # doesn't define "pcap_if_t" so you can't actually *use*
446         # "pcap_findalldevs()".
447         #
448         # That even appears to be true of systems shipped with
449         # 10.3.4, so it doesn't appear only to be a case of
450         # Software Update not updating header files.
451         #
452         # (You can work around this by installing the 0.8 header
453         # files.)
454         #
455         AC_CACHE_CHECK([whether pcap_findalldevs is present and usable],
456           [ac_cv_func_pcap_findalldevs],
457           [
458             AC_LINK_IFELSE(
459               [
460                 AC_LANG_SOURCE(
461                   [[
462                     #include <pcap.h>
463                     main()
464                     {
465                       pcap_if_t *devpointer;
466                       char errbuf[1];
467
468                       pcap_findalldevs(&devpointer, errbuf);
469                     }
470                   ]])
471               ],
472               [
473                 ac_cv_func_pcap_findalldevs=yes
474               ],
475               [
476                 ac_cv_func_pcap_findalldevs=no
477               ])
478           ])
479         #
480         # Don't check for other new routines that showed up after
481         # "pcap_findalldevs()" if we don't have a usable
482         # "pcap_findalldevs()", so we don't end up using them if the
483         # "pcap.h" is crufty and old and doesn't declare them.
484         #
485         if test $ac_cv_func_pcap_findalldevs = "yes" ; then
486           AC_DEFINE(HAVE_PCAP_FINDALLDEVS, 1,
487            [Define to 1 if you have the `pcap_findalldevs' function and a pcap.h that declares pcap_if_t.])
488           AC_CHECK_FUNCS(pcap_datalink_val_to_name pcap_datalink_name_to_val)
489           AC_CHECK_FUNCS(pcap_list_datalinks pcap_set_datalink pcap_lib_version)
490           AC_CHECK_FUNCS(pcap_get_selectable_fd)
491         fi
492         LIBS="$ac_save_LIBS"
493 ])
494
495 #
496 # AC_WIRESHARK_ZLIB_CHECK
497 #
498 AC_DEFUN([AC_WIRESHARK_ZLIB_CHECK],
499 [
500         if test "x$zlib_dir" != "x"
501         then
502           #
503           # The user specified a directory in which zlib resides,
504           # so add the "include" subdirectory of that directory to
505           # the include file search path and the "lib" subdirectory
506           # of that directory to the library search path.
507           #
508           # XXX - if there's also a zlib in a directory that's
509           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
510           # make us find the version in the specified directory,
511           # as the compiler and/or linker will search that other
512           # directory before it searches the specified directory.
513           #
514           wireshark_save_CFLAGS="$CFLAGS"
515           CFLAGS="$CFLAGS -I$zlib_dir/include"
516           wireshark_save_CPPFLAGS="$CPPFLAGS"
517           CPPFLAGS="$CPPFLAGS -I$zlib_dir/include"
518           wireshark_save_LIBS="$LIBS"
519           AC_WIRESHARK_ADD_DASH_L(LIBS, $zlib_dir/lib)
520         fi
521
522         #
523         # Make sure we have "zlib.h".  If we don't, it means we probably
524         # don't have zlib, so don't use it.
525         #
526         AC_CHECK_HEADER(zlib.h,,
527           [
528             if test "x$zlib_dir" != "x"
529             then
530               #
531               # The user used "--with-zlib=" to specify a directory
532               # containing zlib, but we didn't find the header file
533               # there; that either means they didn't specify the
534               # right directory or are confused about whether zlib
535               # is, in fact, installed.  Report the error and give up.
536               #
537               AC_MSG_ERROR([zlib header not found in directory specified in --with-zlib])
538             else
539               if test "x$want_zlib" = "xyes"
540               then
541                 #
542                 # The user tried to force us to use the library, but we
543                 # couldn't find the header file; report an error.
544                 #
545                 AC_MSG_ERROR(Header file zlib.h not found.)
546               else
547                 #
548                 # We couldn't find the header file; don't use the
549                 # library, as it's probably not present.
550                 #
551                 want_zlib=no
552               fi
553             fi
554           ])
555
556         if test "x$want_zlib" != "xno"
557         then
558                 #
559                 # Well, we at least have the zlib header file.
560                 #
561                 # Check for "gzgets()" in zlib, because we need it, but
562                 # some older versions of zlib don't have it.  It appears
563                 # from the zlib ChangeLog that any released version of zlib
564                 # with "gzgets()" should have the other routines we
565                 # depend on, such as "gzseek()", "gztell()", and "zError()".
566                 #
567                 # Another reason why we require "gzgets()" is that
568                 # some versions of zlib that didn't have it, such
569                 # as 1.0.8, had a bug in "gzseek()" that meant that it
570                 # doesn't work correctly on uncompressed files; this
571                 # means we cannot use version 1.0.8.  (Unfortunately,
572                 # that's the version that comes with recent X11 source,
573                 # and many people who install XFree86 on their Slackware
574                 # boxes don't realize that they should configure it to
575                 # use the native zlib rather than building and installing
576                 # the crappy old version that comes with XFree86.)
577                 #
578                 # I.e., we can't just avoid using "gzgets()", as
579                 # versions of zlib without "gzgets()" are likely to have
580                 # a broken "gzseek()".
581                 #
582                 AC_CHECK_LIB(z, gzgets,
583                 [
584                         if test "x$zlib_dir" != "x"
585                         then
586                                 #
587                                 # Put the "-I" and "-L" flags for zlib at
588                                 # the beginning of CFLAGS, CPPFLAGS, and
589                                 # LIBS.
590                                 #
591                                 LIBS=""
592                                 AC_WIRESHARK_ADD_DASH_L(LIBS, $zlib_dir/lib)
593                                 LIBS="$LIBS -lz $wireshark_save_LIBS"
594                         else
595                                 LIBS="-lz $LIBS"
596                         fi
597                         AC_DEFINE(HAVE_LIBZ, 1, [Define to use libz library])
598                 ],[
599                         if test "x$zlib_dir" != "x"
600                         then
601                                 #
602                                 # Restore the versions of CFLAGS, CPPFLAGS,
603                                 # and LIBS before we added the "-with-zlib="
604                                 # directory, as we didn't actually find
605                                 # zlib there, or didn't find a zlib that
606                                 # contains gzgets there.
607                                 #
608                                 CFLAGS="$wireshark_save_CFLAGS"
609                                 CPPFLAGS="$wireshark_save_CPPFLAGS"
610                                 LIBS="$wireshark_save_LIBS"
611                         fi
612                         want_zlib=no
613                 ])
614         fi
615
616         if test "x$want_zlib" != "xno"
617         then
618                 #
619                 # Well, we at least have the zlib header file and a zlib
620                 # with "gzgets()".
621                 #
622                 # Now check for "gzgets()" in zlib when linking with the
623                 # linker flags for GTK+ applications; people often grab
624                 # XFree86 source and build and install it on their systems,
625                 # and they appear sometimes to misconfigure XFree86 so that,
626                 # even on systems with zlib, it assumes there is no zlib,
627                 # so the XFree86 build process builds and installs its
628                 # own zlib in the X11 library directory.
629                 #
630                 # The XFree86 zlib is an older version that lacks
631                 # "gzgets()", and that's the zlib with which Ethereal
632                 # gets linked, so the build of Ethereal fails.
633                 #
634                 ac_save_CFLAGS="$CFLAGS"
635                 ac_save_LIBS="$LIBS"
636                 CFLAGS="$CFLAGS $GTK_CFLAGS"
637                 LIBS="$GTK_LIBS -lz $LIBS"
638                 AC_MSG_CHECKING([for gzgets missing when linking with X11])
639                 AC_TRY_LINK_FUNC(gzgets, AC_MSG_RESULT(no),
640                   [
641                     AC_MSG_RESULT(yes)
642                     AC_MSG_ERROR(old zlib found when linking with X11 - get rid of old zlib.)
643                   ])
644                 CFLAGS="$ac_save_CFLAGS"
645                 LIBS="$ac_save_LIBS"
646         fi
647 ])
648
649 #
650 # AC_WIRESHARK_LIBPCRE_CHECK
651 #
652 AC_DEFUN([AC_WIRESHARK_LIBPCRE_CHECK],
653 [
654         if test "x$pcre_dir" != "x"
655         then
656           #
657           # The user specified a directory in which libpcre resides,
658           # so add the "include" subdirectory of that directory to
659           # the include file search path and the "lib" subdirectory
660           # of that directory to the library search path.
661           #
662           # XXX - if there's also a libpcre in a directory that's
663           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
664           # make us find the version in the specified directory,
665           # as the compiler and/or linker will search that other
666           # directory before it searches the specified directory.
667           #
668           wireshark_save_CFLAGS="$CFLAGS"
669           CFLAGS="$CFLAGS -I$pcre_dir/include"
670           wireshark_save_CPPFLAGS="$CPPFLAGS"
671           CPPFLAGS="$CPPFLAGS -I$pcre_dir/include"
672           wireshark_save_LIBS="$LIBS"
673           LIBS="$LIBS -lpcre"
674           wireshark_save_LDFLAGS="$LDFLAGS"
675           LDFLAGS="$LDFLAGS -L$pcre_dir/lib"
676         fi
677
678         #
679         # Make sure we have "pcre.h".  If we don't, it means we probably
680         # don't have libpcre, so don't use it.
681         #
682         AC_CHECK_HEADER(pcre.h,,
683           [
684             if test "x$pcre_dir" != "x"
685             then
686               #
687               # The user used "--with-pcre=" to specify a directory
688               # containing libpcre, but we didn't find the header file
689               # there; that either means they didn't specify the
690               # right directory or are confused about whether libpcre
691               # is, in fact, installed.  Report the error and give up.
692               #
693               AC_MSG_ERROR([libpcre header not found in directory specified in --with-pcre])
694             else
695               if test "x$want_pcre" = "xyes"
696               then
697                 #
698                 # The user tried to force us to use the library, but we
699                 # couldn't find the header file; report an error.
700                 #
701                 AC_MSG_ERROR(Header file pcre.h not found.)
702               else
703                 #
704                 # We couldn't find the header file; don't use the
705                 # library, as it's probably not present.
706                 #
707                 want_pcre=no
708               fi
709             fi
710           ])
711
712         if test "x$want_pcre" != "xno"
713         then
714                 #
715                 # Well, we at least have the pcre header file.
716                 #
717                 # We're only using standard functions from libpcre,
718                 # so we don't need to perform extra checks.
719                 #
720                 AC_CHECK_LIB(pcre, pcre_compile,
721                 [
722                         if test "x$pcre_dir" != "x"
723                         then
724                                 #
725                                 # Put the "-I" and "-L" flags for pcre at
726                                 # the beginning of CFLAGS, CPPFLAGS,
727                                 # LDFLAGS, and LIBS.
728                                 #
729                                 PCRE_LIBS="-L$pcre_dir/lib -lpcre $wireshark_save_LIBS"
730                         else
731                                 PCRE_LIBS="-lpcre"
732                         fi
733                         AC_DEFINE(HAVE_LIBPCRE, 1, [Define to use libpcre library])
734                 ],[
735                         if test "x$pcre_dir" != "x"
736                         then
737                                 #
738                                 # Restore the versions of CFLAGS, CPPFLAGS,
739                                 # LDFLAGS, and LIBS before we added the
740                                 # "--with-pcre=" directory, as we didn't
741                                 # actually find pcre there.
742                                 #
743                                 CFLAGS="$wireshark_save_CFLAGS"
744                                 CPPFLAGS="$wireshark_save_CPPFLAGS"
745                                 LDFLAGS="$wireshark_save_LDFLAGS"
746                                 LIBS="$wireshark_save_LIBS"
747                                 PCRE_LIBS=""
748                         fi
749                         want_pcre=no
750                 ])
751                 AC_SUBST(PCRE_LIBS)
752         fi
753 ])
754
755 #
756 # AC_WIRESHARK_LIBLUA_CHECK
757 #
758 AC_DEFUN([AC_WIRESHARK_LIBLUA_CHECK],[
759
760         if test "x$lua_dir" != "x"
761         then
762                 #
763                 # The user specified a directory in which liblua resides,
764                 # so add the "include" subdirectory of that directory to
765                 # the include file search path and the "lib" subdirectory
766                 # of that directory to the library search path.
767                 #
768                 # XXX - if there's also a liblua in a directory that's
769                 # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
770                 # make us find the version in the specified directory,
771                 # as the compiler and/or linker will search that other
772                 # directory before it searches the specified directory.
773                 #
774                 wireshark_save_CFLAGS="$CFLAGS"
775                 CFLAGS="$CFLAGS -I$lua_dir/include"
776                 wireshark_save_CPPFLAGS="$CPPFLAGS"
777                 CPPFLAGS="$CPPFLAGS -I$lua_dir/include"
778                 wireshark_save_LIBS="$LIBS"
779                 LIBS="$LIBS -L$lua_dir/lib -llua"
780                 wireshark_save_LDFLAGS="$LDFLAGS"
781                 LDFLAGS="$LDFLAGS -L$lua_dir/lib"
782         else 
783                 #
784                 # The user specified no directory in which liblua resides,
785                 # so just add "-llua -lliblua" to the used libs.
786                 #
787                 wireshark_save_CFLAGS="$CFLAGS"
788                 wireshark_save_CPPFLAGS="$CPPFLAGS"
789                 wireshark_save_LDFLAGS="$LDFLAGS"
790                 wireshark_save_LIBS="$LIBS"
791                 LIBS="$LIBS -llua"
792         fi
793
794         #
795         # Make sure we have "lua.h", "lualib.h" and "lauxlib.h".  If we don't, it means we probably
796         # don't have liblua, so don't use it.
797         #
798         AC_CHECK_HEADERS(lua.h lualib.h lauxlib.h,,
799         [
800                 if test "x$lua_dir" != "x"
801                 then
802                         #
803                         # The user used "--with-lua=" to specify a directory
804                         # containing liblua, but we didn't find the header file
805                         # there; that either means they didn't specify the
806                         # right directory or are confused about whether liblua
807                         # is, in fact, installed.  Report the error and give up.
808                         #
809                         AC_MSG_ERROR([liblua header not found in directory specified in --with-lua])
810                 else
811                         if test "x$want_lua" = "xyes"
812                         then
813                                 #
814                                 # The user tried to force us to use the library, but we
815                                 # couldn't find the header file; report an error.
816                                 #
817                                 AC_MSG_ERROR(Header file lua.h not found.)
818                         else
819                                 #
820                                 # We couldn't find the header file; don't use the
821                                 # library, as it's probably not present.
822                                 #
823                                 want_lua=no
824                         fi
825                 fi
826         ])
827
828         if test "x$want_lua" != "xno"
829         then
830                 #
831                 # Well, we at least have the lua header file.
832                 #
833                 # let's check if the libs are there
834                 #
835
836                 # At least on Suse 9.3 systems, liblualib needs linking
837                 # against libm.
838                 LIBS="$LIBS $LUA_LIBS -lm"
839
840                 AC_CHECK_LIB(lua, lua_call,
841                 [
842                         if test "x$lua_dir" != "x"
843                         then
844                                 #
845                                 # Put the "-I" and "-L" flags for lua at
846                                 # the beginning of CFLAGS, CPPFLAGS,
847                                 # LDFLAGS, and LIBS.
848                                 #
849                                 LUA_LIBS="-L$lua_dir/lib -llua"
850                                 LUA_INCLUDES="-I$lua_dir/include"
851                         else
852                                 LUA_LIBS="-llua"
853                                 LUA_INCLUDES=""
854                         fi
855
856                         #
857                         # we got lua, now look for lualib
858                         #
859                         AC_CHECK_LIB(lualib, luaL_openlib,
860                         [
861                                 #
862                                 # we have 5.0
863                                 #
864                                 LUA_LIBS="$LUA_LIBS -llualib"
865                         ],[
866                                 #
867                                 # no lualib, in 5.1 there's only liblua
868                                 # do we have 5.1?
869                                 #
870                                 
871                                 LIBS="$wireshark_save_LIBS $LUA_LIBS"
872
873                                 AC_CHECK_LIB(lua, luaL_register,
874                                 [
875                                     #
876                                     #  Lua 5.1 found
877                                     #
878                                     AC_DEFINE(HAVE_LUA_5_1, 1, [Define to use Lua 5.1])
879                                 ],[
880                                     #
881                                     # No, it is not 5.1
882                                     #
883                                     if test "x$lua_dir" != "x"
884                                     then
885                                         #
886                                         # Restore the versions of CFLAGS, CPPFLAGS,
887                                         # LDFLAGS, and LIBS before we added the
888                                         # "--with-lua=" directory, as we didn't
889                                         # actually find lua there.
890                                         #
891                                         CFLAGS="$wireshark_save_CFLAGS"
892                                         CPPFLAGS="$wireshark_save_CPPFLAGS"
893                                         LDFLAGS="$wireshark_save_LDFLAGS"
894                                         LIBS="$wireshark_save_LIBS"
895                                         LUA_LIBS=""
896                                     fi
897                                     # User requested --with-lua but it isn't available
898                                     if test "x$want_lua" = "xyes"
899                                     then
900                                         AC_MSG_ERROR(Linking with liblualib failed.)
901                                     fi
902                                     want_lua=no
903                                 ])
904                         ])
905                 ],[  
906                         #
907                         # Restore the versions of CFLAGS, CPPFLAGS,
908                         # LDFLAGS, and LIBS before we added the
909                         # "--with-lua=" directory, as we didn't
910                         # actually find lua there.
911                         #
912                         CFLAGS="$wireshark_save_CFLAGS"
913                         CPPFLAGS="$wireshark_save_CPPFLAGS"
914                         LDFLAGS="$wireshark_save_LDFLAGS"
915                         LIBS="$wireshark_save_LIBS"
916                         LUA_LIBS=""
917                         # User requested --with-lua but it isn't available
918                         if test "x$want_lua" = "xyes"
919                         then
920                                 AC_MSG_ERROR(Linking with liblua failed.)
921                         fi
922                         want_lua=no
923                 ])
924
925         CFLAGS="$wireshark_save_CFLAGS"
926         CPPFLAGS="$wireshark_save_CPPFLAGS"
927         LDFLAGS="$wireshark_save_LDFLAGS"
928         LIBS="$wireshark_save_LIBS"
929         AC_SUBST(LUA_LIBS)
930         AC_SUBST(LUA_INCLUDES)
931
932         fi
933 ])
934
935 #
936 # AC_WIRESHARK_NETSNMP_CHECK
937 #
938 AC_DEFUN([AC_WIRESHARK_NETSNMP_CHECK],
939 [
940         dnl get the net-snmp-config binary
941         if test "x$netsnmpconfig" = "x" ; then
942                 #
943                 # The user didn't specify where net-snmp-config is
944                 # located; search for it.
945                 #
946                 AC_PATH_PROG(NETSNMPCONFIG, net-snmp-config)
947         else
948                 NETSNMPCONFIG=$netsnmpconfig
949                 if test ! -x $NETSNMPCONFIG -o ! -f $NETSNMPCONFIG ; then
950                         NETSNMPCONFIG=$netsnmpconfig/bin/net-snmp-config
951                         if test ! -x $NETSNMPCONFIG -o ! -f $NETSNMPCONFIG ; then
952                                 AC_MSG_ERROR(Invalid net-snmp-config: $netsnmpconfig)
953                         fi
954                 fi
955         fi
956
957         #
958         # XXX - check whether $NETSNMPCONFIG is executable?
959         # if test "x$NETSNMPCONFIG" != "xno" -a "x$NETSNMPCONFIG" != "x" -a -x "$NETSNMPCONFIG" ; then
960         # We already did that if it was set; presumably AC_PATH_PROG
961         # will fail if it doesn't find an executable version.
962         #
963         if test "x$NETSNMPCONFIG" != "x" ; then
964                 dnl other choices for flags to use here: could also use
965                 dnl --prefix or --exec-prefix if you don't want the full list.
966
967                 #
968                 # Save the current settings of CFLAGS and CPPFLAGS, and add
969                 # the output of "$NETSNMPCONFIG --cflags" to it, so that when
970                 # searching for the Net-SNMP headers, we look in whatever
971                 # directory that output specifies.
972                 #
973                 wireshark_save_CFLAGS="$CFLAGS"
974                 wireshark_save_CPPFLAGS="$CPPFLAGS"
975                 CFLAGS="$CFLAGS `$NETSNMPCONFIG --cflags`"
976                 CPPFLAGS="$CPPFLAGS `$NETSNMPCONFIG --cflags`"
977
978                 AC_CHECK_HEADERS(net-snmp/net-snmp-config.h net-snmp/library/default_store.h)
979                 if test "x$ac_cv_header_net_snmp_net_snmp_config_h" = "xyes" -a "x$ac_cv_header_net_snmp_library_default_store_h" = "xyes" ; then
980                         SNMP_LIBS=`$NETSNMPCONFIG --libs`
981                         if echo "$SNMP_LIBS" | grep crypto >/dev/null  && test "x$SSL_LIBS" = "x"; then
982                                 if test "x$want_netsnmp" = "xyes" ; then
983                                         AC_MSG_ERROR(Net-SNMP requires openssl but ssl not enabled)
984                                 else
985                                         AC_MSG_RESULT(Net-SNMP requires openssl but ssl not enabled - disabling Net-SNMP)
986                                 fi
987                                 CFLAGS="$wireshark_save_CFLAGS"
988                                 CPPFLAGS="$wireshark_save_CPPFLAGS"
989                                 SNMP_LIBS=
990                         else
991                                 AC_DEFINE(HAVE_NET_SNMP, 1, [Define to enable support for Net-SNMP])
992                                 have_net_snmp="yes"
993                         fi
994                 else
995                         if test "x$want_netsnmp" = "xyes" ; then
996                                 AC_MSG_ERROR(Net-SNMP not found)
997                         else
998                                 #
999                                 # Restore the versions of CFLAGS and
1000                                 # CPPFLAGS before we added the output
1001                                 # of '$NETSNMPCONFIG --cflags", as we
1002                                 # didn't actually find Net-SNMP there.
1003                                 #
1004                                 CFLAGS="$wireshark_save_CFLAGS"
1005                                 CPPFLAGS="$wireshark_save_CPPFLAGS"
1006                         fi
1007                 fi
1008         fi      
1009 ])
1010
1011 #
1012 # AC_WIRESHARK_UCDSNMP_CHECK
1013 #
1014 AC_DEFUN([AC_WIRESHARK_UCDSNMP_CHECK],
1015 [
1016         if test "x$ucdsnmp_dir" != "x"
1017         then
1018                 #
1019                 # The user specified a directory in which UCD SNMP resides,
1020                 # so add the "include" subdirectory of that directory to
1021                 # the include file search path and the "lib" subdirectory
1022                 # of that directory to the library search path.
1023                 #
1024                 # XXX - if there's also a libpcap in a directory that's
1025                 # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
1026                 # make us find the version in the specified directory,
1027                 # as the compiler and/or linker will search that other
1028                 # directory before it searches the specified directory.
1029                 #
1030                 CFLAGS="$CFLAGS -I$ucdsnmp_dir/include"
1031                 CPPFLAGS="$CPPFLAGS -I$ucdsnmp_dir/include"
1032                 AC_WIRESHARK_ADD_DASH_L(LDFLAGS, $ucdsnmp_dir/lib)
1033         fi
1034
1035         #
1036         # Check for one of the UCD SNMP header files we include,
1037         # to see whether we have UCD SNMP installed.
1038         #
1039         AC_CHECK_HEADER(ucd-snmp/ucd-snmp-config.h,
1040         [
1041                 #
1042                 # UCD SNMP or Net-SNMP might require various helper
1043                 # libraries on various platforms, such as "-ldes425"
1044                 # in "/usr/kerberos/lib" on some versions of Red
1045                 # Hat Linux, or "-lkstat" on Solaris.
1046                 #
1047                 # It might also require "-lcrypto" on some platforms;
1048                 # if the user didn't specify --with-ssl, we check
1049                 # whether it would have made a difference and, if so,
1050                 # we tell the user that they needed to request it.
1051                 # (There are annoying licensing issues with it and
1052                 # GPL'ed code, so we don't include it by default.)
1053                 #
1054                 # XXX - autoconf really needs a way to test for
1055                 # a given routine in a given library *and* to test
1056                 # whether additional "-L"/"-R"/whatever flags are
1057                 # needed *before* the "-l" flag for the library
1058                 # and to test whether additional libraries are
1059                 # needed after the library *and* to cache all that
1060                 # information.
1061                 #
1062                 wireshark_save_LIBS="$LIBS"
1063                 found_sprint_realloc_objid=no
1064                 for extras in "" "-L/usr/kerberos/lib -ldes425" "-lkstat"
1065                 do
1066                         LIBS="-lsnmp $extras $SOCKET_LIBS $NSL_LIBS $SSL_LIBS"
1067                         if test -z "$extras"
1068                         then
1069                                 AC_MSG_CHECKING([whether UCD SNMP includes sprint_realloc_objid])
1070                         else
1071                                 AC_MSG_CHECKING([whether UCD SNMP includes sprint_realloc_objid (linking with $extras)])
1072                         fi
1073                         AC_TRY_LINK(
1074                             [
1075                             ],
1076                             [
1077                                 sprint_realloc_objid();
1078                             ],
1079                             [
1080                                 #
1081                                 # We found "sprint_realloc_objid()",
1082                                 # and required the libraries in
1083                                 # extras as well.
1084                                 #
1085                                 AC_MSG_RESULT(yes)
1086                                 SNMP_LIBS="-lsnmp $extras"; break;
1087                                 found_sprint_realloc_objid=yes
1088                                 break
1089                             ],
1090                             [
1091                                 #
1092                                 # The link failed.  If they didn't ask
1093                                 # for SSL, try linking with -lcrypto
1094                                 # as well, and if *that* succeeds,
1095                                 # tell them they'll need to specify
1096                                 # --want-ssl.
1097                                 #
1098                                 AC_MSG_RESULT(no)
1099                                 if test "x$want_ssl" = "xno"
1100                                 then
1101                                         LIBS="$LIBS -lcrypto"
1102                                         AC_TRY_LINK(
1103                                             [
1104                                             ],
1105                                             [
1106                                                 sprint_realloc_objid();
1107                                             ],
1108                                             [
1109                                                 #
1110                                                 # It worked with -lcrypto; tell
1111                                                 # them they'll need to specify
1112                                                 # --with-ssl.
1113                                                 #
1114                                                 AC_MSG_ERROR([UCD SNMP requires -lcrypto but --with-ssl not specified])
1115                                             ])
1116                                 fi
1117                             ])
1118                 done
1119                 LIBS="$wireshark_save_LIBS"
1120
1121                 #
1122                 # If we didn't find "sprint_realloc_objid()", fail.
1123                 # Either the user needs a newer version of UCD SNMP
1124                 # with "sprint_realloc_objid()", or they may need to
1125                 # specify "--with-ssl".
1126                 #
1127                 if test "$found_snmp_sprint_realloc_objid" = no; then
1128                     AC_MSG_ERROR([UCD SNMP header files found, but sprint_realloc_objid not found in SNMP library.])
1129                 fi
1130
1131                 #
1132                 # We found it, so we have UCD SNMP.
1133                 #
1134                 AC_DEFINE(HAVE_UCD_SNMP, 1, [Define to enable support for UCD-SNMP])
1135                 have_ucd_snmp="yes"
1136         ],[
1137                 #
1138                 # No, we don't have it.
1139                 # If the user explicitly asked for UCD SNMP, fail,
1140                 # otherwise just don't use the UCD SNMP library.
1141                 #
1142                 if test "x$want_ucdsnmp" = "xyes" ; then
1143                         AC_MSG_ERROR(Header file ucd-snmp/snmp.h not found.)
1144                 fi
1145         ])
1146 ])
1147
1148 #
1149 # AC_WIRESHARK_RPM_CHECK
1150 # Looks for the rpm program, and checks to see if we can redefine "_topdir".
1151 #
1152 AC_DEFUN([AC_WIRESHARK_RPM_CHECK],
1153 [
1154         AC_CHECK_PROG(ac_cv_wireshark_have_rpm, rpm, "yes", "no")
1155         if test "x$ac_cv_wireshark_have_rpm" = "xyes"; then
1156                 rpm --define '_topdir /tmp' > /dev/null 2>&1
1157                 AC_MSG_CHECKING(to see if we can redefine _topdir)
1158                 if test $? -eq 0 ; then
1159                         AC_MSG_RESULT(yes)
1160                         HAVE_RPM=yes
1161                 else
1162                         AC_MSG_RESULT(no.  You'll have to build packages manually.)
1163                         HAVE_RPM=no
1164                 fi
1165         fi
1166 ])
1167
1168 #
1169 # AC_WIRESHARK_GNU_SED_CHECK
1170 # Checks if GNU sed is the first sed in PATH.
1171 #
1172 AC_DEFUN([AC_WIRESHARK_GNU_SED_CHECK],
1173 [
1174         AC_MSG_CHECKING(for GNU sed as first sed in PATH)
1175         if  ( sh -c "sed --version" </dev/null 2> /dev/null | grep "GNU sed" 2>&1 > /dev/null ) ;  then
1176                 AC_MSG_RESULT(yes)
1177                 HAVE_GNU_SED=yes
1178         else
1179                 AC_MSG_RESULT(no)
1180                 HAVE_GNU_SED=no
1181         fi
1182 ])
1183
1184 #
1185 # AC_WIRESHARK_ADNS_CHECK
1186 #
1187 AC_DEFUN([AC_WIRESHARK_ADNS_CHECK],
1188 [
1189         want_adns=defaultyes
1190
1191         if test "x$want_adns" = "xdefaultyes"; then
1192                 want_adns=yes
1193                 withval=/usr/local
1194                 if test -d "$withval"; then
1195                         AC_WIRESHARK_ADD_DASH_L(LDFLAGS, ${withval}/lib)
1196                 fi
1197         fi
1198
1199         if test "x$want_adns" = "xyes"; then
1200                 AC_CHECK_LIB(adns, adns_init,
1201                   [
1202                     ADNS_LIBS=-ladns
1203                 AC_DEFINE(HAVE_GNU_ADNS, 1, [Define to use GNU ADNS library])
1204                 have_good_adns=yes
1205                   ],, $SOCKET_LIBS $NSL_LIBS
1206                 )
1207         else
1208                 AC_MSG_RESULT(not required)
1209         fi
1210 ])
1211
1212
1213 #
1214 # AC_WIRESHARK_KRB5_CHECK
1215 #
1216 AC_DEFUN([AC_WIRESHARK_KRB5_CHECK],
1217 [
1218         wireshark_save_CFLAGS="$CFLAGS"
1219         wireshark_save_CPPFLAGS="$CPPFLAGS"
1220         if test "x$krb5_dir" != "x"
1221         then
1222           #
1223           # The user specified a directory in which kerberos resides,
1224           # so add the "include" subdirectory of that directory to
1225           # the include file search path and the "lib" subdirectory
1226           # of that directory to the library search path.
1227           #
1228           # XXX - if there's also a kerberos in a directory that's
1229           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
1230           # make us find the version in the specified directory,
1231           # as the compiler and/or linker will search that other
1232           # directory before it searches the specified directory.
1233           #
1234           CFLAGS="$CFLAGS -I$krb5_dir/include"
1235           CPPFLAGS="$CPPFLAGS -I$krb5_dir/include"
1236           ac_heimdal_version=`grep heimdal $krb5_dir/include/krb5.h | head -n 1 | sed 's/^.*heimdal.*$/HEIMDAL/'`
1237           ac_mit_version=`grep 'Massachusetts Institute of Technology' $krb5_dir/include/krb5.h | head -n 1 | sed 's/^.*Massachusetts Institute of Technology.*$/MIT/'`
1238           ac_krb5_version="$ac_heimdal_version$ac_mit_version"
1239           if test "x$ac_krb5_version" = "xHEIMDAL"
1240               KRB5_LIBS="-L$krb5_dir/lib -lkrb5 -lasn1 $SSL_LIBS -lroken -lcrypt"
1241           then
1242               KRB5_LIBS="-L$krb5_dir/lib -lkrb5 -lk5crypto -lcom_err"
1243           fi
1244           if test "x$ac_krb5_version" = "xMIT"
1245           then
1246             AC_DEFINE(HAVE_MIT_KERBEROS, 1, [Define to use MIT kerberos])
1247           fi
1248         else
1249           AC_PATH_PROG(KRB5_CONFIG, krb5-config) 
1250           if test -x "$KRB5_CONFIG"
1251           then
1252             KRB5_FLAGS=`"$KRB5_CONFIG" --cflags`
1253             KRB5_LIBS=`"$KRB5_CONFIG" --libs`
1254             CFLAGS="$CFLAGS $KRB5_FLAGS"
1255             CPPFLAGS="$CPPFLAGS $KRB5_FLAGS"
1256             #
1257             # If -lcrypto is in KRB5_FLAGS, we require it to build
1258             # with Heimdal/MIT.  We don't want to built with it by
1259             # default, due to annoying license incompatibilities
1260             # between the OpenSSL license and the GPL, so:
1261             #
1262             #   if SSL_LIBS is set to a non-empty string, we
1263             #   remove -lcrypto from KRB5_LIBS and replace
1264             #   it with SSL_LIBS;
1265             #
1266             #   if SSL_LIBS is not set to a non-empty string
1267             #   we fail with an appropriate error message.
1268             #
1269             case "$KRB5_LIBS" in
1270             *-lcrypto*)
1271                 if test ! -z "$SSL_LIBS"
1272                 then
1273                     KRB5_LIBS=`echo $KRB5_LIBS | sed 's/-lcrypto//'`
1274                     KRB5_LIBS="$KRB5_LIBS $SSL_LIBS"
1275                 else
1276                     AC_MSG_ERROR([Kerberos library requires -lcrypto but --with-ssl not specified])
1277                 fi
1278                 ;;
1279             esac
1280             ac_krb5_version=`"$KRB5_CONFIG" --version | head -n 1 | sed -e 's/^.*heimdal.*$/HEIMDAL/' -e 's/^Kerberos .*$/MIT/'`
1281           fi
1282         fi
1283
1284         #
1285         # Make sure we have "krb5.h".  If we don't, it means we probably
1286         # don't have kerberos, so don't use it.
1287         #
1288         AC_CHECK_HEADER(krb5.h,,
1289           [
1290             if test "x$krb5_dir" != "x"
1291             then
1292               #
1293               # The user used "--with-krb5=" to specify a directory
1294               # containing kerberos, but we didn't find the header file
1295               # there; that either means they didn't specify the
1296               # right directory or are confused about whether kerberos
1297               # is, in fact, installed.  Report the error and give up.
1298               #
1299               AC_MSG_ERROR([kerberos header not found in directory specified in --with-krb5])
1300             else
1301               if test "x$want_krb5" = "xyes"
1302               then
1303                 #
1304                 # The user tried to force us to use the library, but we
1305                 # couldn't find the header file; report an error.
1306                 #
1307                 AC_MSG_ERROR(Header file krb5.h not found.)
1308               else
1309                 #
1310                 # We couldn't find the header file; don't use the
1311                 # library, as it's probably not present.
1312                 #
1313                 want_krb5=no
1314                 AC_MSG_RESULT(No Heimdal or MIT header found - disabling dissection for some kerberos data in packet decoding)
1315               fi
1316             fi
1317           ])
1318
1319         if test "x$want_krb5" != "xno"
1320         then
1321             #
1322             # Well, we at least have the krb5 header file.
1323             # Check whether this is Heimdal or MIT.
1324             #
1325             AC_MSG_CHECKING(whether the Kerberos library is Heimdal or MIT)
1326             if test "x$ac_krb5_version" = "xHEIMDAL" -o "x$ac_krb5_version" = "xMIT"
1327             then
1328                 #
1329                 # Yes.
1330                 # Check whether we have krb5_kt_resolve - and whether
1331                 # we need to link with -lresolv when linking with
1332                 # the Kerberos library.
1333                 #
1334                 AC_MSG_RESULT($ac_krb5_version)
1335                 wireshark_save_LIBS="$LIBS"
1336                 found_krb5_kt_resolve=no
1337                 for extras in "" "-lresolv"
1338                 do
1339                     LIBS="$KRB5_LIBS $extras"
1340                     if test -z "$extras"
1341                     then
1342                         AC_MSG_CHECKING([whether $ac_krb5_version includes krb5_kt_resolve])
1343                     else
1344                         AC_MSG_CHECKING([whether $ac_krb5_version includes krb5_kt_resolve (linking with $extras)])
1345                     fi
1346                     AC_TRY_LINK(
1347                         [
1348                         ],
1349                         [
1350                             krb5_kt_resolve();
1351                         ],
1352                         [
1353                             #
1354                             # We found "krb5_kt_resolve()", and required
1355                             # the libraries in extras as well.
1356                             #
1357                             AC_MSG_RESULT(yes)
1358                             KRB5_LIBS="$LIBS"
1359                             AC_DEFINE(HAVE_KERBEROS, 1, [Define to use kerberos])
1360                             if test "x$ac_krb5_version" = "xHEIMDAL"
1361                             then
1362                                 AC_DEFINE(HAVE_HEIMDAL_KERBEROS, 1, [Define to use heimdal kerberos])
1363                             elif test "x$ac_krb5_version" = "xMIT"
1364                             then
1365                                 AC_DEFINE(HAVE_MIT_KERBEROS, 1, [Define to use MIT kerberos])
1366                             fi
1367                             found_krb5_kt_resolve=yes
1368                             break
1369                         ],
1370                         [
1371                             AC_MSG_RESULT(no)
1372                         ])
1373                 done
1374                 if test "$found_krb5_kt_resolve" = no
1375                 then
1376                     #
1377                     # We didn't find "krb5_kt_resolve()" in the
1378                     # Kerberos library, even when we tried linking
1379                     # with -lresolv; we can't link with kerberos.
1380                     #
1381                     if test "x$want_krb5" = "xyes"
1382                     then
1383                         #
1384                         # The user tried to force us to use the library,
1385                         # but we can't do so; report an error.
1386                         #
1387                         AC_MSG_ERROR(Usable $ac_krb5_version not found)
1388                     else
1389                         #
1390                         # Restore the versions of CFLAGS and CPPFLAGS
1391                         # from before we added the flags for Kerberos.
1392                         #
1393                         AC_MSG_RESULT(Usable $ac_krb5_version not found - disabling dissection for some kerberos data in packet decoding)
1394                         CFLAGS="$wireshark_save_CFLAGS"
1395                         CPPFLAGS="$wireshark_save_CPPFLAGS"
1396                         KRB5_LIBS=""
1397                         want_krb5=no
1398                     fi
1399                 else
1400                     #
1401                     # We can link with Kerberos; see whether krb5.h
1402                     # defines KEYTYPE_ARCFOUR_56 (where "defines" means
1403                     # "as a #define or as an enum member).
1404                     #
1405                     AC_MSG_CHECKING([whether krb5.h defines KEYTYPE_ARCFOUR_56])
1406                     AC_COMPILE_IFELSE(
1407                       [
1408                         AC_LANG_SOURCE(
1409                           [[
1410                             #include <krb5.h>
1411                             #include <stdio.h>
1412
1413                             main()
1414                             {
1415                               printf("%u\n", KEYTYPE_ARCFOUR_56);
1416                             }
1417                           ]])
1418                       ],
1419                       [
1420                         AC_MSG_RESULT(yes)
1421                         AC_DEFINE(HAVE_KEYTYPE_ARCFOUR_56, 1, [Define if krb5.h defines KEYTYPE_ARCFOUR_56])
1422                       ],
1423                       [
1424                         AC_MSG_RESULT(no)
1425                       ])
1426                 fi
1427                 LIBS="$wireshark_save_LIBS"
1428             else
1429                 #
1430                 # It's not Heimdal or MIT.
1431                 #
1432                 AC_MSG_RESULT(no)
1433                 if test "x$want_krb5" = "xyes"
1434                 then
1435                     #
1436                     # The user tried to force us to use the library,
1437                     # but we can't do so; report an error.
1438                     #
1439                     AC_MSG_ERROR(Kerberos not found)
1440                 else
1441                     #
1442                     # Restore the versions of CFLAGS and CPPFLAGS
1443                     # from before we added the flags for Kerberos.
1444                     #
1445                     AC_MSG_RESULT(Kerberos not found - disabling dissection for some kerberos data in packet decoding)
1446                     CFLAGS="$wireshark_save_CFLAGS"
1447                     CPPFLAGS="$wireshark_save_CPPFLAGS"
1448                     KRB5_LIBS=""
1449                     want_krb5=no
1450                 fi
1451             fi
1452         else
1453             #
1454             # The user asked us not to use Kerberos, or they didn't
1455             # say whether they wanted us to use it but we found
1456             # that we couldn't.
1457             #
1458             # Restore the versions of CFLAGS and CPPFLAGS
1459             # from before we added the flags for Kerberos.
1460             #
1461             CFLAGS="$wireshark_save_CFLAGS"
1462             CPPFLAGS="$wireshark_save_CPPFLAGS"
1463             KRB5_LIBS=""
1464             want_krb5=no
1465         fi
1466         AC_SUBST(KRB5_LIBS)
1467 ])
1468