CMakeLists.txt

   1 # CMakeLists.txt
   2 #
   3 # $Id$
   4 #
   5 # Wireshark - Network traffic analyzer
   6 # By Gerald Combs <gerald@wireshark.org>
   7 # Copyright 1998 Gerald Combs
   8 #
   9 # This program is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU General Public License
  11 # as published by the Free Software Foundation; either version 2
  12 # of the License, or (at your option) any later version.
  13 #
  14 # This program is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program; if not, write to the Free Software
  21 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
  22 #
  23
  24 project(wireshark C)
  25
  26 cmake_minimum_required(VERSION 2.6)
  27
  28 #Where to find local cmake scripts
  29 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  30 INCLUDE(UseLemon)
  31
  32 # Under linux the release mode (CMAKE_BUILD_TYPE=release) defines NDEBUG
  33
  34 # Disable this later. Alternative: "make VERBOSE=1"
  35 set(CMAKE_VERBOSE_MAKEFILE ON)
  36
  37 set(BUILD_SHARED_LIBS ON)
  38
  39 #Defines CMAKE_INSTALL_BINDIR, CMAKE_INSTALL_DATADIR, etc ...
  40 include(CMakeInstallDirs)
  41
  42 include_directories(
  43         ${CMAKE_BINARY_DIR}
  44
  45         ${CMAKE_SOURCE_DIR}
  46         ${CMAKE_SOURCE_DIR}/epan
  47         ${CMAKE_SOURCE_DIR}/tools/lemon
  48         ${CMAKE_SOURCE_DIR}/wiretap
  49 )
  50
  51 #Where to put libraries
  52 if(NOT LIBRARY_OUTPUT_PATH)
  53         set(LIBRARY_OUTPUT_PATH ${wireshark_BINARY_DIR}/lib CACHE INTERNAL
  54                    "Single output directory for building all libraries.")
  55 endif()
  56
  57 option(BUILD_wireshark   "Build the GUI version of Wireshark" ON)
  58 option(BUILD_tshark      "Build tshark" ON)
  59 option(BUILD_rawshark    "Build rawshark" ON)
  60 option(BUILD_dumpcap     "Build dumpcap" ON)
  61 option(BUILD_text2pcap   "Build text2pcap" ON)
  62 option(BUILD_mergecap    "Build mergecap" ON)
  63 option(BUILD_editcap     "Build editcap" ON)
  64 option(BUILD_capinfos    "Build capinfos" ON)
  65 option(BUILD_randpkt     "Build randpkt" ON)
  66 option(BUILD_dftest      "Build dftest" ON)
  67
  68 option(DISABLE_WERROR    "Do not treat Warnings as errors" OFF)
  69 option(ENABLE_EXTRA_GCC_CHECKS "Do additional -W checks in GCC (disables -Werror)" ON)
  70 option(ENABLE_AIRPCAP    "Enable Airpcap support" ON)
  71 # todo
  72 option(ENABLE_STATIC     "Build a static version of Wireshark" OFF)
  73 option(ENABLE_PLUGINS    "Build with plugins" ON)
  74
  75 option(ENABLE_ADNS       "Build with adns support" ON)
  76 option(ENABLE_PCRE       "Build with pcre support" ON)
  77 option(ENABLE_PORTAUDIO  "Build with portaudio support" ON)
  78 option(ENABLE_Z          "Build with zlib compression support" ON)
  79 # todo wslua currently seems to be broken
  80 option(ENABLE_LUA        "Build with lua dissector support" ON)
  81 option(ENABLE_PYTHON     "Build with python dissector support" ON)
  82 option(ENABLE_SMI        "Build with smi snmp support" ON)
  83 option(ENABLE_GNUTLS     "Build with GNU TLS support" ON)
  84 option(ENABLE_GCRYPT     "Build with GNU crypto support" ON)
  85 option(ENABLE_GEOIP      "Build with GeoIP support" ON)
  86 option(ENABLE_CAP        "Build with posix capabilities support" ON)
  87 option(ENABLE_CARES      "Build with c_ares support" ON)
  88 # todo Mostly hardcoded
  89 option(ENABLE_KERBEROS   "Build with Kerberos support" ON)
  90
  91
  92 set(WIRESHARK_C_FLAGS
  93         -O2
  94         -Werror
  95         -Wall
  96         -W
  97         -Wextra
  98         -Wdeclaration-after-statement
  99         -Wendif-labels
 100         -Wpointer-arith
 101         -Wno-pointer-sign
 102         -Warray-bounds
 103         -Wcast-align
 104         -Wformat-security
 105 )
 106
 107 set(WIRESHARK_EXTRA_C_FLAGS
 108         -pedantic
 109         -Woverflow
 110         -Wlogical-op
 111         -Wno-overlength-strings
 112         -fstrict-overflow -Wstrict-overflow=4
 113         -Wunreachable-code
 114         -Wunsafe-loop-optimizations
 115         -Wno-long-long
 116         -Wbad-function-cast
 117         -Wcast-qual
 118         -Waddress
 119         -Warray-bounds
 120         -Wattributes
 121         -Wdiv-by-zero
 122         -Wformat-security
 123         -Wignored-qualifiers
 124         -Wpragmas
 125         -Wredundant-decls
 126         -Wvla
 127         # packet-ncp2222.inc prevents this from going into all warnings
 128         -Wwrite-strings
 129         -Wstrict-prototypes
 130         -Wmissing-declarations
 131         # Problem with packet-afs.c
 132         -Wshadow
 133         # More cleanup needed for this on LP64
 134         -Wshorten-64-to-32
 135 )
 136
 137 if(ENABLE_EXTRA_GCC_CHECKS)
 138         set(WIRESHARK_C_FLAGS ${WIRESHARK_C_FLAGS} ${WIRESHARK_EXTRA_C_FLAGS})
 139 endif()
 140
 141 add_definitions(
 142         -DHAVE_CONFIG_H
 143         -DPACKAGE=\"wireshark\"
 144         -DNEW_PACKET_LIST
 145 )
 146
 147 # Counterhack to work around some cache magic in CHECK_C_SOURCE_COMPILES
 148 include(CheckCCompilerFlag)
 149 set(C 0)
 150 # Sigh: Have to use THIS_FLAG instead of ${F} for some reason
 151 foreach(THIS_FLAG ${WIRESHARK_C_FLAGS})
 152         set(F WS_C_FLAG_${C})
 153         set(${F} ${THIS_FLAG})
 154         set(V WS_C_FLAG_VALID${C})
 155         check_c_compiler_flag(${${F}} ${V})
 156         if (${${V}})
 157                 add_definitions(${${F}})
 158         endif()
 159         math(EXPR C "${C} + 1")
 160 endforeach()
 161
 162 if(DISABLE_WERROR OR ENABLE_EXTRA_GCC_CHECKS)
 163         remove_definitions( -Werror )
 164 endif()
 165
 166 if(CMAKE_COMPILER_IS_GNUCC)
 167         add_definitions( -D_U_=__attribute__\(\(unused\)\) )
 168 else()
 169         add_definitions( -D_U_=\"\" )
 170 endif()
 171
 172 # todo
 173 # Same for linker flags, but it looks like it's do-it-yourself here
 174 # AC_WIRESHARK_GCC_LDFLAGS_CHECK([-Wl,--as-needed])
 175
 176 #The minimum package list
 177 set(PACKAGELIST GLIB2 PCAP M LEX YACC Perl SH PythonInterp HtmlViewer ${PACKAGELIST})
 178
 179 #Build the gui ?
 180 if(BUILD_wireshark)
 181         set(PACKAGELIST GTK2 ${PACKAGELIST})
 182 endif()
 183
 184 # SMI SNMP
 185 if(ENABLE_SMI)
 186         set(PACKAGELIST SMI ${PACKAGELIST})
 187 endif()
 188
 189 # GNU crypto
 190 if(ENABLE_GCRYPT)
 191         set(PACKAGELIST GCRYPT ${PACKAGELIST})
 192 endif()
 193
 194 # GNU SSL/TLS support
 195 if(ENABLE_GNUTLS)
 196         set(PACKAGELIST GNUTLS ${PACKAGELIST})
 197 endif()
 198
 199 # Regular expressions lib
 200 if(ENABLE_PCRE)
 201         set(PACKAGELIST PCRE ${PACKAGELIST})
 202 endif()
 203
 204 # Kerberos
 205 if(ENABLE_KERBEROS)
 206         set(PACKAGELIST KERBEROS ${PACKAGELIST})
 207 endif()
 208
 209 # Portable audio
 210 if(ENABLE_PORTAUDIO)
 211         set(PACKAGELIST PORTAUDIO ${PACKAGELIST})
 212 endif()
 213
 214
 215 # Prefer c-ares over adns
 216 if(ENABLE_CARES)        # C Asynchronouse resolver
 217         set(PACKAGELIST CARES ${PACKAGELIST})
 218 elseif(ENABLE_ADNS)     # Gnu asynchronous DNS
 219         set(PACKAGELIST ADNS ${PACKAGELIST})
 220 endif()
 221
 222 # Zlib compression
 223 if(ENABLE_Z)
 224         set(PACKAGELIST Z ${PACKAGELIST})
 225 endif()
 226
 227 # Lua 5.1 dissectors
 228 if(ENABLE_LUA)
 229         set(PACKAGELIST LUA ${PACKAGELIST})
 230 endif()
 231
 232 # GeoIP address resolving
 233 if(ENABLE_GEOIP)
 234         set(PACKAGELIST GEOIP ${PACKAGELIST})
 235 endif()
 236
 237 # Capabilities
 238 if(ENABLE_CAP)
 239         set(PACKAGELIST CAP ${PACKAGELIST})
 240 endif()
 241
 242 if(ENABLE_PYTHON)
 243         set(PACKAGELIST PYTHON ${PACKAGELIST})
 244 endif()
 245
 246 set(PROGLIST text2pcap mergecap capinfos editcap dumpcap)
 247
 248 #Let's loop the package list
 249 foreach(PACKAGE ${PACKAGELIST})
 250         find_package(${PACKAGE} REQUIRED)
 251         message(${PACKAGE}_FOUND)
 252         if (${PACKAGE}_FOUND)
 253                 set(HAVE_LIB${PACKAGE} 1)
 254                 include_directories(${${PACKAGE}_INCLUDE_DIRS})
 255                 message(STATUS "${PACKAGE} includes: ${${PACKAGE}_INCLUDE_DIRS}")
 256                 message(STATUS "${PACKAGE} libs: ${${PACKAGE}_LIBRARIES}")
 257         endif()
 258 endforeach()
 259
 260 if(HAVE_LIBPYTHON)
 261         set(HAVE_PYTHON 1)
 262         set(PYTHON_DIR "${CMAKE_INSTALL_PREFIX}/lib/wireshark/python/${VERSION}")
 263 endif()
 264 if(HAVE_LIBLUA)
 265         set(HAVE_LUA_H 1)
 266         set(HAVE_LUA_5_1 1)
 267 endif()
 268 if(HAVE_LIBKERBEROS)
 269         set(HAVE_KERBEROS 1)
 270         # HAVE_HEIMDAL_KERBEROS
 271         set(HAVE_MIT_KERBEROS 1)
 272         set(HAVE_KEYTYPE_ARCFOUR_56 1)
 273 endif()
 274 if(HAVE_LIBGEOIP)
 275         set(HAVE_GEOIP 1)
 276 endif()
 277 if(HAVE_LIBCARES)
 278         set(HAVE_C_ARES 1)
 279 endif()
 280 if(HAVE_LIBADNS)
 281         set(HAVE_GNU_ADNS 1)
 282 endif()
 283 if(ENABLE_AIRPCAP)
 284         set(HAVE_AIRPCAP 1)
 285 endif()
 286
 287 include(ConfigureChecks.cmake)
 288
 289 #Big or little endian ?
 290 include(TestBigEndian)
 291 test_big_endian(WORDS_BIGENDIAN)
 292
 293 #packaging
 294 set(CPACK_PACKAGE_NAME wireshark)
 295 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "capture packet")
 296 set(CPACK_PACKAGE_VENDOR "wireshark")
 297 set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README")
 298 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/COPYING")
 299 set(CPACK_PACKAGE_VERSION_MAJOR "1")
 300 set(CPACK_PACKAGE_VERSION_MINOR "3")
 301 set(CPACK_PACKAGE_VERSION_PATCH "1")
 302 set(CPACK_PACKAGE_VERSION "${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 303
 304 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
 305 set(CPACK_PACKAGE_INSTALL_DIRECTORY "/usr")
 306 set(CPACK_GENERATOR "TGZ")
 307 set(CPACK_SOURCE_GENERATOR "TGZ")
 308
 309 set(DATAFILE_DIR "${CMAKE_INSTALL_PREFIX}/share/${CPACK_PACKAGE_NAME}")
 310
 311 if(ENABLE_PLUGINS)
 312         set(HAVE_PLUGINS 1)
 313         set(PLUGIN_DIR="${DATAFILE_DIR}/plugins/${CPACK_PACKAGE_VERSION}")
 314         set(PLUGIN_SRC_DIRS
 315                 plugins/asn1
 316                 plugins/docsis
 317                 plugins/ethercat
 318 #               plugins/giop
 319                 plugins/gryphon
 320                 plugins/irda
 321                 plugins/m2m
 322                 plugins/mate
 323                 plugins/opcua
 324                 plugins/profinet
 325                 plugins/sercosiii
 326                 plugins/stats_tree
 327 #               plugins/tpg
 328                 plugins/unistim
 329                 plugins/wimax
 330                 plugins/wimaxasncp
 331         )
 332 else()
 333         set(PLUGIN_SRC_DIRS )
 334 endif()
 335
 336 foreach(PLUGIN_DIR ${PLUGIN_SRC_DIRS})
 337         add_subdirectory( ${PLUGIN_DIR} )
 338 endforeach()
 339
 340 #Platform specific
 341 if(UNIX)
 342         set(WS_VAR_IMPORT "extern")
 343 endif()
 344
 345 if(APPLE)
 346 #TODO verify that APPLE implies HAVE_OS_X_FRAMEWORKS
 347         set(HAVE_OS_X_FRAMEWORKS 1)
 348         FIND_LIBRARY (APPLE_CORE_SERVICES_LIBRARY CoreServices)
 349         FIND_LIBRARY (APPLE_COCOA_LIBRARY Cocoa)
 350 endif()
 351
 352 if(WIN32)
 353         add_definitions(-D_NEED_VAR_IMPORT_)
 354         set(WS_VAR_IMPORT "__declspec(dllimport) extern")
 355
 356         # Disable deprecation
 357         if(MSVC80 OR MSVC90)
 358                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 359         endif()
 360 endif()
 361
 362
 363 add_subdirectory( codecs )
 364 add_subdirectory( epan )
 365 add_subdirectory( gtk )
 366 add_subdirectory( wiretap )
 367 add_subdirectory( wsutil )
 368
 369 configure_file(${CMAKE_SOURCE_DIR}/cmakeconfig.h.in ${CMAKE_BINARY_DIR}/config.h)
 370
 371 include(FeatureSummary)
 372 #SET_FEATURE_INFO(NAME DESCRIPTION [URL [COMMENT] ]
 373 PRINT_ENABLED_FEATURES()
 374 PRINT_DISABLED_FEATURES()
 375
 376 link_directories(
 377         gtk
 378         codecs
 379         epan
 380         wiretap
 381         wsutil
 382 )
 383
 384 ADD_CUSTOM_COMMAND(
 385         OUTPUT svnversion.h
 386         COMMAND ${PERL}
 387                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 388                 ${CMAKE_CURRENT_SOURCE_DIR}
 389         DEPENDS
 390                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 391 )
 392
 393 # Create the necessary tools
 394 set(lemon_FILES
 395         tools/lemon/lemon.c
 396 )
 397 set(lemon_LIBS
 398         # Do we need something here on any platform?
 399 )
 400 add_executable(lemon ${lemon_FILES})
 401 target_link_libraries(lemon ${lemon_LIBS})
 402 # but don't install
 403
 404 ADD_CUSTOM_COMMAND(
 405         OUTPUT tshark-tap-register.c
 406         COMMAND ${SHELL}
 407           ${CMAKE_SOURCE_DIR}/make-tapreg-dotc
 408           tshark-tap-register.c
 409           ${CMAKE_CURRENT_SOURCE_DIR}
 410           ${TSHARK_TAP_SRC}
 411         DEPENDS
 412           ${CMAKE_SOURCE_DIR}/make-tapreg-dotc
 413           ${TSHARK_TAP_SRC}
 414 )
 415
 416 ADD_CUSTOM_COMMAND(
 417         OUTPUT ps.c
 418         COMMAND ${PYTHON_EXECUTABLE}
 419           ${CMAKE_CURRENT_SOURCE_DIR}/rdps.py
 420           ${CMAKE_CURRENT_SOURCE_DIR}/print.ps
 421           ps.c
 422         DEPENDS
 423           ${CMAKE_CURRENT_SOURCE_DIR}/rdps.py
 424           ${CMAKE_CURRENT_SOURCE_DIR}/print.ps
 425 )
 426
 427 if(UNIX)
 428         set(PLATFORM_SRC
 429                 capture-pcap-util-unix.c
 430         )
 431 endif()
 432
 433 if(WIN32)
 434         set(PLATFORM_SRC
 435                 capture-wpcap.c capture_wpcap_packet.c
 436         )
 437 endif()
 438
 439 set(WTAP_PLUGIN_SOURCES
 440         epan/plugins.c
 441         epan/report_err.c
 442         epan/filesystem.c
 443 )
 444
 445 set(WIRESHARK_COMMON_SRC
 446         ${PLATFORM_SRC}
 447         capture_errs.c
 448         capture-pcap-util.c
 449         capture_ui_utils.c
 450         cfile.c
 451         clopts_common.c
 452         disabled_protos.c
 453         packet-range.c
 454         print.c
 455         ps.c
 456         sync_pipe_write.c
 457         timestats.c
 458         util.c
 459         tap-megaco-common.c
 460         tap-rtp-common.c
 461         version_info.c
 462 )
 463
 464 set(TSHARK_TAP_SRC
 465         tap-afpstat.c
 466         tap-ansi_astat.c
 467         tap-bootpstat.c
 468         tap-camelcounter.c
 469         tap-camelsrt.c
 470         tap-comparestat.c
 471         tap-dcerpcstat.c
 472         tap-funnel.c
 473         tap-gsm_astat.c
 474         tap-h225counter.c
 475         tap-h225rassrt.c
 476         tap-httpstat.c
 477         tap-iostat.c
 478         tap-iousers.c
 479         tap-mgcpstat.c
 480         tap-megacostat.c
 481         tap-protocolinfo.c
 482         tap-protohierstat.c
 483         tap-radiusstat.c
 484         tap-rpcstat.c
 485         tap-rpcprogs.c
 486         tap-rtp.c
 487         tap-sctpchunkstat.c
 488         tap-sipstat.c
 489         tap-smbsids.c
 490         tap-smbstat.c
 491         tap-stats_tree.c
 492         tap-wspstat.c
 493 )
 494
 495 set(INSTALL_DIRS
 496         diameter
 497         dtds
 498         help
 499         radius
 500         tpncp
 501         wimaxasncp
 502 )
 503
 504 set(INSTALL_FILES
 505         ${CMAKE_BINARY_DIR}/AUTHORS-SHORT
 506         COPYING
 507 #       capinfos.html
 508         cfilters
 509         colorfilters
 510 #       console.lua
 511         dfilters
 512 #       dtd_gen.lua
 513 #       dumpcap.html
 514 #       editcap.html
 515 #       idl2wrs.html
 516 #       init.lua
 517 #       ipmap.html
 518         manuf
 519 #       mergecap.html
 520 #       rawshark.html
 521         services
 522         smi_modules
 523 #       text2pcap.html
 524 #       tshark.html
 525 #       wireshark-filter.html
 526 #       wireshark.html
 527 #       ws.css
 528 )
 529
 530 set(LIBEPAN_LIBS
 531 #               $(wireshark_optional_objects)
 532                 epan
 533 #               @INET_PTON_LO@
 534 #               @INET_NTOP_LO@
 535 #               @SSL_LIBS@
 536 #               $(plugin_ldadd)
 537                 ${PCRE_LIBRARIES}
 538                 ${PCAP_LIBRARIES}
 539 #               @SOCKET_LIBS@
 540 #               @NSL_LIBS@
 541                 ${CARES_LIBRARIES}
 542                 ${ADNS_LIBRARIES}
 543                 ${KERBEROS_LIBRARIES}
 544 #               @FRAMEWORKS@
 545                 ${LUA_LIBRARIES}
 546                 ${PYTHON_LIBRARIES}
 547                 ${GEOIP_LIBRARIES}
 548                 ${GCRYPT_LIBRARIES}
 549                 ${GNUTLS_LIBRARIES}
 550                 ${SMI_LIBRARIES}
 551                 ${Z_LIBRARIES}
 552                 ${M_LIBRARIES}
 553 )
 554
 555 if(BUILD_wireshark)
 556         set(wireshark_LIBS
 557                 ui
 558                 ${GTK2_LIBRARIES}
 559                 codecs
 560                 ${PORTAUDIO_LIBRARIES}
 561                 ${LIBEPAN_LIBS}
 562                 ${APPLE_CORE_SERVICES_LIBRARY}
 563                 ${APPLE_COCOA_LIBRARY}
 564         )
 565         set(wireshark_FILES
 566                 airpcap_loader.c
 567                 alert_box.c
 568                 capture.c
 569                 capture_info.c
 570                 capture_opts.c
 571                 capture_sync.c
 572                 color_filters.c
 573                 file.c
 574                 fileset.c
 575                 filters.c
 576                 g711.c
 577                 merge.c
 578                 proto_hier_stats.c
 579                 summary.c
 580                 tempfile.c
 581                 ${WIRESHARK_COMMON_SRC}
 582         )
 583         add_executable(wireshark ${wireshark_FILES})
 584         target_link_libraries(wireshark ${wireshark_LIBS})
 585         install(TARGETS wireshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 586 endif()
 587
 588 if(BUILD_tshark)
 589         set(tshark_LIBS
 590                 ${LIBEPAN_LIBS}
 591                 ${APPLE_COCOA_LIBRARY}
 592         )
 593         set(tshark_FILES
 594                 capture_opts.c
 595                 capture_sync.c
 596                 tempfile.c
 597                 tshark-tap-register.c
 598                 tshark.c
 599                 ${TSHARK_TAP_SRC}
 600                 ${WIRESHARK_COMMON_SRC}
 601         )
 602         add_executable(tshark ${tshark_FILES})
 603         target_link_libraries(tshark ${tshark_LIBS})
 604         install(TARGETS tshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 605 endif()
 606
 607 if(BUILD_rawshark)
 608         set(rawshark_LIBS
 609                 ${LIBEPAN_LIBS}
 610                 ${APPLE_COCOA_LIBRARY}
 611         )
 612         set(rawshark_FILES
 613                 ${WIRESHARK_COMMON_SRC}
 614                 rawshark.c
 615         )
 616         add_executable(rawshark ${rawshark_FILES})
 617         target_link_libraries(rawshark ${rawshark_LIBS})
 618         install(TARGETS rawshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 619 endif()
 620
 621 if(BUILD_dftest)
 622         set(dftest_LIBS
 623                 ${LIBEPAN_LIBS}
 624         )
 625         set(dftest_FILES
 626                 dftest.c
 627                 util.c
 628         )
 629         add_executable(dftest ${dftest_FILES})
 630         target_link_libraries(dftest ${dftest_LIBS})
 631         install(TARGETS dftest RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 632 endif()
 633
 634 if(BUILD_randpkt)
 635         set(randpkt_LIBS
 636                 wiretap
 637                 ${M_LIBRARIES}
 638                 ${PCAP_LIBRARIES}
 639 #               @SOCKET_LIBS@
 640 #               @NSL_LIBS@
 641                 ${CARES_LIBRARIES}
 642                 ${ADNS_LIBRARIES}
 643                 ${Z_LIBRARIES}
 644         )
 645         set(randpkt_FILES
 646                 randpkt.c
 647         )
 648         add_executable(randpkt ${randpkt_FILES})
 649         target_link_libraries(randpkt ${randpkt_LIBS})
 650         install(TARGETS randpkt RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 651 endif()
 652
 653 if(BUILD_text2pcap)
 654         set(text2pcap_LIBS
 655                 wiretap
 656                 ${M_LIBRARIES}
 657                 ${Z_LIBRARIES}
 658         )
 659         set(text2pcap_FILES
 660                 text2pcap.c
 661         )
 662         add_lex_files(text2pcap_FILES
 663                 text2pcap-scanner.l
 664         )
 665         add_executable(text2pcap ${text2pcap_FILES})
 666         target_link_libraries(text2pcap ${text2pcap_LIBS})
 667         install(TARGETS text2pcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 668 endif()
 669
 670 if(BUILD_mergecap)
 671         set(mergecap_LIBS
 672                 wiretap
 673                 ${Z_LIBRARIES}
 674         )
 675         set(mergecap_FILES
 676                 mergecap.c
 677                 merge.c
 678                 svnversion.h
 679         )
 680         add_executable(mergecap ${mergecap_FILES})
 681         target_link_libraries(mergecap ${mergecap_LIBS})
 682         install(TARGETS mergecap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 683 endif()
 684
 685 if(BUILD_capinfos)
 686         set(capinfos_LIBS
 687                 wiretap
 688                 ${Z_LIBRARIES}
 689                 ${APPLE_COCOA_LIBRARY}
 690         )
 691         set(capinfos_FILES
 692                 capinfos.c
 693                 ${WTAP_PLUGIN_SOURCES}
 694         )
 695         add_executable(capinfos ${capinfos_FILES})
 696         target_link_libraries(capinfos ${capinfos_LIBS})
 697         install(TARGETS capinfos RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 698 endif()
 699
 700 if(BUILD_editcap)
 701         set(editcap_LIBS
 702                 wiretap
 703                 ${Z_LIBRARIES}
 704         )
 705         set(editcap_FILES
 706                 editcap.c
 707                 epan/crypt/crypt-md5.c
 708                 epan/nstime.c
 709                 ${WTAP_PLUGIN_SOURCES}
 710         )
 711         add_executable(editcap ${editcap_FILES})
 712         target_link_libraries(editcap ${editcap_LIBS})
 713         install(TARGETS editcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 714 endif()
 715
 716 if(BUILD_dumpcap)
 717         set(dumpcap_LIBS
 718                 wiretap
 719 #               @INET_NTOP_LO@
 720                 ${PCAP_LIBRARIES}
 721                 ${CAP_LIBRARIES}
 722 #               @SOCKET_LIBS@
 723 #               @NSL_LIBS@
 724 #               @FRAMEWORKS@
 725                 ${GCRYPT_LIBRARIES}
 726                 ${GNUTLS_LIBRARIES}
 727                 ${Z_LIBRARIES}
 728                 ${APPLE_COCOA_LIBRARY}
 729         )
 730         set(dumpcap_FILES
 731                 svnversion.h
 732                 capture_opts.c
 733                 capture-pcap-util.c
 734                 capture_stop_conditions.c
 735                 clopts_common.c
 736                 conditions.c
 737                 dumpcap.c
 738                 pcapio.c
 739                 ringbuffer.c
 740                 sync_pipe_write.c
 741                 tempfile.c
 742                 version_info.c
 743                 ${PLATFORM_SRC}
 744         )
 745         add_executable(dumpcap ${dumpcap_FILES})
 746         target_link_libraries(dumpcap ${dumpcap_LIBS})
 747         install(TARGETS dumpcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 748 endif()
 749
 750 ADD_CUSTOM_COMMAND(
 751         OUTPUT  AUTHORS-SHORT
 752         COMMAND ${PERL}
 753                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
 754                 ${CMAKE_SOURCE_DIR}/doc/make-authors-short.pl
 755                 < ${CMAKE_SOURCE_DIR}/AUTHORS
 756                 > AUTHORS-SHORT
 757         DEPENDS
 758                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
 759                 ${CMAKE_SOURCE_DIR}/doc/make-authors-short.pl
 760                 ${CMAKE_SOURCE_DIR}/AUTHORS
 761 )
 762
 763 add_custom_target(
 764         auxiliary ALL
 765         DEPENDS
 766                 AUTHORS-SHORT
 767                 # todo: Add manpages and onlinedocs and generate them
 768 )
 769
 770 install(
 771         FILES
 772                 ${INSTALL_FILES}
 773         DESTINATION
 774                 ${CMAKE_INSTALL_DATADIR}/${CPACK_PACKAGE_NAME}
 775 )
 776
 777 install(
 778         DIRECTORY
 779                 ${INSTALL_DIRS}
 780         DIRECTORY_PERMISSIONS
 781                 OWNER_EXECUTE OWNER_WRITE OWNER_READ
 782                 GROUP_EXECUTE GROUP_READ
 783                 WORLD_EXECUTE WORLD_READ
 784         DESTINATION
 785                 ${CMAKE_INSTALL_DATADIR}/${CPACK_PACKAGE_NAME}
 786         PATTERN ".svn" EXCLUDE
 787         PATTERN "Makefile.*" EXCLUDE
 788         PATTERN "faq.py" EXCLUDE
 789 )