r19227: - add a AC_CACHE_CHECK() around the net/if.h test
[ira/wip.git] / source4 / lib / replace / libreplace.m4
1 AC_DEFUN_ONCE(AC_LIBREPLACE_LOCATION_CHECKS,
2 [
3 echo "LIBREPLACE_LOCATION_CHECKS: START"
4
5 dnl find the libreplace sources. This is meant to work both for 
6 dnl libreplace standalone builds, and builds of packages using libreplace
7 libreplacedir=""
8 libreplacepaths="$srcdir $srcdir/lib/replace $srcdir/libreplace $srcdir/../libreplace $srcdir/../replace"
9 for d in $libreplacepaths; do
10         if test -f "$d/replace.c"; then
11                 libreplacedir="$d"              
12                 AC_SUBST(libreplacedir)
13                 break;
14         fi
15 done
16 if test x"$libreplacedir" = "x"; then
17         AC_MSG_ERROR([cannot find libreplace in $libreplacepaths])
18 fi
19 LIBREPLACEOBJ="replace.o"
20 AC_SUBST(LIBREPLACEOBJ)
21
22 AC_CANONICAL_BUILD
23 AC_CANONICAL_HOST
24 AC_CANONICAL_TARGET
25
26 echo "LIBREPLACE_LOCATION_CHECKS: END"
27 ]) dnl end AC_LIBREPLACE_LOCATION_CHECKS
28
29
30 AC_DEFUN_ONCE(AC_LIBREPLACE_BROKEN_CHECKS,
31 [
32 echo "LIBREPLACE_BROKEN_CHECKS: START"
33
34 dnl find the libreplace sources. This is meant to work both for 
35 dnl libreplace standalone builds, and builds of packages using libreplace
36 libreplacedir=""
37 for d in "$srcdir" "$srcdir/lib/replace" "$srcdir/libreplace" "$srcdir/../libreplace" "$srcdir/../replace"; do
38         if test -f "$d/replace.c"; then
39                 libreplacedir="$d"              
40                 AC_SUBST(libreplacedir)
41                 break;
42         fi
43 done
44 LIBREPLACEOBJ="replace.o"
45 AC_SUBST(LIBREPLACEOBJ)
46
47 LIBREPLACEOBJ="${LIBREPLACEOBJ} snprintf.o"
48
49 AC_TYPE_SIGNAL
50 AC_TYPE_UID_T
51 AC_TYPE_MODE_T
52 AC_TYPE_OFF_T
53 AC_TYPE_SIZE_T
54 AC_TYPE_PID_T
55 AC_STRUCT_ST_RDEV
56 AC_CHECK_TYPE(ino_t,unsigned)
57 AC_CHECK_TYPE(loff_t,off_t)
58 AC_CHECK_TYPE(offset_t,loff_t)
59
60 AC_FUNC_MEMCMP
61
62 AC_CHECK_FUNCS(pipe strftime srandom random srand rand usleep setbuffer lstat getpgrp)
63
64 AC_CHECK_HEADERS(stdbool.h sys/select.h)
65
66 AC_CHECK_HEADERS(sys/epoll.h)
67 AC_CHECK_FUNCS(epoll_create)
68
69 AC_CHECK_TYPE(bool, 
70 [AC_DEFINE(HAVE_BOOL, 1, [Whether the bool type is available])],,
71 [
72 AC_INCLUDES_DEFAULT
73 #ifdef HAVE_STDBOOL_H
74 #include <stdbool.h>
75 #endif]
76 )
77
78 AC_CHECK_TYPE(_Bool, 
79 [AC_DEFINE(HAVE__Bool, 1, [Whether the _Bool type is available])],,
80 [
81 AC_INCLUDES_DEFAULT
82 #ifdef HAVE_STDBOOL_H
83 #include <stdbool.h>
84 #endif]
85 )
86
87 AC_CACHE_CHECK([for working mmap],samba_cv_HAVE_MMAP,[
88 AC_TRY_RUN([#include "$libreplacedir/test/shared_mmap.c"],
89            samba_cv_HAVE_MMAP=yes,samba_cv_HAVE_MMAP=no,samba_cv_HAVE_MMAP=cross)])
90 if test x"$samba_cv_HAVE_MMAP" = x"yes"; then
91     AC_DEFINE(HAVE_MMAP,1,[Whether mmap works])
92 fi
93
94
95 AC_CHECK_HEADERS(sys/syslog.h syslog.h)
96 AC_CHECK_HEADERS(sys/time.h time.h)
97 AC_CHECK_HEADERS(stdarg.h vararg.h)
98 AC_CHECK_HEADERS(sys/socket.h netinet/in.h netdb.h arpa/inet.h)
99 AC_CHECK_HEADERS(netinet/ip.h netinet/tcp.h netinet/in_systm.h netinet/in_ip.h)
100 AC_CHECK_HEADERS(sys/sockio.h sys/un.h)
101
102
103 dnl we need to check that net/if.h really can be used, to cope with hpux
104 dnl where including it always fails
105 AC_CACHE_CHECK([for usable net/if.h],libreplace_cv_USABLE_NET_IF_H,[
106         AC_COMPILE_IFELSE([
107                 AC_INCLUDES_DEFAULT
108                 #if HAVE_SYS_SOCKET_H
109                 # include <sys/socket.h>
110                 #endif
111                 #include <net/if.h>
112                 int main(void) {return 0;}],
113                 [libreplace_cv_USABLE_NET_IF_H=yes],
114                 [libreplace_cv_USABLE_NET_IF_H=no]
115         )
116 ])
117 if test x"$libreplace_cv_USABLE_NET_IF_H" = x"yes";then
118         AC_DEFINE(HAVE_NET_IF_H, 1, usability of net/if.h)
119 fi
120
121 AC_CACHE_CHECK([for broken inet_ntoa],samba_cv_REPLACE_INET_NTOA,[
122 AC_TRY_RUN([
123 #include <stdio.h>
124 #include <unistd.h>
125 #include <sys/types.h>
126 #include <netinet/in.h>
127 #ifdef HAVE_ARPA_INET_H
128 #include <arpa/inet.h>
129 #endif
130 main() { struct in_addr ip; ip.s_addr = 0x12345678;
131 if (strcmp(inet_ntoa(ip),"18.52.86.120") &&
132     strcmp(inet_ntoa(ip),"120.86.52.18")) { exit(0); } 
133 exit(1);}],
134            samba_cv_REPLACE_INET_NTOA=yes,samba_cv_REPLACE_INET_NTOA=no,samba_cv_REPLACE_INET_NTOA=cross)])
135 if test x"$samba_cv_REPLACE_INET_NTOA" = x"yes"; then
136     AC_DEFINE(REPLACE_INET_NTOA,1,[Whether inet_ntoa should be replaced])
137 fi
138
139 dnl Provided by replace.c:
140 AC_TRY_COMPILE([
141 #include <sys/types.h>
142 #if STDC_HEADERS
143 #include <stdlib.h>
144 #include <stddef.h>
145 #endif
146 #include <sys/socket.h>], 
147 [socklen_t foo;],,
148 [AC_DEFINE(socklen_t, int,[Socket length type])])
149
150 AC_CHECK_FUNCS(seteuid setresuid setegid setresgid chroot bzero strerror)
151 AC_CHECK_FUNCS(vsyslog setlinebuf mktime ftruncate chsize rename)
152 AC_CHECK_FUNCS(waitpid strlcpy strlcat innetgr initgroups memmove strdup)
153 AC_CHECK_FUNCS(pread pwrite strndup strcasestr strtok_r mkdtemp)
154 AC_HAVE_DECL(setresuid, [#include <unistd.h>])
155 AC_HAVE_DECL(setresgid, [#include <unistd.h>])
156 AC_HAVE_DECL(errno, [#include <errno.h>])
157
158 AC_CACHE_CHECK([for secure mkstemp],samba_cv_HAVE_SECURE_MKSTEMP,[
159 AC_TRY_RUN([#include <stdlib.h>
160 #include <sys/types.h>
161 #include <sys/stat.h>
162 #include <unistd.h>
163 main() { 
164   struct stat st;
165   char tpl[20]="/tmp/test.XXXXXX"; 
166   int fd = mkstemp(tpl); 
167   if (fd == -1) exit(1);
168   unlink(tpl);
169   if (fstat(fd, &st) != 0) exit(1);
170   if ((st.st_mode & 0777) != 0600) exit(1);
171   exit(0);
172 }],
173 samba_cv_HAVE_SECURE_MKSTEMP=yes,
174 samba_cv_HAVE_SECURE_MKSTEMP=no,
175 samba_cv_HAVE_SECURE_MKSTEMP=cross)])
176 if test x"$samba_cv_HAVE_SECURE_MKSTEMP" = x"yes"; then
177     AC_DEFINE(HAVE_SECURE_MKSTEMP,1,[Whether mkstemp is secure])
178 fi
179
180 dnl Provided by snprintf.c:
181 AC_CHECK_HEADERS(stdio.h strings.h)
182 AC_CHECK_DECLS([snprintf, vsnprintf, asprintf, vasprintf])
183 AC_CHECK_FUNCS(snprintf vsnprintf asprintf vasprintf)
184
185 AC_CACHE_CHECK([for C99 vsnprintf],samba_cv_HAVE_C99_VSNPRINTF,[
186 AC_TRY_RUN([
187 #include <sys/types.h>
188 #include <stdio.h>
189 #include <stdarg.h>
190 #include <stdlib.h>
191 void foo(const char *format, ...) { 
192        va_list ap;
193        int len;
194        char buf[20];
195        long long l = 1234567890;
196        l *= 100;
197
198        va_start(ap, format);
199        len = vsnprintf(buf, 0, format, ap);
200        va_end(ap);
201        if (len != 5) exit(1);
202
203        va_start(ap, format);
204        len = vsnprintf(0, 0, format, ap);
205        va_end(ap);
206        if (len != 5) exit(2);
207
208        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(3);
209
210        if (snprintf(buf, 20, "%lld", l) != 12 || strcmp(buf, "123456789000") != 0) exit(4);
211        if (snprintf(buf, 20, "%zu", 123456789) != 9 || strcmp(buf, "123456789") != 0) exit(5);
212        if (snprintf(buf, 20, "%2\$d %1\$d", 3, 4) != 3 || strcmp(buf, "4 3") != 0) exit(6);
213        if (snprintf(buf, 20, "%s", 0) < 3) exit(7);
214
215        exit(0);
216 }
217 main() { foo("hello"); }
218 ],
219 samba_cv_HAVE_C99_VSNPRINTF=yes,samba_cv_HAVE_C99_VSNPRINTF=no,samba_cv_HAVE_C99_VSNPRINTF=cross)])
220 if test x"$samba_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
221     AC_DEFINE(HAVE_C99_VSNPRINTF,1,[Whether there is a C99 compliant vsnprintf])
222 fi
223
224
225 dnl VA_COPY
226 AC_CACHE_CHECK([for va_copy],samba_cv_HAVE_VA_COPY,[
227 AC_TRY_LINK([#include <stdarg.h>
228 va_list ap1,ap2;], [va_copy(ap1,ap2);],
229 samba_cv_HAVE_VA_COPY=yes,samba_cv_HAVE_VA_COPY=no)])
230 if test x"$samba_cv_HAVE_VA_COPY" = x"yes"; then
231     AC_DEFINE(HAVE_VA_COPY,1,[Whether va_copy() is available])
232 fi
233
234 if test x"$samba_cv_HAVE_VA_COPY" != x"yes"; then
235 AC_CACHE_CHECK([for __va_copy],samba_cv_HAVE___VA_COPY,[
236 AC_TRY_LINK([#include <stdarg.h>
237 va_list ap1,ap2;], [__va_copy(ap1,ap2);],
238 samba_cv_HAVE___VA_COPY=yes,samba_cv_HAVE___VA_COPY=no)])
239 if test x"$samba_cv_HAVE___VA_COPY" = x"yes"; then
240     AC_DEFINE(HAVE___VA_COPY,1,[Whether __va_copy() is available])
241 fi
242 fi
243
244 dnl __FUNCTION__ macro
245 AC_CACHE_CHECK([for __FUNCTION__ macro],samba_cv_HAVE_FUNCTION_MACRO,[
246 AC_TRY_COMPILE([#include <stdio.h>], [printf("%s\n", __FUNCTION__);],
247 samba_cv_HAVE_FUNCTION_MACRO=yes,samba_cv_HAVE_FUNCTION_MACRO=no)])
248 if test x"$samba_cv_HAVE_FUNCTION_MACRO" = x"yes"; then
249     AC_DEFINE(HAVE_FUNCTION_MACRO,1,[Whether there is a __FUNCTION__ macro])
250 else
251     dnl __func__ macro
252     AC_CACHE_CHECK([for __func__ macro],samba_cv_HAVE_func_MACRO,[
253     AC_TRY_COMPILE([#include <stdio.h>], [printf("%s\n", __func__);],
254     samba_cv_HAVE_func_MACRO=yes,samba_cv_HAVE_func_MACRO=no)])
255     if test x"$samba_cv_HAVE_func_MACRO" = x"yes"; then
256        AC_DEFINE(HAVE_func_MACRO,1,[Whether there is a __func__ macro])
257     fi
258 fi
259
260 AC_CHECK_HEADERS([sys/param.h limits.h])
261
262 AC_CHECK_TYPE(comparison_fn_t, 
263 [AC_DEFINE(HAVE_COMPARISON_FN_T, 1,[Whether or not we have comparison_fn_t])])
264
265 AC_CHECK_FUNCS(strnlen setenv)
266 AC_CHECK_FUNCS(strtoull __strtoull strtouq strtoll __strtoll strtoq)
267
268 # this test disabled as we don't actually need __VA_ARGS__ yet
269 AC_TRY_CPP([
270 #define eprintf(...) fprintf(stderr, __VA_ARGS__)
271 eprintf("bla", "bar");
272 ], AC_DEFINE(HAVE__VA_ARGS__MACRO, 1, [Whether the __VA_ARGS__ macro is available]))
273
274 # Check prerequisites
275 AC_CHECK_FUNCS([memset printf syslog], [], 
276                            [ AC_MSG_ERROR([Required function not found])])
277
278 AC_CACHE_CHECK([for sig_atomic_t type],samba_cv_sig_atomic_t, [
279     AC_TRY_COMPILE([
280 #include <sys/types.h>
281 #if STDC_HEADERS
282 #include <stdlib.h>
283 #include <stddef.h>
284 #endif
285 #include <signal.h>],[sig_atomic_t i = 0],
286         samba_cv_sig_atomic_t=yes,samba_cv_sig_atomic_t=no)])
287 if test x"$samba_cv_sig_atomic_t" = x"yes"; then
288    AC_DEFINE(HAVE_SIG_ATOMIC_T_TYPE,1,[Whether we have the atomic_t variable type])
289 fi
290
291
292 AC_CACHE_CHECK([for O_DIRECT flag to open(2)],samba_cv_HAVE_OPEN_O_DIRECT,[
293 AC_TRY_COMPILE([
294 #include <unistd.h>
295 #ifdef HAVE_FCNTL_H
296 #include <fcntl.h>
297 #endif],
298 [int fd = open("/dev/null", O_DIRECT);],
299 samba_cv_HAVE_OPEN_O_DIRECT=yes,samba_cv_HAVE_OPEN_O_DIRECT=no)])
300 if test x"$samba_cv_HAVE_OPEN_O_DIRECT" = x"yes"; then
301     AC_DEFINE(HAVE_OPEN_O_DIRECT,1,[Whether the open(2) accepts O_DIRECT])
302 fi 
303
304
305 AC_CACHE_CHECK([that the C compiler can precompile header files],samba_cv_precompiled_headers, [
306         dnl Check whether the compiler can generate precompiled headers
307         touch conftest.h
308         if ${CC-cc} conftest.h 2> /dev/null && test -f conftest.h.gch; then
309                 precompiled_headers=yes
310         else
311                 precompiled_headers=no
312         fi])
313 AC_SUBST(precompiled_headers)
314
315
316 dnl Check if the C compiler understands volatile (it should, being ANSI).
317 AC_CACHE_CHECK([that the C compiler understands volatile],samba_cv_volatile, [
318         AC_TRY_COMPILE([#include <sys/types.h>],[volatile int i = 0],
319                 samba_cv_volatile=yes,samba_cv_volatile=no)])
320 if test x"$samba_cv_volatile" = x"yes"; then
321         AC_DEFINE(HAVE_VOLATILE, 1, [Whether the C compiler understands volatile])
322 fi
323
324 m4_include(system/config.m4)
325
326 m4_include(dlfcn.m4)
327 m4_include(getpass.m4)
328 m4_include(win32.m4)
329 m4_include(timegm.m4)
330 m4_include(repdir.m4)
331
332 AC_CHECK_FUNCS([syslog memset setnetgrent getnetgrent endnetgrent memcpy],,
333                            [AC_MSG_ERROR([Required function not found])])
334
335 echo "LIBREPLACE_BROKEN_CHECKS: END"
336 ]) dnl end AC_LIBREPLACE_BROKEN_CHECKS
337
338 AC_DEFUN_ONCE(AC__LIBREPLACE_ALL_CHECKS_START,
339 [
340 #LIBREPLACE_ALL_CHECKS: START"
341 ])
342 AC_DEFUN_ONCE(AC__LIBREPLACE_ALL_CHECKS_END,
343 [
344 #LIBREPLACE_ALL_CHECKS: END"
345 ])
346 m4_define(AC_LIBREPLACE_ALL_CHECKS,
347 [
348 AC__LIBREPLACE_ALL_CHECKS_START
349 AC_LIBREPLACE_LOCATION_CHECKS
350 AC_LIBREPLACE_CC_CHECKS
351 AC_LIBREPLACE_BROKEN_CHECKS
352 AC__LIBREPLACE_ALL_CHECKS_END
353 ])
354
355 m4_include(libreplace_cc.m4)
356 m4_include(libreplace_macros.m4)
357 m4_include(autoconf-2.60.m4)