CMakeLists.txt

   1 # CMakeLists.txt
   2 #
   3 # $Id$
   4 #
   5 # Wireshark - Network traffic analyzer
   6 # By Gerald Combs <gerald@wireshark.org>
   7 # Copyright 1998 Gerald Combs
   8 #
   9 # This program is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU General Public License
  11 # as published by the Free Software Foundation; either version 2
  12 # of the License, or (at your option) any later version.
  13 #
  14 # This program is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program; if not, write to the Free Software
  21 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
  22 #
  23
  24 project(wireshark C)
  25
  26 cmake_minimum_required(VERSION 2.6)
  27
  28 #Where to find local cmake scripts
  29 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  30 INCLUDE(UseLemon)
  31
  32 # Under linux the release mode (CMAKE_BUILD_TYPE=release) defines NDEBUG
  33
  34 # Disable this later. Alternative: "make VERBOSE=1"
  35 set(CMAKE_VERBOSE_MAKEFILE ON)
  36
  37 set(BUILD_SHARED_LIBS ON)
  38
  39 #Defines CMAKE_INSTALL_BINDIR, CMAKE_INSTALL_DATADIR, etc ...
  40 include(CMakeInstallDirs)
  41
  42 include_directories(
  43         ${CMAKE_BINARY_DIR}
  44
  45         ${CMAKE_SOURCE_DIR}
  46         ${CMAKE_SOURCE_DIR}/epan
  47         ${CMAKE_SOURCE_DIR}/tools/lemon
  48         ${CMAKE_SOURCE_DIR}/wiretap
  49 )
  50
  51 #Where to put libraries
  52 if(NOT LIBRARY_OUTPUT_PATH)
  53         set(LIBRARY_OUTPUT_PATH ${wireshark_BINARY_DIR}/lib CACHE INTERNAL
  54                    "Single output directory for building all libraries.")
  55 endif()
  56
  57 option(BUILD_wireshark   "Build the GUI version of Wireshark" ON)
  58 option(BUILD_tshark      "Build tshark" ON)
  59 option(BUILD_rawshark    "Build rawshark" ON)
  60 option(BUILD_dumpcap     "Build dumpcap" ON)
  61 option(BUILD_text2pcap   "Build text2pcap" ON)
  62 option(BUILD_mergecap    "Build mergecap" ON)
  63 option(BUILD_editcap     "Build editcap" ON)
  64 option(BUILD_capinfos    "Build capinfos" ON)
  65 option(BUILD_randpkt     "Build randpkt" ON)
  66 option(BUILD_dftest      "Build dftest" ON)
  67
  68 option(DISABLE_WERROR    "Do not treat Warnings as errors" OFF)
  69 option(ENABLE_EXTRA_GCC_CHECKS "Do additional -W checks in GCC (disables -Werror)" ON)
  70 option(ENABLE_AIRPCAP    "Enable Airpcap support" ON)
  71 # todo
  72 option(ENABLE_STATIC     "Build a static version of Wireshark" OFF)
  73 option(ENABLE_PLUGINS    "Build with plugins" ON)
  74
  75 option(ENABLE_ADNS       "Build with adns support" ON)
  76 option(ENABLE_PCRE       "Build with pcre support" ON)
  77 option(ENABLE_PORTAUDIO  "Build with portaudio support" ON)
  78 option(ENABLE_Z          "Build with zlib compression support" ON)
  79 # todo wslua currently seems to be broken
  80 option(ENABLE_LUA        "Build with lua dissector support" OFF)
  81 option(ENABLE_PYTHON     "Build with python dissector support" ON)
  82 option(ENABLE_SMI        "Build with smi snmp support" ON)
  83 option(ENABLE_GNUTLS     "Build with GNU TLS support" ON)
  84 option(ENABLE_GCRYPT     "Build with GNU crypto support" ON)
  85 option(ENABLE_GEOIP      "Build with GeoIP support" ON)
  86 option(ENABLE_CAP        "Build with posix capabilities support" ON)
  87 option(ENABLE_CARES      "Build with c_ares support" ON)
  88 # todo Mostly hardcoded
  89 option(ENABLE_KERBEROS   "Build with Kerberos support" ON)
  90
  91
  92 set(WIRESHARK_C_FLAGS
  93         # todo Workaround for problem described below
  94         -doesntexist
  95         -O2
  96         -Werror
  97         -Wall
  98         -W
  99         -Wextra
 100         -Wdeclaration-after-statement
 101         -Wendif-labels
 102         -Wpointer-arith
 103         -Wno-pointer-sign
 104         -Warray-bounds
 105         -Wcast-align
 106         -Wformat-security
 107 )
 108
 109 set(WIRESHARK_EXTRA_C_FLAGS
 110         -pedantic
 111         -Woverflow
 112         -Wlogical-op
 113         -Wno-overlength-strings
 114         -fstrict-overflow -Wstrict-overflow=4
 115         -Wunreachable-code
 116         -Wunsafe-loop-optimizations
 117         -Wno-long-long
 118         -Wbad-function-cast
 119         -Wcast-qual
 120         -Waddress
 121         -Warray-bounds
 122         -Wattributes
 123         -Wdiv-by-zero
 124         -Wformat-security
 125         -Wignored-qualifiers
 126         -Wpragmas
 127         -Wredundant-decls
 128         -Wvla
 129         # packet-ncp2222.inc prevents this from going into all warnings
 130         -Wwrite-strings
 131         -Wstrict-prototypes
 132         -Wmissing-declarations
 133         # Problem with packet-afs.c
 134         -Wshadow
 135         # More cleanup needed for this on LP64
 136         -Wshorten-64-to-32
 137 )
 138
 139 if(ENABLE_EXTRA_GCC_CHECKS)
 140         set(WIRESHARK_C_FLAGS ${WIRESHARK_C_FLAGS} ${WIRESHARK_EXTRA_C_FLAGS})
 141 endif()
 142
 143 add_definitions(
 144         -DHAVE_CONFIG_H
 145         -DPACKAGE=\"wireshark\"
 146         -DNEW_PACKET_LIST
 147 )
 148
 149 # todo
 150 # This doesn't actually work because of some cache magic in
 151 # CHECK_C_SOURCE_COMPILES
 152 include(CheckCCompilerFlag)
 153 foreach(WS_C_FLAG ${WIRESHARK_C_FLAGS})
 154         message(STATUS "Flag pre: ${WS_C_FLAG}")
 155         check_c_compiler_flag(${WS_C_FLAG} WS_C_FLAG_VALID)
 156         if (${WS_C_FLAG_VALID})
 157                 add_definitions(${WS_C_FLAG})
 158         endif()
 159         message(STATUS "Flag post ${WS_C_FLAG}: ${WS_C_FLAG_VALID}")
 160         #set(WS_C_FLAG_VALID "" CACHE INTERNAL "Dummy" )
 161 endforeach()
 162
 163 if(DISABLE_WERROR OR ENABLE_EXTRA_GCC_CHECKS)
 164         remove_definitions( -Werror )
 165 endif()
 166
 167 if(CMAKE_COMPILER_IS_GNUCC)
 168         add_definitions( -D_U_=__attribute__\(\(unused\)\) )
 169 else()
 170         add_definitions( -D_U_=\"\" )
 171 endif()
 172
 173 # todo
 174 # Same for linker flags, but it looks like it's do-it-yourself here
 175 # AC_WIRESHARK_GCC_LDFLAGS_CHECK([-Wl,--as-needed])
 176
 177 #The minimum package list
 178 set(PACKAGELIST GLIB2 PCAP M LEX YACC Perl SH PythonInterp HtmlViewer ${PACKAGELIST})
 179
 180 #Build the gui ?
 181 if(BUILD_wireshark)
 182         set(PACKAGELIST GTK2 ${PACKAGELIST})
 183 endif()
 184
 185 # SMI SNMP
 186 if(ENABLE_SMI)
 187         set(PACKAGELIST SMI ${PACKAGELIST})
 188 endif()
 189
 190 # GNU crypto
 191 if(ENABLE_GCRYPT)
 192         set(PACKAGELIST GCRYPT ${PACKAGELIST})
 193 endif()
 194
 195 # GNU SSL/TLS support
 196 if(ENABLE_GNUTLS)
 197         set(PACKAGELIST GNUTLS ${PACKAGELIST})
 198 endif()
 199
 200 # Regular expressions lib
 201 if(ENABLE_PCRE)
 202         set(PACKAGELIST PCRE ${PACKAGELIST})
 203 endif()
 204
 205 # Kerberos
 206 if(ENABLE_KERBEROS)
 207         set(PACKAGELIST KERBEROS ${PACKAGELIST})
 208 endif()
 209
 210 # Portable audio
 211 if(ENABLE_PORTAUDIO)
 212         set(PACKAGELIST PORTAUDIO ${PACKAGELIST})
 213 endif()
 214
 215
 216 # Prefer c-ares over adns
 217 if(ENABLE_CARES)        # C Asynchronouse resolver
 218         set(PACKAGELIST CARES ${PACKAGELIST})
 219 elseif(ENABLE_ADNS)     # Gnu asynchronous DNS
 220         set(PACKAGELIST ADNS ${PACKAGELIST})
 221 endif()
 222
 223 # Zlib compression
 224 if(ENABLE_Z)
 225         set(PACKAGELIST Z ${PACKAGELIST})
 226 endif()
 227
 228 # Lua 5.1 dissectors
 229 if(ENABLE_LUA)
 230         set(PACKAGELIST LUA ${PACKAGELIST})
 231 endif()
 232
 233 # GeoIP address resolving
 234 if(ENABLE_GEOIP)
 235         set(PACKAGELIST GEOIP ${PACKAGELIST})
 236 endif()
 237
 238 # Capabilities
 239 if(ENABLE_CAP)
 240         set(PACKAGELIST CAP ${PACKAGELIST})
 241 endif()
 242
 243 if(ENABLE_PYTHON)
 244         set(PACKAGELIST PYTHON ${PACKAGELIST})
 245 endif()
 246
 247 set(PROGLIST text2pcap mergecap capinfos editcap dumpcap)
 248
 249 #Let's loop the package list
 250 foreach(PACKAGE ${PACKAGELIST})
 251         find_package(${PACKAGE} REQUIRED)
 252         message(${PACKAGE}_FOUND)
 253         if (${PACKAGE}_FOUND)
 254                 set(HAVE_LIB${PACKAGE} 1)
 255                 include_directories(${${PACKAGE}_INCLUDE_DIRS})
 256                 message(STATUS "${PACKAGE} includes: ${${PACKAGE}_INCLUDE_DIRS}")
 257                 message(STATUS "${PACKAGE} libs: ${${PACKAGE}_LIBRARIES}")
 258         endif()
 259 endforeach()
 260
 261 if(HAVE_LIBPYTHON)
 262         set(HAVE_PYTHON 1)
 263         set(PYTHON_DIR "${CMAKE_INSTALL_PREFIX}/lib/wireshark/python/${VERSION}")
 264 endif()
 265 if(HAVE_LIBLUA)
 266         set(HAVE_LUA_H 1)
 267         set(HAVE_LUA_5_1 1)
 268 endif()
 269 if(HAVE_LIBKERBEROS)
 270         set(HAVE_KERBEROS 1)
 271         # HAVE_HEIMDAL_KERBEROS
 272         set(HAVE_MIT_KERBEROS 1)
 273         set(HAVE_KEYTYPE_ARCFOUR_56 1)
 274 endif()
 275 if(HAVE_LIBGEOIP)
 276         set(HAVE_GEOIP 1)
 277 endif()
 278 if(HAVE_LIBCARES)
 279         set(HAVE_C_ARES 1)
 280 endif()
 281 if(HAVE_LIBADNS)
 282         set(HAVE_GNU_ADNS 1)
 283 endif()
 284 if(ENABLE_AIRPCAP)
 285         set(HAVE_AIRPCAP 1)
 286 endif()
 287
 288 #packaging
 289 set(CPACK_PACKAGE_NAME wireshark)
 290 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "capture packet")
 291 set(CPACK_PACKAGE_VENDOR "wireshark")
 292 set(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README")
 293 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/COPYING")
 294 set(CPACK_PACKAGE_VERSION_MAJOR "1")
 295 set(CPACK_PACKAGE_VERSION_MINOR "3")
 296 set(CPACK_PACKAGE_VERSION_PATCH "0")
 297 set(CPACK_PACKAGE_VERSION "${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 298
 299 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
 300 set(CPACK_PACKAGE_INSTALL_DIRECTORY "/usr")
 301 set(CPACK_GENERATOR "TGZ")
 302 set(CPACK_SOURCE_GENERATOR "TGZ")
 303
 304 include(ConfigureChecks.cmake)
 305
 306 #Big or little endian ?
 307 include(TestBigEndian)
 308 test_big_endian(WORDS_BIGENDIAN)
 309
 310 set(DATAFILE_DIR "${CMAKE_INSTALL_PREFIX}/share/${CPACK_PACKAGE_NAME}")
 311
 312 if(ENABLE_PLUGINS)
 313         set(HAVE_PLUGINS 1)
 314         set(PLUGIN_DIR="${DATAFILE_DIR}/plugins/${CPACK_PACKAGE_VERSION}")
 315         set(PLUGIN_SRC_DIRS
 316                 plugins/asn1
 317                 plugins/docsis
 318                 plugins/ethercat
 319 #               plugins/giop
 320                 plugins/gryphon
 321                 plugins/irda
 322                 plugins/m2m
 323                 plugins/mate
 324                 plugins/opcua
 325 #               plugins/profinet
 326 #               plugins/sercosiii
 327 #               plugins/stats_tree
 328 #               plugins/unistim
 329 #               plugins/wimax
 330 #               plugins/wimaxasncp
 331         )
 332 else()
 333         set(PLUGIN_SRC_DIRS )
 334 endif()
 335
 336 foreach(PLUGIN_DIR ${PLUGIN_SRC_DIRS})
 337         add_subdirectory( ${PLUGIN_DIR} )
 338 endforeach()
 339
 340 #Platform specific
 341 if(UNIX)
 342         set(WS_VAR_IMPORT "extern")
 343 endif()
 344
 345 if(APPLE)
 346 #TODO verify that APPLE implies HAVE_OS_X_FRAMEWORKS
 347         set(HAVE_OS_X_FRAMEWORKS 1)
 348 endif()
 349
 350 if(WIN32)
 351         add_definitions(-D_NEED_VAR_IMPORT_)
 352         set(WS_VAR_IMPORT "__declspec(dllimport) extern")
 353
 354         # Disable deprecation
 355         if(MSVC80 OR MSVC90)
 356                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 357         endif()
 358 endif()
 359
 360
 361 add_subdirectory( codecs )
 362 add_subdirectory( epan )
 363 add_subdirectory( gtk )
 364 add_subdirectory( wiretap )
 365 add_subdirectory( wsutil )
 366
 367 if (ENABLE_PLUGINS)
 368         add_subdirectory( plugins )
 369 endif()
 370
 371 configure_file(${CMAKE_SOURCE_DIR}/cmakeconfig.h.in ${CMAKE_BINARY_DIR}/config.h)
 372
 373 link_directories(
 374         gtk
 375         codecs
 376         epan
 377         wiretap
 378         wsutil
 379 )
 380
 381 ADD_CUSTOM_COMMAND(
 382         OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/svnversion.h
 383         COMMAND ${PERL} ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 384           ${CMAKE_CURRENT_SOURCE_DIR}
 385 )
 386 SET_SOURCE_FILES_PROPERTIES(${CMAKE_CURRENT_BINARY_DIR}/svnversion.h GENERATED)
 387
 388 # Create the necessary tools
 389 set(lemon_FILES
 390         tools/lemon/lemon.c
 391 )
 392 set(lemon_LIBS
 393         # Do we need something here on any platform?
 394 )
 395 add_executable(lemon ${lemon_FILES})
 396 target_link_libraries(lemon ${lemon_LIBS})
 397 # but don't install
 398
 399 ADD_CUSTOM_COMMAND(
 400         OUTPUT tshark-tap-register.c
 401         COMMAND ${SHELL}
 402           ${CMAKE_SOURCE_DIR}/make-tapreg-dotc
 403           tshark-tap-register.c
 404           ${CMAKE_CURRENT_SOURCE_DIR}
 405           ${TSHARK_TAP_SRC}
 406         DEPENDS
 407           ${CMAKE_SOURCE_DIR}/make-tapreg-dotc
 408           ${TSHARK_TAP_SRC}
 409 )
 410
 411 ADD_CUSTOM_COMMAND(
 412         OUTPUT ps.c
 413         COMMAND ${PYTHON_EXECUTABLE}
 414           ${CMAKE_CURRENT_SOURCE_DIR}/rdps.py
 415           ${CMAKE_CURRENT_SOURCE_DIR}/print.ps
 416           ps.c
 417         DEPENDS
 418           ${CMAKE_CURRENT_SOURCE_DIR}/rdps.py
 419           ${CMAKE_CURRENT_SOURCE_DIR}/print.ps
 420 )
 421
 422 if(UNIX)
 423         set(PLATFORM_SRC
 424                 capture-pcap-util-unix.c
 425         )
 426 endif()
 427
 428 if(WIN32)
 429         set(PLATFORM_SRC
 430                 capture-wpcap.c capture_wpcap_packet.c
 431         )
 432 endif()
 433
 434 set(WTAP_PLUGIN_SOURCES
 435         epan/plugins.c
 436         epan/report_err.c
 437         epan/filesystem.c
 438 )
 439
 440 set(WIRESHARK_COMMON_SRC
 441         ${PLATFORM_SRC}
 442         capture_errs.c
 443         capture-pcap-util.c
 444         capture_ui_utils.c
 445         cfile.c
 446         clopts_common.c
 447         disabled_protos.c
 448         packet-range.c
 449         print.c
 450         ps.c
 451         sync_pipe_write.c
 452         timestats.c
 453         util.c
 454         tap-megaco-common.c
 455         tap-rtp-common.c
 456         version_info.c
 457 )
 458
 459 set(TSHARK_TAP_SRC
 460         tap-afpstat.c
 461         tap-ansi_astat.c
 462         tap-bootpstat.c
 463         tap-camelcounter.c
 464         tap-camelsrt.c
 465         tap-comparestat.c
 466         tap-dcerpcstat.c
 467         tap-funnel.c
 468         tap-gsm_astat.c
 469         tap-h225counter.c
 470         tap-h225rassrt.c
 471         tap-httpstat.c
 472         tap-iostat.c
 473         tap-iousers.c
 474         tap-mgcpstat.c
 475         tap-megacostat.c
 476         tap-protocolinfo.c
 477         tap-protohierstat.c
 478         tap-radiusstat.c
 479         tap-rpcstat.c
 480         tap-rpcprogs.c
 481         tap-rtp.c
 482         tap-sctpchunkstat.c
 483         tap-sipstat.c
 484         tap-smbsids.c
 485         tap-smbstat.c
 486         tap-stats_tree.c
 487         tap-wspstat.c
 488 )
 489
 490 set(INSTALL_DIRS
 491         diameter
 492         dtds
 493         help
 494         radius
 495         tpncp
 496         wimaxasncp
 497 )
 498
 499 set(INSTALL_FILES
 500 #       AUTHORS-SHORT
 501         COPYING
 502 #       capinfos.html
 503 #       cfilters
 504 #       colorfilters
 505 #       console.lua
 506 #       dfilters
 507 #       dtd_gen.lua
 508 #       dumpcap.html
 509 #       editcap.html
 510 #       idl2wrs.html
 511 #       init.lua
 512 #       ipmap.html
 513 #       manuf
 514 #       mergecap.html
 515 #       rawshark.html
 516 #       services
 517 #       smi_modules
 518 #       text2pcap.html
 519 #       tshark.html
 520 #       wireshark-filter.html
 521 #       wireshark.html
 522 #       ws.css
 523 )
 524
 525 set(LIBEPAN_LIBS
 526 #               $(wireshark_optional_objects)
 527                 wiretap
 528                 wsutil
 529                 epan
 530 #               @INET_PTON_LO@
 531 #               @INET_NTOP_LO@
 532 #               @SSL_LIBS@
 533 #               $(plugin_ldadd)
 534                 ${PCRE_LIBRARIES}
 535                 ${GLIB2_LIBRARIES}
 536                 ${PCAP_LIBRARIES}
 537 #               @SOCKET_LIBS@
 538 #               @NSL_LIBS@
 539                 ${CARES_LIBRARIES}
 540                 ${ADNS_LIBRARIES}
 541                 ${KERBEROS_LIBRARIES}
 542 #               @FRAMEWORKS@
 543                 ${LUA_LIBRARIES}
 544                 ${PYTHON_LIBRARIES}
 545                 ${GEOIP_LIBRARIES}
 546                 ${GCRYPT_LIBRARIES}
 547                 ${GNUTLS_LIBRARIES}
 548                 ${SMI_LIBRARIES}
 549                 ${Z_LIBRARIES}
 550                 ${M_LIBRARIES}
 551 )
 552
 553 if(BUILD_wireshark)
 554         set(wireshark_LIBS
 555                 ui
 556                 ${GTK2_LIBRARIES}
 557                 codecs
 558                 ${PORTAUDIO_LIBRARIES}
 559                 ${LIBEPAN_LIBS}
 560         )
 561         set(wireshark_FILES
 562                 airpcap_loader.c
 563                 alert_box.c
 564                 capture.c
 565                 capture_info.c
 566                 capture_opts.c
 567                 capture_sync.c
 568                 color_filters.c
 569                 file.c
 570                 fileset.c
 571                 filters.c
 572                 g711.c
 573                 merge.c
 574                 proto_hier_stats.c
 575                 summary.c
 576                 tempfile.c
 577                 ${WIRESHARK_COMMON_SRC}
 578         )
 579         add_executable(wireshark ${wireshark_FILES})
 580         target_link_libraries(wireshark ${wireshark_LIBS})
 581         install(TARGETS wireshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 582 endif()
 583
 584 if(BUILD_tshark)
 585         set(tshark_LIBS
 586                 ${LIBEPAN_LIBS}
 587         )
 588         set(tshark_FILES
 589                 capture_opts.c
 590                 capture_sync.c
 591                 tempfile.c
 592                 tshark-tap-register.c
 593                 tshark.c
 594                 ${TSHARK_TAP_SRC}
 595                 ${WIRESHARK_COMMON_SRC}
 596         )
 597         add_executable(tshark ${tshark_FILES})
 598         target_link_libraries(tshark ${tshark_LIBS})
 599         install(TARGETS tshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 600 endif()
 601
 602 if(BUILD_rawshark)
 603         set(rawshark_LIBS
 604                 ${LIBEPAN_LIBS}
 605         )
 606         set(rawshark_FILES
 607                 ${WIRESHARK_COMMON_SRC}
 608                 rawshark.c
 609         )
 610         add_executable(rawshark ${rawshark_FILES})
 611         target_link_libraries(rawshark ${rawshark_LIBS})
 612         install(TARGETS rawshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 613 endif()
 614
 615 if(BUILD_dftest)
 616         set(dftest_LIBS
 617                 ${LIBEPAN_LIBS}
 618         )
 619         set(dftest_FILES
 620                 dftest.c
 621                 util.c
 622         )
 623         add_executable(dftest ${dftest_FILES})
 624         target_link_libraries(dftest ${dftest_LIBS})
 625         install(TARGETS dftest RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 626 endif()
 627
 628 if(BUILD_randpkt)
 629         set(randpkt_LIBS
 630                 wiretap
 631                 wsutil
 632                 ${GLIB2_LIBRARIES}
 633                 ${M_LIBRARIES}
 634                 ${PCAP_LIBRARIES}
 635 #               @SOCKET_LIBS@
 636 #               @NSL_LIBS@
 637                 ${CARES_LIBRARIES}
 638                 ${ADNS_LIBRARIES}
 639                 ${Z_LIBRARIES}
 640         )
 641         set(randpkt_FILES
 642                 randpkt.c
 643         )
 644         add_executable(randpkt ${randpkt_FILES})
 645         target_link_libraries(randpkt ${randpkt_LIBS})
 646         install(TARGETS randpkt RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 647 endif()
 648
 649 if(BUILD_text2pcap)
 650         set(text2pcap_LIBS
 651                 wiretap
 652                 wsutil
 653                 ${GLIB2_LIBRARIES}
 654                 ${M_LIBRARIES}
 655                 ${Z_LIBRARIES}
 656         )
 657         set(text2pcap_FILES
 658                 text2pcap.c
 659         )
 660         add_lex_files(text2pcap_FILES
 661                 text2pcap-scanner.l
 662         )
 663         add_executable(text2pcap ${text2pcap_FILES})
 664         target_link_libraries(text2pcap ${text2pcap_LIBS})
 665         install(TARGETS text2pcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 666 endif()
 667
 668 if(BUILD_mergecap)
 669         set(mergecap_LIBS
 670                 wiretap
 671                 wsutil
 672                 ${GLIB2_LIBRARIES}
 673                 ${Z_LIBRARIES}
 674         )
 675         set(mergecap_FILES
 676                 mergecap.c
 677                 merge.c
 678                 svnversion.h
 679         )
 680         add_executable(mergecap ${mergecap_FILES})
 681         target_link_libraries(mergecap ${mergecap_LIBS})
 682         install(TARGETS mergecap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 683 endif()
 684
 685 if(BUILD_capinfos)
 686         set(capinfos_LIBS
 687                 wiretap
 688                 wsutil
 689                 ${GLIB2_LIBRARIES}
 690                 ${Z_LIBRARIES}
 691         )
 692         set(capinfos_FILES
 693                 capinfos.c
 694                 ${WTAP_PLUGIN_SOURCES}
 695         )
 696         add_executable(capinfos ${capinfos_FILES})
 697         target_link_libraries(capinfos ${capinfos_LIBS})
 698         install(TARGETS capinfos RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 699 endif()
 700
 701 if(BUILD_editcap)
 702         set(editcap_LIBS
 703                 wiretap
 704                 wsutil
 705                 ${GLIB2_LIBRARIES}
 706                 ${Z_LIBRARIES}
 707         )
 708         set(editcap_FILES
 709                 editcap.c
 710                 epan/crypt/crypt-md5.c
 711                 epan/nstime.c
 712                 ${WTAP_PLUGIN_SOURCES}
 713         )
 714         add_executable(editcap ${editcap_FILES})
 715         target_link_libraries(editcap ${editcap_LIBS})
 716         install(TARGETS editcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 717 endif()
 718
 719 if(BUILD_dumpcap)
 720         set(dumpcap_LIBS
 721                 wiretap
 722                 wsutil
 723 #               @INET_NTOP_LO@
 724                 ${GLIB2_LIBRARIES}
 725                 ${PCAP_LIBRARIES}
 726                 ${CAP_LIBRARIES}
 727 #               @SOCKET_LIBS@
 728 #               @NSL_LIBS@
 729 #               @FRAMEWORKS@
 730                 ${GCRYPT_LIBRARIES}
 731                 ${GNUTLS_LIBRARIES}
 732                 ${Z_LIBRARIES}
 733
 734         )
 735         set(dumpcap_FILES
 736                 svnversion.h
 737                 capture_opts.c
 738                 capture-pcap-util.c
 739                 capture_stop_conditions.c
 740                 clopts_common.c
 741                 conditions.c
 742                 dumpcap.c
 743                 pcapio.c
 744                 ringbuffer.c
 745                 sync_pipe_write.c
 746                 tempfile.c
 747                 version_info.c
 748                 ${PLATFORM_SRC}
 749         )
 750         add_executable(dumpcap ${dumpcap_FILES})
 751         target_link_libraries(dumpcap ${dumpcap_LIBS})
 752         install(TARGETS dumpcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 753 endif()
 754
 755 install(
 756         FILES
 757                 ${INSTALL_FILES}
 758         DESTINATION
 759                 ${CMAKE_INSTALL_DATADIR}/${CPACK_PACKAGE_NAME}
 760 )
 761
 762 install(
 763         DIRECTORY
 764                 ${INSTALL_DIRS}
 765         DESTINATION
 766                 ${CMAKE_INSTALL_DATADIR}/${CPACK_PACKAGE_NAME}
 767         PATTERN ".svn" EXCLUDE
 768         PATTERN "Makefile.*" EXCLUDE
 769 )