r22697: Support building with external talloc.
[jelmer/samba4-debian.git] / source / configure.ac
1 dnl -*- mode: m4-mode -*-
2 dnl Process this file with autoconf to produce a configure script.
3
4 dnl disabled 2.53 requirement - we do work with 2.52 on suse 7.3 for example
5 dnl AC_PREREQ(2.53)
6
7 AC_INIT([samba],[],[samba-technical@samba.org])
8
9 AC_CONFIG_SRCDIR([include/includes.h])
10 AC_CONFIG_HEADER(include/config_tmp.h)
11 AC_DEFINE(CONFIG_H_IS_FROM_SAMBA,1,[Marker for samba's config.h])
12
13 # Configuration rules.
14 m4_include(build/m4/env.m4)
15 m4_include(lib/replace/samba.m4)
16 m4_include(lib/smbreadline/readline.m4)
17 m4_include(heimdal_build/config.m4)
18 m4_include(lib/util/fault.m4)
19 m4_include(lib/util/signal.m4)
20 m4_include(lib/util/util.m4)
21 m4_include(lib/util/fsusage.m4)
22 m4_include(lib/util/xattr.m4)
23 m4_include(lib/util/capability.m4)
24 m4_include(lib/util/time.m4)
25 m4_include(lib/popt/samba.m4)
26 m4_include(lib/charset/config.m4)
27 m4_include(lib/socket/config.m4)
28 SMB_EXT_LIB_FROM_PKGCONFIG(LIBTALLOC, talloc >= 1.0, [], [
29         m4_include(lib/talloc/libtalloc.m4)
30         SMB_INCLUDE_MK(lib/talloc/config.mk)
31 ])
32 m4_include(lib/tdb/libtdb.m4)
33 m4_include(lib/ldb/sqlite3.m4)
34 m4_include(lib/ldb/libldb.m4)
35 m4_include(lib/tls/config.m4)
36 m4_include(lib/events/config.m4)
37
38 dnl m4_include(auth/kerberos/config.m4)
39
40 m4_include(auth/gensec/config.m4)
41 m4_include(smbd/process_model.m4)
42 m4_include(scripting/swig/config.m4)
43 m4_include(ntvfs/posix/config.m4)
44 m4_include(ntvfs/unixuid/config.m4)
45 m4_include(lib/socket_wrapper/config.m4)
46 m4_include(auth/config.m4)
47 m4_include(kdc/config.m4)
48 m4_include(ntvfs/sysdep/config.m4)
49 m4_include(lib/appweb/config.m4)
50 m4_include(nsswitch/config.m4)
51 m4_include(libcli/config.m4)
52
53 #################################################
54 # add *_CFLAGS only for the real build
55 CFLAGS="${CFLAGS} ${DEVELOPER_CFLAGS}"
56
57 #################################################
58 # final configure stuff
59
60 AC_MSG_CHECKING([configure summary])
61 AC_TRY_RUN([#include "${srcdir-.}/build/tests/summary.c"],
62            AC_MSG_RESULT(yes),
63            AC_MSG_ERROR([summary failure. Aborting config]); exit 1;,
64            AC_MSG_WARN([cannot run when cross-compiling]))
65
66 LIBS=`echo $LIBS | sed -e 's/ *//g'`
67 if test x"$LIBS" != x""; then
68         echo "LIBS: $LIBS"
69         AC_MSG_WARN([the global \$LIBS variable contains some libraries!])
70         AC_MSG_WARN([this should not happen, please report to samba-technical@lists.samba.org!])
71         AC_MSG_ERROR([only _EXT macros from aclocal.m4 should be used!])
72 fi
73
74 dnl Remove -L/usr/lib/? from LDFLAGS and LIBS
75 LIB_REMOVE_USR_LIB(LDFLAGS)
76 LIB_REMOVE_USR_LIB(LIBS)
77
78 dnl Remove -I/usr/include/? from CFLAGS and CPPFLAGS
79 CFLAGS_REMOVE_USR_INCLUDE(CFLAGS)
80 CFLAGS_REMOVE_USR_INCLUDE(CPPFLAGS)
81
82 AC_SUBST(ac_default_prefix)
83
84 for d in build/smb_build bin include ; do
85     test -d ${builddir}/$d || AS_MKDIR_P(${builddir}/$d)
86 done
87
88 echo "configure: creating build/smb_build/config.pm"
89 cat >build/smb_build/config.pm<<CEOF
90 # config.pm - Autogenerate by configure. DO NOT EDIT!
91
92 package config;
93 require Exporter;
94 @ISA = qw(Exporter);
95 @EXPORT_OK = qw(%enabled %config);
96 use strict;
97
98 use vars qw(%enabled %config);
99
100 %config = (AC_FOREACH([AC_Var], m4_defn([_AC_SUBST_VARS]), [
101         AC_Var => '$AC_Var',])
102 );
103
104 $SMB_INFO_ENABLES
105 1;
106 CEOF
107
108 echo "configure: creating config.mk"
109 cat >config.mk<<CEOF
110 # config.mk - Autogenerated by configure, DO NOT EDIT!
111 $SMB_INFO_EXT_LIBS
112 $SMB_INFO_SUBSYSTEMS
113 $SMB_INFO_LIBRARIES
114 CEOF
115
116 AC_OUTPUT_COMMANDS(
117 [
118 test "x$ac_abs_srcdir" != "x$ac_abs_builddir" && (
119         cd $builddir;
120         # NOTE: We *must* use -R so we don't follow symlinks (at least on BSD
121         # systems).
122         test -d heimdal || cp -R $srcdir/heimdal $builddir/
123         test -d heimdal_build || cp -R $srcdir/heimdal_build $builddir/
124         test -d build || builddir="$builddir" \
125                         srcdir="$srcdir" \
126                         $PERL ${srcdir}/script/buildtree.pl
127  )
128
129 $PERL -I${builddir} -I${builddir}/build \
130     -I${srcdir} -I${srcdir}/build \
131     ${srcdir}/build/smb_build/main.pl || exit $?
132 ],
133 [
134 srcdir="$srcdir"
135 builddir="$builddir"
136 PERL="$PERL"
137
138 export PERL
139 export srcdir
140 export builddir
141 ])
142 AC_OUTPUT
143
144 cmp include/config_tmp.h include/config.h >/dev/null 2>&1
145 CMP_RET=$?
146 if test $CMP_RET != 0; then
147         cp include/config_tmp.h include/config.h
148 fi