selftest/selftest.pl

   1 #!/usr/bin/perl
   2 # Bootstrap Samba and run a number of tests against it.
   3 # Copyright (C) 2005-2008 Jelmer Vernooij <jelmer@samba.org>
   4 # Published under the GNU GPL, v3 or later.
   5
   6 =pod
   7
   8 =head1 NAME
   9
  10 selftest - Samba test runner
  11
  12 =head1 SYNOPSIS
  13
  14 selftest --help
  15
  16 selftest [--srcdir=DIR] [--builddir=DIR] [--target=samba4|samba3|win|kvm] [--socket-wrapper] [--quick] [--exclude=FILE] [--include=FILE] [--one] [--prefix=prefix] [--immediate] [--testlist=FILE] [TESTS]
  17
  18 =head1 DESCRIPTION
  19
  20 A simple test runner. TESTS is a regular expression with tests to run.
  21
  22 =head1 OPTIONS
  23
  24 =over 4
  25
  26 =item I<--help>
  27
  28 Show list of available options.
  29
  30 =item I<--srcdir=DIR>
  31
  32 Source directory.
  33
  34 =item I<--builddir=DIR>
  35
  36 Build directory.
  37
  38 =item I<--prefix=DIR>
  39
  40 Change directory to run tests in. Default is 'st'.
  41
  42 =item I<--immediate>
  43
  44 Show errors as soon as they happen rather than at the end of the test run.
  45
  46 =item I<--target samba4|samba3|win|kvm>
  47
  48 Specify test target against which to run. Default is 'samba4'.
  49
  50 =item I<--quick>
  51
  52 Run only a limited number of tests. Intended to run in about 30 seconds on
  53 moderately recent systems.
  54
  55 =item I<--socket-wrapper>
  56
  57 Use socket wrapper library for communication with server. Only works
  58 when the server is running locally.
  59
  60 Will prevent TCP and UDP ports being opened on the local host but
  61 (transparently) redirects these calls to use unix domain sockets.
  62
  63 =item I<--expected-failures>
  64
  65 Specify a file containing a list of tests that are expected to fail. Failures for
  66 these tests will be counted as successes, successes will be counted as failures.
  67
  68 The format for the file is, one entry per line:
  69
  70 TESTSUITE-NAME.TEST-NAME
  71
  72 The reason for a test can also be specified, by adding a hash sign (#) and the reason
  73 after the test name.
  74
  75 =item I<--exclude>
  76
  77 Specify a file containing a list of tests that should be skipped. Possible
  78 candidates are tests that segfault the server, flip or don't end. The format of this file is the same as
  79 for the --expected-failures flag.
  80
  81 =item I<--include>
  82
  83 Specify a file containing a list of tests that should be run. Same format
  84 as the --exclude flag.
  85
  86 Not includes specified means all tests will be run.
  87
  88 =item I<--one>
  89
  90 Abort as soon as one test fails.
  91
  92 =item I<--testlist>
  93
  94 Load a list of tests from the specified location.
  95
  96 =back
  97
  98 =head1 ENVIRONMENT
  99
 100 =over 4
 101
 102 =item I<SMBD_VALGRIND>
 103
 104 =item I<TORTURE_MAXTIME>
 105
 106 =item I<VALGRIND>
 107
 108 =item I<TLS_ENABLED>
 109
 110 =item I<srcdir>
 111
 112 =back
 113
 114 =head1 LICENSE
 115
 116 selftest is licensed under the GNU General Public License L<http://www.gnu.org/licenses/gpl.html>.
 117
 118 =head1 AUTHOR
 119
 120 Jelmer Vernooij
 121
 122 =cut
 123
 124 use strict;
 125
 126 use FindBin qw($RealBin $Script);
 127 use File::Spec;
 128 use Getopt::Long;
 129 use POSIX;
 130 use Cwd qw(abs_path);
 131 use lib "$RealBin";
 132 use Subunit qw(parse_results);
 133 use SocketWrapper;
 134
 135 my $opt_help = 0;
 136 my $opt_target = "samba4";
 137 my $opt_quick = 0;
 138 my $opt_socket_wrapper = 0;
 139 my $opt_socket_wrapper_pcap = undef;
 140 my $opt_socket_wrapper_keep_pcap = undef;
 141 my $opt_one = 0;
 142 my $opt_immediate = 0;
 143 my $opt_expected_failures = undef;
 144 my @opt_exclude = ();
 145 my @opt_include = ();
 146 my $opt_verbose = 0;
 147 my $opt_image = undef;
 148 my $opt_testenv = 0;
 149 my $ldap = undef;
 150 my $opt_analyse_cmd = undef;
 151 my $opt_resetup_env = undef;
 152 my $opt_bindir = undef;
 153 my $opt_no_lazy_setup = undef;
 154 my $opt_format = "plain";
 155 my @testlists = ();
 156
 157 my $srcdir = ".";
 158 my $builddir = ".";
 159 my $prefix = "./st";
 160
 161 my @expected_failures = ();
 162 my @includes = ();
 163 my @excludes = ();
 164
 165 my $statistics = {
 166         SUITES_FAIL => 0,
 167
 168         TESTS_UNEXPECTED_OK => 0,
 169         TESTS_EXPECTED_OK => 0,
 170         TESTS_UNEXPECTED_FAIL => 0,
 171         TESTS_EXPECTED_FAIL => 0,
 172         TESTS_ERROR => 0,
 173         TESTS_SKIP => 0,
 174 };
 175
 176 sub find_in_list($$)
 177 {
 178         my ($list, $fullname) = @_;
 179
 180         foreach (@$list) {
 181                 if ($fullname =~ /$$_[0]/) {
 182                          return ($$_[1]) if ($$_[1]);
 183                          return "NO REASON SPECIFIED";
 184                 }
 185         }
 186
 187         return undef;
 188 }
 189
 190 sub expecting_failure($)
 191 {
 192         my ($name) = @_;
 193         return find_in_list(\@expected_failures, $name);
 194 }
 195
 196 sub skip($)
 197 {
 198         my ($name) = @_;
 199
 200         return find_in_list(\@excludes, $name);
 201 }
 202
 203 sub getlog_env($);
 204
 205 sub setup_pcap($)
 206 {
 207         my ($name) = @_;
 208
 209         return unless ($opt_socket_wrapper_pcap);
 210         return unless defined($ENV{SOCKET_WRAPPER_PCAP_DIR});
 211
 212         my $fname = $name;
 213         $fname =~ s%[^abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789\-]%_%g;
 214
 215         my $pcap_file = "$ENV{SOCKET_WRAPPER_PCAP_DIR}/$fname.pcap";
 216
 217         SocketWrapper::setup_pcap($pcap_file);
 218
 219         return $pcap_file;
 220 }
 221
 222 sub cleanup_pcap($$$)
 223 {
 224         my ($pcap_file, $expected_ret, $ret) = @_;
 225
 226         return unless ($opt_socket_wrapper_pcap);
 227         return if ($opt_socket_wrapper_keep_pcap);
 228         return unless ($expected_ret == $ret);
 229         return unless defined($pcap_file);
 230
 231         unlink($pcap_file);
 232 }
 233
 234 sub run_testsuite($$$$$$)
 235 {
 236         my ($envname, $name, $cmd, $i, $totalsuites, $msg_ops) = @_;
 237         my $pcap_file = setup_pcap($name);
 238
 239         $msg_ops->start_test([], $name);
 240
 241         unless (open(RESULT, "$cmd 2>&1|")) {
 242                 $statistics->{TESTS_ERROR}++;
 243                 $msg_ops->end_test([], $name, "error", 1, "Unable to run $cmd: $!");
 244                 $statistics->{SUITES_FAIL}++;
 245                 return 0;
 246         }
 247
 248         my $expected_ret = parse_results(
 249                 $msg_ops, $statistics, *RESULT, \&expecting_failure, [$name]);
 250
 251         my $envlog = getlog_env($envname);
 252         $msg_ops->output_msg("ENVLOG: $envlog\n") if ($envlog ne "");
 253
 254         $msg_ops->output_msg("CMD: $cmd\n");
 255
 256         my $ret = close(RESULT);
 257         $ret = 0 unless $ret == 1;
 258
 259         my $exitcode = $? >> 8;
 260
 261         if ($ret == 1) {
 262                 $msg_ops->end_test([], $name, "success", $expected_ret != $ret, undef);
 263         } else {
 264                 $msg_ops->end_test([], $name, "failure", $expected_ret != $ret, "Exit code was $exitcode");
 265         }
 266
 267         cleanup_pcap($pcap_file, $expected_ret, $ret);
 268
 269         if (not $opt_socket_wrapper_keep_pcap and defined($pcap_file)) {
 270                 $msg_ops->output_msg("PCAP FILE: $pcap_file\n");
 271         }
 272
 273         if ($ret != $expected_ret) {
 274                 $statistics->{SUITES_FAIL}++;
 275                 exit(1) if ($opt_one);
 276         }
 277
 278         return ($ret == $expected_ret);
 279 }
 280
 281 sub ShowHelp()
 282 {
 283         print "Samba test runner
 284 Copyright (C) Jelmer Vernooij <jelmer\@samba.org>
 285
 286 Usage: $Script [OPTIONS] PREFIX
 287
 288 Generic options:
 289  --help                     this help page
 290  --target=samba[34]|win|kvm Samba version to target
 291  --testlist=FILE                        file to read available tests from
 292
 293 Paths:
 294  --prefix=DIR               prefix to run tests in [st]
 295  --srcdir=DIR               source directory [.]
 296  --builddir=DIR             output directory [.]
 297
 298 Target Specific:
 299  --socket-wrapper-pcap          save traffic to pcap directories
 300  --socket-wrapper-keep-pcap keep all pcap files, not just those for tests that
 301                             failed
 302  --socket-wrapper           enable socket wrapper
 303  --expected-failures=FILE   specify list of tests that is guaranteed to fail
 304
 305 Samba4 Specific:
 306  --ldap=openldap|fedora-ds     back smbd onto specified ldap server
 307
 308 Samba3 Specific:
 309  --bindir=PATH              path to binaries
 310
 311 Kvm Specific:
 312  --image=PATH               path to KVM image
 313
 314 Behaviour:
 315  --quick                    run quick overall test
 316  --one                      abort when the first test fails
 317  --immediate                print test output for failed tests during run
 318  --verbose                  be verbose
 319  --analyse-cmd CMD          command to run after each test
 320 ";
 321         exit(0);
 322 }
 323
 324 my $result = GetOptions (
 325                 'help|h|?' => \$opt_help,
 326                 'target=s' => \$opt_target,
 327                 'prefix=s' => \$prefix,
 328                 'socket-wrapper' => \$opt_socket_wrapper,
 329                 'socket-wrapper-pcap' => \$opt_socket_wrapper_pcap,
 330                 'socket-wrapper-keep-pcap' => \$opt_socket_wrapper_keep_pcap,
 331                 'quick' => \$opt_quick,
 332                 'one' => \$opt_one,
 333                 'immediate' => \$opt_immediate,
 334                 'expected-failures=s' => \$opt_expected_failures,
 335                 'exclude=s' => \@opt_exclude,
 336                 'include=s' => \@opt_include,
 337                 'srcdir=s' => \$srcdir,
 338                 'builddir=s' => \$builddir,
 339                 'verbose' => \$opt_verbose,
 340                 'testenv' => \$opt_testenv,
 341                 'ldap:s' => \$ldap,
 342                 'analyse-cmd=s' => \$opt_analyse_cmd,
 343                 'no-lazy-setup' => \$opt_no_lazy_setup,
 344                 'resetup-environment' => \$opt_resetup_env,
 345                 'bindir:s' => \$opt_bindir,
 346                 'format=s' => \$opt_format,
 347                 'image=s' => \$opt_image,
 348                 'testlist=s' => \@testlists
 349             );
 350
 351 exit(1) if (not $result);
 352
 353 ShowHelp() if ($opt_help);
 354
 355 my $tests = shift;
 356
 357 # quick hack to disable rpc validation when using valgrind - its way too slow
 358 unless (defined($ENV{VALGRIND})) {
 359         $ENV{VALIDATE} = "validate";
 360         $ENV{MALLOC_CHECK_} = 2;
 361 }
 362
 363 my $old_pwd = "$RealBin/..";
 364
 365 # Backwards compatibility:
 366 if (defined($ENV{TEST_LDAP}) and $ENV{TEST_LDAP} eq "yes") {
 367         if (defined($ENV{FEDORA_DS_ROOT})) {
 368                 $ldap = "fedora-ds";
 369         } else {
 370                 $ldap = "openldap";
 371         }
 372 }
 373
 374 my $torture_maxtime = ($ENV{TORTURE_MAXTIME} or 1200);
 375 if ($ldap) {
 376         # LDAP is slow
 377         $torture_maxtime *= 2;
 378 }
 379
 380 $prefix =~ s+//+/+;
 381 $prefix =~ s+/./+/+;
 382 $prefix =~ s+/$++;
 383
 384 die("using an empty prefix isn't allowed") unless $prefix ne "";
 385
 386 #Ensure we have the test prefix around
 387 mkdir($prefix, 0777) unless -d $prefix;
 388
 389 my $prefix_abs = abs_path($prefix);
 390 my $srcdir_abs = abs_path($srcdir);
 391
 392 die("using an empty absolute prefix isn't allowed") unless $prefix_abs ne "";
 393 die("using '/' as absolute prefix isn't allowed") unless $prefix_abs ne "/";
 394
 395 $ENV{PREFIX} = $prefix;
 396 $ENV{KRB5CCNAME} = "$prefix/krb5ticket";
 397 $ENV{PREFIX_ABS} = $prefix_abs;
 398 $ENV{SRCDIR} = $srcdir;
 399 $ENV{SRCDIR_ABS} = $srcdir_abs;
 400
 401 if (defined($ENV{RUN_FROM_BUILD_FARM}) and
 402         ($ENV{RUN_FROM_BUILD_FARM} eq "yes")) {
 403         $opt_format = "buildfarm";
 404 }
 405
 406 my $tls_enabled = not $opt_quick;
 407 $ENV{TLS_ENABLED} = ($tls_enabled?"yes":"no");
 408 $ENV{LDB_MODULES_PATH} = "$old_pwd/source4/bin/modules/ldb";
 409 $ENV{LD_SAMBA_MODULE_PATH} = "$old_pwd/source4/bin/modules";
 410 sub prefix_pathvar($$)
 411 {
 412         my ($name, $newpath) = @_;
 413         if (defined($ENV{$name})) {
 414                 $ENV{$name} = "$newpath:$ENV{$name}";
 415         } else {
 416                 $ENV{$name} = $newpath;
 417         }
 418 }
 419 prefix_pathvar("PKG_CONFIG_PATH", "$old_pwd/source4/bin/pkgconfig");
 420 # Required for smbscript:
 421 prefix_pathvar("PATH", "$old_pwd/source4/bin");
 422 prefix_pathvar("PYTHONPATH", "$old_pwd/source4/bin/python");
 423
 424 if ($opt_socket_wrapper_keep_pcap) {
 425         # Socket wrapper keep pcap implies socket wrapper pcap
 426         $opt_socket_wrapper_pcap = 1;
 427 }
 428
 429 if ($opt_socket_wrapper_pcap) {
 430         # Socket wrapper pcap implies socket wrapper
 431         $opt_socket_wrapper = 1;
 432 }
 433
 434 my $socket_wrapper_dir;
 435 if ($opt_socket_wrapper) {
 436         $socket_wrapper_dir = SocketWrapper::setup_dir("$prefix/w", $opt_socket_wrapper_pcap);
 437         print "SOCKET_WRAPPER_DIR=$socket_wrapper_dir\n";
 438 } else {
 439         warn("Not using socket wrapper, but also not running as root. Will not be able to listen on proper ports") unless $< == 0;
 440 }
 441
 442 my $target;
 443 my $testenv_default = "none";
 444
 445 if ($opt_target eq "samba4") {
 446         $testenv_default = "member";
 447         require target::Samba4;
 448         $target = new Samba4($opt_bindir or "$srcdir/bin", $ldap, "$srcdir/setup");
 449 } elsif ($opt_target eq "samba3") {
 450         if ($opt_socket_wrapper and `$opt_bindir/smbd -b | grep SOCKET_WRAPPER` eq "") {
 451                 die("You must include --enable-socket-wrapper when compiling Samba in order to execute 'make test'.  Exiting....");
 452         }
 453         $testenv_default = "dc";
 454         require target::Samba3;
 455         $target = new Samba3($opt_bindir);
 456 } elsif ($opt_target eq "win") {
 457         die("Windows tests will not run with socket wrapper enabled.")
 458                 if ($opt_socket_wrapper);
 459         $testenv_default = "dc";
 460         require target::Windows;
 461         $target = new Windows();
 462 } elsif ($opt_target eq "kvm") {
 463         die("Kvm tests will not run with socket wrapper enabled.")
 464                 if ($opt_socket_wrapper);
 465         require target::Kvm;
 466         die("No image specified") unless ($opt_image);
 467         $target = new Kvm($opt_image, undef);
 468 }
 469
 470 #
 471 # Start a Virtual Distributed Ethernet Switch
 472 # Returns the pid of the switch.
 473 #
 474 sub start_vde_switch($)
 475 {
 476         my ($path) = @_;
 477
 478         system("vde_switch --pidfile $path/vde.pid --sock $path/vde.sock --daemon");
 479
 480         open(PID, "$path/vde.pid");
 481         <PID> =~ /([0-9]+)/;
 482         my $pid = $1;
 483         close(PID);
 484
 485         return $pid;
 486 }
 487
 488 # Stop a Virtual Distributed Ethernet Switch
 489 sub stop_vde_switch($)
 490 {
 491         my ($pid) = @_;
 492         kill 9, $pid;
 493 }
 494
 495 sub read_test_regexes($)
 496 {
 497         my ($name) = @_;
 498         my @ret = ();
 499         open(LF, "<$name") or die("unable to read $name: $!");
 500         while (<LF>) {
 501                 chomp;
 502                 next if (/^#/);
 503                 if (/^(.*?)([ \t]+)\#([\t ]*)(.*?)$/) {
 504                         push (@ret, [$1, $4]);
 505                 } else {
 506                         s/^(.*?)([ \t]+)\#([\t ]*)(.*?)$//;
 507                         push (@ret, [$_, undef]);
 508                 }
 509         }
 510         close(LF);
 511         return @ret;
 512 }
 513
 514 if (defined($opt_expected_failures)) {
 515         @expected_failures = read_test_regexes($opt_expected_failures);
 516 }
 517
 518 foreach (@opt_exclude) {
 519         push (@excludes, read_test_regexes($_));
 520 }
 521
 522 if ($opt_quick) {
 523         push (@includes, read_test_regexes("samba4-quick"));
 524 }
 525
 526 foreach (@opt_include) {
 527         push (@includes, read_test_regexes($_));
 528 }
 529
 530 my $interfaces = join(',', ("127.0.0.6/8",
 531                             "127.0.0.7/8",
 532                             "127.0.0.8/8",
 533                             "127.0.0.9/8",
 534                             "127.0.0.10/8",
 535                             "127.0.0.11/8"));
 536
 537 my $conffile = "$prefix_abs/client/client.conf";
 538
 539 sub write_clientconf($$)
 540 {
 541         my ($conffile, $vars) = @_;
 542
 543         mkdir("$prefix/client", 0777) unless -d "$prefix/client";
 544
 545         if ( -d "$prefix/client/private" ) {
 546                 unlink <$prefix/client/private/*>;
 547         } else {
 548                 mkdir("$prefix/client/private", 0777);
 549         }
 550
 551         open(CF, ">$conffile");
 552         print CF "[global]\n";
 553         if (defined($ENV{VALGRIND})) {
 554                 print CF "\ticonv:native = true\n";
 555         } else {
 556                 print CF "\ticonv:native = false\n";
 557         }
 558         print CF "\tnetbios name = client\n";
 559         if (defined($vars->{DOMAIN})) {
 560                 print CF "\tworkgroup = $vars->{DOMAIN}\n";
 561         }
 562         if (defined($vars->{REALM})) {
 563                 print CF "\trealm = $vars->{REALM}\n";
 564         }
 565         if (defined($vars->{NCALRPCDIR})) {
 566                 print CF "\tncalrpc dir = $vars->{NCALRPCDIR}\n";
 567         }
 568         if (defined($vars->{PIDDIR})) {
 569                 print CF "\tpid directory = $vars->{PIDDIR}\n";
 570         }
 571         if (defined($vars->{WINBINDD_SOCKET_DIR})) {
 572                 print CF "\twinbindd socket directory = $vars->{WINBINDD_SOCKET_DIR}\n";
 573         }
 574         if ($opt_socket_wrapper) {
 575                 print CF "\tinterfaces = $interfaces\n";
 576         }
 577         print CF "
 578         private dir = $prefix_abs/client/private
 579         js include = $srcdir_abs/scripting/libjs
 580         name resolve order = bcast
 581         panic action = $srcdir_abs/script/gdb_backtrace \%PID\% \%PROG\%
 582         max xmit = 32K
 583         notify:inotify = false
 584         ldb:nosync = true
 585         system:anonymous = true
 586         torture:basedir = $prefix_abs/client
 587 #We don't want to pass our self-tests if the PAC code is wrong
 588         gensec:require_pac = true
 589         modules dir = $ENV{LD_SAMBA_MODULE_PATH}
 590 ";
 591         close(CF);
 592 }
 593
 594 my @torture_options = ();
 595 push (@torture_options, "--configfile=$conffile");
 596 # ensure any one smbtorture call doesn't run too long
 597 push (@torture_options, "--maximum-runtime=$torture_maxtime");
 598 push (@torture_options, "--target=$opt_target");
 599 push (@torture_options, "--basedir=$prefix_abs");
 600 push (@torture_options, "--option=torture:progress=no") unless ($opt_verbose);
 601 push (@torture_options, "--format=subunit");
 602 push (@torture_options, "--option=torture:quick=yes") if ($opt_quick);
 603
 604 $ENV{TORTURE_OPTIONS} = join(' ', @torture_options);
 605 print "OPTIONS $ENV{TORTURE_OPTIONS}\n";
 606
 607 my @todo = ();
 608
 609 my $testsdir = "$srcdir/selftest";
 610 $ENV{SMB_CONF_PATH} = "$conffile";
 611 $ENV{CONFIGURATION} = "--configfile=$conffile";
 612
 613 my %required_envs = ();
 614
 615 sub read_testlist($)
 616 {
 617         my ($filename) = @_;
 618
 619         my @ret = ();
 620         open(IN, $filename) or die("Unable to open $filename: $!");
 621
 622         while (<IN>) {
 623                 if ($_ eq "-- TEST --\n") {
 624                         my $name = <IN>;
 625                         $name =~ s/\n//g;
 626                         my $env = <IN>;
 627                         $env =~ s/\n//g;
 628                         my $cmdline = <IN>;
 629                         $cmdline =~ s/\n//g;
 630                         if (not defined($tests) or $name =~ /$tests/) {
 631                                 $required_envs{$env} = 1;
 632                                 push (@ret, [$name, $env, $cmdline]);
 633                         }
 634                 } else {
 635                         print;
 636                 }
 637         }
 638         close(IN) or die("Error creating recipe");
 639         return @ret;
 640 }
 641
 642 if ($#testlists == -1) {
 643         die("No testlists specified");
 644 }
 645
 646 my @available = ();
 647 foreach my $fn (@testlists) {
 648         foreach (read_testlist($fn)) {
 649                 my $name = $$_[0];
 650                 next if (@includes and not find_in_list(\@includes, $name));
 651                 push (@available, $_);
 652         }
 653 }
 654
 655 my $msg_ops;
 656 if ($opt_format eq "buildfarm") {
 657         require output::buildfarm;
 658         $msg_ops = new output::buildfarm($statistics);
 659 } elsif ($opt_format eq "plain") {
 660         require output::plain;
 661         $msg_ops = new output::plain("$prefix/summary", $opt_verbose, $opt_immediate, $statistics, $#available+1);
 662 } elsif ($opt_format eq "html") {
 663         require output::html;
 664         mkdir("test-results", 0777);
 665         $msg_ops = new output::html("test-results", $statistics);
 666 } else {
 667         die("Invalid output format '$opt_format'");
 668 }
 669
 670
 671 foreach (@available) {
 672         my $name = $$_[0];
 673         my $skipreason = skip($name);
 674         if ($skipreason) {
 675                 $msg_ops->skip_testsuite($name, $skipreason);
 676         } else {
 677                 push(@todo, $_);
 678         }
 679 }
 680
 681 if ($#todo == -1) {
 682         print STDERR "No tests to run\n";
 683         exit(1);
 684         }
 685
 686 my $suitestotal = $#todo + 1;
 687 my $i = 0;
 688 $| = 1;
 689
 690 my %running_envs = ();
 691
 692 my @exported_envvars = (
 693         # domain stuff
 694         "DOMAIN",
 695         "REALM",
 696
 697         # domain controller stuff
 698         "DC_SERVER",
 699         "DC_SERVER_IP",
 700         "DC_NETBIOSNAME",
 701         "DC_NETBIOSALIAS",
 702
 703         # server stuff
 704         "SERVER",
 705         "SERVER_IP",
 706         "NETBIOSNAME",
 707         "NETBIOSALIAS",
 708
 709         # user stuff
 710         "USERNAME",
 711         "PASSWORD",
 712         "DC_USERNAME",
 713         "DC_PASSWORD",
 714
 715         # misc stuff
 716         "KRB5_CONFIG",
 717         "WINBINDD_SOCKET_DIR",
 718         "WINBINDD_PRIV_PIPE_DIR"
 719 );
 720
 721 $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub {
 722         my $signame = shift;
 723         teardown_env($_) foreach(keys %running_envs);
 724         die("Received signal $signame");
 725 };
 726
 727 sub setup_env($)
 728 {
 729         my ($envname) = @_;
 730
 731         my $testenv_vars;
 732         if ($envname eq "none") {
 733                 $testenv_vars = {};
 734         } elsif (defined($running_envs{$envname})) {
 735                 $testenv_vars = $running_envs{$envname};
 736                 if (not $target->check_env($testenv_vars)) {
 737                         $testenv_vars = undef;
 738                 }
 739         } else {
 740                 $testenv_vars = $target->setup_env($envname, $prefix);
 741         }
 742
 743         return undef unless defined($testenv_vars);
 744
 745         $running_envs{$envname} = $testenv_vars;
 746
 747         SocketWrapper::set_default_iface(6);
 748         write_clientconf($conffile, $testenv_vars);
 749
 750         foreach (@exported_envvars) {
 751                 if (defined($testenv_vars->{$_})) {
 752                         $ENV{$_} = $testenv_vars->{$_};
 753                 } else {
 754                         delete $ENV{$_};
 755                 }
 756         }
 757
 758         return $testenv_vars;
 759 }
 760
 761 sub exported_envvars_str($)
 762 {
 763         my ($testenv_vars) = @_;
 764         my $out = "";
 765
 766         foreach (@exported_envvars) {
 767                 next unless defined($testenv_vars->{$_});
 768                 $out .= $_."=".$testenv_vars->{$_}."\n";
 769         }
 770
 771         return $out;
 772 }
 773
 774 sub getlog_env($)
 775 {
 776         my ($envname) = @_;
 777         return "" if ($envname eq "none");
 778         return $target->getlog_env($running_envs{$envname});
 779 }
 780
 781 sub check_env($)
 782 {
 783         my ($envname) = @_;
 784         return 1 if ($envname eq "none");
 785         return $target->check_env($running_envs{$envname});
 786 }
 787
 788 sub teardown_env($)
 789 {
 790         my ($envname) = @_;
 791         return if ($envname eq "none");
 792         $target->teardown_env($running_envs{$envname});
 793         delete $running_envs{$envname};
 794 }
 795
 796 if ($opt_no_lazy_setup) {
 797         setup_env($_) foreach (keys %required_envs);
 798 }
 799
 800 if ($opt_testenv) {
 801         my $testenv_name = $ENV{SELFTEST_TESTENV};
 802         $testenv_name = $testenv_default unless defined($testenv_name);
 803
 804         my $testenv_vars = setup_env($testenv_name);
 805
 806         $ENV{PIDDIR} = $testenv_vars->{PIDDIR};
 807
 808         my $envvarstr = exported_envvars_str($testenv_vars);
 809
 810         my $term = ($ENV{TERM} or "xterm");
 811         system("$term -e 'echo -e \"
 812 Welcome to the Samba4 Test environment '$testenv_name'
 813
 814 This matches the client environment used in make test
 815 smbd is pid `cat \$PIDDIR/smbd.pid`
 816
 817 Some useful environment variables:
 818 TORTURE_OPTIONS=\$TORTURE_OPTIONS
 819 CONFIGURATION=\$CONFIGURATION
 820
 821 $envvarstr
 822 \" && LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} bash'");
 823         teardown_env($testenv_name);
 824 } else {
 825         foreach (@todo) {
 826                 $i++;
 827                 my $cmd = $$_[2];
 828                 $cmd =~ s/([\(\)])/\\$1/g;
 829                 my $name = $$_[0];
 830                 my $envname = $$_[1];
 831
 832                 my $envvars = setup_env($envname);
 833                 if (not defined($envvars)) {
 834                         $msg_ops->skip_testsuite($name, "unable to set up environment $envname");
 835                         next;
 836                 }
 837
 838                 run_testsuite($envname, $name, $cmd, $i, $suitestotal,
 839                               $msg_ops);
 840
 841                 if (defined($opt_analyse_cmd)) {
 842                         system("$opt_analyse_cmd \"$name\"");
 843                 }
 844
 845                 teardown_env($envname) if ($opt_resetup_env);
 846         }
 847 }
 848
 849 print "\n";
 850
 851 teardown_env($_) foreach (keys %running_envs);
 852
 853 $target->stop();
 854
 855 $msg_ops->summary();
 856
 857 my $failed = 0;
 858
 859 # if there were any valgrind failures, show them
 860 foreach (<$prefix/valgrind.log*>) {
 861         next unless (-s $_);
 862         system("grep DWARF2.CFI.reader $_ > /dev/null");
 863         if ($? >> 8 == 0) {
 864             print "VALGRIND FAILURE\n";
 865             $failed++;
 866             system("cat $_");
 867         }
 868 }
 869
 870 if ($opt_format eq "buildfarm") {
 871         print "TEST STATUS: $statistics->{SUITES_FAIL}\n";
 872 }
 873
 874 exit $statistics->{SUITES_FAIL};