CMakeLists.txt

   1 # CMakeLists.txt
   2 #
   3 # $Id$
   4 #
   5 # Wireshark - Network traffic analyzer
   6 # By Gerald Combs <gerald@wireshark.org>
   7 # Copyright 1998 Gerald Combs
   8 #
   9 # This program is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU General Public License
  11 # as published by the Free Software Foundation; either version 2
  12 # of the License, or (at your option) any later version.
  13 #
  14 # This program is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program; if not, write to the Free Software
  21 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
  22 #
  23
  24 project(Wireshark C)
  25
  26 cmake_minimum_required(VERSION 2.6)
  27 set(CMAKE_BACKWARDS_COMPATIBILITY 2.6)
  28
  29 # set(PROJECT_VERSION "1.3.4-rc5")
  30 # set(PROJECT_VERSION "1.3.4rc5")
  31 # set(PROJECT_VERSION "1.3.4")
  32 # If not set, copy over Wireshark version from configure.in AC_INIT
  33 if(NOT PROJECT_VERSION)
  34         file(STRINGS
  35                 ${CMAKE_SOURCE_DIR}/configure.in
  36                 VERSIONLINE
  37                 REGEX "\\(wireshark, .*\\)"
  38         )
  39         string(REGEX REPLACE ".*\\(wireshark, (.*)\\).*"
  40                 "\\1"
  41                 PROJECT_VERSION
  42                 ${VERSIONLINE}
  43         )
  44 endif()
  45 string(REGEX REPLACE "([0-9]+)\\..*"
  46         "\\1"
  47         PROJECT_MAJOR_VERSION
  48         ${PROJECT_VERSION}
  49 )
  50 string(REGEX REPLACE ".*\\.([0-9]+)\\..*"
  51         "\\1"
  52         PROJECT_MINOR_VERSION
  53         ${PROJECT_VERSION}
  54 )
  55 string(REGEX REPLACE ".*\\..*\\.([0-9]+).*"
  56         "\\1"
  57         PROJECT_PATCH_VERSION
  58         ${PROJECT_VERSION}
  59 )
  60 string(REGEX REPLACE ".*\\..*\\.[0-9]+(.*)"
  61         "\\1"
  62         PROJECT_VERSION_EXTENSION
  63         ${PROJECT_VERSION}
  64 )
  65 message(STATUS "V: ${PROJECT_VERSION}, MaV: ${PROJECT_MAJOR_VERSION}, MiV: ${PROJECT_MINOR_VERSION}, PL: ${PROJECT_PATCH_VERSION}, EV: ${PROJECT_VERSION_EXTENSION}.")
  66
  67 #Where to find local cmake scripts
  68 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  69 INCLUDE(UseLemon)
  70 INCLUDE(UseMakeDissectorReg)
  71 INCLUDE(UseMakeTapReg)
  72
  73 # Under linux the release mode (CMAKE_BUILD_TYPE=release) defines NDEBUG
  74
  75 # Disable this later. Alternative: "make VERBOSE=1"
  76 set(CMAKE_VERBOSE_MAKEFILE ON)
  77
  78 #Defines CMAKE_INSTALL_BINDIR, CMAKE_INSTALL_DATADIR, etc ...
  79 include(CMakeInstallDirs)
  80
  81 include_directories(
  82         ${CMAKE_BINARY_DIR}
  83         ${CMAKE_SOURCE_DIR}
  84         ${CMAKE_SOURCE_DIR}/epan
  85         ${CMAKE_SOURCE_DIR}/tools/lemon
  86         ${CMAKE_SOURCE_DIR}/wiretap
  87 )
  88
  89 #Where to put libraries
  90 if(NOT LIBRARY_OUTPUT_PATH)
  91         set(LIBRARY_OUTPUT_PATH ${Wireshark_BINARY_DIR}/lib CACHE INTERNAL
  92                    "Single output directory for building all libraries.")
  93 endif()
  94
  95 option(BUILD_wireshark   "Build the GUI version of Wireshark" ON)
  96 option(BUILD_tshark      "Build tshark" ON)
  97 option(BUILD_rawshark    "Build rawshark" ON)
  98 option(BUILD_dumpcap     "Build dumpcap" ON)
  99 option(BUILD_text2pcap   "Build text2pcap" ON)
 100 option(BUILD_mergecap    "Build mergecap" ON)
 101 option(BUILD_editcap     "Build editcap" ON)
 102 option(BUILD_capinfos    "Build capinfos" ON)
 103 option(BUILD_randpkt     "Build randpkt" ON)
 104 option(BUILD_dftest      "Build dftest" ON)
 105 option(AUTOGEN_dcerpc    "Autogenerate dcerpc dissectors" OFF)
 106 option(AUTOGEN_pidl      "Autogenerate pidl dissectors" OFF)
 107
 108 option(DISABLE_WERROR    "Do not treat Warnings as errors" OFF)
 109 option(ENABLE_EXTRA_GCC_CHECKS "Do additional -W checks in GCC (disables -Werror)" OFF)
 110 option(ENABLE_AIRPCAP    "Enable Airpcap support" ON)
 111 # todo
 112 option(ENABLE_STATIC     "Build a static version of Wireshark (not yet working)" OFF)
 113 option(ENABLE_PLUGINS    "Build with plugins" ON)
 114 # todo
 115 option(ENABLE_GUIDES     "Build Guides" ON)
 116
 117 option(ENABLE_ADNS       "Build with adns support" ON)
 118 option(ENABLE_PCRE       "Build with pcre support" ON)
 119 option(ENABLE_PORTAUDIO  "Build with portaudio support" ON)
 120 option(ENABLE_ZLIB       "Build with zlib compression support" ON)
 121 option(ENABLE_LUA        "Build with lua dissector support" ON)
 122 option(ENABLE_PYTHON     "Build with python dissector support" ON)
 123 option(ENABLE_SMI        "Build with smi snmp support" ON)
 124 option(ENABLE_GNUTLS     "Build with GNU TLS support" ON)
 125 option(ENABLE_GCRYPT     "Build with GNU crypto support" ON)
 126 option(ENABLE_GEOIP      "Build with GeoIP support" ON)
 127 option(ENABLE_CAP        "Build with posix capabilities support" ON)
 128 option(ENABLE_CARES      "Build with c_ares support" ON)
 129 # todo Mostly hardcoded
 130 option(ENABLE_KERBEROS   "Build with Kerberos support" ON)
 131
 132
 133 set(WIRESHARK_C_FLAGS
 134         -O2
 135         -Wall
 136         -W
 137         -Wextra
 138         -Wdeclaration-after-statement
 139         -Wendif-labels
 140         -Wpointer-arith
 141         -Wno-pointer-sign
 142         -Warray-bounds
 143         -Wcast-align
 144         -Wformat-security
 145 )
 146
 147 set(WIRESHARK_EXTRA_C_FLAGS
 148         -pedantic
 149         -Woverflow
 150         -Wlogical-op
 151         -Wno-overlength-strings
 152         -fstrict-overflow -Wstrict-overflow=4
 153         -Wunreachable-code
 154         -Wunsafe-loop-optimizations
 155         -Wno-long-long
 156         -Wbad-function-cast
 157         -Wcast-qual
 158         -Waddress
 159         -Warray-bounds
 160         -Wattributes
 161         -Wdiv-by-zero
 162         -Wformat-security
 163         -Wignored-qualifiers
 164         -Wpragmas
 165         -Wredundant-decls
 166         -Wvla
 167         -Wc++-compat
 168         -Wjump-misses-init
 169         # packet-ncp2222.inc prevents this from going into all warnings
 170         -Wwrite-strings
 171         -Wstrict-prototypes
 172         -Wmissing-declarations
 173         # Problem with packet-afs.c
 174         -Wshadow
 175         # More cleanup needed for this on LP64
 176         -Wshorten-64-to-32
 177 )
 178
 179 if(ENABLE_EXTRA_GCC_CHECKS)   # This overrides -Werror
 180         set(WIRESHARK_C_FLAGS ${WIRESHARK_C_FLAGS} ${WIRESHARK_EXTRA_C_FLAGS})
 181 endif()
 182
 183 add_definitions(
 184         -DHAVE_CONFIG_H
 185         -DPACKAGE=\"wireshark\"
 186         -DNEW_PACKET_LIST
 187 )
 188
 189 # Counterhack to work around some cache magic in CHECK_C_SOURCE_COMPILES
 190 include(CheckCCompilerFlag)
 191 set(C 0)
 192 # Sigh: Have to use THIS_FLAG instead of ${F} for some reason
 193 foreach(THIS_FLAG ${WIRESHARK_C_FLAGS})
 194         set(F WS_C_FLAG_${C})
 195         set(${F} ${THIS_FLAG})
 196         set(V WS_C_FLAG_VALID${C})
 197         check_c_compiler_flag(${${F}} ${V})
 198         if (${${V}})
 199                 add_definitions(${${F}})
 200         endif()
 201         math(EXPR C "${C} + 1")
 202 endforeach()
 203
 204 if(NOT DISABLE_WERROR AND NOT ENABLE_EXTRA_GCC_CHECKS)
 205         check_c_compiler_flag(-Werror WERROR)
 206 else()
 207         set(WERROR 0)
 208 endif()
 209
 210 if(CMAKE_COMPILER_IS_GNUCC)
 211         add_definitions( -D_U_=__attribute__\(\(unused\)\) )
 212 else()
 213         add_definitions( -D_U_=\"\" )
 214 endif()
 215
 216 set(WIRESHARK_LD_FLAGS
 217         -Wl,--as-needed
 218         # -flto
 219         # -fwhopr
 220         # -fwhole-program
 221 )
 222
 223 include(CheckCLinkerFlag)
 224 set(C 0)
 225 # Sigh: Have to use THIS_FLAG instead of ${F} for some reason
 226 foreach(THIS_FLAG ${WIRESHARK_LD_FLAGS})
 227         set(F WS_LD_FLAG_${C})
 228         set(${F} ${THIS_FLAG})
 229         set(V WS_LD_FLAG_VALID${C})
 230         check_c_linker_flag(${${F}} ${V})
 231         if (${${V}})
 232                 set(WS_LINK_FLAGS ${WS_LINK_FLAGS} ${${F}})
 233         endif()
 234         math(EXPR C "${C} + 1")
 235 endforeach()
 236
 237 if(ENABLE_STATIC)
 238   set(LINK_MODE_LIB STATIC)
 239   set(LINK_MODE_MODULE STATIC)
 240 else()
 241   set(LINK_MODE_LIB SHARED)
 242   set(LINK_MODE_MODULE MODULE)
 243 endif()
 244
 245 #The minimum package list
 246 set(PACKAGELIST GLIB2 PCAP M LEX YACC Perl SH PythonInterp HtmlViewer ${PACKAGELIST})
 247
 248 #Build the gui ?
 249 if(BUILD_wireshark)
 250         set(PACKAGELIST GTK2 ${PACKAGELIST})
 251         set(GTK2_OPTIONS COMPONENTS gtk)
 252         set(GTK2_DEBUG false)
 253 endif()
 254
 255 # SMI SNMP
 256 if(ENABLE_SMI)
 257         set(PACKAGELIST SMI ${PACKAGELIST})
 258 endif()
 259
 260 # GNU crypto
 261 if(ENABLE_GCRYPT)
 262         set(PACKAGELIST GCRYPT ${PACKAGELIST})
 263 endif()
 264
 265 # GNU SSL/TLS support
 266 if(ENABLE_GNUTLS)
 267         set(PACKAGELIST GNUTLS ${PACKAGELIST})
 268 endif()
 269
 270 # Regular expressions lib
 271 if(ENABLE_PCRE)
 272         set(PACKAGELIST PCRE ${PACKAGELIST})
 273 endif()
 274
 275 # Kerberos
 276 if(ENABLE_KERBEROS)
 277         set(PACKAGELIST KERBEROS ${PACKAGELIST})
 278 endif()
 279
 280 # Portable audio
 281 if(ENABLE_PORTAUDIO)
 282         set(PACKAGELIST PORTAUDIO ${PACKAGELIST})
 283 endif()
 284
 285
 286 # Prefer c-ares over adns
 287 if(ENABLE_CARES)        # C Asynchronouse resolver
 288         set(PACKAGELIST CARES ${PACKAGELIST})
 289 elseif(ENABLE_ADNS)     # Gnu asynchronous DNS
 290         set(PACKAGELIST ADNS ${PACKAGELIST})
 291 endif()
 292
 293 # Zlib compression
 294 if(ENABLE_ZLIB)
 295         set(PACKAGELIST ZLIB ${PACKAGELIST})
 296 endif()
 297
 298 # Lua 5.1 dissectors
 299 if(ENABLE_LUA)
 300         set(PACKAGELIST LUA ${PACKAGELIST})
 301 endif()
 302
 303 # GeoIP address resolving
 304 if(ENABLE_GEOIP)
 305         set(PACKAGELIST GEOIP ${PACKAGELIST})
 306 endif()
 307
 308 # Capabilities
 309 if(ENABLE_CAP)
 310         set(PACKAGELIST CAP ${PACKAGELIST})
 311 endif()
 312
 313 if(ENABLE_PYTHON)
 314         set(PACKAGELIST PYTHON ${PACKAGELIST})
 315 endif()
 316
 317 set(PROGLIST text2pcap mergecap capinfos editcap dumpcap)
 318
 319 #Let's loop the package list
 320 foreach(PACKAGE ${PACKAGELIST})
 321         if(${PACKAGE}_OPTIONS)
 322                 find_package(${PACKAGE} ${${PACKAGE}_OPTIONS})
 323         else()
 324                 find_package(${PACKAGE} REQUIRED)
 325         endif()
 326         message(${PACKAGE}_FOUND)
 327         if (${PACKAGE}_FOUND)
 328                 set(HAVE_LIB${PACKAGE} 1)
 329                 include_directories(${${PACKAGE}_INCLUDE_DIRS})
 330                 message(STATUS "${PACKAGE} includes: ${${PACKAGE}_INCLUDE_DIRS}")
 331                 message(STATUS "${PACKAGE} libs: ${${PACKAGE}_LIBRARIES}")
 332         endif()
 333 endforeach()
 334
 335 find_package(YAPP)
 336
 337 #packaging
 338 include(CPackConfig.txt)
 339
 340 if(HAVE_LIBPYTHON)
 341         set(HAVE_PYTHON 1)
 342         set(PYTHON_DIR "${CMAKE_INSTALL_PREFIX}/lib/wireshark/python/${CPACK_PACKAGE_VERSION}")
 343 endif()
 344 if(HAVE_LIBLUA)
 345         set(HAVE_LUA_H 1)
 346         set(HAVE_LUA_5_1 1)
 347 endif()
 348 if(HAVE_LIBKERBEROS)
 349         set(HAVE_KERBEROS 1)
 350         # HAVE_HEIMDAL_KERBEROS
 351         set(HAVE_MIT_KERBEROS 1)
 352         set(HAVE_KEYTYPE_ARCFOUR_56 1)
 353 endif()
 354 if(HAVE_LIBGEOIP)
 355         set(HAVE_GEOIP 1)
 356 endif()
 357 if(HAVE_LIBCARES)
 358         set(HAVE_C_ARES 1)
 359 endif()
 360 if(HAVE_LIBADNS)
 361         set(HAVE_GNU_ADNS 1)
 362 endif()
 363 if(ENABLE_AIRPCAP)
 364         set(HAVE_AIRPCAP 1)
 365 endif()
 366
 367 include(ConfigureChecks.cmake)
 368
 369 #Big or little endian ?
 370 include(TestBigEndian)
 371 test_big_endian(WORDS_BIGENDIAN)
 372
 373 set(DATAFILE_DIR "${CMAKE_INSTALL_PREFIX}/share/${CPACK_PACKAGE_NAME}")
 374
 375 if(ENABLE_PLUGINS)
 376         set(HAVE_PLUGINS 1)
 377         set(PLUGIN_DIR="${DATAFILE_DIR}/plugins/${CPACK_PACKAGE_VERSION}")
 378         set(PLUGIN_SRC_DIRS
 379                 plugins/asn1
 380                 plugins/docsis
 381                 plugins/ethercat
 382                 plugins/giop
 383                 plugins/gryphon
 384                 plugins/interlink
 385                 plugins/irda
 386                 plugins/m2m
 387                 plugins/mate
 388                 plugins/opcua
 389                 plugins/profinet
 390                 plugins/sercosiii
 391                 plugins/stats_tree
 392                 plugins/unistim
 393                 plugins/wimax
 394                 plugins/wimaxasncp
 395         )
 396 # It seems this stuff doesn't build with autofoo either...
 397 #       if(YAPP_FOUND)
 398 #               set(PLUGIN_SRC_DIRS
 399 #                       ${PLUGIN_SRC_DIRS}
 400 #                       plugins/tpg
 401 #               )
 402 #       endif()
 403 else()
 404         set(PLUGIN_SRC_DIRS )
 405 endif()
 406
 407 foreach(PLUGIN_DIR ${PLUGIN_SRC_DIRS})
 408         add_subdirectory( ${PLUGIN_DIR} )
 409 endforeach()
 410
 411 add_subdirectory( codecs )
 412 add_subdirectory( epan )
 413 add_subdirectory( gtk )
 414 add_subdirectory( tools/lemon )
 415 add_subdirectory( wiretap )
 416 add_subdirectory( wsutil )
 417
 418 if(ENABLE_GUIDES)
 419 #       FIXME: Disabling the build via option currently doesn't work
 420 #       add_subdirectory( docbook )
 421 endif()
 422
 423 find_package(POD)
 424
 425 #Platform specific
 426 if(UNIX)
 427         set(WS_VAR_IMPORT "extern")
 428 endif()
 429
 430 if(APPLE)
 431 #TODO verify that APPLE implies HAVE_OS_X_FRAMEWORKS
 432         set(HAVE_OS_X_FRAMEWORKS 1)
 433         FIND_LIBRARY (APPLE_CORE_SERVICES_LIBRARY CoreServices)
 434         FIND_LIBRARY (APPLE_COCOA_LIBRARY Cocoa)
 435 endif()
 436
 437 if(WIN32)
 438         add_definitions(-D_NEED_VAR_IMPORT_)
 439         set(WS_VAR_IMPORT "__declspec(dllimport) extern")
 440
 441         # Disable deprecation
 442         if(MSVC80 OR MSVC90)
 443                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 444         endif()
 445 endif()
 446
 447 configure_file(${CMAKE_SOURCE_DIR}/cmakeconfig.h.in ${CMAKE_BINARY_DIR}/config.h)
 448
 449 include(FeatureSummary)
 450 #SET_FEATURE_INFO(NAME DESCRIPTION [URL [COMMENT] ]
 451 PRINT_ENABLED_FEATURES()
 452 PRINT_DISABLED_FEATURES()
 453
 454 link_directories(
 455         gtk
 456         codecs
 457         epan
 458         wiretap
 459         wsutil
 460 )
 461
 462 ADD_CUSTOM_TARGET(
 463         svnversion ALL
 464         COMMAND ${PERL}
 465                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 466                 ${CMAKE_CURRENT_SOURCE_DIR}
 467         DEPENDS
 468                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 469 )
 470
 471 ADD_CUSTOM_COMMAND(
 472         OUTPUT  svnversion.h
 473         COMMAND ${PERL}
 474                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 475                 ${CMAKE_CURRENT_SOURCE_DIR}
 476         DEPENDS
 477                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 478 )
 479
 480 register_tap_files(tshark-tap-register.c
 481         ${TSHARK_TAP_SRC}
 482 )
 483
 484 ADD_CUSTOM_COMMAND(
 485         OUTPUT  ps.c
 486         COMMAND ${PYTHON_EXECUTABLE}
 487                 ${CMAKE_CURRENT_SOURCE_DIR}/tools/rdps.py
 488                 ${CMAKE_CURRENT_SOURCE_DIR}/print.ps
 489                 ps.c
 490         DEPENDS
 491                 ${CMAKE_CURRENT_SOURCE_DIR}/tools/rdps.py
 492                 ${CMAKE_CURRENT_SOURCE_DIR}/print.ps
 493 )
 494
 495 if(UNIX)
 496         set(PLATFORM_SRC
 497                 capture-pcap-util-unix.c
 498         )
 499 endif()
 500
 501 if(WIN32)
 502         set(PLATFORM_SRC
 503                 capture-wpcap.c capture_wpcap_packet.c
 504         )
 505 endif()
 506
 507 set(WTAP_PLUGIN_SOURCES
 508         epan/plugins.c
 509         epan/report_err.c
 510         epan/filesystem.c
 511 )
 512
 513 set(SHARK_COMMON_CAPTURE_SRC
 514         capture_errs.c
 515         capture_ifinfo.c
 516         capture_ui_utils.c
 517 )
 518
 519 set(WIRESHARK_COMMON_SRC
 520         ${PLATFORM_SRC}
 521         capture-pcap-util.c
 522         cfile.c
 523         clopts_common.c
 524         disabled_protos.c
 525         packet-range.c
 526         print.c
 527         ps.c
 528         svnversion.h
 529         sync_pipe_write.c
 530         timestats.c
 531         util.c
 532         tap-megaco-common.c
 533         tap-rtp-common.c
 534         version_info.c
 535 )
 536
 537 set(TSHARK_TAP_SRC
 538         tap-afpstat.c
 539         tap-ansi_astat.c
 540         tap-bootpstat.c
 541         tap-camelcounter.c
 542         tap-camelsrt.c
 543         tap-comparestat.c
 544         tap-dcerpcstat.c
 545         tap-diameter-avp.c
 546         tap-funnel.c
 547         tap-gsm_astat.c
 548         tap-h225counter.c
 549         tap-h225rassrt.c
 550         tap-httpstat.c
 551         tap-iostat.c
 552         tap-iousers.c
 553         tap-mgcpstat.c
 554         tap-megacostat.c
 555         tap-protocolinfo.c
 556         tap-protohierstat.c
 557         tap-radiusstat.c
 558         tap-rpcstat.c
 559         tap-rpcprogs.c
 560         tap-rtp.c
 561         tap-sctpchunkstat.c
 562         tap-sipstat.c
 563         tap-smbsids.c
 564         tap-smbstat.c
 565         tap-stats_tree.c
 566         tap-wspstat.c
 567 )
 568
 569 set(INSTALL_DIRS
 570         diameter
 571         dtds
 572         help
 573         radius
 574         tpncp
 575         wimaxasncp
 576 )
 577
 578 set(INSTALL_FILES
 579         ${CMAKE_BINARY_DIR}/AUTHORS-SHORT
 580         COPYING
 581         ${CMAKE_BINARY_DIR}/capinfos.html
 582         cfilters
 583         colorfilters
 584         dfilters
 585         ${CMAKE_BINARY_DIR}/dumpcap.html
 586         ${CMAKE_BINARY_DIR}/editcap.html
 587         ${CMAKE_BINARY_DIR}/idl2wrs.html
 588         ipmap.html
 589         manuf
 590         ${CMAKE_BINARY_DIR}/mergecap.html
 591         ${CMAKE_BINARY_DIR}/rawshark.html
 592         services
 593         smi_modules
 594         ${CMAKE_BINARY_DIR}/text2pcap.html
 595         ${CMAKE_BINARY_DIR}/tshark.html
 596         ${CMAKE_BINARY_DIR}/wireshark-filter.html
 597         ${CMAKE_BINARY_DIR}/wireshark.html
 598         docbook/ws.css
 599 )
 600
 601 set(LIBEPAN_LIBS
 602 #               @GETOPT_O@      # wsgetopt.c
 603 #               @INET_ATON_LO@  # epan/inet_aton.c
 604 #               @INET_NTOP_LO@  # inet_ntop.c
 605 #               @INET_PTON_LO@  # inet_pton.c
 606 #               @NSL_LIBS@      # -lnsl
 607 #               @SOCKET_LIBS@   # -lsocket
 608 #               @SSL_LIBS@      # -lcrypto
 609 #               @STRERROR_O@    # strerror.c
 610 #               @STRNCASECMP_O@ # strncasecmp.c
 611 #               @STRPTIME_O@    # strptime.c
 612                 epan
 613 #               $(plugin_ldadd) # in case of static
 614                 ${PCRE_LIBRARIES}
 615                 ${PCAP_LIBRARIES}
 616                 ${CARES_LIBRARIES}
 617                 ${ADNS_LIBRARIES}
 618                 ${KERBEROS_LIBRARIES}
 619                 ${LUA_LIBRARIES}
 620                 ${PYTHON_LIBRARIES}
 621                 ${GEOIP_LIBRARIES}
 622                 ${GCRYPT_LIBRARIES}
 623                 ${GNUTLS_LIBRARIES}
 624                 ${SMI_LIBRARIES}
 625                 ${Z_LIBRARIES}
 626                 ${M_LIBRARIES}
 627 )
 628
 629 if(BUILD_wireshark)
 630         set(wireshark_LIBS
 631                 ui
 632                 ${GTK2_LIBRARIES}
 633                 codecs
 634                 ${PORTAUDIO_LIBRARIES}
 635                 ${LIBEPAN_LIBS}
 636                 ${APPLE_CORE_SERVICES_LIBRARY}
 637                 ${APPLE_COCOA_LIBRARY}
 638         )
 639         set(wireshark_FILES
 640                 airpcap_loader.c
 641                 alert_box.c
 642                 capture.c
 643                 capture_info.c
 644                 capture_opts.c
 645                 capture_sync.c
 646                 color_filters.c
 647                 file.c
 648                 fileset.c
 649                 filters.c
 650                 g711.c
 651                 merge.c
 652                 proto_hier_stats.c
 653                 summary.c
 654                 tempfile.c
 655                 ${SHARK_COMMON_CAPTURE_SRC}
 656                 ${WIRESHARK_COMMON_SRC}
 657         )
 658         add_executable(wireshark ${wireshark_FILES})
 659         add_dependencies(wireshark svnversion)
 660         set_target_properties(wireshark PROPERTIES LINK_FLAGS ${WS_LINK_FLAGS})
 661         target_link_libraries(wireshark ${wireshark_LIBS})
 662         install(TARGETS wireshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 663 endif()
 664
 665 if(BUILD_tshark)
 666         set(tshark_LIBS
 667                 ${LIBEPAN_LIBS}
 668                 ${APPLE_COCOA_LIBRARY}
 669         )
 670         set(tshark_FILES
 671                 capture_opts.c
 672                 capture_sync.c
 673                 tempfile.c
 674                 tshark-tap-register.c
 675                 tshark.c
 676                 ${TSHARK_TAP_SRC}
 677                 ${SHARK_COMMON_CAPTURE_SRC}
 678                 ${WIRESHARK_COMMON_SRC}
 679         )
 680         add_executable(tshark ${tshark_FILES})
 681         add_dependencies(tshark svnversion)
 682         set_target_properties(tshark PROPERTIES LINK_FLAGS ${WS_LINK_FLAGS})
 683         target_link_libraries(tshark ${tshark_LIBS})
 684         install(TARGETS tshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 685 endif()
 686
 687 if(BUILD_rawshark)
 688         set(rawshark_LIBS
 689                 ${LIBEPAN_LIBS}
 690                 ${APPLE_COCOA_LIBRARY}
 691         )
 692         set(rawshark_FILES
 693                 ${WIRESHARK_COMMON_SRC}
 694                 rawshark.c
 695         )
 696         add_executable(rawshark ${rawshark_FILES})
 697         add_dependencies(rawshark svnversion)
 698         set_target_properties(rawshark PROPERTIES LINK_FLAGS ${WS_LINK_FLAGS})
 699         target_link_libraries(rawshark ${rawshark_LIBS})
 700         install(TARGETS rawshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 701 endif()
 702
 703 if(BUILD_dftest)
 704         set(dftest_LIBS
 705                 ${LIBEPAN_LIBS}
 706         )
 707         set(dftest_FILES
 708                 dftest.c
 709                 util.c
 710         )
 711         add_executable(dftest ${dftest_FILES})
 712         set_target_properties(dftest PROPERTIES LINK_FLAGS ${WS_LINK_FLAGS})
 713         target_link_libraries(dftest ${dftest_LIBS})
 714         install(TARGETS dftest RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 715 endif()
 716
 717 if(BUILD_randpkt)
 718         set(randpkt_LIBS
 719                 wiretap
 720                 ${M_LIBRARIES}
 721                 ${PCAP_LIBRARIES}
 722 #               @SOCKET_LIBS@
 723 #               @NSL_LIBS@
 724                 ${CARES_LIBRARIES}
 725                 ${ADNS_LIBRARIES}
 726                 ${Z_LIBRARIES}
 727         )
 728         set(randpkt_FILES
 729                 randpkt.c
 730         )
 731         add_executable(randpkt ${randpkt_FILES})
 732         set_target_properties(randpkt PROPERTIES LINK_FLAGS ${WS_LINK_FLAGS})
 733         target_link_libraries(randpkt ${randpkt_LIBS})
 734         install(TARGETS randpkt RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 735 endif()
 736
 737 if(BUILD_text2pcap)
 738         set(text2pcap_LIBS
 739                 wiretap
 740                 ${M_LIBRARIES}
 741                 ${Z_LIBRARIES}
 742         )
 743         set(text2pcap_FILES
 744                 text2pcap.c
 745         )
 746         add_lex_files(text2pcap_FILES
 747                 text2pcap-scanner.l
 748         )
 749         add_executable(text2pcap ${text2pcap_FILES})
 750         add_dependencies(text2pcap svnversion)
 751         set_target_properties(text2pcap PROPERTIES LINK_FLAGS ${WS_LINK_FLAGS})
 752         target_link_libraries(text2pcap ${text2pcap_LIBS})
 753         install(TARGETS text2pcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 754 endif()
 755
 756 if(BUILD_mergecap)
 757         set(mergecap_LIBS
 758                 wiretap
 759                 ${Z_LIBRARIES}
 760         )
 761         set(mergecap_FILES
 762                 mergecap.c
 763                 merge.c
 764                 svnversion.h
 765         )
 766         add_executable(mergecap ${mergecap_FILES})
 767         add_dependencies(mergecap svnversion)
 768         set_target_properties(mergecap PROPERTIES LINK_FLAGS ${WS_LINK_FLAGS})
 769         target_link_libraries(mergecap ${mergecap_LIBS})
 770         install(TARGETS mergecap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 771 endif()
 772
 773 if(BUILD_capinfos)
 774         set(capinfos_LIBS
 775                 wiretap
 776                 ${Z_LIBRARIES}
 777                 ${GCRYPT_LIBRARIES}
 778                 ${APPLE_COCOA_LIBRARY}
 779         )
 780         set(capinfos_FILES
 781                 capinfos.c
 782                 ${WTAP_PLUGIN_SOURCES}
 783         )
 784         add_executable(capinfos ${capinfos_FILES})
 785         set_target_properties(capinfos PROPERTIES LINK_FLAGS ${WS_LINK_FLAGS})
 786         target_link_libraries(capinfos ${capinfos_LIBS})
 787         install(TARGETS capinfos RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 788 endif()
 789
 790 if(BUILD_editcap)
 791         set(editcap_LIBS
 792                 wiretap
 793                 ${Z_LIBRARIES}
 794         )
 795         set(editcap_FILES
 796                 editcap.c
 797                 epan/crypt/crypt-md5.c
 798                 epan/nstime.c
 799                 ${WTAP_PLUGIN_SOURCES}
 800         )
 801         add_executable(editcap ${editcap_FILES})
 802         add_dependencies(editcap svnversion)
 803         set_target_properties(editcap PROPERTIES LINK_FLAGS ${WS_LINK_FLAGS})
 804         target_link_libraries(editcap ${editcap_LIBS})
 805         install(TARGETS editcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 806 endif()
 807
 808 if(BUILD_dumpcap)
 809         set(dumpcap_LIBS
 810                 wiretap
 811 #               @INET_NTOP_LO@
 812                 ${PCAP_LIBRARIES}
 813                 ${CAP_LIBRARIES}
 814 #               @SOCKET_LIBS@
 815 #               @NSL_LIBS@
 816                 ${GCRYPT_LIBRARIES}
 817                 ${GNUTLS_LIBRARIES}
 818                 ${Z_LIBRARIES}
 819                 ${APPLE_COCOA_LIBRARY}
 820         )
 821         set(dumpcap_FILES
 822                 svnversion.h
 823                 capture_opts.c
 824                 capture-pcap-util.c
 825                 capture_stop_conditions.c
 826                 clopts_common.c
 827                 conditions.c
 828                 dumpcap.c
 829                 pcapio.c
 830                 ringbuffer.c
 831                 sync_pipe_write.c
 832                 tempfile.c
 833                 version_info.c
 834                 ${PLATFORM_SRC}
 835         )
 836         add_executable(dumpcap ${dumpcap_FILES})
 837         add_dependencies(dumpcap svnversion)
 838         set_target_properties(dumpcap PROPERTIES LINK_FLAGS ${WS_LINK_FLAGS})
 839         target_link_libraries(dumpcap ${dumpcap_LIBS})
 840         install(TARGETS dumpcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 841 endif()
 842
 843 ADD_CUSTOM_COMMAND(
 844         OUTPUT  AUTHORS-SHORT
 845         COMMAND ${PERL}
 846                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
 847                 ${CMAKE_SOURCE_DIR}/doc/make-authors-short.pl
 848                 < ${CMAKE_SOURCE_DIR}/AUTHORS
 849                 > AUTHORS-SHORT
 850         DEPENDS
 851                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
 852                 ${CMAKE_SOURCE_DIR}/doc/make-authors-short.pl
 853                 ${CMAKE_SOURCE_DIR}/AUTHORS
 854 )
 855
 856 ADD_CUSTOM_COMMAND(
 857         OUTPUT  AUTHORS-SHORT-FORMAT
 858                 wireshark.pod
 859         COMMAND ${PERL}
 860                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
 861                 ${CMAKE_SOURCE_DIR}/doc/make-authors-format.pl
 862                 < AUTHORS-SHORT
 863                 > AUTHORS-SHORT-FORMAT
 864         COMMAND cat
 865                 ${CMAKE_SOURCE_DIR}/doc/wireshark.pod.template
 866                 AUTHORS-SHORT-FORMAT
 867                 > wireshark.pod
 868         DEPENDS
 869                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
 870                 ${CMAKE_SOURCE_DIR}/doc/make-authors-format.pl
 871                 AUTHORS-SHORT
 872                 ${CMAKE_SOURCE_DIR}/doc/wireshark.pod.template
 873 )
 874
 875 ADD_CUSTOM_COMMAND(
 876         OUTPUT  wireshark-filter.pod
 877         COMMAND tshark
 878                 -G fields |
 879                 ${PERL}
 880                 ${CMAKE_SOURCE_DIR}/doc/dfilter2pod.pl
 881                 ${CMAKE_SOURCE_DIR}/doc/wireshark-filter.pod.template
 882                 > wireshark-filter.pod
 883         DEPENDS
 884                 ${CMAKE_SOURCE_DIR}/doc/dfilter2pod.pl
 885                 ${CMAKE_SOURCE_DIR}/doc/wireshark-filter.pod.template
 886                 tshark
 887 )
 888
 889 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/capinfos 1 )
 890 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/dumpcap 1 )
 891 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/editcap 1 )
 892 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/idl2wrs 1 )
 893 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/mergecap 1 )
 894 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/rawshark 1 )
 895 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/text2pcap 1 )
 896 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/tshark 1 )
 897 pod2manhtml( wireshark 1 )
 898 pod2manhtml( wireshark-filter 4 )
 899
 900 add_custom_target(
 901         auxiliary ALL
 902         DEPENDS
 903                 AUTHORS-SHORT
 904                 capinfos.html
 905                 dumpcap.html
 906                 editcap.html
 907                 idl2wrs.html
 908                 mergecap.html
 909                 rawshark.html
 910                 text2pcap.html
 911                 tshark.html
 912                 wireshark.html
 913                 wireshark-filter.html
 914 )
 915
 916 set(MAN1_FILES
 917         ${CMAKE_BINARY_DIR}/capinfos.1
 918         ${CMAKE_BINARY_DIR}/dumpcap.1
 919         ${CMAKE_BINARY_DIR}/editcap.1
 920         ${CMAKE_BINARY_DIR}/idl2wrs.1
 921         ${CMAKE_BINARY_DIR}/mergecap.1
 922         ${CMAKE_BINARY_DIR}/rawshark.1
 923         ${CMAKE_BINARY_DIR}/text2pcap.1
 924         ${CMAKE_BINARY_DIR}/tshark.1
 925         ${CMAKE_BINARY_DIR}/wireshark.1
 926 )
 927
 928 set(MAN4_FILES
 929         ${CMAKE_BINARY_DIR}/wireshark-filter.4
 930 )
 931
 932 set(CLEAN_FILES
 933         ${wireshark_FILES}
 934         ${tshark_FILES}
 935         ${rawshark_FILES}
 936         ${dftest_FILES}
 937         ${randpkt_FILES}
 938         ${text2pcap_FILES}
 939         ${mergecap_FILES}
 940         ${capinfos_FILES}
 941         ${editcap_FILES}
 942         ${dumpcap_FILES}
 943 )
 944
 945 if (WERROR)
 946         set_source_files_properties(
 947                 ${CLEAN_FILES}
 948                 PROPERTIES
 949                 COMPILE_FLAGS -Werror
 950         )
 951 endif()
 952
 953 install(
 954         FILES
 955                 ${INSTALL_FILES}
 956         DESTINATION
 957                 ${CMAKE_INSTALL_DATADIR}/${CPACK_PACKAGE_NAME}
 958 )
 959
 960 install(
 961         FILES
 962                 ${MAN1_FILES}
 963         DESTINATION
 964                 ${CMAKE_INSTALL_MANDIR}/man1
 965 )
 966
 967 install(
 968         FILES
 969                 ${MAN4_FILES}
 970         DESTINATION
 971                 ${CMAKE_INSTALL_MANDIR}/man4
 972 )
 973
 974 install(
 975         DIRECTORY
 976                 ${INSTALL_DIRS}
 977         DIRECTORY_PERMISSIONS
 978                 OWNER_EXECUTE OWNER_WRITE OWNER_READ
 979                 GROUP_EXECUTE GROUP_READ
 980                 WORLD_EXECUTE WORLD_READ
 981         DESTINATION
 982                 ${CMAKE_INSTALL_DATADIR}/${CPACK_PACKAGE_NAME}
 983         PATTERN ".svn" EXCLUDE
 984         PATTERN "Makefile.*" EXCLUDE
 985         PATTERN "faq.py" EXCLUDE
 986 )