CMakeLists.txt

   1 # CMakeLists.txt
   2 #
   3 # $Id$
   4 #
   5 # Wireshark - Network traffic analyzer
   6 # By Gerald Combs <gerald@wireshark.org>
   7 # Copyright 1998 Gerald Combs
   8 #
   9 # This program is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU General Public License
  11 # as published by the Free Software Foundation; either version 2
  12 # of the License, or (at your option) any later version.
  13 #
  14 # This program is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program; if not, write to the Free Software
  21 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
  22 #
  23
  24 project(Wireshark C)
  25
  26 cmake_minimum_required(VERSION 2.6)
  27 set(CMAKE_BACKWARDS_COMPATIBILITY 2.6)
  28
  29 # Needs to be set after cmake_minimum_required or cmake_policy(VERSION)
  30 #if(COMMAND cmake_policy)
  31 #       cmake_policy(SET CMP0015 NEW)
  32 #endif(COMMAND cmake_policy)
  33
  34 # set(PROJECT_VERSION "1.3.4-rc5")
  35 # set(PROJECT_VERSION "1.3.4rc5")
  36 # set(PROJECT_VERSION "1.3.4")
  37 # If not set, copy over Wireshark version from configure.in AC_INIT
  38 if(NOT PROJECT_VERSION)
  39         file(STRINGS
  40                 ${CMAKE_SOURCE_DIR}/configure.in
  41                 VERSIONLINE
  42                 REGEX "\\(wireshark, .*\\)"
  43         )
  44         string(REGEX REPLACE ".*\\(wireshark, (.*)\\).*"
  45                 "\\1"
  46                 PROJECT_VERSION
  47                 ${VERSIONLINE}
  48         )
  49 endif()
  50 string(REGEX REPLACE "([0-9]+)\\..*"
  51         "\\1"
  52         PROJECT_MAJOR_VERSION
  53         ${PROJECT_VERSION}
  54 )
  55 string(REGEX REPLACE ".*\\.([0-9]+)\\..*"
  56         "\\1"
  57         PROJECT_MINOR_VERSION
  58         ${PROJECT_VERSION}
  59 )
  60 string(REGEX REPLACE ".*\\..*\\.([0-9]+).*"
  61         "\\1"
  62         PROJECT_PATCH_VERSION
  63         ${PROJECT_VERSION}
  64 )
  65 string(REGEX REPLACE ".*\\..*\\.[0-9]+(.*)"
  66         "\\1"
  67         PROJECT_VERSION_EXTENSION
  68         ${PROJECT_VERSION}
  69 )
  70 message(STATUS "V: ${PROJECT_VERSION}, MaV: ${PROJECT_MAJOR_VERSION}, MiV: ${PROJECT_MINOR_VERSION}, PL: ${PROJECT_PATCH_VERSION}, EV: ${PROJECT_VERSION_EXTENSION}.")
  71
  72 #Where to find local cmake scripts
  73 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  74 INCLUDE(UseLemon)
  75 INCLUDE(UseMakeDissectorReg)
  76 INCLUDE(UseMakeTapReg)
  77
  78 # Under linux the release mode (CMAKE_BUILD_TYPE=release) defines NDEBUG
  79
  80 # Disable this later. Alternative: "make VERBOSE=1"
  81 set(CMAKE_VERBOSE_MAKEFILE ON)
  82
  83 #Defines CMAKE_INSTALL_BINDIR, CMAKE_INSTALL_DATADIR, etc ...
  84 include(CMakeInstallDirs)
  85
  86 include_directories(
  87         ${CMAKE_BINARY_DIR}
  88         ${CMAKE_SOURCE_DIR}
  89         ${CMAKE_SOURCE_DIR}/epan
  90         ${CMAKE_SOURCE_DIR}/tools/lemon
  91         ${CMAKE_SOURCE_DIR}/wiretap
  92 )
  93
  94 #Where to put libraries
  95 if(NOT LIBRARY_OUTPUT_PATH)
  96         set(LIBRARY_OUTPUT_PATH ${Wireshark_BINARY_DIR}/lib CACHE INTERNAL
  97                    "Single output directory for building all libraries.")
  98 endif()
  99
 100
 101 include(CMakeOptions.txt)
 102
 103
 104 set(WIRESHARK_C_FLAGS
 105         -O2
 106         -Wall
 107         -W
 108         -Wextra
 109         -Wdeclaration-after-statement
 110         -Wendif-labels
 111         -Wpointer-arith
 112         -Wno-pointer-sign
 113         -Warray-bounds
 114         -Wcast-align
 115         -Wformat-security
 116         -fexcess-precision=fast
 117 )
 118
 119 set(WIRESHARK_EXTRA_C_FLAGS
 120         -pedantic
 121         -Woverflow
 122         -Wlogical-op
 123         -Wno-overlength-strings
 124         -fstrict-overflow -Wstrict-overflow=4
 125         -Wunreachable-code
 126         -Wunsafe-loop-optimizations
 127         -Wno-long-long
 128         -Wbad-function-cast
 129         -Wcast-qual
 130         -Waddress
 131         -Warray-bounds
 132         -Wattributes
 133         -Wdiv-by-zero
 134         -Wformat-security
 135         -Wignored-qualifiers
 136         -Wpragmas
 137         -Wredundant-decls
 138         -Wvla
 139         -Wc++-compat
 140         -Wjump-misses-init
 141         # packet-ncp2222.inc prevents this from going into all warnings
 142         -Wwrite-strings
 143         -Wstrict-prototypes
 144         -Wmissing-declarations
 145         # Problem with packet-afs.c
 146         -Wshadow
 147         # More cleanup needed for this on LP64
 148         -Wshorten-64-to-32
 149 )
 150
 151 if(ENABLE_EXTRA_GCC_CHECKS)   # This overrides -Werror
 152         set(WIRESHARK_C_FLAGS ${WIRESHARK_C_FLAGS} ${WIRESHARK_EXTRA_C_FLAGS})
 153 endif()
 154
 155 add_definitions(
 156         -DHAVE_CONFIG_H
 157         -DPACKAGE=\"wireshark\"
 158 )
 159
 160 # Counterhack to work around some cache magic in CHECK_C_SOURCE_COMPILES
 161 include(CheckCCompilerFlag)
 162 set(C 0)
 163 # Sigh: Have to use THIS_FLAG instead of ${F} for some reason
 164 foreach(THIS_FLAG ${WIRESHARK_C_FLAGS})
 165         set(F WS_C_FLAG_${C})
 166         set(${F} ${THIS_FLAG})
 167         set(V WS_C_FLAG_VALID${C})
 168         check_c_compiler_flag(${${F}} ${V})
 169         if (${${V}})
 170                 add_definitions(${${F}})
 171         endif()
 172         math(EXPR C "${C} + 1")
 173 endforeach()
 174
 175 if(NOT DISABLE_WERROR AND NOT ENABLE_EXTRA_GCC_CHECKS)
 176         check_c_compiler_flag(-Werror WERROR)
 177 else()
 178         set(WERROR 0)
 179 endif()
 180
 181 if(CMAKE_COMPILER_IS_GNUCC)
 182         add_definitions( -D_U_=__attribute__\(\(unused\)\) )
 183 else()
 184         add_definitions( -D_U_=\"\" )
 185 endif()
 186
 187 set(WIRESHARK_LD_FLAGS
 188         -Wl,--as-needed
 189         # -flto
 190         # -fwhopr
 191         # -fwhole-program
 192 )
 193
 194 include(CheckCLinkerFlag)
 195 set(C 0)
 196 # Sigh: Have to use THIS_FLAG instead of ${F} for some reason
 197 foreach(THIS_FLAG ${WIRESHARK_LD_FLAGS})
 198         set(F WS_LD_FLAG_${C})
 199         set(${F} ${THIS_FLAG})
 200         set(V WS_LD_FLAG_VALID${C})
 201         check_c_linker_flag(${${F}} ${V})
 202         if (${${V}})
 203                 set(WS_LINK_FLAGS ${WS_LINK_FLAGS} ${${F}})
 204         endif()
 205         math(EXPR C "${C} + 1")
 206 endforeach()
 207
 208 if(ENABLE_STATIC)
 209   set(LINK_MODE_LIB STATIC)
 210   set(LINK_MODE_MODULE STATIC)
 211 else()
 212   set(LINK_MODE_LIB SHARED)
 213   set(LINK_MODE_MODULE MODULE)
 214 endif()
 215
 216 # The packagelist is doing some magic:  If we add XXX to the packagelist, we
 217 # - may optionally set XXX_OPTIONS to pass to the find_package command
 218 # - will call FindXXX.cmake
 219 # - return found libraries in XXX_LIBRARIES
 220 # - return found include in XXX_INCLUDE_DIRS
 221 # - set HAVE_XXX
 222
 223 #The minimum package list
 224 set(PACKAGELIST GLIB2 GMODULE2 PCAP M LEX YACC Perl SH PythonInterp)
 225 set(GLIB2_FIND_REQUIRED)
 226 set(GLIB2_MIN_VERSION 2.4.0)
 227 set(PCAP_REQUIRED)
 228 set(M_REQUIRED)
 229
 230 set(PACKAGELIST ${PACKAGELIST} HtmlViewer)
 231
 232 #Build the gui ?
 233 if(BUILD_wireshark)
 234         set(PACKAGELIST ${PACKAGELIST} GTK2)
 235         set(GTK2_OPTIONS COMPONENTS gtk)
 236         set(GTK2_DEBUG false)
 237 endif()
 238
 239 # SMI SNMP
 240 if(ENABLE_SMI)
 241         set(PACKAGELIST ${PACKAGELIST} SMI)
 242 endif()
 243
 244 # GNU crypto
 245 if(ENABLE_GCRYPT)
 246         set(PACKAGELIST ${PACKAGELIST} GCRYPT)
 247 endif()
 248
 249 # GNU SSL/TLS support
 250 if(ENABLE_GNUTLS)
 251         set(PACKAGELIST ${PACKAGELIST} GNUTLS)
 252 endif()
 253
 254 # Regular expressions lib
 255 if(ENABLE_PCRE)
 256         set(PACKAGELIST ${PACKAGELIST} PCRE)
 257 endif()
 258
 259 # Kerberos
 260 if(ENABLE_KERBEROS)
 261         set(PACKAGELIST ${PACKAGELIST} KERBEROS)
 262 endif()
 263
 264 # Portable audio
 265 if(ENABLE_PORTAUDIO)
 266         set(PACKAGELIST ${PACKAGELIST} PORTAUDIO)
 267 endif()
 268
 269
 270 # Prefer c-ares over adns
 271 if(ENABLE_CARES)        # C Asynchronouse resolver
 272         set(PACKAGELIST ${PACKAGELIST} CARES)
 273 elseif(ENABLE_ADNS)     # Gnu asynchronous DNS
 274         set(PACKAGELIST ${PACKAGELIST} ADNS)
 275 endif()
 276
 277 # Zlib compression
 278 if(ENABLE_ZLIB)
 279         set(PACKAGELIST ${PACKAGELIST} ZLIB)
 280 endif()
 281
 282 # Lua 5.1 dissectors
 283 if(ENABLE_LUA)
 284         set(PACKAGELIST ${PACKAGELIST} LUA)
 285 endif()
 286
 287 # GeoIP address resolving
 288 if(ENABLE_GEOIP)
 289         set(PACKAGELIST ${PACKAGELIST} GEOIP)
 290 endif()
 291
 292 # Capabilities
 293 if(ENABLE_CAP)
 294         set(PACKAGELIST ${PACKAGELIST} CAP)
 295 endif()
 296
 297 if(ENABLE_PYTHON)
 298         set(PACKAGELIST ${PACKAGELIST} PYTHON)
 299 endif()
 300
 301 set(PACKAGELIST ${PACKAGELIST} YAPP)
 302
 303 set(PACKAGELIST ${PACKAGELIST} POD)
 304
 305
 306 set(PROGLIST text2pcap mergecap capinfos editcap dumpcap)
 307
 308 #Let's loop the package list
 309 foreach(PACKAGE ${PACKAGELIST})
 310         if(${PACKAGE}_OPTIONS)
 311                 find_package(${PACKAGE} ${${PACKAGE}_OPTIONS})
 312         elseif(${PACKAGE}_REQUIRED)
 313                 find_package(${PACKAGE} REQUIRED)
 314         else()
 315                 find_package(${PACKAGE})
 316         endif()
 317         message(${PACKAGE}_FOUND)
 318         if (${PACKAGE}_FOUND)
 319                 set(HAVE_LIB${PACKAGE} 1)
 320                 include_directories(${${PACKAGE}_INCLUDE_DIRS})
 321                 message(STATUS "${PACKAGE} includes: ${${PACKAGE}_INCLUDE_DIRS}")
 322                 message(STATUS "${PACKAGE} libs: ${${PACKAGE}_LIBRARIES}")
 323         endif()
 324 endforeach()
 325
 326 #packaging
 327 include(CPackConfig.txt)
 328
 329 if(HAVE_LIBPYTHON)
 330         set(HAVE_PYTHON 1)
 331         set(PYTHON_DIR "${CMAKE_INSTALL_PREFIX}/lib/wireshark/python/${CPACK_PACKAGE_VERSION}")
 332 endif()
 333 if(HAVE_LIBLUA)
 334         set(HAVE_LUA_H 1)
 335         set(HAVE_LUA_5_1 1)
 336 endif()
 337 if(HAVE_LIBKERBEROS)
 338         set(HAVE_KERBEROS 1)
 339         # HAVE_HEIMDAL_KERBEROS
 340         set(HAVE_MIT_KERBEROS 1)
 341         set(HAVE_KEYTYPE_ARCFOUR_56 1)
 342 endif()
 343 if(HAVE_LIBGEOIP)
 344         set(HAVE_GEOIP 1)
 345 endif()
 346 if(HAVE_LIBCARES)
 347         set(HAVE_C_ARES 1)
 348 endif()
 349 if(HAVE_LIBADNS)
 350         set(HAVE_GNU_ADNS 1)
 351 endif()
 352 if(ENABLE_AIRPCAP)
 353         set(HAVE_AIRPCAP 1)
 354 endif()
 355 # That's the name autofoo uses
 356 if(HAVE_LIBZLIB)
 357         set(HAVE_LIBZ 1)
 358 endif()
 359
 360 include(ConfigureChecks.cmake)
 361
 362 #Big or little endian ?
 363 include(TestBigEndian)
 364 test_big_endian(WORDS_BIGENDIAN)
 365
 366 set(DATAFILE_DIR "${CMAKE_INSTALL_PREFIX}/share/${CPACK_PACKAGE_NAME}")
 367
 368 if(ENABLE_PLUGINS)
 369         set(HAVE_PLUGINS 1)
 370         set(PLUGIN_DIR="${DATAFILE_DIR}/plugins/${CPACK_PACKAGE_VERSION}")
 371         set(PLUGIN_SRC_DIRS
 372                 plugins/asn1
 373                 plugins/docsis
 374                 plugins/ethercat
 375                 plugins/giop
 376                 plugins/gryphon
 377                 plugins/interlink
 378                 plugins/irda
 379                 plugins/m2m
 380                 plugins/mate
 381                 plugins/opcua
 382                 plugins/profinet
 383                 plugins/sercosiii
 384                 plugins/stats_tree
 385                 plugins/unistim
 386                 plugins/wimax
 387                 plugins/wimaxasncp
 388         )
 389 # It seems this stuff doesn't build with autofoo either...
 390 #       if(YAPP_FOUND)
 391 #               set(PLUGIN_SRC_DIRS
 392 #                       ${PLUGIN_SRC_DIRS}
 393 #                       plugins/tpg
 394 #               )
 395 #       endif()
 396 else()
 397         set(PLUGIN_SRC_DIRS )
 398 endif()
 399
 400 foreach(PLUGIN_DIR ${PLUGIN_SRC_DIRS})
 401         add_subdirectory( ${PLUGIN_DIR} )
 402 endforeach()
 403
 404 add_subdirectory( codecs )
 405 add_subdirectory( epan )
 406 add_subdirectory( tools/lemon )
 407 add_subdirectory( wiretap )
 408 add_subdirectory( wsutil )
 409
 410 if(BUILD_wireshark AND GTK2_FOUND)
 411         add_subdirectory( gtk )
 412 endif()
 413
 414 # Basedir where to install guides
 415 set(DOC_DIR "$ENV{docdir}")
 416 message(STATUS "docdir: ${DOC_DIR}")
 417
 418 if(ENABLE_GUIDES)
 419         add_subdirectory( docbook )
 420 endif()
 421
 422 #Platform specific
 423 if(UNIX)
 424         set(WS_VAR_IMPORT "extern")
 425 endif()
 426
 427 if(APPLE)
 428 #TODO verify that APPLE implies HAVE_OS_X_FRAMEWORKS
 429         set(HAVE_OS_X_FRAMEWORKS 1)
 430         FIND_LIBRARY (APPLE_CORE_SERVICES_LIBRARY CoreServices)
 431         FIND_LIBRARY (APPLE_COCOA_LIBRARY Cocoa)
 432 endif()
 433
 434 if(WIN32)
 435         add_definitions(-D_NEED_VAR_IMPORT_)
 436         set(WS_VAR_IMPORT "__declspec(dllimport) extern")
 437         set(WS_MSVC_NORETURN "__declspec(noreturn)")
 438
 439         # Disable deprecation
 440         if(MSVC80 OR MSVC90)
 441                 add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 442         endif()
 443 else()
 444         set(WS_MSVC_NORETURN " ")
 445 endif()
 446
 447 configure_file(${CMAKE_SOURCE_DIR}/cmakeconfig.h.in ${CMAKE_BINARY_DIR}/config.h)
 448
 449 include(FeatureSummary)
 450 #SET_FEATURE_INFO(NAME DESCRIPTION [URL [COMMENT] ]
 451 PRINT_ENABLED_FEATURES()
 452 PRINT_DISABLED_FEATURES()
 453
 454 link_directories(
 455         ${CMAKE_BINARY_DIR}/gtk
 456         ${CMAKE_BINARY_DIR}/codecs
 457         ${CMAKE_BINARY_DIR}/epan
 458         ${CMAKE_BINARY_DIR}/wiretap
 459         ${CMAKE_BINARY_DIR}/wsutil
 460 )
 461
 462 ADD_CUSTOM_TARGET(
 463         svnversion ALL
 464         COMMAND ${PERL}
 465                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 466                 ${CMAKE_CURRENT_SOURCE_DIR}
 467         DEPENDS
 468                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 469 )
 470
 471 ADD_CUSTOM_COMMAND(
 472         OUTPUT  svnversion.h
 473         COMMAND ${PERL}
 474                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 475                 ${CMAKE_CURRENT_SOURCE_DIR}
 476         DEPENDS
 477                 ${CMAKE_CURRENT_SOURCE_DIR}/make-version.pl
 478 )
 479
 480 register_tap_files(tshark-tap-register.c
 481         ${TSHARK_TAP_SRC}
 482 )
 483
 484 ADD_CUSTOM_COMMAND(
 485         OUTPUT  ps.c
 486         COMMAND ${PYTHON_EXECUTABLE}
 487                 ${CMAKE_CURRENT_SOURCE_DIR}/tools/rdps.py
 488                 ${CMAKE_CURRENT_SOURCE_DIR}/print.ps
 489                 ps.c
 490         DEPENDS
 491                 ${CMAKE_CURRENT_SOURCE_DIR}/tools/rdps.py
 492                 ${CMAKE_CURRENT_SOURCE_DIR}/print.ps
 493 )
 494
 495 if(UNIX)
 496         set(PLATFORM_SRC
 497                 capture-pcap-util-unix.c
 498         )
 499 endif()
 500
 501 if(WIN32)
 502         set(PLATFORM_SRC
 503                 capture-wpcap.c capture_wpcap_packet.c
 504         )
 505 endif()
 506
 507 set(WTAP_PLUGIN_SOURCES
 508         epan/plugins.c
 509         epan/report_err.c
 510         epan/filesystem.c
 511 )
 512
 513 set(SHARK_COMMON_CAPTURE_SRC
 514         capture_errs.c
 515         capture_ifinfo.c
 516         capture_ui_utils.c
 517 )
 518
 519 set(WIRESHARK_COMMON_SRC
 520         ${PLATFORM_SRC}
 521         capture-pcap-util.c
 522         cfile.c
 523         clopts_common.c
 524         disabled_protos.c
 525         packet-range.c
 526         print.c
 527         ps.c
 528         svnversion.h
 529         sync_pipe_write.c
 530         timestats.c
 531         util.c
 532         tap-megaco-common.c
 533         tap-rtp-common.c
 534         version_info.c
 535 )
 536
 537 set(TSHARK_TAP_SRC
 538         tap-afpstat.c
 539         tap-ansi_astat.c
 540         tap-bootpstat.c
 541         tap-camelcounter.c
 542         tap-camelsrt.c
 543         tap-comparestat.c
 544         tap-dcerpcstat.c
 545         tap-diameter-avp.c
 546         tap-funnel.c
 547         tap-gsm_astat.c
 548         tap-h225counter.c
 549         tap-h225rassrt.c
 550         tap-httpstat.c
 551         tap-icmpstat.c
 552         tap-iostat.c
 553         tap-iousers.c
 554         tap-mgcpstat.c
 555         tap-megacostat.c
 556         tap-protocolinfo.c
 557         tap-protohierstat.c
 558         tap-radiusstat.c
 559         tap-rpcstat.c
 560         tap-rpcprogs.c
 561         tap-rtp.c
 562         tap-scsistat.c
 563         tap-sctpchunkstat.c
 564         tap-sipstat.c
 565         tap-smbsids.c
 566         tap-smbstat.c
 567         tap-stats_tree.c
 568         tap-sv.c
 569         tap-wspstat.c
 570 )
 571
 572 set(INSTALL_DIRS
 573         diameter
 574         docbook
 575         dtds
 576         help
 577         radius
 578         tpncp
 579         wimaxasncp
 580 )
 581
 582 set(INSTALL_FILES
 583         ${CMAKE_BINARY_DIR}/AUTHORS-SHORT
 584         COPYING
 585         ${CMAKE_BINARY_DIR}/capinfos.html
 586         cfilters
 587         colorfilters
 588         dfilters
 589         ${CMAKE_BINARY_DIR}/dftest.html
 590         ${CMAKE_BINARY_DIR}/dumpcap.html
 591         ${CMAKE_BINARY_DIR}/editcap.html
 592         ${CMAKE_BINARY_DIR}/idl2wrs.html
 593         ipmap.html
 594         manuf
 595         ${CMAKE_BINARY_DIR}/mergecap.html
 596         ${CMAKE_BINARY_DIR}/randpkt.html
 597         ${CMAKE_BINARY_DIR}/rawshark.html
 598         services
 599         smi_modules
 600         ${CMAKE_BINARY_DIR}/text2pcap.html
 601         ${CMAKE_BINARY_DIR}/tshark.html
 602         ${CMAKE_BINARY_DIR}/wireshark-filter.html
 603         ${CMAKE_BINARY_DIR}/wireshark.html
 604         docbook/ws.css
 605 )
 606
 607 set(LIBEPAN_LIBS
 608 #               @NSL_LIBS@      # -lnsl
 609 #               @SOCKET_LIBS@   # -lsocket
 610 #               @SSL_LIBS@      # -lcrypto
 611                 epan
 612 #               $(plugin_ldadd) # in case of static
 613                 ${PCRE_LIBRARIES}
 614                 ${PCAP_LIBRARIES}
 615                 ${CARES_LIBRARIES}
 616                 ${ADNS_LIBRARIES}
 617                 ${KERBEROS_LIBRARIES}
 618                 ${LUA_LIBRARIES}
 619                 ${PYTHON_LIBRARIES}
 620                 ${GEOIP_LIBRARIES}
 621                 ${GCRYPT_LIBRARIES}
 622                 ${GNUTLS_LIBRARIES}
 623                 ${SMI_LIBRARIES}
 624                 ${ZLIB_LIBRARIES}
 625                 ${M_LIBRARIES}
 626 )
 627
 628 if(BUILD_wireshark AND GTK2_FOUND)
 629         set(wireshark_LIBS
 630                 ui
 631                 ${GTK2_LIBRARIES}
 632                 codecs
 633                 ${PORTAUDIO_LIBRARIES}
 634                 ${LIBEPAN_LIBS}
 635                 ${APPLE_CORE_SERVICES_LIBRARY}
 636                 ${APPLE_COCOA_LIBRARY}
 637         )
 638         set(wireshark_FILES
 639                 airpcap_loader.c
 640                 alert_box.c
 641                 capture.c
 642                 capture_info.c
 643                 capture_opts.c
 644                 capture_sync.c
 645                 color_filters.c
 646                 file.c
 647                 fileset.c
 648                 filters.c
 649                 g711.c
 650                 merge.c
 651                 proto_hier_stats.c
 652                 summary.c
 653                 tempfile.c
 654                 u3.c
 655                 ${SHARK_COMMON_CAPTURE_SRC}
 656                 ${WIRESHARK_COMMON_SRC}
 657         )
 658         add_executable(wireshark ${wireshark_FILES})
 659         add_dependencies(wireshark svnversion)
 660         set_target_properties(wireshark PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 661         target_link_libraries(wireshark ${wireshark_LIBS})
 662         install(TARGETS wireshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 663 endif()
 664
 665 if(BUILD_tshark)
 666         set(tshark_LIBS
 667                 ${LIBEPAN_LIBS}
 668                 ${APPLE_COCOA_LIBRARY}
 669         )
 670         set(tshark_FILES
 671                 capture_opts.c
 672                 capture_sync.c
 673                 tempfile.c
 674                 tshark-tap-register.c
 675                 tshark.c
 676                 ${TSHARK_TAP_SRC}
 677                 ${SHARK_COMMON_CAPTURE_SRC}
 678                 ${WIRESHARK_COMMON_SRC}
 679         )
 680         add_executable(tshark ${tshark_FILES})
 681         add_dependencies(tshark svnversion)
 682         set_target_properties(tshark PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 683         target_link_libraries(tshark ${tshark_LIBS})
 684         install(TARGETS tshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 685 endif()
 686
 687 if(BUILD_rawshark)
 688         set(rawshark_LIBS
 689                 ${LIBEPAN_LIBS}
 690                 ${APPLE_COCOA_LIBRARY}
 691         )
 692         set(rawshark_FILES
 693                 ${WIRESHARK_COMMON_SRC}
 694                 rawshark.c
 695         )
 696         add_executable(rawshark ${rawshark_FILES})
 697         add_dependencies(rawshark svnversion)
 698         set_target_properties(rawshark PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 699         target_link_libraries(rawshark ${rawshark_LIBS})
 700         install(TARGETS rawshark RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 701 endif()
 702
 703 if(BUILD_dftest)
 704         set(dftest_LIBS
 705                 ${LIBEPAN_LIBS}
 706         )
 707         set(dftest_FILES
 708                 dftest.c
 709                 util.c
 710         )
 711         add_executable(dftest ${dftest_FILES})
 712         set_target_properties(dftest PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 713         target_link_libraries(dftest ${dftest_LIBS})
 714         install(TARGETS dftest RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 715 endif()
 716
 717 if(BUILD_randpkt)
 718         set(randpkt_LIBS
 719                 wiretap
 720                 ${M_LIBRARIES}
 721                 ${PCAP_LIBRARIES}
 722 #               @SOCKET_LIBS@
 723 #               @NSL_LIBS@
 724                 ${CARES_LIBRARIES}
 725                 ${ADNS_LIBRARIES}
 726                 ${ZLIB_LIBRARIES}
 727         )
 728         set(randpkt_FILES
 729                 randpkt.c
 730         )
 731         add_executable(randpkt ${randpkt_FILES})
 732         set_target_properties(randpkt PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 733         target_link_libraries(randpkt ${randpkt_LIBS})
 734         install(TARGETS randpkt RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 735 endif()
 736
 737 if(BUILD_text2pcap)
 738         set(text2pcap_LIBS
 739                 wiretap
 740                 ${M_LIBRARIES}
 741                 ${ZLIB_LIBRARIES}
 742         )
 743         set(text2pcap_CLEAN_FILES
 744                 text2pcap.c
 745         )
 746         set(text2pcap_FILES
 747                 ${text2pcap_CLEAN_FILES}
 748         )
 749         add_lex_files(text2pcap_FILES
 750                 text2pcap-scanner.l
 751         )
 752         add_executable(text2pcap ${text2pcap_FILES})
 753         add_dependencies(text2pcap svnversion)
 754         set_target_properties(text2pcap PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 755         target_link_libraries(text2pcap ${text2pcap_LIBS})
 756         install(TARGETS text2pcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 757 endif()
 758
 759 if(BUILD_mergecap)
 760         set(mergecap_LIBS
 761                 wiretap
 762                 ${ZLIB_LIBRARIES}
 763         )
 764         set(mergecap_FILES
 765                 mergecap.c
 766                 merge.c
 767                 svnversion.h
 768         )
 769         add_executable(mergecap ${mergecap_FILES})
 770         add_dependencies(mergecap svnversion)
 771         set_target_properties(mergecap PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 772         target_link_libraries(mergecap ${mergecap_LIBS})
 773         install(TARGETS mergecap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 774 endif()
 775
 776 if(BUILD_capinfos)
 777         set(capinfos_LIBS
 778                 wiretap
 779                 ${ZLIB_LIBRARIES}
 780                 ${GCRYPT_LIBRARIES}
 781                 ${APPLE_COCOA_LIBRARY}
 782         )
 783         set(capinfos_FILES
 784                 capinfos.c
 785                 ${WTAP_PLUGIN_SOURCES}
 786         )
 787         add_executable(capinfos ${capinfos_FILES})
 788         add_dependencies(capinfos svnversion)
 789         set_target_properties(capinfos PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 790         target_link_libraries(capinfos ${capinfos_LIBS})
 791         install(TARGETS capinfos RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 792 endif()
 793
 794 if(BUILD_editcap)
 795         set(editcap_LIBS
 796                 wiretap
 797                 ${ZLIB_LIBRARIES}
 798         )
 799         set(editcap_FILES
 800                 editcap.c
 801                 epan/crypt/crypt-md5.c
 802                 epan/nstime.c
 803                 ${WTAP_PLUGIN_SOURCES}
 804         )
 805         add_executable(editcap ${editcap_FILES})
 806         add_dependencies(editcap svnversion)
 807         set_target_properties(editcap PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 808         target_link_libraries(editcap ${editcap_LIBS})
 809         install(TARGETS editcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 810 endif()
 811
 812 if(BUILD_dumpcap)
 813         set(dumpcap_LIBS
 814 #               @INET_NTOP_LO@
 815                 wsutil
 816                 ${PCAP_LIBRARIES}
 817                 ${CAP_LIBRARIES}
 818 #               @SOCKET_LIBS@
 819 #               @NSL_LIBS@
 820                 ${GLIB2_LIBRARIES}
 821                 ${ZLIB_LIBRARIES}
 822                 ${APPLE_COCOA_LIBRARY}
 823         )
 824         set(dumpcap_FILES
 825                 svnversion.h
 826                 capture_opts.c
 827                 capture-pcap-util.c
 828                 capture_stop_conditions.c
 829                 clopts_common.c
 830                 conditions.c
 831                 dumpcap.c
 832                 pcapio.c
 833                 ringbuffer.c
 834                 sync_pipe_write.c
 835                 tempfile.c
 836                 version_info.c
 837                 ${PLATFORM_SRC}
 838         )
 839         add_executable(dumpcap ${dumpcap_FILES})
 840         add_dependencies(dumpcap svnversion)
 841         set_target_properties(dumpcap PROPERTIES LINK_FLAGS "${WS_LINK_FLAGS}")
 842         target_link_libraries(dumpcap ${dumpcap_LIBS})
 843         install(TARGETS dumpcap RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 844 endif()
 845
 846 ADD_CUSTOM_COMMAND(
 847         OUTPUT  ${CMAKE_BINARY_DIR}/AUTHORS-SHORT
 848         COMMAND ${PERL}
 849                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
 850                 ${CMAKE_SOURCE_DIR}/doc/make-authors-short.pl
 851                 < ${CMAKE_SOURCE_DIR}/AUTHORS
 852                 > ${CMAKE_BINARY_DIR}/AUTHORS-SHORT
 853         DEPENDS
 854                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
 855                 ${CMAKE_SOURCE_DIR}/doc/make-authors-short.pl
 856                 ${CMAKE_SOURCE_DIR}/AUTHORS
 857 )
 858
 859 ADD_CUSTOM_COMMAND(
 860         OUTPUT  ${CMAKE_BINARY_DIR}/AUTHORS-SHORT-FORMAT
 861                 ${CMAKE_BINARY_DIR}/wireshark.pod
 862         COMMAND ${PERL}
 863                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
 864                 ${CMAKE_SOURCE_DIR}/doc/make-authors-format.pl
 865                 < ${CMAKE_BINARY_DIR}/AUTHORS-SHORT
 866                 > ${CMAKE_BINARY_DIR}/AUTHORS-SHORT-FORMAT
 867         COMMAND cat
 868                 ${CMAKE_SOURCE_DIR}/doc/wireshark.pod.template
 869                 ${CMAKE_BINARY_DIR}/AUTHORS-SHORT-FORMAT
 870                 > ${CMAKE_BINARY_DIR}/wireshark.pod
 871         DEPENDS
 872                 ${CMAKE_SOURCE_DIR}/doc/perlnoutf.pl
 873                 ${CMAKE_SOURCE_DIR}/doc/make-authors-format.pl
 874                 ${CMAKE_BINARY_DIR}/AUTHORS-SHORT
 875                 ${CMAKE_SOURCE_DIR}/doc/wireshark.pod.template
 876 )
 877
 878 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/capinfos 1 )
 879 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/dftest 1 )
 880 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/dumpcap 1 )
 881 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/editcap 1 )
 882 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/idl2wrs 1 )
 883 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/mergecap 1 )
 884 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/randpkt 1 )
 885 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/rawshark 1 )
 886 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/text2pcap 1 )
 887 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/tshark 1 )
 888 pod2manhtml( wireshark 1 )
 889 pod2manhtml( ${CMAKE_SOURCE_DIR}/doc/wireshark-filter 4 )
 890
 891 add_custom_target(
 892         auxiliary ALL
 893         DEPENDS
 894                 AUTHORS-SHORT
 895                 capinfos.html
 896                 dftest.html
 897                 dumpcap.html
 898                 editcap.html
 899                 idl2wrs.html
 900                 mergecap.html
 901                 randpkt.html
 902                 rawshark.html
 903                 text2pcap.html
 904                 tshark.html
 905                 wireshark.html
 906                 wireshark-filter.html
 907 )
 908
 909 set(MAN1_FILES
 910         ${CMAKE_BINARY_DIR}/capinfos.1
 911         ${CMAKE_BINARY_DIR}/dftest.1
 912         ${CMAKE_BINARY_DIR}/dumpcap.1
 913         ${CMAKE_BINARY_DIR}/editcap.1
 914         ${CMAKE_BINARY_DIR}/idl2wrs.1
 915         ${CMAKE_BINARY_DIR}/mergecap.1
 916         ${CMAKE_BINARY_DIR}/randpkt.1
 917         ${CMAKE_BINARY_DIR}/rawshark.1
 918         ${CMAKE_BINARY_DIR}/text2pcap.1
 919         ${CMAKE_BINARY_DIR}/tshark.1
 920         ${CMAKE_BINARY_DIR}/wireshark.1
 921 )
 922
 923 set(MAN4_FILES
 924         ${CMAKE_BINARY_DIR}/wireshark-filter.4
 925 )
 926
 927 set(CLEAN_FILES
 928         ${wireshark_FILES}
 929         ${tshark_FILES}
 930         ${rawshark_FILES}
 931         ${dftest_FILES}
 932         ${randpkt_FILES}
 933         ${text2pcap_CLEAN_FILES}
 934         ${mergecap_FILES}
 935         ${capinfos_FILES}
 936         ${editcap_FILES}
 937         ${dumpcap_FILES}
 938 )
 939
 940 if (WERROR)
 941         set_source_files_properties(
 942                 ${CLEAN_FILES}
 943                 PROPERTIES
 944                 COMPILE_FLAGS -Werror
 945         )
 946 endif()
 947
 948 install(
 949         FILES
 950                 ${INSTALL_FILES}
 951         DESTINATION
 952                 ${CMAKE_INSTALL_DATADIR}/${CPACK_PACKAGE_NAME}
 953 )
 954
 955 install(
 956         FILES
 957                 ${MAN1_FILES}
 958         DESTINATION
 959                 ${CMAKE_INSTALL_MANDIR}/man1
 960 )
 961
 962 install(
 963         FILES
 964                 ${MAN4_FILES}
 965         DESTINATION
 966                 ${CMAKE_INSTALL_MANDIR}/man4
 967 )
 968
 969 install(
 970         DIRECTORY
 971                 ${INSTALL_DIRS}
 972         DIRECTORY_PERMISSIONS
 973                 OWNER_EXECUTE OWNER_WRITE OWNER_READ
 974                 GROUP_EXECUTE GROUP_READ
 975                 WORLD_EXECUTE WORLD_READ
 976         DESTINATION
 977                 ${CMAKE_INSTALL_DATADIR}/${CPACK_PACKAGE_NAME}
 978         PATTERN ".svn" EXCLUDE
 979         PATTERN "Makefile.*" EXCLUDE
 980         PATTERN "faq.py" EXCLUDE
 981 )