CMakeLists.txt

   1 # CMakeLists.txt
   2 #
   3 # $Id$
   4 #
   5 # Wireshark - Network traffic analyzer
   6 # By Gerald Combs <gerald@wireshark.org>
   7 # Copyright 1998 Gerald Combs
   8 #
   9 # This program is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU General Public License
  11 # as published by the Free Software Foundation; either version 2
  12 # of the License, or (at your option) any later version.
  13 #
  14 # This program is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program; if not, write to the Free Software
  21 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
  22 #
  23
  24 project(Wireshark C)
  25
  26 cmake_minimum_required(VERSION 2.6)
  27 set(CMAKE_BACKWARDS_COMPATIBILITY 2.6)
  28
  29 # Needs to be set after cmake_minimum_required or cmake_policy(VERSION)
  30 #if(COMMAND cmake_policy)
  31 #       cmake_policy(SET CMP0015 NEW)
  32 #endif(COMMAND cmake_policy)
  33
  34 # set(PROJECT_VERSION "1.3.4-rc5")
  35 # set(PROJECT_VERSION "1.3.4rc5")
  36 # set(PROJECT_VERSION "1.3.4")
  37 # If not set, copy over Wireshark version from configure.in AC_INIT
  38 if(NOT PROJECT_VERSION)
  39         file(STRINGS
  40                 ${CMAKE_SOURCE_DIR}/configure.in
  41                 VERSIONLINE
  42                 REGEX "\\(wireshark, .*\\)"
  43         )
  44         string(REGEX REPLACE ".*\\(wireshark, (.*)\\).*"
  45                 "\\1"
  46                 PROJECT_VERSION
  47                 ${VERSIONLINE}
  48         )
  49 endif()
  50 string(REGEX REPLACE "([0-9]+)\\..*"
  51         "\\1"
  52         PROJECT_MAJOR_VERSION
  53         ${PROJECT_VERSION}
  54 )
  55 string(REGEX REPLACE ".*\\.([0-9]+)\\..*"
  56         "\\1"
  57         PROJECT_MINOR_VERSION
  58         ${PROJECT_VERSION}
  59 )
  60 string(REGEX REPLACE ".*\\..*\\.([0-9]+).*"
  61         "\\1"
  62         PROJECT_PATCH_VERSION
  63         ${PROJECT_VERSION}
  64 )
  65 string(REGEX REPLACE ".*\\..*\\.[0-9]+(.*)"
  66         "\\1"
  67         PROJECT_VERSION_EXTENSION
  68         ${PROJECT_VERSION}
  69 )
  70 message(STATUS "V: ${PROJECT_VERSION}, MaV: ${PROJECT_MAJOR_VERSION}, MiV: ${PROJECT_MINOR_VERSION}, PL: ${PROJECT_PATCH_VERSION}, EV: ${PROJECT_VERSION_EXTENSION}.")
  71
  72 #Where to find local cmake scripts
  73 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  74 INCLUDE(UseLemon)
  75 INCLUDE(UseMakeDissectorReg)
  76 INCLUDE(UseMakeTapReg)
  77
  78 # Under linux the release mode (CMAKE_BUILD_TYPE=release) defines NDEBUG
  79
  80 # Disable this later. Alternative: "make VERBOSE=1"
  81 set(CMAKE_VERBOSE_MAKEFILE ON)
  82
  83 #Defines CMAKE_INSTALL_BINDIR, CMAKE_INSTALL_DATADIR, etc ...
  84 include(CMakeInstallDirs)
  85
  86 include_directories(
  87         ${CMAKE_BINARY_DIR}
  88         ${CMAKE_SOURCE_DIR}
  89         ${CMAKE_SOURCE_DIR}/epan
  90         ${CMAKE_SOURCE_DIR}/tools/lemon
  91         ${CMAKE_SOURCE_DIR}/wiretap
  92 )
  93
  94 #Where to put libraries
  95 if(NOT LIBRARY_OUTPUT_PATH)
  96         set(LIBRARY_OUTPUT_PATH ${Wireshark_BINARY_DIR}/lib CACHE INTERNAL
  97                    "Single output directory for building all libraries.")
  98 endif()
  99
 100
 101 include(CMakeOptions.txt)
 102
 103
 104 set(WIRESHARK_C_FLAGS
 105         -O2
 106         -Wall
 107         -W
 108         -Wextra
 109         -Wdeclaration-after-statement
 110         -Wendif-labels
 111         -Wpointer-arith
 112         -Wno-pointer-sign
 113         -Warray-bounds
 114         -Wcast-align
 115         -Wformat-security
 116         -fexcess-precision=fast
 117 )
 118
 119 set(WIRESHARK_EXTRA_C_FLAGS
 120         -pedantic
 121         -Woverflow
 122         -Wlogical-op
 123         -Wno-overlength-strings
 124         -fstrict-overflow -Wstrict-overflow=4
 125         -Wunreachable-code
 126         -Wunsafe-loop-optimizations
 127         -Wno-long-long
 128         -Wbad-function-cast
 129         -Wcast-qual
 130         -Waddress
 131         -Warray-bounds
 132         -Wattributes
 133         -Wdiv-by-zero
 134         -Wformat-security
 135         -Wignored-qualifiers
 136         -Wpragmas
 137         -Wredundant-decls
 138         -Wvla
 139         -Wc++-compat
 140         -Wjump-misses-init
 141         # packet-ncp2222.inc prevents this from going into all warnings
 142         -Wwrite-strings
 143         -Wstrict-prototypes
 144         -Wmissing-declarations
 145         # Problem with packet-afs.c
 146         -Wshadow
 147         # More cleanup needed for this on LP64
 148         -Wshorten-64-to-32
 149 )
 150
 151 if(ENABLE_EXTRA_GCC_CHECKS)   # This overrides -Werror
 152         set(WIRESHARK_C_FLAGS ${WIRESHARK_C_FLAGS} ${WIRESHARK_EXTRA_C_FLAGS})
 153 endif()
 154
 155 add_definitions(
 156         -DHAVE_CONFIG_H
 157         -DPACKAGE=\"wireshark\"
 158 )
 159
 160 # Counterhack to work around some cache magic in CHECK_C_SOURCE_COMPILES
 161 include(CheckCCompilerFlag)
 162 set(C 0)
 163 # Sigh: Have to use THIS_FLAG instead of ${F} for some reason
 164 foreach(THIS_FLAG ${WIRESHARK_C_FLAGS})
 165         set(F WS_C_FLAG_${C})
 166         set(${F} ${THIS_FLAG})
 167         set(V WS_C_FLAG_VALID${C})
 168         check_c_compiler_flag(${${F}} ${V})
 169         if (${${V}})
 170                 add_definitions(${${F}})
 171         endif()
 172         math(EXPR C "${C} + 1")
 173 endforeach()
 174
 175 if(NOT DISABLE_WERROR AND NOT ENABLE_EXTRA_GCC_CHECKS)
 176         check_c_compiler_flag(-Werror WERROR)
 177 else()
 178         set(WERROR 0)
 179 endif()
 180
 181 if(CMAKE_COMPILER_IS_GNUCC)
 182         add_definitions( -D_U_=__attribute__\(\(unused\)\) )
 183 else()
 184         add_definitions( -D_U_=\"\" )
 185 endif()
 186
 187 set(WIRESHARK_LD_FLAGS
 188         -Wl,--as-needed
 189         # -flto
 190         # -fwhopr
 191         # -fwhole-program
 192 )
 193
 194 include(CheckCLinkerFlag)
 195 set(C 0)
 196 # Sigh: Have to use THIS_FLAG instead of ${F} for some reason
 197 foreach(THIS_FLAG ${WIRESHARK_LD_FLAGS})
 198         set(F WS_LD_FLAG_${C})
 199         set(${F} ${THIS_FLAG})
 200         set(V WS_LD_FLAG_VALID${C})
 201         check_c_linker_flag(${${F}} ${V})
 202         if (${${V}})
 203                 set(WS_LINK_FLAGS ${WS_LINK_FLAGS} ${${F}})
 204         endif()
 205         math(EXPR C "${C} + 1")
 206 endforeach()
 207
 208 if(ENABLE_STATIC)
 209   set(LINK_MODE_LIB STATIC)
 210   set(LINK_MODE_MODULE STATIC)
 211 else()
 212   set(LINK_MODE_LIB SHARED)
 213   set(LINK_MODE_MODULE MODULE)
 214 endif()
 215
 216 # The packagelist is doing some magic:  If we add XXX to the packagelist, we
 217 # - may optionally set XXX_OPTIONS to pass to the find_package command
 218 # - will call FindXXX.cmake
 219 # - return found libraries in XXX_LIBRARIES
 220 # - return found include in XXX_INCLUDE_DIRS
 221 # - set HAVE_XXX
 222
 223 #The minimum package list
 224 set(PACKAGELIST GLIB2 GMODULE2 PCAP M LEX YACC Perl SH PythonInterp)
 225 set(GLIB2_FIND_REQUIRED)
 226 set(GLIB2_MIN_VERSION 2.4.0)
 227 set(PCAP_REQUIRED)
 228 set(M_REQUIRED)
 229
 230 set(PACKAGELIST ${PACKAGELIST} HtmlViewer)
 231
 232 #Build the gui ?
 233 if(BUILD_wireshark)
 234         set(PACKAGELIST ${PACKAGELIST} GTK2)
 235         set(GTK2_OPTIONS COMPONENTS gtk)
 236         set(GTK2_DEBUG false)
 237 endif()
 238
 239 # SMI SNMP
 240 if(ENABLE_SMI)
 241         set(PACKAGELIST ${PACKAGELIST} SMI)
 242 endif()
 243
 244 # GNU crypto
 245 if(ENABLE_GCRYPT)
 246         set(PACKAGELIST ${PACKAGELIST} GCRYPT)
 247 endif()
 248
 249 # GNU SSL/TLS support
 250 if(ENABLE_GNUTLS)
 251         set(PACKAGELIST ${PACKAGELIST} GNUTLS)
 252 endif()
 253
 254 # Regular expressions lib
 255 if(ENABLE_PCRE)
 256         set(PACKAGELIST ${PACKAGELIST} PCRE)
 257 endif()
 258
 259 # Kerberos
 260 if(ENABLE_KERBEROS)
 261         set(PACKAGELIST ${PACKAGELIST} KERBEROS)
 262 endif()
 263
 264 # Portable audio
 265 if(ENABLE_PORTAUDIO)
 266         set(PACKAGELIST ${PACKAGELIST} PORTAUDIO)
 267 endif()
 268
 269
 270 # Prefer c-ares over adns
 271 if(ENABLE_CARES)        # C Asynchronouse resolver
 272         set(PACKAGELIST ${PACKAGELIST} CARES)
 273 elseif(ENABLE_ADNS)     # Gnu asynchronous DNS
 274         set(PACKAGELIST ${PACKAGELIST} ADNS)
 275 endif()
 276
 277 # Zlib compression
 278 if(ENABLE_ZLIB)
 279         set(PACKAGELIST ${PACKAGELIST} ZLIB)
 280 endif()
 281
 282 # Lua 5.1 dissectors
 283 if(ENABLE_LUA)
 284         set(PACKAGELIST ${PACKAGELIST} LUA)
 285 endif()
 286
 287 # GeoIP address resolving
 288 if(ENABLE_GEOIP)
 289         set(PACKAGELIST ${PACKAGELIST} GEOIP)
 290 endif()
 291
 292 # Capabilities
 293 if(ENABLE_CAP)
 294         set(PACKAGELIST ${PACKAGELIST} CAP)
 295 endif()
 296
 297 if(ENABLE_PYTHON)
 298         set(PACKAGELIST ${PACKAGELIST} PYTHON)
 299 endif()
 300
 301 set(PACKAGELIST ${PACKAGELIST} YAPP)
 302
 303 if(ENABLE_GUIDES)
 304         set(PACKAGELIST ${PACKAGELIST} POD)
 305 endif()
 306
 307
 308 set(PROGLIST text2pcap mergecap capinfos editcap dumpcap)
 309
 310 #Let's loop the package list
 311 foreach(PACKAGE ${PACKAGELIST})
 312         if(${PACKAGE}_OPTIONS)
 313                 find_package(${PACKAGE} ${${PACKAGE}_OPTIONS})
 314         elseif(${PACKAGE}_REQUIRED)
 315                 find_package(${PACKAGE} REQUIRED)
 316         else()
 317                 find_package(${PACKAGE})
 318         endif()
 319         message(${PACKAGE}_FOUND)
 320         if (${PACKAGE}_FOUND)
 321                 set(HAVE_LIB${PACKAGE} 1)
 322                 include_directories(${${PACKAGE}_INCLUDE_DIRS})
 323                 message(STATUS "${PACKAGE} includes: ${${PACKAGE}_INCLUDE_DIRS}")
 324                 message(STATUS "${PACKAGE} libs: ${${PACKAGE}_LIBRARIES}")
 325         endif()
 326 endforeach()
 327
 328 #packaging
 329 include(CPackConfig.txt)
 330
 331 if(HAVE_LIBPYTHON)
 332         set(HAVE_PYTHON 1)
 333         set(PYTHON_DIR "${CMAKE_INSTALL_PREFIX}/lib/wireshark/python/${CPACK_PACKAGE_VERSION}")
 334 endif()
 335 if(HAVE_LIBLUA)
 336         set(HAVE_LUA_H 1)
 337         set(HAVE_LUA_5_1 1)
 338 endif()
 339 if(HAVE_LIBKERBEROS)
 340         set(HAVE_KERBEROS 1)
 341         # HAVE_HEIMDAL_KERBEROS
 342         set(HAVE_MIT_KERBEROS 1)
 343         set(HAVE_KEYTYPE_ARCFOUR_56 1)
 344 endif()
 345 if(HAVE_LIBGEOIP)
 346         set(HAVE_GEOIP 1)
 347 endif()
 348 if(HAVE_LIBCARES)
 349         set(HAVE_C_ARES 1)
 350 endif()
 351 if(HAVE_LIBADNS)
 352         set(HAVE_GNU_ADNS 1)
 353 endif()
 354 if(ENABLE_AIRPCAP)
 355         set(HAVE_AIRPCAP 1)
 356 endif()
 357 # That's the name autofoo uses
 358 if(HAVE_LIBZLIB)
 359         set(HAVE_LIBZ 1)
 360 endif()
 361
 362 include(ConfigureChecks.cmake)
 363
 364 #Big or little endian ?
 365 include(TestBigEndian)
 366 test_big_endian(WORDS_BIGENDIAN)
 367
 368 set(DATAFILE_DIR "${CMAKE_INSTALL_PREFIX}/share/${CPACK_PACKAGE_NAME}")
 369
 370 if(ENABLE_PLUGINS)
 371         set(HAVE_PLUGINS 1)
 372         set(PLUGIN_DIR="${DATAFILE_DIR}/plugins/${CPACK_PACKAGE_VERSION}")
 373         set(PLUGIN_SRC_DIRS
 374                 plugins/asn1
 375                 plugins/docsis
 376                 plugins/ethercat
 377                 plugins/giop
 378                 plugins/gryphon
 379                 plugins/interlink
 380                 plugins/irda
 381                 plugins/m2m
 382                 plugins/mate
 383                 plugins/opcua
 384                 plugins/profinet
 385                 plugins/sercosiii
 386                 plugins/stats_tree
 387                 plugins/unistim
 388                 plugins/wimax
 389                 plugins/wimaxasncp
 390         )
 391 # It seems this stuff doesn't build with autofoo either...
 392 #       if(YAPP_FOUND)
 393 #               set(PLUGIN_SRC_DIRS
 394 #                       ${PLUGIN_SRC_DIRS}
 395 #                       plugins/tpg
 396 #               )
 397 #       endif()
 398 else()
 399         set(PLUGIN_SRC_DIRS )
 400 endif()
 401
 402 foreach(PLUGIN_DIR ${PLUGIN_SRC_DIRS})
 403         add_subdirectory( ${PLUGIN_DIR} )
 404 endforeach()
 405
 406 add_subdirectory( codecs )
 407 add_subdirectory( epan )
 408 add_subdirectory( gtk )
 409 add_subdirectory( tools/lemon )
 410 add_subdirectory( wiretap )
 411 add_subdirectory( wsutil )
 412
 413 # Basedir where to install guides
 414 set(DOC_DIR "$ENV{docdir}")
 415 message(STATUS "docdir: ${DOC_DIR}")
 416
 417 if(ENABLE_GUIDES)
 418         add_subdirectory( docbook )
 419 endif()
 420
 421 #Platform specific
 422 if(UNIX)
 423         set(WS_VAR_IMPORT "extern")
 424 endif()
 425
 426 if(APPLE)
 427 #TODO verify that APPLE implies HAVE_OS_X_FRAMEWORKS
 428         set(HAVE_OS_X_FRAMEWORKS 1)
 429         FIND_LIBRARY (APPLE_CORE_SERVICES_LIBRARY CoreServices)
 430         FIND_LIBRARY (APPLE_COCOA_LIBRARY Cocoa)
 431 endif()
 432
 433 if(WIN32)
 434         add_definitions(-D_NEED_VAR_IMPORT_)
 435         set(WS_VAR_IMPORT "__declspec(dllimport) extern")
 436
 437         # Disable deprecation
 438         if(MSVC80 OR MSVC90)
 439                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 440         endif()
 441 endif()
 442
 443 configure_file(${CMAKE_SOURCE_DIR}/cmakeconfig.h.in ${CMAKE_BINARY_DIR}/config.h)
 444
 445 include(FeatureSummary)
 446 #SET_FEATURE_INFO(NAME DESCRIPTION [URL [COMMENT] ]
 447 PRINT_ENABLED_FEATURES()
 448 PRINT_DISABLED_FEATURES()
 449
 450 link_directories(
 451         ${CMAKE_BINARY_DIR}/gtk
 452         ${CMAKE_BINARY_DIR}/codecs
 453         ${CMAKE_BINARY_DIR}/epan
 454         ${CMAKE_BINARY_DIR}/wiretap
 455         ${CMAKE_BINARY_DIR}/wsutil
 456 )
 457
 458 ADD_CUSTOM_TARGET(
 459         svnversion ALL
 460         COMMAND ${PERL}
 461                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 462                 ${CMAKE_CURRENT_SOURCE_DIR}
 463         DEPENDS
 464                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 465 )
 466
 467 ADD_CUSTOM_COMMAND(
 468         OUTPUT  svnversion.h
 469         COMMAND ${PERL}
 470                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 471                 ${CMAKE_CURRENT_SOURCE_DIR}
 472         DEPENDS
 473                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 474 )
 475
 476 register_tap_files(tshark-tap-register.c
 477         ${TSHARK_TAP_SRC}
 478 )
 479
 480 ADD_CUSTOM_COMMAND(
 481         OUTPUT  ps.c
 482         COMMAND ${PYTHON_EXECUTABLE}
 483                 ${CMAKE_CURRENT_SOURCE_DIR}/tools/rdps.py
 484                 ${CMAKE_CURRENT_SOURCE_DIR}/print.ps
 485                 ps.c
 486         DEPENDS
 487                 ${CMAKE_CURRENT_SOURCE_DIR}/tools/rdps.py
 488                 ${CMAKE_CURRENT_SOURCE_DIR}/print.ps
 489 )
 490
 491 if(UNIX)
 492         set(PLATFORM_SRC
 493                 capture-pcap-util-unix.c
 494         )
 495 endif()
 496
 497 if(WIN32)
 498         set(PLATFORM_SRC
 499                 capture-wpcap.c capture_wpcap_packet.c
 500         )
 501 endif()
 502
 503 set(WTAP_PLUGIN_SOURCES
 504         epan/plugins.c
 505         epan/report_err.c
 506         epan/filesystem.c
 507 )
 508
 509 set(SHARK_COMMON_CAPTURE_SRC
 510         capture_errs.c
 511         capture_ifinfo.c
 512         capture_ui_utils.c
 513 )
 514
 515 set(WIRESHARK_COMMON_SRC
 516         ${PLATFORM_SRC}
 517         capture-pcap-util.c
 518         cfile.c
 519         clopts_common.c
 520         disabled_protos.c
 521         packet-range.c
 522         print.c
 523         ps.c
 524         svnversion.h
 525         sync_pipe_write.c
 526         timestats.c
 527         util.c
 528         tap-megaco-common.c
 529         tap-rtp-common.c
 530         version_info.c
 531 )
 532
 533 set(TSHARK_TAP_SRC
 534         tap-afpstat.c
 535         tap-ansi_astat.c
 536         tap-bootpstat.c
 537         tap-camelcounter.c
 538         tap-camelsrt.c
 539         tap-comparestat.c
 540         tap-dcerpcstat.c
 541         tap-diameter-avp.c
 542         tap-funnel.c
 543         tap-gsm_astat.c
 544         tap-h225counter.c
 545         tap-h225rassrt.c
 546         tap-httpstat.c
 547         tap-iostat.c
 548         tap-iousers.c
 549         tap-mgcpstat.c
 550         tap-megacostat.c
 551         tap-protocolinfo.c
 552         tap-protohierstat.c
 553         tap-radiusstat.c
 554         tap-rpcstat.c
 555         tap-rpcprogs.c
 556         tap-rtp.c
 557         tap-scsistat.c
 558         tap-sctpchunkstat.c
 559         tap-sipstat.c
 560         tap-smbsids.c
 561         tap-smbstat.c
 562         tap-stats_tree.c
 563         tap-sv.c
 564         tap-wspstat.c
 565 )
 566
 567 set(INSTALL_DIRS
 568         diameter
 569         dtds
 570         help
 571         radius
 572         tpncp
 573         wimaxasncp
 574 )
 575
 576 set(INSTALL_FILES
 577         ${CMAKE_BINARY_DIR}/AUTHORS-SHORT
 578         COPYING
 579         ${CMAKE_BINARY_DIR}/capinfos.html
 580         cfilters
 581         colorfilters
 582         dfilters
 583         ${CMAKE_BINARY_DIR}/dftest.html
 584         ${CMAKE_BINARY_DIR}/dumpcap.html
 585         ${CMAKE_BINARY_DIR}/editcap.html
 586         ${CMAKE_BINARY_DIR}/idl2wrs.html
 587         ipmap.html
 588         manuf
 589         ${CMAKE_BINARY_DIR}/mergecap.html
 590         ${CMAKE_BINARY_DIR}/randpkt.html
 591         ${CMAKE_BINARY_DIR}/rawshark.html
 592         services
 593         smi_modules
 594         ${CMAKE_BINARY_DIR}/text2pcap.html
 595         ${CMAKE_BINARY_DIR}/tshark.html
 596         ${CMAKE_BINARY_DIR}/wireshark-filter.html
 597         ${CMAKE_BINARY_DIR}/wireshark.html
 598         docbook/ws.css
 599 )
 600
 601 set(LIBEPAN_LIBS
 602 #               @NSL_LIBS@      # -lnsl
 603 #               @SOCKET_LIBS@   # -lsocket
 604 #               @SSL_LIBS@      # -lcrypto
 605                 epan
 606 #               $(plugin_ldadd) # in case of static
 607                 ${PCRE_LIBRARIES}
 608                 ${PCAP_LIBRARIES}
 609                 ${CARES_LIBRARIES}
 610                 ${ADNS_LIBRARIES}
 611                 ${KERBEROS_LIBRARIES}
 612                 ${LUA_LIBRARIES}
 613                 ${PYTHON_LIBRARIES}
 614                 ${GEOIP_LIBRARIES}
 615                 ${GCRYPT_LIBRARIES}
 616                 ${GNUTLS_LIBRARIES}
 617                 ${SMI_LIBRARIES}
 618                 ${ZLIB_LIBRARIES}
 619                 ${M_LIBRARIES}
 620 )
 621
 622 if(BUILD_wireshark)
 623         set(wireshark_LIBS
 624                 ui
 625                 ${GTK2_LIBRARIES}
 626                 codecs
 627                 ${PORTAUDIO_LIBRARIES}
 628                 ${LIBEPAN_LIBS}
 629                 ${APPLE_CORE_SERVICES_LIBRARY}
 630                 ${APPLE_COCOA_LIBRARY}
 631         )
 632         set(wireshark_FILES
 633                 airpcap_loader.c
 634                 alert_box.c
 635                 capture.c
 636                 capture_info.c
 637                 capture_opts.c
 638                 capture_sync.c
 639                 color_filters.c
 640                 file.c
 641                 fileset.c
 642                 filters.c
 643                 g711.c
 644                 merge.c
 645                 proto_hier_stats.c
 646                 summary.c
 647                 tempfile.c
 648                 ${SHARK_COMMON_CAPTURE_SRC}
 649                 ${WIRESHARK_COMMON_SRC}
 650         )
 651         add_executable(wireshark ${wireshark_FILES})
 652         add_dependencies(wireshark svnversion)
 653         set_target_properties(wireshark PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 654         target_link_libraries(wireshark ${wireshark_LIBS})
 655         install(TARGETS wireshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 656 endif()
 657
 658 if(BUILD_tshark)
 659         set(tshark_LIBS
 660                 ${LIBEPAN_LIBS}
 661                 ${APPLE_COCOA_LIBRARY}
 662         )
 663         set(tshark_FILES
 664                 capture_opts.c
 665                 capture_sync.c
 666                 tempfile.c
 667                 tshark-tap-register.c
 668                 tshark.c
 669                 ${TSHARK_TAP_SRC}
 670                 ${SHARK_COMMON_CAPTURE_SRC}
 671                 ${WIRESHARK_COMMON_SRC}
 672         )
 673         add_executable(tshark ${tshark_FILES})
 674         add_dependencies(tshark svnversion)
 675         set_target_properties(tshark PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 676         target_link_libraries(tshark ${tshark_LIBS})
 677         install(TARGETS tshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 678 endif()
 679
 680 if(BUILD_rawshark)
 681         set(rawshark_LIBS
 682                 ${LIBEPAN_LIBS}
 683                 ${APPLE_COCOA_LIBRARY}
 684         )
 685         set(rawshark_FILES
 686                 ${WIRESHARK_COMMON_SRC}
 687                 rawshark.c
 688         )
 689         add_executable(rawshark ${rawshark_FILES})
 690         add_dependencies(rawshark svnversion)
 691         set_target_properties(rawshark PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 692         target_link_libraries(rawshark ${rawshark_LIBS})
 693         install(TARGETS rawshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 694 endif()
 695
 696 if(BUILD_dftest)
 697         set(dftest_LIBS
 698                 ${LIBEPAN_LIBS}
 699         )
 700         set(dftest_FILES
 701                 dftest.c
 702                 util.c
 703         )
 704         add_executable(dftest ${dftest_FILES})
 705         set_target_properties(dftest PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 706         target_link_libraries(dftest ${dftest_LIBS})
 707         install(TARGETS dftest RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 708 endif()
 709
 710 if(BUILD_randpkt)
 711         set(randpkt_LIBS
 712                 wiretap
 713                 ${M_LIBRARIES}
 714                 ${PCAP_LIBRARIES}
 715 #               @SOCKET_LIBS@
 716 #               @NSL_LIBS@
 717                 ${CARES_LIBRARIES}
 718                 ${ADNS_LIBRARIES}
 719                 ${ZLIB_LIBRARIES}
 720         )
 721         set(randpkt_FILES
 722                 randpkt.c
 723         )
 724         add_executable(randpkt ${randpkt_FILES})
 725         set_target_properties(randpkt PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 726         target_link_libraries(randpkt ${randpkt_LIBS})
 727         install(TARGETS randpkt RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 728 endif()
 729
 730 if(BUILD_text2pcap)
 731         set(text2pcap_LIBS
 732                 wiretap
 733                 ${M_LIBRARIES}
 734                 ${ZLIB_LIBRARIES}
 735         )
 736         set(text2pcap_CLEAN_FILES
 737                 text2pcap.c
 738         )
 739         set(text2pcap_FILES
 740                 ${text2pcap_CLEAN_FILES}
 741         )
 742         add_lex_files(text2pcap_FILES
 743                 text2pcap-scanner.l
 744         )
 745         add_executable(text2pcap ${text2pcap_FILES})
 746         add_dependencies(text2pcap svnversion)
 747         set_target_properties(text2pcap PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 748         target_link_libraries(text2pcap ${text2pcap_LIBS})
 749         install(TARGETS text2pcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 750 endif()
 751
 752 if(BUILD_mergecap)
 753         set(mergecap_LIBS
 754                 wiretap
 755                 ${ZLIB_LIBRARIES}
 756         )
 757         set(mergecap_FILES
 758                 mergecap.c
 759                 merge.c
 760                 svnversion.h
 761         )
 762         add_executable(mergecap ${mergecap_FILES})
 763         add_dependencies(mergecap svnversion)
 764         set_target_properties(mergecap PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 765         target_link_libraries(mergecap ${mergecap_LIBS})
 766         install(TARGETS mergecap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 767 endif()
 768
 769 if(BUILD_capinfos)
 770         set(capinfos_LIBS
 771                 wiretap
 772                 ${ZLIB_LIBRARIES}
 773                 ${GCRYPT_LIBRARIES}
 774                 ${APPLE_COCOA_LIBRARY}
 775         )
 776         set(capinfos_FILES
 777                 capinfos.c
 778                 ${WTAP_PLUGIN_SOURCES}
 779         )
 780         add_executable(capinfos ${capinfos_FILES})
 781         add_dependencies(capinfos svnversion)
 782         set_target_properties(capinfos PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 783         target_link_libraries(capinfos ${capinfos_LIBS})
 784         install(TARGETS capinfos RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 785 endif()
 786
 787 if(BUILD_editcap)
 788         set(editcap_LIBS
 789                 wiretap
 790                 ${ZLIB_LIBRARIES}
 791         )
 792         set(editcap_FILES
 793                 editcap.c
 794                 epan/crypt/crypt-md5.c
 795                 epan/nstime.c
 796                 ${WTAP_PLUGIN_SOURCES}
 797         )
 798         add_executable(editcap ${editcap_FILES})
 799         add_dependencies(editcap svnversion)
 800         set_target_properties(editcap PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 801         target_link_libraries(editcap ${editcap_LIBS})
 802         install(TARGETS editcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 803 endif()
 804
 805 if(BUILD_dumpcap)
 806         set(dumpcap_LIBS
 807                 wiretap
 808 #               @INET_NTOP_LO@
 809                 ${PCAP_LIBRARIES}
 810                 ${CAP_LIBRARIES}
 811 #               @SOCKET_LIBS@
 812 #               @NSL_LIBS@
 813                 ${ZLIB_LIBRARIES}
 814                 ${APPLE_COCOA_LIBRARY}
 815         )
 816         set(dumpcap_FILES
 817                 svnversion.h
 818                 capture_opts.c
 819                 capture-pcap-util.c
 820                 capture_stop_conditions.c
 821                 clopts_common.c
 822                 conditions.c
 823                 dumpcap.c
 824                 pcapio.c
 825                 ringbuffer.c
 826                 sync_pipe_write.c
 827                 tempfile.c
 828                 version_info.c
 829                 ${PLATFORM_SRC}
 830         )
 831         add_executable(dumpcap ${dumpcap_FILES})
 832         add_dependencies(dumpcap svnversion)
 833         set_target_properties(dumpcap PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 834         target_link_libraries(dumpcap ${dumpcap_LIBS})
 835         install(TARGETS dumpcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 836 endif()
 837
 838 ADD_CUSTOM_COMMAND(
 839         OUTPUT  ${CMAKE_BINARY_DIR}/AUTHORS-SHORT
 840         COMMAND ${PERL}
 841                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
 842                 ${CMAKE_SOURCE_DIR}/doc/make-authors-short.pl
 843                 < ${CMAKE_SOURCE_DIR}/AUTHORS
 844                 > ${CMAKE_BINARY_DIR}/AUTHORS-SHORT
 845         DEPENDS
 846                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
 847                 ${CMAKE_SOURCE_DIR}/doc/make-authors-short.pl
 848                 ${CMAKE_SOURCE_DIR}/AUTHORS
 849 )
 850
 851 ADD_CUSTOM_COMMAND(
 852         OUTPUT  ${CMAKE_BINARY_DIR}/AUTHORS-SHORT-FORMAT
 853                 ${CMAKE_BINARY_DIR}/wireshark.pod
 854         COMMAND ${PERL}
 855                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
 856                 ${CMAKE_SOURCE_DIR}/doc/make-authors-format.pl
 857                 < ${CMAKE_BINARY_DIR}/AUTHORS-SHORT
 858                 > ${CMAKE_BINARY_DIR}/AUTHORS-SHORT-FORMAT
 859         COMMAND cat
 860                 ${CMAKE_SOURCE_DIR}/doc/wireshark.pod.template
 861                 ${CMAKE_BINARY_DIR}/AUTHORS-SHORT-FORMAT
 862                 > ${CMAKE_BINARY_DIR}/wireshark.pod
 863         DEPENDS
 864                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
 865                 ${CMAKE_SOURCE_DIR}/doc/make-authors-format.pl
 866                 ${CMAKE_BINARY_DIR}/AUTHORS-SHORT
 867                 ${CMAKE_SOURCE_DIR}/doc/wireshark.pod.template
 868 )
 869
 870 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/capinfos 1 )
 871 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/dftest 1 )
 872 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/dumpcap 1 )
 873 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/editcap 1 )
 874 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/idl2wrs 1 )
 875 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/mergecap 1 )
 876 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/randpkt 1 )
 877 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/rawshark 1 )
 878 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/text2pcap 1 )
 879 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/tshark 1 )
 880 pod2manhtml( wireshark 1 )
 881 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/wireshark-filter 4 )
 882
 883 add_custom_target(
 884         auxiliary ALL
 885         DEPENDS
 886                 AUTHORS-SHORT
 887                 capinfos.html
 888                 dftest.html
 889                 dumpcap.html
 890                 editcap.html
 891                 idl2wrs.html
 892                 mergecap.html
 893                 randpkt.html
 894                 rawshark.html
 895                 text2pcap.html
 896                 tshark.html
 897                 wireshark.html
 898                 wireshark-filter.html
 899 )
 900
 901 set(MAN1_FILES
 902         ${CMAKE_BINARY_DIR}/capinfos.1
 903         ${CMAKE_BINARY_DIR}/dftest.1
 904         ${CMAKE_BINARY_DIR}/dumpcap.1
 905         ${CMAKE_BINARY_DIR}/editcap.1
 906         ${CMAKE_BINARY_DIR}/idl2wrs.1
 907         ${CMAKE_BINARY_DIR}/mergecap.1
 908         ${CMAKE_BINARY_DIR}/randpkt.1
 909         ${CMAKE_BINARY_DIR}/rawshark.1
 910         ${CMAKE_BINARY_DIR}/text2pcap.1
 911         ${CMAKE_BINARY_DIR}/tshark.1
 912         ${CMAKE_BINARY_DIR}/wireshark.1
 913 )
 914
 915 set(MAN4_FILES
 916         ${CMAKE_BINARY_DIR}/wireshark-filter.4
 917 )
 918
 919 set(CLEAN_FILES
 920         ${wireshark_FILES}
 921         ${tshark_FILES}
 922         ${rawshark_FILES}
 923         ${dftest_FILES}
 924         ${randpkt_FILES}
 925         ${text2pcap_CLEAN_FILES}
 926         ${mergecap_FILES}
 927         ${capinfos_FILES}
 928         ${editcap_FILES}
 929         ${dumpcap_FILES}
 930 )
 931
 932 if (WERROR)
 933         set_source_files_properties(
 934                 ${CLEAN_FILES}
 935                 PROPERTIES
 936                 COMPILE_FLAGS -Werror
 937         )
 938 endif()
 939
 940 install(
 941         FILES
 942                 ${INSTALL_FILES}
 943         DESTINATION
 944                 ${CMAKE_INSTALL_DATADIR}/${CPACK_PACKAGE_NAME}
 945 )
 946
 947 install(
 948         FILES
 949                 ${MAN1_FILES}
 950         DESTINATION
 951                 ${CMAKE_INSTALL_MANDIR}/man1
 952 )
 953
 954 install(
 955         FILES
 956                 ${MAN4_FILES}
 957         DESTINATION
 958                 ${CMAKE_INSTALL_MANDIR}/man4
 959 )
 960
 961 install(
 962         DIRECTORY
 963                 ${INSTALL_DIRS}
 964         DIRECTORY_PERMISSIONS
 965                 OWNER_EXECUTE OWNER_WRITE OWNER_READ
 966                 GROUP_EXECUTE GROUP_READ
 967                 WORLD_EXECUTE WORLD_READ
 968         DESTINATION
 969                 ${CMAKE_INSTALL_DATADIR}/${CPACK_PACKAGE_NAME}
 970         PATTERN ".svn" EXCLUDE
 971         PATTERN "Makefile.*" EXCLUDE
 972         PATTERN "faq.py" EXCLUDE
 973 )