Merge branch 'v4-0-test' of ssh://git.samba.org/data/git/samba into v4-0-python
[jelmer/samba4-debian.git] / source / configure.ac
1 dnl -*- mode: m4-mode -*-
2 dnl Process this file with autoconf to produce a configure script.
3
4 dnl disabled 2.53 requirement - we do work with 2.52 on suse 7.3 for example
5 dnl AC_PREREQ(2.53)
6
7 AC_INIT([samba],[],[samba-technical@samba.org])
8
9 AC_CONFIG_SRCDIR([include/includes.h])
10 AC_CONFIG_HEADER(include/config_tmp.h)
11 AC_DEFINE(CONFIG_H_IS_FROM_SAMBA,1,[Marker for samba's config.h])
12
13 # Configuration rules.
14 m4_include(build/m4/env.m4)
15 m4_include(lib/replace/samba.m4)
16 m4_include(lib/smbreadline/readline.m4)
17 m4_include(heimdal_build/config.m4)
18 m4_include(lib/util/fault.m4)
19 m4_include(lib/util/signal.m4)
20 m4_include(lib/util/util.m4)
21 m4_include(lib/util/fsusage.m4)
22 m4_include(lib/util/xattr.m4)
23 m4_include(lib/util/capability.m4)
24 m4_include(lib/util/time.m4)
25 m4_include(lib/popt/samba.m4)
26 m4_include(lib/charset/config.m4)
27 m4_include(lib/socket/config.m4)
28 m4_include(nsswitch/nsstest.m4)
29
30 AC_CONFIG_FILES(lib/registry/registry.pc)
31 AC_CONFIG_FILES(librpc/dcerpc.pc)
32 AC_CONFIG_FILES(librpc/ndr.pc)
33 AC_CONFIG_FILES(torture/torture.pc)
34 AC_CONFIG_FILES(auth/gensec/gensec.pc)
35 AC_CONFIG_FILES(param/samba-config.pc)
36 AC_CONFIG_FILES(librpc/dcerpc_samr.pc)
37
38 SMB_EXT_LIB_FROM_PKGCONFIG(LIBTALLOC, talloc >= 1.1.0,
39         [],
40         [
41                 m4_include(lib/talloc/libtalloc.m4)
42                 SMB_INCLUDE_MK(lib/talloc/config.mk)
43                 AC_CONFIG_FILES(lib/talloc/talloc.pc)
44         ]
45 )
46
47 SMB_EXT_LIB_FROM_PKGCONFIG(LIBTDB, tdb >= 1.1.0,
48         [],
49         [
50                 m4_include(lib/tdb/libtdb.m4)
51                 SMB_INCLUDE_MK(lib/tdb/config.mk)
52                 AC_CONFIG_FILES(lib/tdb/tdb.pc)
53         ]
54 )
55
56 SMB_INCLUDE_MK(lib/tdb/python.mk) 
57
58 SMB_EXT_LIB_FROM_PKGCONFIG(LIBLDB, ldb >= 0.9.1,
59         [
60                 SMB_INCLUDE_MK(lib/ldb/ldb_ildap/config.mk)
61                 SMB_INCLUDE_MK(lib/ldb/tools/config.mk)
62                 SMB_SUBSYSTEM(ldb_map, [], [LIBLDB])
63                 define_ldb_modulesdir=no
64         ],
65         [
66                 # Here we need to do some tricks
67                 # with AC_CONFIG_COMMANDS_PRE
68                 # as that's the deferrs the commands
69                 # to location after $prefix and $exec_prefix
70                 # have usefull values and directly before
71                 # creating config.status.
72                 #
73                 # The 'eval eval echo' trick is used to
74                 # actually get the raw absolute directory
75                 # path as this is needed in config.h
76                 define_ldb_modulesdir=yes
77                 AC_CONFIG_COMMANDS_PRE([
78                 if test x"$define_ldb_modulesdir" = x"yes";then
79                         LDB_MODULESDIR=`eval eval echo ${modulesdir}/ldb`
80                         AC_DEFINE_UNQUOTED(LDB_MODULESDIR, "${LDB_MODULESDIR}" , [ldb Modules directory])
81                 fi
82                 ])
83                 m4_include(lib/ldb/sqlite3.m4)
84                 m4_include(lib/ldb/libldb.m4)
85                 SMB_INCLUDE_MK(lib/ldb/config.mk)
86                 AC_CONFIG_FILES(lib/ldb/ldb.pc)
87         ]
88 )
89 SMB_INCLUDE_MK(lib/ldb/python.mk) 
90
91 m4_include(lib/tls/config.m4)
92 m4_include(lib/events/config.m4)
93
94 dnl m4_include(auth/kerberos/config.m4)
95 m4_include(scripting/python/config.m4)
96 m4_include(auth/gensec/config.m4)
97 m4_include(smbd/process_model.m4)
98 m4_include(ntvfs/posix/config.m4)
99 m4_include(ntvfs/unixuid/config.m4)
100 m4_include(lib/socket_wrapper/config.m4)
101 m4_include(lib/nss_wrapper/config.m4)
102 m4_include(auth/config.m4)
103 m4_include(kdc/config.m4)
104 m4_include(ntvfs/sysdep/config.m4)
105 m4_include(lib/appweb/config.m4)
106 m4_include(nsswitch/config.m4)
107
108 #################################################
109 # add *_CFLAGS only for the real build
110 CFLAGS="${CFLAGS} ${DEVELOPER_CFLAGS}"
111
112 #################################################
113 # final configure stuff
114
115 AC_MSG_CHECKING([configure summary])
116 AC_TRY_RUN([#include "${srcdir-.}/build/tests/summary.c"],
117            AC_MSG_RESULT(yes),
118            AC_MSG_ERROR([summary failure. Aborting config]); exit 1;,
119            AC_MSG_WARN([cannot run when cross-compiling]))
120
121 LIBS=`echo $LIBS | sed -e 's/ *//g'`
122 if test x"$LIBS" != x""; then
123         echo "LIBS: $LIBS"
124         AC_MSG_WARN([the global \$LIBS variable contains some libraries!])
125         AC_MSG_WARN([this should not happen, please report to samba-technical@lists.samba.org!])
126         AC_MSG_ERROR([only _EXT macros from aclocal.m4 should be used!])
127 fi
128
129 dnl Remove -L/usr/lib/? from LDFLAGS and LIBS
130 LIB_REMOVE_USR_LIB(LDFLAGS)
131 LIB_REMOVE_USR_LIB(LIBS)
132
133 dnl Remove -I/usr/include/? from CFLAGS and CPPFLAGS
134 CFLAGS_REMOVE_USR_INCLUDE(CFLAGS)
135 CFLAGS_REMOVE_USR_INCLUDE(CPPFLAGS)
136
137 AC_SUBST(ac_default_prefix)
138
139 for d in build/smb_build bin include ; do
140     test -d ${builddir}/$d || AS_MKDIR_P(${builddir}/$d)
141 done
142
143 echo "configure: creating build/smb_build/config.pm"
144 cat >build/smb_build/config.pm<<CEOF
145 # config.pm - Autogenerate by configure. DO NOT EDIT!
146
147 package config;
148 require Exporter;
149 @ISA = qw(Exporter);
150 @EXPORT_OK = qw(%enabled %config);
151 use strict;
152
153 use vars qw(%enabled %config);
154
155 %config = (AC_FOREACH([AC_Var], m4_defn([_AC_SUBST_VARS]), [
156         AC_Var => '$AC_Var',])
157 );
158
159 $SMB_INFO_ENABLES
160 1;
161 CEOF
162
163 echo "configure: creating config.mk"
164 cat >config.mk<<CEOF
165 # config.mk - Autogenerated by configure, DO NOT EDIT!
166 $SMB_INFO_EXT_LIBS
167 $SMB_INFO_SUBSYSTEMS
168 $SMB_INFO_LIBRARIES
169 CEOF
170
171 AC_OUTPUT_COMMANDS(
172 [
173 test "x$ac_abs_srcdir" != "x$ac_abs_builddir" && (
174         cd $builddir;
175         # NOTE: We *must* use -R so we don't follow symlinks (at least on BSD
176         # systems).
177         test -d heimdal || cp -R $srcdir/heimdal $builddir/
178         test -d heimdal_build || cp -R $srcdir/heimdal_build $builddir/
179         test -d build || builddir="$builddir" \
180                         srcdir="$srcdir" \
181                         $PERL ${srcdir}/script/buildtree.pl
182  )
183
184 $PERL -I${builddir} -I${builddir}/build \
185     -I${srcdir} -I${srcdir}/build \
186     ${srcdir}/build/smb_build/main.pl || exit $?
187 ],
188 [
189 srcdir="$srcdir"
190 builddir="$builddir"
191 PERL="$PERL"
192
193 export PERL
194 export srcdir
195 export builddir
196 ])
197 AC_OUTPUT
198
199 cmp include/config_tmp.h include/config.h >/dev/null 2>&1
200 CMP_RET=$?
201 if test $CMP_RET != 0; then
202         cp include/config_tmp.h include/config.h
203 fi
204
205 echo "configure: creating mkconfig.mk"
206 cat >mkconfig.mk<<CEOF
207 # mkconfig.mk - Autogenerated by configure, DO NOT EDIT!
208 AC_FOREACH([AC_Var], m4_defn([_AC_SUBST_VARS]), [
209 AC_Var = $AC_Var])
210 $MAKE_SETTINGS
211 CEOF