source4/heimdal/lib/com_err/parse.y

   1 %{
   2 /*
   3  * Copyright (c) 1998 - 2000 Kungliga Tekniska Högskolan
   4  * (Royal Institute of Technology, Stockholm, Sweden).
   5  * All rights reserved.
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  *
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  *
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  *
  18  * 3. Neither the name of the Institute nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE INSTITUTE AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE INSTITUTE OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  */
  34
  35 #include "compile_et.h"
  36 #include "lex.h"
  37
  38 void yyerror (char *s);
  39 static long name2number(const char *str);
  40
  41 extern char *yytext;
  42
  43 /* This is for bison */
  44
  45 #if !defined(alloca) && !defined(HAVE_ALLOCA)
  46 #define alloca(x) malloc(x)
  47 #endif
  48
  49 #define YYMALLOC malloc
  50 #define YYFREE free
  51
  52 %}
  53
  54 %union {
  55   char *string;
  56   int number;
  57 }
  58
  59 %token ET INDEX PREFIX EC ID END
  60 %token <string> STRING
  61 %token <number> NUMBER
  62
  63 %%
  64
  65 file            : /* */
  66                 | header statements
  67                 ;
  68
  69 header          : id et
  70                 | et
  71                 ;
  72
  73 id              : ID STRING
  74                 {
  75                     id_str = $2;
  76                 }
  77                 ;
  78
  79 et              : ET STRING
  80                 {
  81                     base_id = name2number($2);
  82                     strlcpy(name, $2, sizeof(name));
  83                     free($2);
  84                 }
  85                 | ET STRING STRING
  86                 {
  87                     base_id = name2number($2);
  88                     strlcpy(name, $3, sizeof(name));
  89                     free($2);
  90                     free($3);
  91                 }
  92                 ;
  93
  94 statements      : statement
  95                 | statements statement
  96                 ;
  97
  98 statement       : INDEX NUMBER
  99                 {
 100                         number = $2;
 101                 }
 102                 | PREFIX STRING
 103                 {
 104                     free(prefix);
 105                     asprintf (&prefix, "%s_", $2);
 106                     if (prefix == NULL)
 107                         errx(1, "malloc");
 108                     free($2);
 109                 }
 110                 | PREFIX
 111                 {
 112                     prefix = realloc(prefix, 1);
 113                     if (prefix == NULL)
 114                         errx(1, "malloc");
 115                     *prefix = '\0';
 116                 }
 117                 | EC STRING ',' STRING
 118                 {
 119                     struct error_code *ec = malloc(sizeof(*ec));
 120
 121                     if (ec == NULL)
 122                         errx(1, "malloc");
 123
 124                     ec->next = NULL;
 125                     ec->number = number;
 126                     if(prefix && *prefix != '\0') {
 127                         asprintf (&ec->name, "%s%s", prefix, $2);
 128                         if (ec->name == NULL)
 129                             errx(1, "malloc");
 130                         free($2);
 131                     } else
 132                         ec->name = $2;
 133                     ec->string = $4;
 134                     APPEND(codes, ec);
 135                     number++;
 136                 }
 137                 | END
 138                 {
 139                         YYACCEPT;
 140                 }
 141                 ;
 142
 143 %%
 144
 145 static long
 146 name2number(const char *str)
 147 {
 148     const char *p;
 149     long num = 0;
 150     const char *x = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 151         "abcdefghijklmnopqrstuvwxyz0123456789_";
 152     if(strlen(str) > 4) {
 153         yyerror("table name too long");
 154         return 0;
 155     }
 156     for(p = str; *p; p++){
 157         char *q = strchr(x, *p);
 158         if(q == NULL) {
 159             yyerror("invalid character in table name");
 160             return 0;
 161         }
 162         num = (num << 6) + (q - x) + 1;
 163     }
 164     num <<= 8;
 165     if(num > 0x7fffffff)
 166         num = -(0xffffffff - num + 1);
 167     return num;
 168 }
 169
 170 void
 171 yyerror (char *s)
 172 {
 173      lex_error_message ("%s\n", s);
 174 }