r23403: Make nsstest build on Samba4.
[jelmer/samba4-debian.git] / source / configure.ac
1 dnl -*- mode: m4-mode -*-
2 dnl Process this file with autoconf to produce a configure script.
3
4 dnl disabled 2.53 requirement - we do work with 2.52 on suse 7.3 for example
5 dnl AC_PREREQ(2.53)
6
7 AC_INIT([samba],[],[samba-technical@samba.org])
8
9 AC_CONFIG_SRCDIR([include/includes.h])
10 AC_CONFIG_HEADER(include/config_tmp.h)
11 AC_DEFINE(CONFIG_H_IS_FROM_SAMBA,1,[Marker for samba's config.h])
12
13 # Configuration rules.
14 m4_include(build/m4/env.m4)
15 m4_include(lib/replace/samba.m4)
16 m4_include(lib/smbreadline/readline.m4)
17 m4_include(heimdal_build/config.m4)
18 m4_include(lib/util/fault.m4)
19 m4_include(lib/util/signal.m4)
20 m4_include(lib/util/util.m4)
21 m4_include(lib/util/fsusage.m4)
22 m4_include(lib/util/xattr.m4)
23 m4_include(lib/util/capability.m4)
24 m4_include(lib/util/time.m4)
25 m4_include(lib/popt/samba.m4)
26 m4_include(lib/charset/config.m4)
27 m4_include(lib/socket/config.m4)
28 m4_include(torture/nsstest.m4)
29
30 #SMB_EXT_LIB_FROM_PKGCONFIG(LIBTALLOC, talloc >= 1.0,
31 #                          [samba_cv_internal_talloc=no],
32 #                          [samba_cv_internal_talloc=yes])
33 samba_cv_internal_talloc=yes
34 if test x"$samba_cv_internal_talloc" = x"yes"; then
35         m4_include(lib/talloc/libtalloc.m4)
36         SMB_INCLUDE_MK(lib/talloc/config.mk)
37 fi
38
39 #SMB_EXT_LIB_FROM_PKGCONFIG(LIBTDB, tdb >= 1.1.0,
40 #                          [samba_cv_internal_tdb=no],
41 #                          [samba_cv_internal_tdb=yes])
42 samba_cv_internal_tdb=yes
43 if test x"$samba_cv_internal_tdb" = x"yes"; then
44         m4_include(lib/tdb/libtdb.m4)
45         SMB_INCLUDE_MK(lib/tdb/config.mk)
46 fi
47
48 m4_include(lib/ldb/sqlite3.m4)
49 m4_include(lib/ldb/libldb.m4)
50 m4_include(lib/tls/config.m4)
51 m4_include(lib/events/config.m4)
52
53 dnl m4_include(auth/kerberos/config.m4)
54
55 m4_include(auth/gensec/config.m4)
56 m4_include(smbd/process_model.m4)
57 m4_include(scripting/swig/config.m4)
58 m4_include(ntvfs/posix/config.m4)
59 m4_include(ntvfs/unixuid/config.m4)
60 m4_include(lib/socket_wrapper/config.m4)
61 m4_include(auth/config.m4)
62 m4_include(kdc/config.m4)
63 m4_include(ntvfs/sysdep/config.m4)
64 m4_include(lib/appweb/config.m4)
65 m4_include(nsswitch/config.m4)
66 m4_include(libcli/config.m4)
67
68 #################################################
69 # add *_CFLAGS only for the real build
70 CFLAGS="${CFLAGS} ${DEVELOPER_CFLAGS}"
71
72 #################################################
73 # final configure stuff
74
75 AC_MSG_CHECKING([configure summary])
76 AC_TRY_RUN([#include "${srcdir-.}/build/tests/summary.c"],
77            AC_MSG_RESULT(yes),
78            AC_MSG_ERROR([summary failure. Aborting config]); exit 1;,
79            AC_MSG_WARN([cannot run when cross-compiling]))
80
81 LIBS=`echo $LIBS | sed -e 's/ *//g'`
82 if test x"$LIBS" != x""; then
83         echo "LIBS: $LIBS"
84         AC_MSG_WARN([the global \$LIBS variable contains some libraries!])
85         AC_MSG_WARN([this should not happen, please report to samba-technical@lists.samba.org!])
86         AC_MSG_ERROR([only _EXT macros from aclocal.m4 should be used!])
87 fi
88
89 dnl Remove -L/usr/lib/? from LDFLAGS and LIBS
90 LIB_REMOVE_USR_LIB(LDFLAGS)
91 LIB_REMOVE_USR_LIB(LIBS)
92
93 dnl Remove -I/usr/include/? from CFLAGS and CPPFLAGS
94 CFLAGS_REMOVE_USR_INCLUDE(CFLAGS)
95 CFLAGS_REMOVE_USR_INCLUDE(CPPFLAGS)
96
97 AC_SUBST(ac_default_prefix)
98
99 for d in build/smb_build bin include ; do
100     test -d ${builddir}/$d || AS_MKDIR_P(${builddir}/$d)
101 done
102
103 echo "configure: creating build/smb_build/config.pm"
104 cat >build/smb_build/config.pm<<CEOF
105 # config.pm - Autogenerate by configure. DO NOT EDIT!
106
107 package config;
108 require Exporter;
109 @ISA = qw(Exporter);
110 @EXPORT_OK = qw(%enabled %config);
111 use strict;
112
113 use vars qw(%enabled %config);
114
115 %config = (AC_FOREACH([AC_Var], m4_defn([_AC_SUBST_VARS]), [
116         AC_Var => '$AC_Var',])
117 );
118
119 $SMB_INFO_ENABLES
120 1;
121 CEOF
122
123 echo "configure: creating config.mk"
124 cat >config.mk<<CEOF
125 # config.mk - Autogenerated by configure, DO NOT EDIT!
126 $SMB_INFO_EXT_LIBS
127 $SMB_INFO_SUBSYSTEMS
128 $SMB_INFO_LIBRARIES
129 CEOF
130
131 AC_OUTPUT_COMMANDS(
132 [
133 test "x$ac_abs_srcdir" != "x$ac_abs_builddir" && (
134         cd $builddir;
135         # NOTE: We *must* use -R so we don't follow symlinks (at least on BSD
136         # systems).
137         test -d heimdal || cp -R $srcdir/heimdal $builddir/
138         test -d heimdal_build || cp -R $srcdir/heimdal_build $builddir/
139         test -d build || builddir="$builddir" \
140                         srcdir="$srcdir" \
141                         $PERL ${srcdir}/script/buildtree.pl
142  )
143
144 $PERL -I${builddir} -I${builddir}/build \
145     -I${srcdir} -I${srcdir}/build \
146     ${srcdir}/build/smb_build/main.pl || exit $?
147 ],
148 [
149 srcdir="$srcdir"
150 builddir="$builddir"
151 PERL="$PERL"
152
153 export PERL
154 export srcdir
155 export builddir
156 ])
157 AC_OUTPUT
158
159 cmp include/config_tmp.h include/config.h >/dev/null 2>&1
160 CMP_RET=$?
161 if test $CMP_RET != 0; then
162         cp include/config_tmp.h include/config.h
163 fi