docs/xslt/sambadoc2pearson.xsl

   1 <?xml version='1.0'?>
   2 <!--
   3         Convert DocBook to XML validating against the Pearson DTD
   4
   5         (C) Jelmer Vernooij <jelmer@samba.org>                  2004
   6 -->
   7 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   8         xmlns:doc="http://nwalsh.com/xsl/documentation/1.0"
   9         exclude-result-prefixes="doc"
  10         version="1.1" >
  11
  12         <xsl:import href="docbook2pearson.xsl"/>
  13
  14         <xsl:strip-space elements="smbconfoption smbconfsection"/>
  15
  16         <xsl:template match="smbconfblock/smbconfsection">
  17                 <xsl:text>&#10;</xsl:text>
  18                 <xsl:value-of select="."/><xsl:text>&#10;</xsl:text>
  19         </xsl:template>
  20
  21         <xsl:template match="smbconfblock/smbconfoption">
  22                 <xsl:text>      </xsl:text><xsl:value-of select="@name"/><xsl:text> = </xsl:text><xsl:value-of select="text()"/><xsl:text>&#10;</xsl:text>
  23         </xsl:template>
  24
  25         <xsl:template match="smbconfblock">
  26                 <xsl:call-template name="transform.id.attribute"/>
  27                 <listingcode>
  28                 <xsl:apply-templates/>
  29                 </listingcode>
  30         </xsl:template>
  31
  32         <xsl:template match="image">
  33                 <figure>
  34                         <xsl:call-template name="transform.id.attribute"/>
  35                         <description><xsl:value-of select="imagedescription"/></description>
  36                         <figureref>
  37                                 <xsl:attribute name="fileref">
  38                                         <xsl:value-of select="imagefile"/>
  39                                 </xsl:attribute>
  40                                 <xsl:if test="@scale != ''">
  41                                         <xsl:attribute name="scale">
  42                                                 <xsl:value-of select="@scale"/>
  43                                         </xsl:attribute>
  44                                 </xsl:if>
  45                         </figureref>
  46                 </figure>
  47         </xsl:template>
  48
  49         <xsl:template match="smbconfblock/smbconfcomment">
  50                 <xsl:text># </xsl:text><xsl:value-of select="text()"/><xsl:text>&#10;</xsl:text>
  51         </xsl:template>
  52
  53         <xsl:template match="smbconfblock/member">
  54                 <xsl:value-of select="text()"/><xsl:text>&#10;</xsl:text>
  55                 <xsl:message><xsl:text>Encountered &lt;member&gt; element inside of smbconfblock!</xsl:text></xsl:message>
  56         </xsl:template>
  57
  58         <xsl:template match="filterline">
  59                 <code><xsl:apply-templates/></code>
  60         </xsl:template>
  61
  62         <xsl:template match="smbconfoption">
  63                 <code><xsl:value-of select="@name"/></code>
  64                 <xsl:if test="text() != ''">
  65                         <xsl:text> = </xsl:text>
  66                         <xsl:value-of select="text()"/>
  67                 </xsl:if>
  68                 <xsl:text>&#10;</xsl:text>
  69         </xsl:template>
  70
  71         <xsl:template match="smbconfsection">
  72                 <code><xsl:apply-templates/></code>
  73         </xsl:template>
  74
  75         <xsl:template match="ntgroup|ntuser">
  76                 <em><xsl:apply-templates/></em>
  77         </xsl:template>
  78         <!-- translator -->
  79
  80 </xsl:stylesheet>