source/configure.ac

   1 dnl -*- mode: m4-mode -*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 dnl disabled 2.53 requirement - we do work with 2.52 on suse 7.3 for example
   5 dnl AC_PREREQ(2.53)
   6
   7 AC_INIT([samba],[],[samba-technical@samba.org])
   8
   9 AC_CONFIG_SRCDIR([include/includes.h])
  10 AC_CONFIG_HEADER(include/config_tmp.h)
  11 AC_DEFINE(CONFIG_H_IS_FROM_SAMBA,1,[Marker for samba's config.h])
  12
  13 # Configuration rules.
  14 m4_include(build/m4/env.m4)
  15 m4_include(lib/replace/samba.m4)
  16 m4_include(lib/smbreadline/readline.m4)
  17 m4_include(heimdal_build/config.m4)
  18 m4_include(lib/util/fault.m4)
  19 m4_include(lib/util/signal.m4)
  20 m4_include(lib/util/util.m4)
  21 m4_include(lib/util/fsusage.m4)
  22 m4_include(lib/util/xattr.m4)
  23 m4_include(lib/util/capability.m4)
  24 m4_include(lib/util/time.m4)
  25 m4_include(lib/popt/samba.m4)
  26 m4_include(lib/charset/config.m4)
  27 m4_include(lib/socket/config.m4)
  28
  29 SMB_EXT_LIB_FROM_PKGCONFIG(LIBTALLOC, talloc >= 1.0,
  30                            [samba_cv_internal_talloc=no],
  31                            [samba_cv_internal_talloc=yes])
  32 if test x"$samba_cv_internal_talloc" = x"yes"; then
  33         m4_include(lib/talloc/libtalloc.m4)
  34         SMB_INCLUDE_MK(lib/talloc/config.mk)
  35 fi
  36
  37 SMB_EXT_LIB_FROM_PKGCONFIG(LIBTDB, tdb >= 1.1.0,
  38                            [samba_cv_internal_tdb=no],
  39                            [samba_cv_internal_tdb=yes])
  40 if test x"$samba_cv_internal_tdb" = x"yes"; then
  41         m4_include(lib/tdb/libtdb.m4)
  42         SMB_INCLUDE_MK(lib/tdb/config.mk)
  43 fi
  44
  45 m4_include(lib/ldb/sqlite3.m4)
  46 m4_include(lib/ldb/libldb.m4)
  47 m4_include(lib/tls/config.m4)
  48 m4_include(lib/events/config.m4)
  49
  50 dnl m4_include(auth/kerberos/config.m4)
  51
  52 m4_include(auth/gensec/config.m4)
  53 m4_include(smbd/process_model.m4)
  54 m4_include(scripting/swig/config.m4)
  55 m4_include(ntvfs/posix/config.m4)
  56 m4_include(ntvfs/unixuid/config.m4)
  57 m4_include(lib/socket_wrapper/config.m4)
  58 m4_include(auth/config.m4)
  59 m4_include(kdc/config.m4)
  60 m4_include(ntvfs/sysdep/config.m4)
  61 m4_include(lib/appweb/config.m4)
  62 m4_include(nsswitch/config.m4)
  63 m4_include(libcli/config.m4)
  64
  65 #################################################
  66 # add *_CFLAGS only for the real build
  67 CFLAGS="${CFLAGS} ${DEVELOPER_CFLAGS}"
  68
  69 #################################################
  70 # final configure stuff
  71
  72 AC_MSG_CHECKING([configure summary])
  73 AC_TRY_RUN([#include "${srcdir-.}/build/tests/summary.c"],
  74            AC_MSG_RESULT(yes),
  75            AC_MSG_ERROR([summary failure. Aborting config]); exit 1;,
  76            AC_MSG_WARN([cannot run when cross-compiling]))
  77
  78 LIBS=`echo $LIBS | sed -e 's/ *//g'`
  79 if test x"$LIBS" != x""; then
  80         echo "LIBS: $LIBS"
  81         AC_MSG_WARN([the global \$LIBS variable contains some libraries!])
  82         AC_MSG_WARN([this should not happen, please report to samba-technical@lists.samba.org!])
  83         AC_MSG_ERROR([only _EXT macros from aclocal.m4 should be used!])
  84 fi
  85
  86 dnl Remove -L/usr/lib/? from LDFLAGS and LIBS
  87 LIB_REMOVE_USR_LIB(LDFLAGS)
  88 LIB_REMOVE_USR_LIB(LIBS)
  89
  90 dnl Remove -I/usr/include/? from CFLAGS and CPPFLAGS
  91 CFLAGS_REMOVE_USR_INCLUDE(CFLAGS)
  92 CFLAGS_REMOVE_USR_INCLUDE(CPPFLAGS)
  93
  94 AC_SUBST(ac_default_prefix)
  95
  96 for d in build/smb_build bin include ; do
  97     test -d ${builddir}/$d || AS_MKDIR_P(${builddir}/$d)
  98 done
  99
 100 echo "configure: creating build/smb_build/config.pm"
 101 cat >build/smb_build/config.pm<<CEOF
 102 # config.pm - Autogenerate by configure. DO NOT EDIT!
 103
 104 package config;
 105 require Exporter;
 106 @ISA = qw(Exporter);
 107 @EXPORT_OK = qw(%enabled %config);
 108 use strict;
 109
 110 use vars qw(%enabled %config);
 111
 112 %config = (AC_FOREACH([AC_Var], m4_defn([_AC_SUBST_VARS]), [
 113         AC_Var => '$AC_Var',])
 114 );
 115
 116 $SMB_INFO_ENABLES
 117 1;
 118 CEOF
 119
 120 echo "configure: creating config.mk"
 121 cat >config.mk<<CEOF
 122 # config.mk - Autogenerated by configure, DO NOT EDIT!
 123 $SMB_INFO_EXT_LIBS
 124 $SMB_INFO_SUBSYSTEMS
 125 $SMB_INFO_LIBRARIES
 126 CEOF
 127
 128 AC_OUTPUT_COMMANDS(
 129 [
 130 test "x$ac_abs_srcdir" != "x$ac_abs_builddir" && (
 131         cd $builddir;
 132         # NOTE: We *must* use -R so we don't follow symlinks (at least on BSD
 133         # systems).
 134         test -d heimdal || cp -R $srcdir/heimdal $builddir/
 135         test -d heimdal_build || cp -R $srcdir/heimdal_build $builddir/
 136         test -d build || builddir="$builddir" \
 137                         srcdir="$srcdir" \
 138                         $PERL ${srcdir}/script/buildtree.pl
 139  )
 140
 141 $PERL -I${builddir} -I${builddir}/build \
 142     -I${srcdir} -I${srcdir}/build \
 143     ${srcdir}/build/smb_build/main.pl || exit $?
 144 ],
 145 [
 146 srcdir="$srcdir"
 147 builddir="$builddir"
 148 PERL="$PERL"
 149
 150 export PERL
 151 export srcdir
 152 export builddir
 153 ])
 154 AC_OUTPUT
 155
 156 cmp include/config_tmp.h include/config.h >/dev/null 2>&1
 157 CMP_RET=$?
 158 if test $CMP_RET != 0; then
 159         cp include/config_tmp.h include/config.h
 160 fi