selftest/target/Samba3.pm

   1 #!/usr/bin/perl
   2 # Bootstrap Samba and run a number of tests against it.
   3 # Copyright (C) 2005-2007 Jelmer Vernooij <jelmer@samba.org>
   4 # Published under the GNU GPL, v3 or later.
   5
   6 package Samba3;
   7
   8 use strict;
   9 use Cwd qw(abs_path);
  10 use FindBin qw($RealBin);
  11 use POSIX;
  12 use target::Samba;
  13
  14 sub have_ads($) {
  15         my ($self) = @_;
  16         my $found_ads = 0;
  17         my $smbd_build_options = Samba::bindir_path($self, "smbd") . " -b|";
  18         open(IN, $smbd_build_options) or die("Unable to run $smbd_build_options: $!");
  19
  20         while (<IN>) {
  21                 if (/WITH_ADS/) {
  22                        $found_ads = 1;
  23                 }
  24         }
  25         close IN;
  26
  27         # If we were not built with ADS support, pretend we were never even available
  28         return $found_ads;
  29 }
  30
  31 sub new($$) {
  32         my ($classname, $bindir, $binary_mapping, $srcdir, $server_maxtime) = @_;
  33         my $self = { vars => {},
  34                      bindir => $bindir,
  35                      binary_mapping => $binary_mapping,
  36                      srcdir => $srcdir,
  37                      server_maxtime => $server_maxtime
  38         };
  39         bless $self;
  40         return $self;
  41 }
  42
  43 sub teardown_env($$)
  44 {
  45         my ($self, $envvars) = @_;
  46         my $count = 0;
  47
  48         # This should cause smbd to terminate gracefully
  49         close($envvars->{STDIN_PIPE});
  50
  51         my $smbdpid = $envvars->{SMBD_TL_PID};
  52         my $nmbdpid = $envvars->{NMBD_TL_PID};
  53         my $winbinddpid = $envvars->{WINBINDD_TL_PID};
  54
  55         # This should give it time to write out the gcov data
  56         until ($count > 20) {
  57             my $smbdchild = Samba::cleanup_child($smbdpid, "smbd");
  58             my $nmbdchild = Samba::cleanup_child($nmbdpid, "nmbd");
  59             my $winbinddchild = Samba::cleanup_child($winbinddpid, "winbindd");
  60             if ($smbdchild == -1
  61                 && $nmbdchild == -1
  62                 && $winbinddchild == -1) {
  63                 last;
  64             }
  65             sleep(1);
  66             $count++;
  67         }
  68
  69         if ($count <= 20 && kill(0, $smbdpid, $nmbdpid, $winbinddpid) == 0) {
  70             return;
  71         }
  72
  73         $self->stop_sig_term($smbdpid);
  74         $self->stop_sig_term($nmbdpid);
  75         $self->stop_sig_term($winbinddpid);
  76
  77         $count = 0;
  78         until ($count > 10) {
  79             my $smbdchild = Samba::cleanup_child($smbdpid, "smbd");
  80             my $nmbdchild = Samba::cleanup_child($nmbdpid, "nmbd");
  81             my $winbinddchild = Samba::cleanup_child($winbinddpid, "winbindd");
  82             if ($smbdchild == -1
  83                 && $nmbdchild == -1
  84                 && $winbinddchild == -1) {
  85                 last;
  86             }
  87             sleep(1);
  88             $count++;
  89         }
  90
  91         if ($count <= 10 && kill(0, $smbdpid, $nmbdpid, $winbinddpid) == 0) {
  92             return;
  93         }
  94
  95         warn("timelimit process did not quit on SIGTERM, sending SIGKILL");
  96         $self->stop_sig_kill($smbdpid);
  97         $self->stop_sig_kill($nmbdpid);
  98         $self->stop_sig_kill($winbinddpid);
  99
 100         return 0;
 101 }
 102
 103 sub getlog_env_app($$$)
 104 {
 105         my ($self, $envvars, $name) = @_;
 106
 107         my $title = "$name LOG of: $envvars->{NETBIOSNAME}\n";
 108         my $out = $title;
 109
 110         open(LOG, "<".$envvars->{$name."_TEST_LOG"});
 111
 112         seek(LOG, $envvars->{$name."_TEST_LOG_POS"}, SEEK_SET);
 113         while (<LOG>) {
 114                 $out .= $_;
 115         }
 116         $envvars->{$name."_TEST_LOG_POS"} = tell(LOG);
 117         close(LOG);
 118
 119         return "" if $out eq $title;
 120
 121         return $out;
 122 }
 123
 124 sub getlog_env($$)
 125 {
 126         my ($self, $envvars) = @_;
 127         my $ret = "";
 128
 129         $ret .= $self->getlog_env_app($envvars, "SMBD");
 130         $ret .= $self->getlog_env_app($envvars, "NMBD");
 131         $ret .= $self->getlog_env_app($envvars, "WINBINDD");
 132
 133         return $ret;
 134 }
 135
 136 sub check_env($$)
 137 {
 138         my ($self, $envvars) = @_;
 139
 140         my $childpid = waitpid(-1, WNOHANG);
 141
 142         # TODO ...
 143         return 1;
 144 }
 145
 146 sub setup_env($$$)
 147 {
 148         my ($self, $envname, $path) = @_;
 149
 150         if (defined($self->{vars}->{$envname})) {
 151                 return $self->{vars}->{$envname};
 152         }
 153
 154         if ($envname eq "s3dc") {
 155                 return $self->setup_s3dc("$path/s3dc");
 156         } elsif ($envname eq "secshare") {
 157                 return $self->setup_secshare("$path/secshare");
 158         } elsif ($envname eq "maptoguest") {
 159                 return $self->setup_maptoguest("$path/maptoguest");
 160         } elsif ($envname eq "ktest") {
 161                 return $self->setup_ktest("$path/ktest");
 162         } elsif ($envname eq "member") {
 163                 if (not defined($self->{vars}->{s3dc})) {
 164                         if (not defined($self->setup_s3dc("$path/s3dc"))) {
 165                                 return undef;
 166                         }
 167                 }
 168                 return $self->setup_member("$path/member", $self->{vars}->{s3dc});
 169         } else {
 170                 return "UNKNOWN";
 171         }
 172 }
 173
 174 sub setup_s3dc($$)
 175 {
 176         my ($self, $path) = @_;
 177
 178         print "PROVISIONING S3DC...";
 179
 180         my $s3dc_options = "
 181         domain master = yes
 182         domain logons = yes
 183         lanman auth = yes
 184
 185         rpc_server:epmapper = external
 186         rpc_server:spoolss = external
 187         rpc_server:lsarpc = external
 188         rpc_server:samr = external
 189         rpc_server:netlogon = external
 190         rpc_server:register_embedded_np = yes
 191
 192         rpc_daemon:epmd = fork
 193         rpc_daemon:spoolssd = fork
 194         rpc_daemon:lsasd = fork
 195 ";
 196
 197         my $vars = $self->provision($path,
 198                                     "LOCALS3DC2",
 199                                     "locals3dc2pass",
 200                                     $s3dc_options);
 201
 202         $vars or return undef;
 203
 204         $self->check_or_start($vars,
 205                                "yes", "yes", "yes");
 206
 207         if (not $self->wait_for_start($vars)) {
 208                return undef;
 209         }
 210
 211         $vars->{DC_SERVER} = $vars->{SERVER};
 212         $vars->{DC_SERVER_IP} = $vars->{SERVER_IP};
 213         $vars->{DC_NETBIOSNAME} = $vars->{NETBIOSNAME};
 214         $vars->{DC_USERNAME} = $vars->{USERNAME};
 215         $vars->{DC_PASSWORD} = $vars->{PASSWORD};
 216
 217         $self->{vars}->{s3dc} = $vars;
 218
 219         return $vars;
 220 }
 221
 222 sub setup_member($$$)
 223 {
 224         my ($self, $prefix, $s3dcvars) = @_;
 225
 226         print "PROVISIONING MEMBER...";
 227
 228         my $member_options = "
 229         security = domain
 230         server signing = on
 231 ";
 232         my $ret = $self->provision($prefix,
 233                                    "LOCALMEMBER3",
 234                                    "localmember3pass",
 235                                    $member_options);
 236
 237         $ret or return undef;
 238
 239         my $net = Samba::bindir_path($self, "net");
 240         my $cmd = "";
 241         $cmd .= "SOCKET_WRAPPER_DEFAULT_IFACE=\"$ret->{SOCKET_WRAPPER_DEFAULT_IFACE}\" ";
 242         $cmd .= "$net join $ret->{CONFIGURATION} $s3dcvars->{DOMAIN} member";
 243         $cmd .= " -U$s3dcvars->{USERNAME}\%$s3dcvars->{PASSWORD}";
 244
 245         if (system($cmd) != 0) {
 246             warn("Join failed\n$cmd");
 247             return undef;
 248         }
 249
 250         $self->check_or_start($ret, "yes", "yes", "yes");
 251
 252         if (not $self->wait_for_start($ret)) {
 253                return undef;
 254         }
 255
 256         $ret->{DC_SERVER} = $s3dcvars->{SERVER};
 257         $ret->{DC_SERVER_IP} = $s3dcvars->{SERVER_IP};
 258         $ret->{DC_NETBIOSNAME} = $s3dcvars->{NETBIOSNAME};
 259         $ret->{DC_USERNAME} = $s3dcvars->{USERNAME};
 260         $ret->{DC_PASSWORD} = $s3dcvars->{PASSWORD};
 261
 262         return $ret;
 263 }
 264
 265 sub setup_admember($$$$)
 266 {
 267         my ($self, $prefix, $dcvars) = @_;
 268
 269         # If we didn't build with ADS, pretend this env was never available
 270         if (not $self->have_ads()) {
 271                 return "UNKNOWN";
 272         }
 273
 274         print "PROVISIONING S3 AD MEMBER...";
 275
 276         my $member_options = "
 277         security = ads
 278         server signing = on
 279         workgroup = $dcvars->{DOMAIN}
 280         realm = $dcvars->{REALM}
 281 ";
 282
 283         my $ret = $self->provision($prefix,
 284                                    "LOCALADMEMBER",
 285                                    "loCalMemberPass",
 286                                    $member_options);
 287
 288         $ret or return undef;
 289
 290         close(USERMAP);
 291         $ret->{DOMAIN} = $dcvars->{DOMAIN};
 292         $ret->{REALM} = $dcvars->{REALM};
 293
 294         my $ctx;
 295         my $prefix_abs = abs_path($prefix);
 296         $ctx = {};
 297         $ctx->{krb5_conf} = "$prefix_abs/lib/krb5.conf";
 298         $ctx->{domain} = $dcvars->{DOMAIN};
 299         $ctx->{realm} = $dcvars->{REALM};
 300         $ctx->{dnsname} = lc($dcvars->{REALM});
 301         $ctx->{kdc_ipv4} = $dcvars->{SERVER_IP};
 302         Samba::mk_krb5_conf($ctx, "");
 303
 304         $ret->{KRB5_CONFIG} = $ctx->{krb5_conf};
 305
 306         my $net = Samba::bindir_path($self, "net");
 307         my $cmd = "";
 308         $cmd .= "SOCKET_WRAPPER_DEFAULT_IFACE=\"$ret->{SOCKET_WRAPPER_DEFAULT_IFACE}\" ";
 309         $cmd .= "KRB5_CONFIG=\"$ret->{KRB5_CONFIG}\" ";
 310         $cmd .= "$net join $ret->{CONFIGURATION}";
 311         $cmd .= " -U$dcvars->{USERNAME}\%$dcvars->{PASSWORD}";
 312
 313         if (system($cmd) != 0) {
 314             warn("Join failed\n$cmd");
 315             return undef;
 316         }
 317
 318         # We need world access to this share, as otherwise the domain
 319         # administrator from the AD domain provided by Samba4 can't
 320         # access the share for tests.
 321         chmod 0777, "$prefix/share";
 322
 323         $self->check_or_start($ret,
 324                               "yes", "yes", "yes");
 325
 326         $self->wait_for_start($ret);
 327
 328         $ret->{DC_SERVER} = $dcvars->{SERVER};
 329         $ret->{DC_SERVER_IP} = $dcvars->{SERVER_IP};
 330         $ret->{DC_NETBIOSNAME} = $dcvars->{NETBIOSNAME};
 331         $ret->{DC_USERNAME} = $dcvars->{USERNAME};
 332         $ret->{DC_PASSWORD} = $dcvars->{PASSWORD};
 333
 334         # Special case, this is called from Samba4.pm but needs to use the Samba3 check_env and get_log_env
 335         $ret->{target} = $self;
 336
 337         return $ret;
 338 }
 339
 340 sub setup_secshare($$)
 341 {
 342         my ($self, $path) = @_;
 343         my $vfs_modulesdir_abs = $ENV{VFSLIBDIR};
 344
 345         print "PROVISIONING server with security=share...";
 346
 347         my $prefix_abs = abs_path($path);
 348
 349         my $secshare_options = "
 350         security = share
 351         lanman auth = yes
 352         vfs objects = $vfs_modulesdir_abs/xattr_tdb.so $vfs_modulesdir_abs/streams_depot.so
 353
 354 [vfs_aio_fork]
 355         path = $prefix_abs/share
 356         vfs objects = $vfs_modulesdir_abs/aio_fork.so
 357         read only = no
 358         vfs_aio_fork:erratic_testing_mode=yes
 359 ";
 360
 361         my $vars = $self->provision($path,
 362                                     "LOCALSHARE4",
 363                                     "local4pass",
 364                                     $secshare_options);
 365
 366         $vars or return undef;
 367
 368         $self->check_or_start($vars, "yes", "no", "yes");
 369
 370         if (not $self->wait_for_start($vars)) {
 371                return undef;
 372         }
 373
 374         $self->{vars}->{secshare} = $vars;
 375
 376         return $vars;
 377 }
 378
 379 sub setup_ktest($$$)
 380 {
 381         my ($self, $prefix) = @_;
 382
 383         # If we didn't build with ADS, pretend this env was never available
 384         if (not $self->have_ads()) {
 385                 return "UNKNOWN";
 386         }
 387
 388         print "PROVISIONING server with security=ads...";
 389
 390         my $ktest_options = "
 391         workgroup = KTEST
 392         realm = ktest.samba.example.com
 393         security = ads
 394         username map = $prefix/lib/username.map
 395         server signing = required
 396 ";
 397
 398         my $ret = $self->provision($prefix,
 399                                    "LOCALKTEST6",
 400                                    "localktest6pass",
 401                                    $ktest_options);
 402
 403         $ret or return undef;
 404
 405         my $ctx;
 406         my $prefix_abs = abs_path($prefix);
 407         $ctx = {};
 408         $ctx->{krb5_conf} = "$prefix_abs/lib/krb5.conf";
 409         $ctx->{domain} = "KTEST";
 410         $ctx->{realm} = "KTEST.SAMBA.EXAMPLE.COM";
 411         $ctx->{dnsname} = lc($ctx->{realm});
 412         $ctx->{kdc_ipv4} = "0.0.0.0";
 413         Samba::mk_krb5_conf($ctx, "");
 414
 415         $ret->{KRB5_CONFIG} = $ctx->{krb5_conf};
 416
 417         open(USERMAP, ">$prefix/lib/username.map") or die("Unable to open $prefix/lib/username.map");
 418         print USERMAP "
 419 $ret->{USERNAME} = KTEST\\Administrator
 420 ";
 421         close(USERMAP);
 422
 423 #This is the secrets.tdb created by 'net ads join' from Samba3 to a
 424 #Samba4 DC with the same parameters as are being used here.  The
 425 #domain SID is S-1-5-21-1071277805-689288055-3486227160
 426
 427         system("cp $self->{srcdir}/source3/selftest/ktest-secrets.tdb $prefix/private/secrets.tdb");
 428         chmod 0600, "$prefix/private/secrets.tdb";
 429
 430 #This uses a pre-calculated krb5 credentials cache, obtained by running Samba4 with:
 431 # "--option=kdc:service ticket lifetime=239232" "--option=kdc:user ticket lifetime=239232" "--option=kdc:renewal lifetime=239232"
 432 #
 433 #and having in krb5.conf:
 434 # ticket_lifetime = 799718400
 435 # renew_lifetime = 799718400
 436 #
 437 # The commands for the -2 keytab where were:
 438 # kinit administrator@KTEST.SAMBA.EXAMPLE.COM
 439 # kvno host/localktest6@KTEST.SAMBA.EXAMPLE.COM
 440 # kvno cifs/localktest6@KTEST.SAMBA.EXAMPLE.COM
 441 # kvno host/LOCALKTEST6@KTEST.SAMBA.EXAMPLE.COM
 442 # kvno cifs/LOCALKTEST6@KTEST.SAMBA.EXAMPLE.COM
 443 #
 444 # and then for the -3 keytab, I did
 445 #
 446 # net changetrustpw; kdestroy and the same again.
 447 #
 448 # This creates a credential cache with a very long lifetime (2036 at
 449 # at 2011-04), and shows that running 'net changetrustpw' does not
 450 # break existing logins (for the secrets.tdb method at least).
 451 #
 452
 453         $ret->{KRB5_CCACHE}="FILE:$prefix/krb5_ccache";
 454
 455         system("cp $self->{srcdir}/source3/selftest/ktest-krb5_ccache-2 $prefix/krb5_ccache-2");
 456         chmod 0600, "$prefix/krb5_ccache-2";
 457
 458         system("cp $self->{srcdir}/source3/selftest/ktest-krb5_ccache-3 $prefix/krb5_ccache-3");
 459         chmod 0600, "$prefix/krb5_ccache-3";
 460
 461         # We need world access to this share, as otherwise the domain
 462         # administrator from the AD domain provided by ktest can't
 463         # access the share for tests.
 464         chmod 0777, "$prefix/share";
 465
 466         $self->check_or_start($ret, "yes", "no", "yes");
 467
 468         if (not $self->wait_for_start($ret)) {
 469                return undef;
 470         }
 471         return $ret;
 472 }
 473
 474 sub setup_maptoguest($$)
 475 {
 476         my ($self, $path) = @_;
 477
 478         print "PROVISIONING maptoguest...";
 479
 480         my $options = "
 481 map to guest = bad user
 482 ";
 483
 484         my $vars = $self->provision($path,
 485                                     "maptoguest",
 486                                     "maptoguestpass",
 487                                     $options);
 488
 489         $vars or return undef;
 490
 491         $self->check_or_start($vars,
 492                                "yes", "no", "yes");
 493
 494         if (not $self->wait_for_start($vars)) {
 495                return undef;
 496         }
 497
 498         $self->{vars}->{s3maptoguest} = $vars;
 499
 500         return $vars;
 501 }
 502
 503 sub stop_sig_term($$) {
 504         my ($self, $pid) = @_;
 505         kill("USR1", $pid) or kill("ALRM", $pid) or warn("Unable to kill $pid: $!");
 506 }
 507
 508 sub stop_sig_kill($$) {
 509         my ($self, $pid) = @_;
 510         kill("ALRM", $pid) or warn("Unable to kill $pid: $!");
 511 }
 512
 513 sub write_pid($$$)
 514 {
 515         my ($env_vars, $app, $pid) = @_;
 516
 517         open(PID, ">$env_vars->{PIDDIR}/timelimit.$app.pid");
 518         print PID $pid;
 519         close(PID);
 520 }
 521
 522 sub read_pid($$)
 523 {
 524         my ($env_vars, $app) = @_;
 525
 526         open(PID, "<$env_vars->{PIDDIR}/timelimit.$app.pid");
 527         my $pid = <PID>;
 528         close(PID);
 529         return $pid;
 530 }
 531
 532 sub check_or_start($$$$$) {
 533         my ($self, $env_vars, $nmbd, $winbindd, $smbd) = @_;
 534
 535         # use a pipe for stdin in the child processes. This allows
 536         # those processes to monitor the pipe for EOF to ensure they
 537         # exit when the test script exits
 538         pipe(STDIN_READER, $env_vars->{STDIN_PIPE});
 539
 540         unlink($env_vars->{NMBD_TEST_LOG});
 541         print "STARTING NMBD...";
 542         my $pid = fork();
 543         if ($pid == 0) {
 544                 open STDOUT, ">$env_vars->{NMBD_TEST_LOG}";
 545                 open STDERR, '>&STDOUT';
 546
 547                 SocketWrapper::set_default_iface($env_vars->{SOCKET_WRAPPER_DEFAULT_IFACE});
 548
 549                 $ENV{KRB5_CONFIG} = $env_vars->{KRB5_CONFIG};
 550                 $ENV{WINBINDD_SOCKET_DIR} = $env_vars->{WINBINDD_SOCKET_DIR};
 551                 $ENV{NMBD_SOCKET_DIR} = $env_vars->{NMBD_SOCKET_DIR};
 552
 553                 $ENV{NSS_WRAPPER_PASSWD} = $env_vars->{NSS_WRAPPER_PASSWD};
 554                 $ENV{NSS_WRAPPER_GROUP} = $env_vars->{NSS_WRAPPER_GROUP};
 555                 $ENV{NSS_WRAPPER_WINBIND_SO_PATH} = $env_vars->{NSS_WRAPPER_WINBIND_SO_PATH};
 556
 557                 $ENV{UID_WRAPPER} = "1";
 558
 559                 if ($nmbd ne "yes") {
 560                         $SIG{USR1} = $SIG{ALRM} = $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub {
 561                                 my $signame = shift;
 562                                 print("Skip nmbd received signal $signame");
 563                                 exit 0;
 564                         };
 565                         sleep($self->{server_maxtime});
 566                         exit 0;
 567                 }
 568
 569                 my @optargs = ("-d0");
 570                 if (defined($ENV{NMBD_OPTIONS})) {
 571                         @optargs = split(/ /, $ENV{NMBD_OPTIONS});
 572                 }
 573
 574                 $ENV{MAKE_TEST_BINARY} = Samba::bindir_path($self, "nmbd");
 575
 576                 my @preargs = (Samba::bindir_path($self, "timelimit"), $self->{server_maxtime});
 577                 if(defined($ENV{NMBD_VALGRIND})) {
 578                         @preargs = split(/ /, $ENV{NMBD_VALGRIND});
 579                 }
 580
 581                 close($env_vars->{STDIN_PIPE});
 582                 open STDIN, ">&", \*STDIN_READER or die "can't dup STDIN_READER to STDIN: $!";
 583
 584                 exec(@preargs, Samba::bindir_path($self, "nmbd"), "-F", "--no-process-group", "--log-stdout", "-s", $env_vars->{SERVERCONFFILE}, @optargs) or die("Unable to start nmbd: $!");
 585         }
 586         $env_vars->{NMBD_TL_PID} = $pid;
 587         write_pid($env_vars, "nmbd", $pid);
 588         print "DONE\n";
 589
 590         unlink($env_vars->{WINBINDD_TEST_LOG});
 591         print "STARTING WINBINDD...";
 592         $pid = fork();
 593         if ($pid == 0) {
 594                 open STDOUT, ">$env_vars->{WINBINDD_TEST_LOG}";
 595                 open STDERR, '>&STDOUT';
 596
 597                 SocketWrapper::set_default_iface($env_vars->{SOCKET_WRAPPER_DEFAULT_IFACE});
 598
 599                 $ENV{KRB5_CONFIG} = $env_vars->{KRB5_CONFIG};
 600                 $ENV{WINBINDD_SOCKET_DIR} = $env_vars->{WINBINDD_SOCKET_DIR};
 601                 $ENV{NMBD_SOCKET_DIR} = $env_vars->{NMBD_SOCKET_DIR};
 602
 603                 $ENV{NSS_WRAPPER_PASSWD} = $env_vars->{NSS_WRAPPER_PASSWD};
 604                 $ENV{NSS_WRAPPER_GROUP} = $env_vars->{NSS_WRAPPER_GROUP};
 605                 $ENV{NSS_WRAPPER_WINBIND_SO_PATH} = $env_vars->{NSS_WRAPPER_WINBIND_SO_PATH};
 606
 607                 $ENV{UID_WRAPPER} = "1";
 608
 609                 if ($winbindd ne "yes") {
 610                         $SIG{USR1} = $SIG{ALRM} = $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub {
 611                                 my $signame = shift;
 612                                 print("Skip winbindd received signal $signame");
 613                                 exit 0;
 614                         };
 615                         sleep($self->{server_maxtime});
 616                         exit 0;
 617                 }
 618
 619                 my @optargs = ("-d0");
 620                 if (defined($ENV{WINBINDD_OPTIONS})) {
 621                         @optargs = split(/ /, $ENV{WINBINDD_OPTIONS});
 622                 }
 623
 624                 $ENV{MAKE_TEST_BINARY} = Samba::bindir_path($self, "winbindd");
 625
 626                 my @preargs = (Samba::bindir_path($self, "timelimit"), $self->{server_maxtime});
 627                 if(defined($ENV{WINBINDD_VALGRIND})) {
 628                         @preargs = split(/ /, $ENV{WINBINDD_VALGRIND});
 629                 }
 630
 631                 print "Starting winbindd with config $env_vars->{SERVERCONFFILE}\n";
 632
 633                 close($env_vars->{STDIN_PIPE});
 634                 open STDIN, ">&", \*STDIN_READER or die "can't dup STDIN_READER to STDIN: $!";
 635
 636                 exec(@preargs, Samba::bindir_path($self, "winbindd"), "-F", "--no-process-group", "--stdout", "-s", $env_vars->{SERVERCONFFILE}, @optargs) or die("Unable to start winbindd: $!");
 637         }
 638         $env_vars->{WINBINDD_TL_PID} = $pid;
 639         write_pid($env_vars, "winbindd", $pid);
 640         print "DONE\n";
 641
 642         unlink($env_vars->{SMBD_TEST_LOG});
 643         print "STARTING SMBD...";
 644         $pid = fork();
 645         if ($pid == 0) {
 646                 open STDOUT, ">$env_vars->{SMBD_TEST_LOG}";
 647                 open STDERR, '>&STDOUT';
 648
 649                 SocketWrapper::set_default_iface($env_vars->{SOCKET_WRAPPER_DEFAULT_IFACE});
 650
 651                 $ENV{KRB5_CONFIG} = $env_vars->{KRB5_CONFIG};
 652                 $ENV{WINBINDD_SOCKET_DIR} = $env_vars->{WINBINDD_SOCKET_DIR};
 653                 $ENV{NMBD_SOCKET_DIR} = $env_vars->{NMBD_SOCKET_DIR};
 654
 655                 $ENV{NSS_WRAPPER_PASSWD} = $env_vars->{NSS_WRAPPER_PASSWD};
 656                 $ENV{NSS_WRAPPER_GROUP} = $env_vars->{NSS_WRAPPER_GROUP};
 657                 $ENV{NSS_WRAPPER_WINBIND_SO_PATH} = $env_vars->{NSS_WRAPPER_WINBIND_SO_PATH};
 658
 659                 $ENV{UID_WRAPPER} = "1";
 660
 661                 if ($smbd ne "yes") {
 662                         $SIG{USR1} = $SIG{ALRM} = $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub {
 663                                 my $signame = shift;
 664                                 print("Skip smbd received signal $signame");
 665                                 exit 0;
 666                         };
 667                         sleep($self->{server_maxtime});
 668                         exit 0;
 669                 }
 670
 671                 $ENV{MAKE_TEST_BINARY} = Samba::bindir_path($self, "smbd");
 672                 my @optargs = ("-d0");
 673                 if (defined($ENV{SMBD_OPTIONS})) {
 674                         @optargs = split(/ /, $ENV{SMBD_OPTIONS});
 675                 }
 676                 my @preargs = (Samba::bindir_path($self, "timelimit"), $self->{server_maxtime});
 677                 if(defined($ENV{SMBD_VALGRIND})) {
 678                         @preargs = split(/ /,$ENV{SMBD_VALGRIND});
 679                 }
 680
 681                 close($env_vars->{STDIN_PIPE});
 682                 open STDIN, ">&", \*STDIN_READER or die "can't dup STDIN_READER to STDIN: $!";
 683
 684                 exec(@preargs, Samba::bindir_path($self, "smbd"), "-F", "--no-process-group", "--log-stdout", "-s", $env_vars->{SERVERCONFFILE}, @optargs) or die("Unable to start smbd: $!");
 685         }
 686         $env_vars->{SMBD_TL_PID} = $pid;
 687         write_pid($env_vars, "smbd", $pid);
 688         print "DONE\n";
 689
 690         close(STDIN_READER);
 691
 692         return 0;
 693 }
 694
 695 sub provision($$$$$$)
 696 {
 697         my ($self, $prefix, $server, $password, $extra_options, $no_delete_prefix) = @_;
 698
 699         ##
 700         ## setup the various environment variables we need
 701         ##
 702
 703         my $swiface = Samba::get_interface($server);
 704         my %ret = ();
 705         my $server_ip = "127.0.0.$swiface";
 706         my $domain = "SAMBA-TEST";
 707
 708         my $unix_name = ($ENV{USER} or $ENV{LOGNAME} or `PATH=/usr/ucb:$ENV{PATH} whoami`);
 709         chomp $unix_name;
 710         my $unix_uid = $>;
 711         my $unix_gids_str = $);
 712         my @unix_gids = split(" ", $unix_gids_str);
 713
 714         my $prefix_abs = abs_path($prefix);
 715         my $bindir_abs = abs_path($self->{bindir});
 716         my $vfs_modulesdir_abs = ($ENV{VFSLIBDIR} or $bindir_abs);
 717
 718         my $dns_host_file = "$ENV{SELFTEST_PREFIX}/dns_host_file";
 719
 720         my @dirs = ();
 721
 722         my $shrdir="$prefix_abs/share";
 723         push(@dirs,$shrdir);
 724
 725         my $libdir="$prefix_abs/lib";
 726         push(@dirs,$libdir);
 727
 728         my $piddir="$prefix_abs/pid";
 729         push(@dirs,$piddir);
 730
 731         my $privatedir="$prefix_abs/private";
 732         push(@dirs,$privatedir);
 733
 734         my $lockdir="$prefix_abs/lockdir";
 735         push(@dirs,$lockdir);
 736
 737         my $eventlogdir="$prefix_abs/lockdir/eventlog";
 738         push(@dirs,$eventlogdir);
 739
 740         my $logdir="$prefix_abs/logs";
 741         push(@dirs,$logdir);
 742
 743         my $driver32dir="$shrdir/W32X86";
 744         push(@dirs,$driver32dir);
 745
 746         my $driver64dir="$shrdir/x64";
 747         push(@dirs,$driver64dir);
 748
 749         my $driver40dir="$shrdir/WIN40";
 750         push(@dirs,$driver40dir);
 751
 752         my $ro_shrdir="$shrdir/root-tmp";
 753         push(@dirs,$ro_shrdir);
 754
 755         my $msdfs_shrdir="$shrdir/msdfsshare";
 756         push(@dirs,$msdfs_shrdir);
 757
 758         my $msdfs_deeppath="$msdfs_shrdir/deeppath";
 759         push(@dirs,$msdfs_deeppath);
 760
 761         # this gets autocreated by winbindd
 762         my $wbsockdir="$prefix_abs/winbindd";
 763         my $wbsockprivdir="$lockdir/winbindd_privileged";
 764
 765         my $nmbdsockdir="$prefix_abs/nmbd";
 766         unlink($nmbdsockdir);
 767
 768         ##
 769         ## create the test directory layout
 770         ##
 771         die ("prefix_abs = ''") if $prefix_abs eq "";
 772         die ("prefix_abs = '/'") if $prefix_abs eq "/";
 773
 774         mkdir($prefix_abs, 0777);
 775         print "CREATE TEST ENVIRONMENT IN '$prefix'...";
 776         if (not defined($no_delete_prefix) or not $no_delete_prefix) {
 777             system("rm -rf $prefix_abs/*");
 778         }
 779         mkdir($_, 0777) foreach(@dirs);
 780
 781         ##
 782         ## create ro and msdfs share layout
 783         ##
 784
 785         chmod 0755, $ro_shrdir;
 786         my $unreadable_file = "$ro_shrdir/unreadable_file";
 787         unless (open(UNREADABLE_FILE, ">$unreadable_file")) {
 788                 warn("Unable to open $unreadable_file");
 789                 return undef;
 790         }
 791         close(UNREADABLE_FILE);
 792         chmod 0600, $unreadable_file;
 793
 794         my $msdfs_target = "$ro_shrdir/msdfs-target";
 795         unless (open(MSDFS_TARGET, ">$msdfs_target")) {
 796                 warn("Unable to open $msdfs_target");
 797                 return undef;
 798         }
 799         close(MSDFS_TARGET);
 800         chmod 0666, $msdfs_target;
 801         symlink "msdfs:$server_ip\\ro-tmp", "$msdfs_shrdir/msdfs-src1";
 802         symlink "msdfs:$server_ip\\ro-tmp", "$msdfs_shrdir/deeppath/msdfs-src2";
 803
 804         my $conffile="$libdir/server.conf";
 805
 806         my $nss_wrapper_pl = "$ENV{PERL} $self->{srcdir}/lib/nss_wrapper/nss_wrapper.pl";
 807         my $nss_wrapper_passwd = "$privatedir/passwd";
 808         my $nss_wrapper_group = "$privatedir/group";
 809
 810         my $mod_printer_pl = "$ENV{PERL} $self->{srcdir}/source3/script/tests/printing/modprinter.pl";
 811
 812         my @eventlog_list = ("dns server", "application");
 813
 814         ##
 815         ## calculate uids and gids
 816         ##
 817
 818         my ($max_uid, $max_gid);
 819         my ($uid_nobody, $uid_root, $uid_pdbtest);
 820         my ($gid_nobody, $gid_nogroup, $gid_root, $gid_domusers);
 821
 822         if ($unix_uid < 0xffff - 2) {
 823                 $max_uid = 0xffff;
 824         } else {
 825                 $max_uid = $unix_uid;
 826         }
 827
 828         $uid_root = $max_uid - 1;
 829         $uid_nobody = $max_uid - 2;
 830         $uid_pdbtest = $max_uid - 3;
 831
 832         if ($unix_gids[0] < 0xffff - 3) {
 833                 $max_gid = 0xffff;
 834         } else {
 835                 $max_gid = $unix_gids[0];
 836         }
 837
 838         $gid_nobody = $max_gid - 1;
 839         $gid_nogroup = $max_gid - 2;
 840         $gid_root = $max_gid - 3;
 841         $gid_domusers = $max_gid - 4;
 842
 843         ##
 844         ## create conffile
 845         ##
 846
 847         unless (open(CONF, ">$conffile")) {
 848                 warn("Unable to open $conffile");
 849                 return undef;
 850         }
 851         print CONF "
 852 [global]
 853         netbios name = $server
 854         interfaces = $server_ip/8
 855         bind interfaces only = yes
 856         panic action = $self->{srcdir}/selftest/gdb_backtrace %d %\$(MAKE_TEST_BINARY)
 857         smbd:suicide mode = yes
 858
 859         workgroup = $domain
 860
 861         private dir = $privatedir
 862         pid directory = $piddir
 863         lock directory = $lockdir
 864         log file = $logdir/log.\%m
 865         log level = 1
 866         debug pid = yes
 867         max log size = 0
 868
 869         state directory = $lockdir
 870         cache directory = $lockdir
 871
 872         passdb backend = tdbsam
 873
 874         time server = yes
 875
 876         add user script =               $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type passwd --action add --name %u --gid $gid_nogroup
 877         add group script =              $nss_wrapper_pl --group_path  $nss_wrapper_group  --type group  --action add --name %g
 878         add machine script =            $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type passwd --action add --name %u --gid $gid_nogroup
 879         add user to group script =      $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type member --action add --member %u --name %g --group_path $nss_wrapper_group
 880         delete user script =            $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type passwd --action delete --name %u
 881         delete group script =           $nss_wrapper_pl --group_path  $nss_wrapper_group  --type group  --action delete --name %g
 882         delete user from group script = $nss_wrapper_pl --passwd_path $nss_wrapper_passwd --type member --action delete --member %u --name %g --group_path $nss_wrapper_group
 883
 884         addprinter command =            $mod_printer_pl -a -s $conffile --
 885         deleteprinter command =         $mod_printer_pl -d -s $conffile --
 886
 887         eventlog list = application \"dns server\"
 888
 889         kernel oplocks = no
 890         kernel change notify = no
 891
 892         syslog = no
 893         printing = bsd
 894         printcap name = /dev/null
 895
 896         winbindd:socket dir = $wbsockdir
 897         nmbd:socket dir = $nmbdsockdir
 898         idmap config * : range = 100000-200000
 899         winbind enum users = yes
 900         winbind enum groups = yes
 901
 902 #       min receivefile size = 4000
 903
 904         server max protocol = SMB3
 905         read only = no
 906         server signing = auto
 907
 908         smbd:sharedelay = 100000
 909         smbd:writetimeupdatedelay = 500000
 910         map hidden = no
 911         map system = no
 912         map readonly = no
 913         store dos attributes = yes
 914         create mask = 755
 915         dos filemode = yes
 916         vfs objects = $vfs_modulesdir_abs/acl_xattr.so $vfs_modulesdir_abs/fake_acls.so $vfs_modulesdir_abs/xattr_tdb.so $vfs_modulesdir_abs/streams_depot.so
 917
 918         printing = vlp
 919         print command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb print %p %s
 920         lpq command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb lpq %p
 921         lp rm command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb lprm %p %j
 922         lp pause command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb lppause %p %j
 923         lp resume command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb lpresume %p %j
 924         queue pause command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb queuepause %p
 925         queue resume command = $bindir_abs/vlp tdbfile=$lockdir/vlp.tdb queueresume %p
 926         lpq cache time = 0
 927
 928         ncalrpc dir = $prefix_abs/ncalrpc
 929         resolv:host file = $dns_host_file
 930
 931         # The samba3.blackbox.smbclient_s3 test uses this to test that
 932         # sending messages works, and that the %m sub works.
 933         message command = mv %s $shrdir/message.%m
 934
 935         # Begin extra options
 936         $extra_options
 937         # End extra options
 938
 939         #Include user defined custom parameters if set
 940 ";
 941
 942         if (defined($ENV{INCLUDE_CUSTOM_CONF})) {
 943                 print CONF "\t$ENV{INCLUDE_CUSTOM_CONF}\n";
 944         }
 945
 946         print CONF "
 947 [tmp]
 948         path = $shrdir
 949         comment = smb username is [%U]
 950 [tmpenc]
 951         path = $shrdir
 952         comment = encrypt smb username is [%U]
 953         smb encrypt = required
 954 [tmpguest]
 955         path = $shrdir
 956         guest ok = yes
 957 [guestonly]
 958         path = $shrdir
 959         guest only = yes
 960         guest ok = yes
 961 [forceuser]
 962         path = $shrdir
 963         force user = $unix_name
 964         guest ok = yes
 965 [forcegroup]
 966         path = $shrdir
 967         force group = nogroup
 968         guest ok = yes
 969 [ro-tmp]
 970         path = $ro_shrdir
 971         guest ok = yes
 972 [msdfs-share]
 973         path = $msdfs_shrdir
 974         msdfs root = yes
 975         guest ok = yes
 976 [hideunread]
 977         copy = tmp
 978         hide unreadable = yes
 979 [tmpcase]
 980         copy = tmp
 981         case sensitive = yes
 982 [hideunwrite]
 983         copy = tmp
 984         hide unwriteable files = yes
 985 [print1]
 986         copy = tmp
 987         printable = yes
 988
 989 [print2]
 990         copy = print1
 991 [print3]
 992         copy = print1
 993 [lp]
 994         copy = print1
 995 [xcopy_share]
 996         path = $shrdir
 997         comment = smb username is [%U]
 998         create mask = 777
 999         force create mode = 777
1000 [posix_share]
1001         path = $shrdir
1002         comment = smb username is [%U]
1003         create mask = 0777
1004         force create mode = 0
1005         directory mask = 0777
1006         force directory mode = 0
1007         vfs objects = $vfs_modulesdir_abs/xattr_tdb.so
1008
1009 [print\$]
1010         copy = tmp
1011         ";
1012         close(CONF);
1013
1014         ##
1015         ## create a test account
1016         ##
1017
1018         unless (open(PASSWD, ">$nss_wrapper_passwd")) {
1019            warn("Unable to open $nss_wrapper_passwd");
1020            return undef;
1021         }
1022         print PASSWD "nobody:x:$uid_nobody:$gid_nobody:nobody gecos:$prefix_abs:/bin/false
1023 $unix_name:x:$unix_uid:$unix_gids[0]:$unix_name gecos:$prefix_abs:/bin/false
1024 pdbtest:x:$uid_pdbtest:$gid_nogroup:pdbtest gecos:$prefix_abs:/bin/false
1025 ";
1026         if ($unix_uid != 0) {
1027                 print PASSWD "root:x:$uid_root:$gid_root:root gecos:$prefix_abs:/bin/false";
1028         }
1029         close(PASSWD);
1030
1031         unless (open(GROUP, ">$nss_wrapper_group")) {
1032              warn("Unable to open $nss_wrapper_group");
1033              return undef;
1034         }
1035         print GROUP "nobody:x:$gid_nobody:
1036 nogroup:x:$gid_nogroup:nobody
1037 $unix_name-group:x:$unix_gids[0]:
1038 domusers:X:$gid_domusers:
1039 ";
1040         if ($unix_gids[0] != 0) {
1041                 print GROUP "root:x:$gid_root:";
1042         }
1043
1044         close(GROUP);
1045
1046         foreach my $evlog (@eventlog_list) {
1047                 my $evlogtdb = "$eventlogdir/$evlog.tdb";
1048                 open(EVENTLOG, ">$evlogtdb") or die("Unable to open $evlogtdb");
1049                 close(EVENTLOG);
1050         }
1051
1052         $ENV{NSS_WRAPPER_PASSWD} = $nss_wrapper_passwd;
1053         $ENV{NSS_WRAPPER_GROUP} = $nss_wrapper_group;
1054
1055         my $cmd = Samba::bindir_path($self, "smbpasswd")." -c $conffile -L -s -a $unix_name > /dev/null";
1056         unless (open(PWD, "|$cmd")) {
1057              warn("Unable to set password for test account\n$cmd");
1058              return undef;
1059         }
1060         print PWD "$password\n$password\n";
1061         unless (close(PWD)) {
1062              warn("Unable to set password for test account\n$cmd");
1063              return undef;
1064         }
1065         print "DONE\n";
1066
1067         open(HOSTS, ">>$ENV{SELFTEST_PREFIX}/dns_host_file") or die("Unable to open $ENV{SELFTEST_PREFIX}/dns_host_file");
1068         print HOSTS "A $server. $server_ip
1069 ";
1070         close(HOSTS);
1071
1072         $ret{SERVER_IP} = $server_ip;
1073         $ret{NMBD_TEST_LOG} = "$prefix/nmbd_test.log";
1074         $ret{NMBD_TEST_LOG_POS} = 0;
1075         $ret{WINBINDD_TEST_LOG} = "$prefix/winbindd_test.log";
1076         $ret{WINBINDD_TEST_LOG_POS} = 0;
1077         $ret{SMBD_TEST_LOG} = "$prefix/smbd_test.log";
1078         $ret{SMBD_TEST_LOG_POS} = 0;
1079         $ret{SERVERCONFFILE} = $conffile;
1080         $ret{CONFIGURATION} ="-s $conffile";
1081         $ret{SERVER} = $server;
1082         $ret{USERNAME} = $unix_name;
1083         $ret{USERID} = $unix_uid;
1084         $ret{DOMAIN} = $domain;
1085         $ret{NETBIOSNAME} = $server;
1086         $ret{PASSWORD} = $password;
1087         $ret{PIDDIR} = $piddir;
1088         $ret{WINBINDD_SOCKET_DIR} = $wbsockdir;
1089         $ret{WINBINDD_PRIV_PIPE_DIR} = $wbsockprivdir;
1090         $ret{NMBD_SOCKET_DIR} = $nmbdsockdir;
1091         $ret{SOCKET_WRAPPER_DEFAULT_IFACE} = $swiface;
1092         $ret{NSS_WRAPPER_PASSWD} = $nss_wrapper_passwd;
1093         $ret{NSS_WRAPPER_GROUP} = $nss_wrapper_group;
1094         $ret{NSS_WRAPPER_WINBIND_SO_PATH} = $ENV{NSS_WRAPPER_WINBIND_SO_PATH};
1095         if (not defined($ret{NSS_WRAPPER_WINBIND_SO_PATH})) {
1096                 $ret{NSS_WRAPPER_WINBIND_SO_PATH} = Samba::bindir_path($self, "default/nsswitch/libnss-winbind.so");
1097         }
1098         $ret{LOCAL_PATH} = "$shrdir";
1099
1100         return \%ret;
1101 }
1102
1103 sub wait_for_start($$)
1104 {
1105         my ($self, $envvars) = @_;
1106
1107         # give time for nbt server to register its names
1108         print "delaying for nbt name registration\n";
1109         sleep(10);
1110         # This will return quickly when things are up, but be slow if we need to wait for (eg) SSL init
1111         my $nmblookup = Samba::bindir_path($self, "nmblookup3");
1112         system("$nmblookup $envvars->{CONFIGURATION} -U $envvars->{SERVER_IP} __SAMBA__");
1113         system("$nmblookup $envvars->{CONFIGURATION} __SAMBA__");
1114         system("$nmblookup $envvars->{CONFIGURATION} -U 127.255.255.255 __SAMBA__");
1115         system("$nmblookup $envvars->{CONFIGURATION} -U $envvars->{SERVER_IP} $envvars->{SERVER}");
1116         system("$nmblookup $envvars->{CONFIGURATION} $envvars->{SERVER}");
1117
1118         # make sure smbd is also up set
1119         print "wait for smbd\n";
1120
1121         my $count = 0;
1122         my $ret;
1123         do {
1124             $ret = system(Samba::bindir_path($self, "smbclient3") ." $envvars->{CONFIGURATION} -L $envvars->{SERVER} -U% -p 139");
1125             if ($ret != 0) {
1126                 sleep(2);
1127             }
1128             $count++
1129         } while ($ret != 0 && $count < 10);
1130         if ($count == 10) {
1131             print "SMBD failed to start up in a reasonable time (20sec)\n";
1132             teardown_env($self, $envvars);
1133             return 0;
1134         }
1135         # Ensure we have domain users mapped.
1136         $ret = system(Samba::bindir_path($self, "net") ." $envvars->{CONFIGURATION} groupmap add rid=513 unixgroup=domusers type=domain");
1137         if ($ret != 0) {
1138             return 1;
1139         }
1140
1141         print $self->getlog_env($envvars);
1142
1143         return 1;
1144 }
1145
1146 1;