source/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(include/includes.h)
   3 AC_CONFIG_HEADER(include/config.h)
   4
   5 dnl Unique-to-Samba variables we'll be playing with.
   6 AC_SUBST(SHELL)
   7 AC_SUBST(MPROGS)
   8 AC_SUBST(LDSHFLAGS)
   9 AC_SUBST(HOST_OS)
  10 AC_SUBST(WRAP)
  11 AC_SUBST(WRAP32)
  12 AC_SUBST(PICFLAG)
  13 dnl Checks for programs.
  14 AC_PROG_CC
  15 AC_PROG_INSTALL
  16 AC_PROG_AWK
  17
  18 AC_CANONICAL_SYSTEM
  19 AC_VALIDATE_CACHE_SYSTEM_TYPE
  20 SAMBA_MAINTAINER_MODE
  21
  22 AC_INLINE
  23 AC_HEADER_STDC
  24 AC_HEADER_DIRENT
  25 AC_HEADER_TIME
  26 AC_HEADER_SYS_WAIT
  27 AC_CHECK_HEADERS(sys/fcntl.h sys/select.h fcntl.h sys/time.h sys/unistd.h)
  28 AC_CHECK_HEADERS(unistd.h utime.h grp.h sys/id.h limits.h memory.h net/if.h)
  29 AC_CHECK_HEADERS(compat.h rpc/rpc.h rpc/types.h rpc/xdr.h rpc/auth.h rpc/clnt.h)
  30 AC_CHECK_HEADERS(rpcsvc/yp_prot.h rpcsvc/ypclnt.h sys/param.h ctype.h )
  31 AC_CHECK_HEADERS(sys/wait.h sys/resource.h sys/ioctl.h sys/mode.h)
  32 AC_CHECK_HEADERS(sys/filio.h string.h strings.h stdlib.h sys/socket.h)
  33 AC_CHECK_HEADERS(sys/mount.h sys/vfs.h sys/fs/s5param.h sys/filsys.h termios.h)
  34 AC_CHECK_HEADERS(sys/statfs.h sys/dustat.h sys/statvfs.h stdarg.h sys/sockio.h)
  35 AC_CHECK_HEADERS(shadow.h netinet/tcp.h sys/security.h security/pam_appl.h)
  36 AC_CHECK_HEADERS(stropts.h poll.h readline.h history.h readline/readline.h)
  37 AC_CHECK_HEADERS(readline/history.h sys/capability.h syscall.h sys/syscall.h)
  38 AC_CHECK_HEADERS(sys/acl.h sys/cdefs.h)
  39
  40 AC_CHECK_SIZEOF(int,cross)
  41 AC_CHECK_SIZEOF(long,cross)
  42 AC_CHECK_SIZEOF(short,cross)
  43
  44 AC_C_CONST
  45 AC_C_INLINE
  46 AC_C_BIGENDIAN
  47 AC_C_CHAR_UNSIGNED
  48
  49 AC_TYPE_SIGNAL
  50 AC_TYPE_UID_T
  51 AC_TYPE_MODE_T
  52 AC_TYPE_OFF_T
  53 AC_TYPE_SIZE_T
  54 AC_TYPE_PID_T
  55 AC_STRUCT_ST_RDEV
  56 AC_DIRENT_D_OFF
  57 AC_CHECK_TYPE(ino_t,unsigned)
  58 AC_CHECK_TYPE(loff_t,off_t)
  59 AC_CHECK_TYPE(offset_t,loff_t)
  60 AC_CHECK_TYPE(ssize_t, int)
  61
  62 AC_CACHE_CHECK([for errno in errno.h],samba_cv_errno, [
  63     AC_TRY_COMPILE([#include <errno.h>],[int i = errno],
  64         samba_cv_errno=yes,samba_cv_have_errno_decl=no)])
  65 if test x"$samba_cv_errno" = x"yes"; then
  66    AC_DEFINE(HAVE_ERRNO_DECL)
  67 fi
  68
  69 # stupid glibc has the functions but no declaration. grrrr.
  70 AC_CACHE_CHECK([for setresuid declaration],samba_cv_have_setresuid_decl,[
  71     AC_TRY_COMPILE([#include <unistd.h>],[int i = (int)setresuid],
  72         samba_cv_have_setresuid_decl=yes,samba_cv_have_setresuid_decl=no)])
  73 if test x"$samba_cv_have_setresuid_decl" = x"yes"; then
  74     AC_DEFINE(HAVE_SETRESUID_DECL)
  75 fi
  76
  77 # stupid glibc has the functions but no declaration. grrrr.
  78 AC_CACHE_CHECK([for crypt declaration],samba_cv_have_crypt_decl,[
  79     AC_TRY_COMPILE([#include <unistd.h>],[int i = (int)crypt],
  80         samba_cv_have_crypt_decl=yes,samba_cv_have_crypt_decl=no)])
  81 if test x"$samba_cv_have_crypt_decl" = x"yes"; then
  82     AC_DEFINE(HAVE_CRYPT_DECL)
  83 fi
  84
  85 # and glibc has setresuid under linux but the function does
  86 # nothing until kernel 2.1.44! very dumb.
  87 AC_CACHE_CHECK([for real setresuid],samba_cv_have_setresuid,[
  88     AC_TRY_RUN([#include <errno.h>
  89 main() { setresuid(1,1,1); setresuid(2,2,2); exit(errno==EPERM?0:1);}],
  90         samba_cv_have_setresuid=yes,samba_cv_have_setresuid=no,samba_cv_have_setresuid=cross)])
  91 if test x"$samba_cv_have_setresuid" = x"yes"; then
  92     AC_DEFINE(HAVE_SETRESUID)
  93 fi
  94
  95 AC_FUNC_MEMCMP
  96
  97 ###############################################
  98 # test for where we get crypt() from
  99 AC_CHECK_FUNCS(crypt)
 100 if test x"$ac_cv_func_crypt" = x"no"; then
 101     AC_CHECK_LIB(crypt, crypt, [LIBS="$LIBS -lcrypt";
 102         AC_DEFINE(HAVE_CRYPT)])
 103 fi
 104
 105
 106 ###############################################
 107 # test for where we get pam_authenticate() from
 108 # might need libdl for this to work
 109 if test "$ac_cv_header_security_pam_appl_h" = "yes"; then
 110   AC_CHECK_LIB(dl,main)
 111 fi
 112 AC_CHECK_FUNCS(pam_authenticate)
 113 if test x"$ac_cv_func_pam_authenticate" = x"no"; then
 114     AC_CHECK_LIB(pam, pam_authenticate, [LIBS="$LIBS -lpam"
 115         AC_DEFINE(HAVE_PAM_AUTHENTICATE)])
 116 fi
 117
 118
 119 ###############################################
 120 # test for where we get readline() from
 121 if test "$ac_cv_header_readline_h" = "yes" ||
 122    test "$ac_cv_header_readline_readline_h" = "yes"; then
 123   AC_CHECK_LIB(readline,readline)
 124 fi
 125
 126
 127 # The following test taken from the cvs sources
 128 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
 129 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
 130 # libsocket.so which has a bad implementation of gethostbyname (it
 131 # only looks in /etc/hosts), so we only look for -lsocket if we need
 132 # it.
 133 AC_CHECK_FUNCS(connect)
 134 if test x"$ac_cv_func_connect" = x"no"; then
 135     case "$LIBS" in
 136     *-lnsl*) ;;
 137     *) AC_CHECK_LIB(nsl_s, printf) ;;
 138     esac
 139     case "$LIBS" in
 140     *-lnsl*) ;;
 141     *) AC_CHECK_LIB(nsl, printf) ;;
 142     esac
 143     case "$LIBS" in
 144     *-lsocket*) ;;
 145     *) AC_CHECK_LIB(socket, connect) ;;
 146     esac
 147     case "$LIBS" in
 148     *-linet*) ;;
 149     *) AC_CHECK_LIB(inet, connect) ;;
 150     esac
 151     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
 152     dnl has been cached.
 153     if test x"$ac_cv_lib_socket_connect" = x"yes" ||
 154        test x"$ac_cv_lib_inet_connect" = x"yes"; then
 155         # ac_cv_func_connect=yes
 156         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
 157         AC_DEFINE(HAVE_CONNECT)
 158     fi
 159 fi
 160
 161
 162 AC_CHECK_FUNCS(waitpid getcwd strdup strerror chown chmod chroot)
 163 AC_CHECK_FUNCS(fstat strchr utime utimes getrlimit fsync execl bzero memset)
 164 AC_CHECK_FUNCS(memmove vsnprintf snprintf setsid glob strpbrk pipe crypt16 getauthuid)
 165 AC_CHECK_FUNCS(strftime sigprocmask sigblock sigaction innetgr)
 166 AC_CHECK_FUNCS(initgroups select rdchk getgrnam pathconf putprpwnam)
 167 AC_CHECK_FUNCS(setuidx setgroups mktime rename ftruncate stat64 fstat64 lstat64)
 168 AC_CHECK_FUNCS(set_auth_parameters atexit grantpt getspnam dup2 lseek64 ftruncate64)
 169 AC_CHECK_FUNCS(fseek64 ftell64 bigcrypt getprpwnam setluid yp_get_default_domain getpwanam)
 170 AC_CHECK_FUNCS(srandom random srand rand setenv)
 171 # syscall() is needed for smbwrapper.
 172 AC_CHECK_FUNCS(syscall)
 173
 174 AC_CHECK_FUNCS(_dup _dup2 _opendir _readdir _seekdir _telldir _closedir)
 175 AC_CHECK_FUNCS(__dup __dup2 __opendir __readdir __seekdir __telldir __closedir)
 176 AC_CHECK_FUNCS(__getcwd _getcwd)
 177 AC_CHECK_FUNCS(__xstat __fxstat __lxstat)
 178 AC_CHECK_FUNCS(_stat _lstat _fstat __stat __lstat __fstat)
 179 AC_CHECK_FUNCS(_acl __acl _facl __facl _open __open _chdir __chdir)
 180 AC_CHECK_FUNCS(_close __close _fchdir __fchdir _fcntl __fcntl)
 181 AC_CHECK_FUNCS(getdents _getdents __getdents _lseek __lseek _read __read)
 182 AC_CHECK_FUNCS(_write __write _fork __fork)
 183 AC_CHECK_FUNCS(_stat64 __stat64 _fstat64 __fstat64 _lstat64 __lstat64)
 184 AC_CHECK_FUNCS(__sys_llseek llseek _llseek __llseek readdir64 _readdir64 __readdir64)
 185 AC_CHECK_FUNCS(pread _pread __pread pread64 _pread64 __pread64)
 186 AC_CHECK_FUNCS(pwrite _pwrite __pwrite pwrite64 _pwrite64 __pwrite64)
 187 AC_CHECK_FUNCS(open64 _open64 __open64 creat64)
 188
 189 # this bit needs to be modified for each OS that is suported by
 190 # smbwrapper. You need to specify how to created a shared library and
 191 # how to compile C code to produce PIC object files
 192
 193 # these are the defaults, good for lots of systems
 194 HOST_OS="$host_os"
 195 LDSHFLAGS="-shared"
 196
 197 # and these are for particular systems
 198 case "$host_os" in
 199                 *linux*)   AC_DEFINE(LINUX);;
 200                 *solaris*) AC_DEFINE(SUNOS5)
 201                                         LDSHFLAGS="-G"
 202                 ;;
 203                 *sunos*) AC_DEFINE(SUNOS4)
 204                                         LDSHFLAGS=""
 205                 ;;
 206                 *bsd*) LDSHFLAGS="-shared -Bshareable"
 207                 ;;
 208                 *irix*) AC_DEFINE(IRIX)
 209                         WRAP32=bin/smbwrapper.32.so
 210                 ;;
 211                 *aix*) AC_DEFINE(AIX);;
 212                 *hpux*) AC_DEFINE(HPUX);;
 213                 *qnx*) AC_DEFINE(QNX);;
 214                 *osf*) AC_DEFINE(OSF1);;
 215                 *sco*) AC_DEFINE(SCO);;
 216                 *next2*) AC_DEFINE(NEXT2);;
 217                 *dgux*) AC_CHECK_PROG( ROFF, groff, [groff -etpsR -Tascii -man]);;
 218                 *sysv4.2*) AC_CHECK_LIB(resolv, strcasecmp);;
 219 esac
 220
 221 # try to work out how to produce pic code with this compiler
 222 PICFLAG=""
 223 AC_PROG_CC_FLAG(fpic)
 224 if test $ac_cv_prog_cc_fpic = yes; then
 225    PICFLAG="-fpic";
 226 fi
 227 if test x$PICFLAG = x; then
 228   AC_PROG_CC_FLAG(Kpic)
 229   if test $ac_cv_prog_cc_Kpic = yes; then
 230     PICFLAG="-Kpic";
 231   fi
 232 fi
 233 if test x$PICFLAG = x; then
 234   AC_PROG_CC_FLAG(KPIC)
 235   if test $ac_cv_prog_cc_KPIC = yes; then
 236     PICFLAG="-KPIC";
 237   fi
 238 fi
 239
 240 WRAP="bin/smbsh bin/smbwrapper.so"
 241
 242 # Conditions under which smbwrapper should not be built.
 243
 244 if test x$PICFLAG = x; then
 245    echo No support for PIC code - disabling smbwrapper and smbsh
 246    WRAP=""
 247 elif test x$ac_cv_func_syscall = xno; then
 248    AC_MSG_RESULT([No syscall() -- disabling smbwrapper and smbsh])
 249    WRAP=""
 250 fi
 251
 252 ################
 253
 254 AC_CACHE_CHECK([for long long],samba_cv_have_longlong,[
 255 AC_TRY_RUN([#include <stdio.h>
 256 main() { long long x = 1000000; x *= x; exit(((x/1000000) == 1000000)? 0: 1); }],
 257 samba_cv_have_longlong=yes,samba_cv_have_longlong=no,samba_cv_have_longlong=cross)])
 258 if test x"$samba_cv_have_longlong" = x"yes"; then
 259     AC_DEFINE(HAVE_LONGLONG)
 260 fi
 261
 262 AC_CACHE_CHECK([for 64 bit off_t],samba_cv_SIZEOF_OFF_T,[
 263 AC_TRY_RUN([#include <stdio.h>
 264 #include <sys/stat.h>
 265 main() { exit((sizeof(off_t) == 8) ? 0 : 1); }],
 266 samba_cv_SIZEOF_OFF_T=yes,samba_cv_SIZEOF_OFF_T=no,samba_cv_SIZEOF_OFF_T=cross)])
 267 if test x"$samba_cv_SIZEOF_OFF_T" = x"yes"; then
 268     AC_DEFINE(SIZEOF_OFF_T,8)
 269 fi
 270
 271 AC_CACHE_CHECK([for off64_t],samba_cv_HAVE_OFF64_T,[
 272 AC_TRY_RUN([#include <stdio.h>
 273 #include <sys/stat.h>
 274 main() { struct stat64 st; off64_t s; if (sizeof(off_t) == sizeof(off64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }],
 275 samba_cv_HAVE_OFF64_T=yes,samba_cv_HAVE_OFF64_T=no,samba_cv_HAVE_OFF64_T=cross)])
 276 if test x"$samba_cv_HAVE_OFF64_T" = x"yes"; then
 277     AC_DEFINE(HAVE_OFF64_T)
 278 fi
 279
 280 AC_CACHE_CHECK([for 64 bit ino_t],samba_cv_SIZEOF_INO_T,[
 281 AC_TRY_RUN([#include <stdio.h>
 282 #include <sys/stat.h>
 283 main() { exit((sizeof(ino_t) == 8) ? 0 : 1); }],
 284 samba_cv_SIZEOF_INO_T=yes,samba_cv_SIZEOF_INO_T=no,samba_cv_SIZEOF_INO_T=cross)])
 285 if test x"$samba_cv_SIZEOF_INO_T" = x"yes"; then
 286     AC_DEFINE(SIZEOF_INO_T,8)
 287 fi
 288
 289 AC_CACHE_CHECK([for ino64_t],samba_cv_HAVE_INO64_T,[
 290 AC_TRY_RUN([#include <stdio.h>
 291 #include <sys/stat.h>
 292 main() { struct stat64 st; ino64_t s; if (sizeof(ino_t) == sizeof(ino64_t)) exit(1); exit((lstat64("/dev/null", &st)==0)?0:1); }],
 293 samba_cv_HAVE_INO64_T=yes,samba_cv_HAVE_INO64_T=no,samba_cv_HAVE_INO64_T=cross)])
 294 if test x"$samba_cv_HAVE_INO64_T" = x"yes"; then
 295     AC_DEFINE(HAVE_INO64_T)
 296 fi
 297
 298 AC_CACHE_CHECK([for union semun],samba_cv_HAVE_UNION_SEMUN,[
 299 AC_TRY_RUN([
 300 #include <sys/types.h>
 301 #include <sys/ipc.h>
 302 #include <sys/sem.h>
 303 main() { union semun ss; exit(0); }],
 304 samba_cv_HAVE_UNION_SEMUN=yes,samba_cv_HAVE_UNION_SEMUN=no,samba_cv_HAVE_UNION_SEMUN=cross)])
 305 if test x"$samba_cv_HAVE_UNION_SEMUN" = x"yes"; then
 306     AC_DEFINE(HAVE_UNION_SEMUN)
 307 fi
 308
 309 AC_CACHE_CHECK([for unsigned char],samba_cv_HAVE_UNSIGNED_CHAR,[
 310 AC_TRY_RUN([#include <stdio.h>
 311 main() { char c; c=250; exit((c > 0)?0:1); }],
 312 samba_cv_HAVE_UNSIGNED_CHAR=yes,samba_cv_HAVE_UNSIGNED_CHAR=no,samba_cv_HAVE_UNSIGNED_CHAR=cross)])
 313 if test x"$samba_cv_HAVE_UNSIGNED_CHAR" = x"yes"; then
 314     AC_DEFINE(HAVE_UNSIGNED_CHAR)
 315 fi
 316
 317 AC_CACHE_CHECK([for sin_len in sock],samba_cv_HAVE_SOCK_SIN_LEN,[
 318 AC_TRY_COMPILE([#include <sys/types.h>
 319 #include <sys/socket.h>
 320 #include <netinet/in.h>],
 321 [struct sockaddr_in sock; sock.sin_len = sizeof(sock);],
 322 samba_cv_HAVE_SOCK_SIN_LEN=yes,samba_cv_HAVE_SOCK_SIN_LEN=no)])
 323 if test x"$samba_cv_HAVE_SOCK_SIN_LEN" = x"yes"; then
 324     AC_DEFINE(HAVE_SOCK_SIN_LEN)
 325 fi
 326
 327 AC_CACHE_CHECK([whether seekdir returns void],samba_cv_SEEKDIR_RETURNS_VOID,[
 328 AC_TRY_COMPILE([#include <sys/types.h>
 329 #include <dirent.h>
 330 void seekdir(DIR *d, long loc) { return; }],[return 0;],
 331 samba_cv_SEEKDIR_RETURNS_VOID=yes,samba_cv_SEEKDIR_RETURNS_VOID=no)])
 332 if test x"$samba_cv_SEEKDIR_RETURNS_VOID" = x"yes"; then
 333     AC_DEFINE(SEEKDIR_RETURNS_VOID)
 334 fi
 335
 336 AC_CACHE_CHECK([for __FILE__ macro],samba_cv_HAVE_FILE_MACRO,[
 337 AC_TRY_COMPILE([#include <stdio.h>], [printf("%s\n", __FILE__);],
 338 samba_cv_HAVE_FILE_MACRO=yes,samba_cv_HAVE_FILE_MACRO=no)])
 339 if test x"$samba_cv_HAVE_FILE_MACRO" = x"yes"; then
 340     AC_DEFINE(HAVE_FILE_MACRO)
 341 fi
 342
 343 AC_CACHE_CHECK([for __FUNCTION__ macro],samba_cv_HAVE_FUNCTION_MACRO,[
 344 AC_TRY_COMPILE([#include <stdio.h>], [printf("%s\n", __FUNCTION__);],
 345 samba_cv_HAVE_FUNCTION_MACRO=yes,samba_cv_HAVE_FUNCTION_MACRO=no)])
 346 if test x"$samba_cv_HAVE_FUNCTION_MACRO" = x"yes"; then
 347     AC_DEFINE(HAVE_FUNCTION_MACRO)
 348 fi
 349
 350 AC_CACHE_CHECK([if gettimeofday takes tz argument],samba_cv_HAVE_GETTIMEOFDAY_TZ,[
 351 AC_TRY_RUN([
 352 #include <sys/time.h>
 353 #include <unistd.h>
 354 main() { struct timeval tv; exit(gettimeofday(&tv, NULL));}],
 355            samba_cv_HAVE_GETTIMEOFDAY_TZ=yes,samba_cv_HAVE_GETTIMEOFDAY_TZ=no,samba_cv_HAVE_GETTIMEOFDAY_TZ=cross)])
 356 if test x"$samba_cv_HAVE_GETTIMEOFDAY_TZ" = x"yes"; then
 357     AC_DEFINE(HAVE_GETTIMEOFDAY_TZ)
 358 fi
 359
 360
 361 AC_CACHE_CHECK([for broken readdir],samba_cv_HAVE_BROKEN_READDIR,[
 362 AC_TRY_RUN([#include <sys/types.h>
 363 #include <dirent.h>
 364 main() { struct dirent *di; DIR *d = opendir("."); di = readdir(d);
 365 if (di && di->d_name[-2] == '.' && di->d_name[-1] == 0 &&
 366 di->d_name[0] == 0) exit(0); exit(1);} ],
 367 samba_cv_HAVE_BROKEN_READDIR=yes,samba_cv_HAVE_BROKEN_READDIR=no,samba_cv_HAVE_BROKEN_READDIR=cross)])
 368 if test x"$samba_cv_HAVE_BROKEN_READDIR" = x"yes"; then
 369     AC_DEFINE(HAVE_BROKEN_READDIR)
 370 fi
 371
 372 AC_CACHE_CHECK([for utimbuf],samba_cv_HAVE_UTIMBUF,[
 373 AC_TRY_COMPILE([#include <sys/types.h>
 374 #include <utime.h>],
 375 [struct utimbuf tbuf;  tbuf.actime = 0; tbuf.modtime = 1; exit(utime("foo.c",&tbuf));],
 376 samba_cv_HAVE_UTIMBUF=yes,samba_cv_HAVE_UTIMBUF=no,samba_cv_HAVE_UTIMBUF=cross)])
 377 if test x"$samba_cv_HAVE_UTIMBUF" = x"yes"; then
 378     AC_DEFINE(HAVE_UTIMBUF)
 379 fi
 380
 381 AC_CACHE_CHECK([for kernel oplock type definitions],samba_cv_HAVE_KERNEL_OPLOCKS,[
 382 AC_TRY_COMPILE([#include <sys/types.h>
 383 #include <fcntl.h>],
 384 [oplock_stat_t t; t.os_state = OP_REVOKE; t.os_dev = 1; t.os_ino = 1;],
 385 samba_cv_HAVE_KERNEL_OPLOCKS=yes,samba_cv_HAVE_KERNEL_OPLOCKS=no)])
 386 if test x"$samba_cv_HAVE_KERNEL_OPLOCKS" = x"yes"; then
 387     AC_DEFINE(HAVE_KERNEL_OPLOCKS)
 388 fi
 389
 390 AC_CACHE_CHECK([for irix specific capabilities],samba_cv_HAVE_IRIX_SPECIFIC_CAPABILITIES,[
 391 AC_TRY_RUN([#include <sys/types.h>
 392 #include <sys/capability.h>
 393 main() {
 394  cap_t cap;
 395  if ((cap = cap_get_proc()) == NULL)
 396    exit(1);
 397  cap->cap_effective |= CAP_NETWORK_MGT;
 398  cap->cap_inheritable |= CAP_NETWORK_MGT;
 399  cap_set_proc(cap);
 400  exit(0);
 401 }
 402 ],
 403 samba_cv_HAVE_IRIX_SPECIFIC_CAPABILITIES=yes,samba_cv_HAVE_IRIX_SPECIFIC_CAPABILITIES=no,samba_cv_HAVE_IRIX_SPECIFIC_CAPABILITIES=cross)])
 404 if test x"$samba_cv_HAVE_IRIX_SPECIFIC_CAPABILITIES" = x"yes"; then
 405     AC_DEFINE(HAVE_IRIX_SPECIFIC_CAPABILITIES)
 406 fi
 407
 408 AC_MSG_CHECKING([for test routines])
 409 AC_TRY_RUN([#include "${srcdir-.}/tests/trivial.c"],
 410            AC_MSG_RESULT(yes),
 411            AC_MSG_ERROR([cant find test code. Aborting config]),
 412            AC_MSG_WARN([cannot run when cross-compiling]))
 413
 414 AC_CACHE_CHECK([for ftruncate extend],samba_cv_HAVE_FTRUNCATE_EXTEND,[
 415 AC_TRY_RUN([#include "${srcdir-.}/tests/ftruncate.c"],
 416            samba_cv_HAVE_FTRUNCATE_EXTEND=yes,samba_cv_HAVE_FTRUNCATE_EXTEND=no,samba_cv_HAVE_FTRUNCATE_EXTEND=cross)])
 417 if test x"$samba_cv_HAVE_FTRUNCATE_EXTEND" = x"yes"; then
 418     AC_DEFINE(HAVE_FTRUNCATE_EXTEND)
 419 fi
 420
 421 AC_CACHE_CHECK([for broken getgroups],samba_cv_HAVE_BROKEN_GETGROUPS,[
 422 AC_TRY_RUN([#include "${srcdir-.}/tests/getgroups.c"],
 423            samba_cv_HAVE_BROKEN_GETGROUPS=yes,samba_cv_HAVE_BROKEN_GETGROUPS=no,samba_cv_HAVE_BROKEN_GETGROUPS=cross)])
 424 if test x"$samba_cv_HAVE_BROKEN_GETGROUPS" = x"yes"; then
 425     AC_DEFINE(HAVE_BROKEN_GETGROUPS)
 426 fi
 427
 428 AC_CACHE_CHECK([whether getpass should be replaced],samba_cv_REPLACE_GETPASS,[
 429 SAVE_CPPFLAGS="$CPPFLAGS"
 430 CPPFLAGS="$CPPFLAGS -I${srcdir-.}/include -I${srcdir-.}/ubiqx"
 431 AC_TRY_COMPILE([
 432 #define REPLACE_GETPASS 1
 433 #define NO_CONFIG_H 1
 434 #define main dont_declare_main
 435 #include "${srcdir-.}/lib/getsmbpass.c"
 436 #undef main
 437 ],[],samba_cv_REPLACE_GETPASS=yes,samba_cv_REPLACE_GETPASS=no)
 438 CPPFLAGS="$SAVE_CPPFLAGS"
 439 ])
 440 if test x"$samba_cv_REPLACE_GETPASS" = x"yes"; then
 441         AC_DEFINE(REPLACE_GETPASS)
 442 fi
 443
 444 AC_CACHE_CHECK([for broken inet_ntoa],samba_cv_REPLACE_INET_NTOA,[
 445 AC_TRY_RUN([
 446 #include <stdio.h>
 447 #include <sys/types.h>
 448 #include <netinet/in.h>
 449 #include <arpa/inet.h>
 450 main() { struct in_addr ip; ip.s_addr = 0x12345678;
 451 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
 452     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(0); }
 453 exit(1);}],
 454            samba_cv_REPLACE_INET_NTOA=yes,samba_cv_REPLACE_INET_NTOA=no,samba_cv_REPLACE_INET_NTOA=cross)])
 455 if test x"$samba_cv_REPLACE_INET_NTOA" = x"yes"; then
 456     AC_DEFINE(REPLACE_INET_NTOA)
 457 fi
 458
 459 AC_CACHE_CHECK([for root],samba_cv_HAVE_ROOT,[
 460 AC_TRY_RUN([main() { exit(getuid() != 0); }],
 461            samba_cv_HAVE_ROOT=yes,samba_cv_HAVE_ROOT=no,samba_cv_HAVE_ROOT=cross)])
 462 if test x"$samba_cv_HAVE_ROOT" = x"yes"; then
 463     AC_DEFINE(HAVE_ROOT)
 464 else
 465     AC_MSG_WARN(running as non-root will disable some tests)
 466 fi
 467
 468 netmask=no;
 469 AC_CACHE_CHECK([for netmask ifconf],samba_cv_HAVE_NETMASK_IFCONF,[
 470 AC_TRY_RUN([
 471 #define HAVE_NETMASK_IFCONF 1
 472 #define AUTOCONF 1
 473 #include "${srcdir-.}/lib/netmask.c"],
 474            samba_cv_HAVE_NETMASK_IFCONF=yes,samba_cv_HAVE_NETMASK_IFCONF=no,samba_cv_HAVE_NETMASK_IFCONF=cross)])
 475 if test x"$samba_cv_HAVE_NETMASK_IFCONF" = x"yes"; then
 476     netmask=yes;AC_DEFINE(HAVE_NETMASK_IFCONF)
 477 fi
 478
 479 if test $netmask = no; then
 480 AC_CACHE_CHECK([for netmask ifreq],samba_cv_HAVE_NETMASK_IFREQ,[
 481 AC_TRY_RUN([
 482 #define HAVE_NETMASK_IFREQ 1
 483 #define AUTOCONF 1
 484 #include "${srcdir-.}/lib/netmask.c"],
 485            samba_cv_HAVE_NETMASK_IFREQ=yes,samba_cv_HAVE_NETMASK_IFREQ=no,samba_cv_HAVE_NETMASK_IFREQ=cross)])
 486 if test x"$samba_cv_HAVE_NETMASK_IFREQ" = x"yes"; then
 487     netmask=yes;AC_DEFINE(HAVE_NETMASK_IFREQ)
 488 fi
 489 fi
 490
 491 if test $netmask = no; then
 492 AC_CACHE_CHECK([for netmask AIX],samba_cv_HAVE_NETMASK_AIX,[
 493 AC_TRY_RUN([
 494 #define HAVE_NETMASK_AIX 1
 495 #define AUTOCONF 1
 496 #include "${srcdir-.}/lib/netmask.c"],
 497            samba_cv_HAVE_NETMASK_AIX=yes,samba_cv_HAVE_NETMASK_AIX=no,samba_cv_HAVE_NETMASK_AIX=cross)])
 498 if test x"$samba_cv_HAVE_NETMASK_AIX" = x"yes"; then
 499     netmask=yes;AC_DEFINE(HAVE_NETMASK_AIX)
 500 fi
 501 fi
 502
 503 AC_CACHE_CHECK([for trapdoor seteuid],samba_cv_HAVE_TRAPDOOR_UID,[
 504 AC_TRY_RUN([#include "${srcdir-.}/tests/trapdoor.c"],
 505            samba_cv_HAVE_TRAPDOOR_UID=no,samba_cv_HAVE_TRAPDOOR_UID=yes,:)])
 506 if test x"$samba_cv_HAVE_TRAPDOOR_UID" = x"yes"; then
 507     AC_DEFINE(HAVE_TRAPDOOR_UID)
 508 fi
 509
 510 AC_CACHE_CHECK([for shared mmap],samba_cv_HAVE_SHARED_MMAP,[
 511 AC_TRY_RUN([#include "${srcdir-.}/tests/shared_mmap.c"],
 512            samba_cv_HAVE_SHARED_MMAP=yes,samba_cv_HAVE_SHARED_MMAP=no,samba_cv_HAVE_SHARED_MMAP=cross)])
 513 if test x"$samba_cv_HAVE_SHARED_MMAP" = x"yes"; then
 514     AC_DEFINE(HAVE_SHARED_MMAP)
 515 fi
 516
 517 AC_CACHE_CHECK([for fcntl locking],samba_cv_HAVE_FCNTL_LOCK,[
 518 AC_TRY_RUN([#include "${srcdir-.}/tests/fcntl_lock.c"],
 519            samba_cv_HAVE_FCNTL_LOCK=yes,samba_cv_HAVE_FCNTL_LOCK=no,samba_cv_HAVE_FCNTL_LOCK=cross)])
 520 if test x"$samba_cv_HAVE_FCNTL_LOCK" = x"yes"; then
 521     AC_DEFINE(HAVE_FCNTL_LOCK)
 522 fi
 523
 524 AC_CACHE_CHECK([for 64 bit fcntl locking],samba_cv_HAVE_STRUCT_FLOCK64,[
 525 AC_TRY_RUN([
 526 #include <stdio.h>
 527 #include <stdlib.h>
 528
 529 #ifdef HAVE_FCNTL_H
 530 #include <fcntl.h>
 531 #endif
 532
 533 #ifdef HAVE_SYS_FCNTL_H
 534 #include <sys/fcntl.h>
 535 #endif
 536 main() { struct flock64 fl64;
 537 #if defined(F_SETLKW64) && defined(F_SETLK64) && defined(F_GETLK64)
 538 exit(0);
 539 #else
 540 exit(1);
 541 #endif
 542 }],
 543        samba_cv_HAVE_STRUCT_FLOCK64=yes,samba_cv_HAVE_STRUCT_FLOCK64=no,samba_cv_HAVE_STRUCT_FLOCK64=cross)])
 544 if test x"$samba_cv_HAVE_STRUCT_FLOCK64" = x"yes"; then
 545     AC_DEFINE(HAVE_STRUCT_FLOCK64)
 546 fi
 547
 548 AC_CACHE_CHECK([for sysv ipc],samba_cv_HAVE_SYSV_IPC,[
 549 AC_TRY_RUN([#include "${srcdir-.}/tests/sysv_ipc.c"],
 550            samba_cv_HAVE_SYSV_IPC=yes,samba_cv_HAVE_SYSV_IPC=no,samba_cv_HAVE_SYSV_IPC=cross)])
 551 if test x"$samba_cv_HAVE_SYSV_IPC" = x"yes"; then
 552     AC_DEFINE(HAVE_SYSV_IPC)
 553 fi
 554
 555 #################################################
 556 # check for the AFS filesystem
 557 AC_MSG_CHECKING(whether to use AFS)
 558 AC_ARG_WITH(afs,
 559 [  --with-afs     Include AFS support
 560   --without-afs  Don't include AFS support (default)],
 561 [ case "$withval" in
 562   yes)
 563     AC_MSG_RESULT(yes)
 564     AC_DEFINE(WITH_AFS)
 565     ;;
 566   *)
 567     AC_MSG_RESULT(no)
 568     ;;
 569   esac ],
 570   AC_MSG_RESULT(no)
 571 )
 572
 573
 574 #################################################
 575 # check for the DFS auth system
 576 AC_MSG_CHECKING(whether to use DFS auth)
 577 AC_ARG_WITH(dfs,
 578 [  --with-dfs     Include DFS support
 579   --without-dfs  Don't include DFS support (default)],
 580 [ case "$withval" in
 581   yes)
 582     AC_MSG_RESULT(yes)
 583     AC_DEFINE(WITH_DFS)
 584     ;;
 585   *)
 586     AC_MSG_RESULT(no)
 587     ;;
 588   esac ],
 589   AC_MSG_RESULT(no)
 590 )
 591
 592 #################################################
 593 # check for Kerberos IV auth system
 594 AC_MSG_CHECKING(whether to use Kerberos IV)
 595 AC_ARG_WITH(krb4,
 596 [  --with-krb4=base-dir     Include Kerberos IV support
 597   --whithout-krb4          Don't include Kerbers IV support (default)],
 598 [   AC_MSG_RESULT(yes)
 599     AC_DEFINE(KRB4_AUTH)
 600     AC_CHECK_LIB(resolv, dn_expand)
 601     LIBS="$LIBS -lkrb -ldes"
 602     CFLAGS="$CFLAGS -I$withval/include"
 603     LDFLAGS="$LDFLAGS -L$withval/lib"],
 604   AC_MSG_RESULT(no)
 605 )
 606
 607 #################################################
 608 # check for automount support
 609 AC_MSG_CHECKING(whether to use AUTOMOUNT)
 610 AC_ARG_WITH(automount,
 611 [  --with-automount     Include AUTOMOUNT support
 612   --without-automount  Don't include AUTOMOUNT support (default)],
 613 [ case "$withval" in
 614   yes)
 615     AC_MSG_RESULT(yes)
 616     AC_DEFINE(WITH_AUTOMOUNT)
 617     ;;
 618   *)
 619     AC_MSG_RESULT(no)
 620     ;;
 621   esac ],
 622   AC_MSG_RESULT(no)
 623 )
 624
 625 #################################################
 626 # check for smbmount support
 627 AC_MSG_CHECKING(whether to use SMBMOUNT)
 628 AC_ARG_WITH(smbmount,
 629 [  --with-smbmount     Include SMBMOUNT (Linux only) support
 630   --without-smbmount  Don't include SMBMOUNT support (default)],
 631 [ case "$withval" in
 632   yes)
 633     AC_MSG_RESULT(yes)
 634     AC_DEFINE(WITH_SMBMOUNT)
 635     MPROGS="bin/smbmount bin/smbmnt bin/smbumount"
 636     ;;
 637   *)
 638     AC_MSG_RESULT(no)
 639     MPROGS=
 640     ;;
 641   esac ],
 642   AC_MSG_RESULT(no)
 643   MPROGS=
 644 )
 645
 646 #################################################
 647 # check for a LDAP password database
 648 AC_MSG_CHECKING(whether to use LDAP password database)
 649 AC_ARG_WITH(ldap,
 650 [  --with-ldap     Include LDAP support
 651   --without-ldap  Don't include LDAP support (default)],
 652 [ case "$withval" in
 653   yes)
 654     AC_MSG_RESULT(yes)
 655     AC_DEFINE(WITH_LDAP)
 656     ;;
 657   *)
 658     AC_MSG_RESULT(no)
 659     ;;
 660   esac ],
 661   AC_MSG_RESULT(no)
 662 )
 663
 664 #################################################
 665 # check for a NISPLUS password database
 666 AC_MSG_CHECKING(whether to use NISPLUS password database)
 667 AC_ARG_WITH(nisplus,
 668 [  --with-nisplus     Include NISPLUS password database support
 669   --without-nisplus  Don't include NISPLUS password database support (default)],
 670 [ case "$withval" in
 671   yes)
 672     AC_MSG_RESULT(yes)
 673     AC_DEFINE(WITH_NISPLUS)
 674     ;;
 675   *)
 676     AC_MSG_RESULT(no)
 677     ;;
 678   esac ],
 679   AC_MSG_RESULT(no)
 680 )
 681
 682 #################################################
 683 # check for a NISPLUS_HOME support
 684 AC_MSG_CHECKING(whether to use NISPLUS_HOME)
 685 AC_ARG_WITH(nisplus-home,
 686 [  --with-nisplus-home     Include NISPLUS_HOME support
 687   --without-nisplus-home  Don't include NISPLUS_HOME support (default)],
 688 [ case "$withval" in
 689   yes)
 690     AC_MSG_RESULT(yes)
 691     AC_DEFINE(WITH_NISPLUS_HOME)
 692     ;;
 693   *)
 694     AC_MSG_RESULT(no)
 695     ;;
 696   esac ],
 697   AC_MSG_RESULT(no)
 698 )
 699
 700 #################################################
 701 # check for the secure socket layer
 702 AC_MSG_CHECKING(whether to use SSL)
 703 AC_ARG_WITH(ssl,
 704 [  --with-ssl     Include SSL support
 705   --without-ssl  Don't include SSL support (default)],
 706 [ case "$withval" in
 707   yes)
 708     AC_MSG_RESULT(yes)
 709     AC_DEFINE(WITH_SSL)
 710     ;;
 711   *)
 712     AC_MSG_RESULT(no)
 713     ;;
 714   esac ],
 715   AC_MSG_RESULT(no)
 716 )
 717
 718 #################################################
 719 # check for experimental mmap support
 720 AC_MSG_CHECKING(whether to use MMAP)
 721 AC_ARG_WITH(mmap,
 722 [  --with-mmap     Include experimental MMAP support
 723   --without-mmap  Don't include MMAP support (default)],
 724 [ case "$withval" in
 725   yes)
 726     AC_MSG_RESULT(yes)
 727     AC_DEFINE(WITH_MMAP)
 728     ;;
 729   *)
 730     AC_MSG_RESULT(no)
 731     ;;
 732   esac ],
 733   AC_MSG_RESULT(no)
 734 )
 735
 736 #################################################
 737 # check for syslog logging
 738 AC_MSG_CHECKING(whether to use syslog logging)
 739 AC_ARG_WITH(syslog,
 740 [  --with-syslog     Include experimental SYSLOG support
 741   --without-syslog  Don't include SYSLOG support (default)],
 742 [ case "$withval" in
 743   yes)
 744     AC_MSG_RESULT(yes)
 745     AC_DEFINE(WITH_SYSLOG)
 746     ;;
 747   *)
 748     AC_MSG_RESULT(no)
 749     ;;
 750   esac ],
 751   AC_MSG_RESULT(no)
 752 )
 753
 754 #################################################
 755 # check for experimental netatalk resource fork support
 756 AC_MSG_CHECKING(whether to support netatalk)
 757 AC_ARG_WITH(netatalk,
 758 [  --with-netatalk     Include experimental Netatalk support
 759   --without-netatalk  Don't include experimental Netatalk support (default)],
 760 [ case "$withval" in
 761   yes)
 762     AC_MSG_RESULT(yes)
 763     AC_DEFINE(WITH_NETATALK)
 764     ;;
 765   *)
 766     AC_MSG_RESULT(no)
 767     ;;
 768   esac ],
 769   AC_MSG_RESULT(no)
 770 )
 771
 772 #################################################
 773 # check for experimental disk-quotas support
 774 QUOTAOBJS=noquotas.o
 775
 776 AC_MSG_CHECKING(whether to support disk-quotas)
 777 AC_ARG_WITH(quotas,
 778 [  --with-quotas     Include experimental disk-quota support
 779   --without-quotas  Don't include experimental disk-quota support (default)],
 780 [ case "$withval" in
 781   yes)
 782     AC_MSG_RESULT(yes)
 783     QUOTAOBJS=quotas.o
 784     ;;
 785   *)
 786     AC_MSG_RESULT(no)
 787     ;;
 788   esac ],
 789   AC_MSG_RESULT(no)
 790 )
 791 AC_SUBST(QUOTAOBJS)
 792
 793 #################################################
 794 # these tests are taken from the GNU fileutils package
 795 AC_CHECKING(how to get filesystem space usage)
 796 space=no
 797
 798 # Test for statvfs64.
 799 if test $space = no; then
 800   # SVR4
 801   AC_CACHE_CHECK([statvfs64 function (SVR4)], fu_cv_sys_stat_statvfs64,
 802   [AC_TRY_RUN([
 803 #include <sys/types.h>
 804 #include <sys/statvfs.h>
 805   main ()
 806   {
 807     struct statvfs64 fsd;
 808     exit (statfs64 (".", &fsd));
 809   }],
 810   fu_cv_sys_stat_statvfs64=yes,
 811   fu_cv_sys_stat_statvfs64=no,
 812   fu_cv_sys_stat_statvfs64=cross)])
 813   if test $fu_cv_sys_stat_statvfs64 = yes; then
 814     space=yes
 815     AC_DEFINE(STAT_STATVFS64)
 816   fi
 817 fi
 818
 819 # Perform only the link test since it seems there are no variants of the
 820 # statvfs function.  This check is more than just AC_CHECK_FUNCS(statvfs)
 821 # because that got a false positive on SCO OSR5.  Adding the declaration
 822 # of a `struct statvfs' causes this test to fail (as it should) on such
 823 # systems.  That system is reported to work fine with STAT_STATFS4 which
 824 # is what it gets when this test fails.
 825 if test $space = no; then
 826   # SVR4
 827   AC_CACHE_CHECK([statvfs function (SVR4)], fu_cv_sys_stat_statvfs,
 828                  [AC_TRY_LINK([#include <sys/types.h>
 829 #include <sys/statvfs.h>],
 830                               [struct statvfs fsd; statvfs (0, &fsd);],
 831                               fu_cv_sys_stat_statvfs=yes,
 832                               fu_cv_sys_stat_statvfs=no)])
 833   if test $fu_cv_sys_stat_statvfs = yes; then
 834     space=yes
 835     AC_DEFINE(STAT_STATVFS)
 836   fi
 837 fi
 838
 839 if test $space = no; then
 840   # DEC Alpha running OSF/1
 841   AC_MSG_CHECKING([for 3-argument statfs function (DEC OSF/1)])
 842   AC_CACHE_VAL(fu_cv_sys_stat_statfs3_osf1,
 843   [AC_TRY_RUN([
 844 #include <sys/param.h>
 845 #include <sys/types.h>
 846 #include <sys/mount.h>
 847   main ()
 848   {
 849     struct statfs fsd;
 850     fsd.f_fsize = 0;
 851     exit (statfs (".", &fsd, sizeof (struct statfs)));
 852   }],
 853   fu_cv_sys_stat_statfs3_osf1=yes,
 854   fu_cv_sys_stat_statfs3_osf1=no,
 855   fu_cv_sys_stat_statfs3_osf1=no)])
 856   AC_MSG_RESULT($fu_cv_sys_stat_statfs3_osf1)
 857   if test $fu_cv_sys_stat_statfs3_osf1 = yes; then
 858     space=yes
 859     AC_DEFINE(STAT_STATFS3_OSF1)
 860   fi
 861 fi
 862
 863 if test $space = no; then
 864 # AIX
 865   AC_MSG_CHECKING([for two-argument statfs with statfs.bsize dnl
 866 member (AIX, 4.3BSD)])
 867   AC_CACHE_VAL(fu_cv_sys_stat_statfs2_bsize,
 868   [AC_TRY_RUN([
 869 #ifdef HAVE_SYS_PARAM_H
 870 #include <sys/param.h>
 871 #endif
 872 #ifdef HAVE_SYS_MOUNT_H
 873 #include <sys/mount.h>
 874 #endif
 875 #ifdef HAVE_SYS_VFS_H
 876 #include <sys/vfs.h>
 877 #endif
 878   main ()
 879   {
 880   struct statfs fsd;
 881   fsd.f_bsize = 0;
 882   exit (statfs (".", &fsd));
 883   }],
 884   fu_cv_sys_stat_statfs2_bsize=yes,
 885   fu_cv_sys_stat_statfs2_bsize=no,
 886   fu_cv_sys_stat_statfs2_bsize=no)])
 887   AC_MSG_RESULT($fu_cv_sys_stat_statfs2_bsize)
 888   if test $fu_cv_sys_stat_statfs2_bsize = yes; then
 889     space=yes
 890     AC_DEFINE(STAT_STATFS2_BSIZE)
 891   fi
 892 fi
 893
 894 if test $space = no; then
 895 # SVR3
 896   AC_MSG_CHECKING([for four-argument statfs (AIX-3.2.5, SVR3)])
 897   AC_CACHE_VAL(fu_cv_sys_stat_statfs4,
 898   [AC_TRY_RUN([#include <sys/types.h>
 899 #include <sys/statfs.h>
 900   main ()
 901   {
 902   struct statfs fsd;
 903   exit (statfs (".", &fsd, sizeof fsd, 0));
 904   }],
 905     fu_cv_sys_stat_statfs4=yes,
 906     fu_cv_sys_stat_statfs4=no,
 907     fu_cv_sys_stat_statfs4=no)])
 908   AC_MSG_RESULT($fu_cv_sys_stat_statfs4)
 909   if test $fu_cv_sys_stat_statfs4 = yes; then
 910     space=yes
 911     AC_DEFINE(STAT_STATFS4)
 912   fi
 913 fi
 914
 915 if test $space = no; then
 916 # 4.4BSD and NetBSD
 917   AC_MSG_CHECKING([for two-argument statfs with statfs.fsize dnl
 918 member (4.4BSD and NetBSD)])
 919   AC_CACHE_VAL(fu_cv_sys_stat_statfs2_fsize,
 920   [AC_TRY_RUN([#include <sys/types.h>
 921 #ifdef HAVE_SYS_PARAM_H
 922 #include <sys/param.h>
 923 #endif
 924 #ifdef HAVE_SYS_MOUNT_H
 925 #include <sys/mount.h>
 926 #endif
 927   main ()
 928   {
 929   struct statfs fsd;
 930   fsd.f_fsize = 0;
 931   exit (statfs (".", &fsd));
 932   }],
 933   fu_cv_sys_stat_statfs2_fsize=yes,
 934   fu_cv_sys_stat_statfs2_fsize=no,
 935   fu_cv_sys_stat_statfs2_fsize=no)])
 936   AC_MSG_RESULT($fu_cv_sys_stat_statfs2_fsize)
 937   if test $fu_cv_sys_stat_statfs2_fsize = yes; then
 938     space=yes
 939     AC_DEFINE(STAT_STATFS2_FSIZE)
 940   fi
 941 fi
 942
 943 if test $space = no; then
 944   # Ultrix
 945   AC_MSG_CHECKING([for two-argument statfs with struct fs_data (Ultrix)])
 946   AC_CACHE_VAL(fu_cv_sys_stat_fs_data,
 947   [AC_TRY_RUN([#include <sys/types.h>
 948 #ifdef HAVE_SYS_PARAM_H
 949 #include <sys/param.h>
 950 #endif
 951 #ifdef HAVE_SYS_MOUNT_H
 952 #include <sys/mount.h>
 953 #endif
 954 #ifdef HAVE_SYS_FS_TYPES_H
 955 #include <sys/fs_types.h>
 956 #endif
 957   main ()
 958   {
 959   struct fs_data fsd;
 960   /* Ultrix's statfs returns 1 for success,
 961      0 for not mounted, -1 for failure.  */
 962   exit (statfs (".", &fsd) != 1);
 963   }],
 964   fu_cv_sys_stat_fs_data=yes,
 965   fu_cv_sys_stat_fs_data=no,
 966   fu_cv_sys_stat_fs_data=no)])
 967   AC_MSG_RESULT($fu_cv_sys_stat_fs_data)
 968   if test $fu_cv_sys_stat_fs_data = yes; then
 969     space=yes
 970     AC_DEFINE(STAT_STATFS2_FS_DATA)
 971   fi
 972 fi
 973
 974 echo "checking configure summary"
 975 AC_TRY_RUN([#include "${srcdir-.}/tests/summary.c"],
 976            echo "configure OK";,
 977            AC_MSG_ERROR([summary failure. Aborting config]),:)
 978
 979 builddir=`pwd`
 980 AC_SUBST(builddir)
 981
 982 AC_OUTPUT(include/stamp-h Makefile)