source4/configure.ac

   1 dnl -*- mode: m4-mode -*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 dnl disabled 2.53 requirement - we do work with 2.52 on suse 7.3 for example
   5 dnl AC_PREREQ(2.53)
   6
   7 AC_INIT([samba],[],[samba-technical@samba.org])
   8
   9 AC_CONFIG_SRCDIR([include/includes.h])
  10 AC_CONFIG_HEADER(include/config_tmp.h)
  11 AC_DEFINE(CONFIG_H_IS_FROM_SAMBA,1,[Marker for samba's config.h])
  12
  13 # Configuration rules.
  14 m4_include(build/m4/env.m4)
  15 m4_include(lib/replace/samba.m4)
  16 m4_include(lib/smbreadline/readline.m4)
  17 m4_include(heimdal_build/config.m4)
  18 m4_include(lib/util/fault.m4)
  19 m4_include(lib/util/signal.m4)
  20 m4_include(lib/util/util.m4)
  21 m4_include(lib/util/fsusage.m4)
  22 m4_include(lib/util/xattr.m4)
  23 m4_include(lib/util/capability.m4)
  24 m4_include(lib/util/time.m4)
  25 m4_include(lib/popt/samba.m4)
  26 m4_include(lib/charset/config.m4)
  27 m4_include(lib/socket/config.m4)
  28 m4_include(nsswitch/nsstest.m4)
  29
  30 AC_OUTPUT(lib/registry/registry.pc)
  31 AC_OUTPUT(librpc/dcerpc.pc)
  32 AC_OUTPUT(librpc/ndr.pc)
  33 AC_OUTPUT(torture/torture.pc)
  34 AC_OUTPUT(auth/gensec/gensec.pc)
  35 AC_OUTPUT(param/samba-config.pc)
  36
  37 SMB_EXT_LIB_FROM_PKGCONFIG(LIBTALLOC, talloc >= 1.1.0,
  38         [],
  39         [
  40                 m4_include(lib/talloc/libtalloc.m4)
  41                 SMB_INCLUDE_MK(lib/talloc/config.mk)
  42                 AC_OUTPUT(lib/talloc/talloc.pc)
  43         ]
  44 )
  45
  46 SMB_EXT_LIB_FROM_PKGCONFIG(LIBTDB, tdb >= 1.1.0,
  47         [],
  48         [
  49                 m4_include(lib/tdb/libtdb.m4)
  50                 SMB_INCLUDE_MK(lib/tdb/config.mk)
  51                 AC_OUTPUT(lib/tdb/tdb.pc)
  52         ]
  53 )
  54
  55 SMB_INCLUDE_MK(lib/tdb/python.mk)
  56
  57 SMB_EXT_LIB_FROM_PKGCONFIG(LIBLDB, ldb >= 0.9.1,
  58         [
  59                 SMB_INCLUDE_MK(lib/ldb/ldb_ildap/config.mk)
  60                 SMB_INCLUDE_MK(lib/ldb/tools/config.mk)
  61                 SMB_SUBSYSTEM(ldb_map, [], [LIBLDB])
  62                 AC_OUTPUT(lib/ldb/ldb.pc)
  63                 define_ldb_modulesdir=no
  64         ],
  65         [
  66                 # Here we need to do some tricks
  67                 # with AC_CONFIG_COMMANDS_PRE
  68                 # as that's the deferrs the commands
  69                 # to location after $prefix and $exec_prefix
  70                 # have usefull values and directly before
  71                 # creating config.status.
  72                 #
  73                 # The 'eval eval echo' trick is used to
  74                 # actually get the raw absolute directory
  75                 # path as this is needed in config.h
  76                 define_ldb_modulesdir=yes
  77                 AC_CONFIG_COMMANDS_PRE([
  78                 if test x"$define_ldb_modulesdir" = x"yes";then
  79                         LDB_MODULESDIR=`eval eval echo ${modulesdir}/ldb`
  80                         AC_DEFINE_UNQUOTED(LDB_MODULESDIR, "${LDB_MODULESDIR}" , [ldb Modules directory])
  81                 fi
  82                 ])
  83                 m4_include(lib/ldb/sqlite3.m4)
  84                 m4_include(lib/ldb/libldb.m4)
  85                 SMB_INCLUDE_MK(lib/ldb/config.mk)
  86         ]
  87 )
  88 SMB_INCLUDE_MK(lib/ldb/python.mk)
  89
  90 m4_include(lib/tls/config.m4)
  91 m4_include(lib/events/config.m4)
  92
  93 dnl m4_include(auth/kerberos/config.m4)
  94 m4_include(scripting/python/config.m4)
  95 m4_include(auth/gensec/config.m4)
  96 m4_include(smbd/process_model.m4)
  97 m4_include(ntvfs/posix/config.m4)
  98 m4_include(ntvfs/unixuid/config.m4)
  99 m4_include(lib/socket_wrapper/config.m4)
 100 m4_include(lib/nss_wrapper/config.m4)
 101 m4_include(auth/config.m4)
 102 m4_include(kdc/config.m4)
 103 m4_include(ntvfs/sysdep/config.m4)
 104 m4_include(lib/appweb/config.m4)
 105 m4_include(nsswitch/config.m4)
 106
 107 #################################################
 108 # add *_CFLAGS only for the real build
 109 CFLAGS="${CFLAGS} ${DEVELOPER_CFLAGS}"
 110
 111 #################################################
 112 # final configure stuff
 113
 114 AC_MSG_CHECKING([configure summary])
 115 AC_TRY_RUN([#include "${srcdir-.}/build/tests/summary.c"],
 116            AC_MSG_RESULT(yes),
 117            AC_MSG_ERROR([summary failure. Aborting config]); exit 1;,
 118            AC_MSG_WARN([cannot run when cross-compiling]))
 119
 120 LIBS=`echo $LIBS | sed -e 's/ *//g'`
 121 if test x"$LIBS" != x""; then
 122         echo "LIBS: $LIBS"
 123         AC_MSG_WARN([the global \$LIBS variable contains some libraries!])
 124         AC_MSG_WARN([this should not happen, please report to samba-technical@lists.samba.org!])
 125         AC_MSG_ERROR([only _EXT macros from aclocal.m4 should be used!])
 126 fi
 127
 128 dnl Remove -L/usr/lib/? from LDFLAGS and LIBS
 129 LIB_REMOVE_USR_LIB(LDFLAGS)
 130 LIB_REMOVE_USR_LIB(LIBS)
 131
 132 dnl Remove -I/usr/include/? from CFLAGS and CPPFLAGS
 133 CFLAGS_REMOVE_USR_INCLUDE(CFLAGS)
 134 CFLAGS_REMOVE_USR_INCLUDE(CPPFLAGS)
 135
 136 AC_SUBST(ac_default_prefix)
 137
 138 for d in build/smb_build bin include ; do
 139     test -d ${builddir}/$d || AS_MKDIR_P(${builddir}/$d)
 140 done
 141
 142 echo "configure: creating build/smb_build/config.pm"
 143 cat >build/smb_build/config.pm<<CEOF
 144 # config.pm - Autogenerate by configure. DO NOT EDIT!
 145
 146 package config;
 147 require Exporter;
 148 @ISA = qw(Exporter);
 149 @EXPORT_OK = qw(%enabled %config);
 150 use strict;
 151
 152 use vars qw(%enabled %config);
 153
 154 %config = (AC_FOREACH([AC_Var], m4_defn([_AC_SUBST_VARS]), [
 155         AC_Var => '$AC_Var',])
 156 );
 157
 158 $SMB_INFO_ENABLES
 159 1;
 160 CEOF
 161
 162 echo "configure: creating config.mk"
 163 cat >config.mk<<CEOF
 164 # config.mk - Autogenerated by configure, DO NOT EDIT!
 165 $SMB_INFO_EXT_LIBS
 166 $SMB_INFO_SUBSYSTEMS
 167 $SMB_INFO_LIBRARIES
 168 CEOF
 169
 170 AC_OUTPUT_COMMANDS(
 171 [
 172 test "x$ac_abs_srcdir" != "x$ac_abs_builddir" && (
 173         cd $builddir;
 174         # NOTE: We *must* use -R so we don't follow symlinks (at least on BSD
 175         # systems).
 176         test -d heimdal || cp -R $srcdir/heimdal $builddir/
 177         test -d heimdal_build || cp -R $srcdir/heimdal_build $builddir/
 178         test -d build || builddir="$builddir" \
 179                         srcdir="$srcdir" \
 180                         $PERL ${srcdir}/script/buildtree.pl
 181  )
 182
 183 $PERL -I${builddir} -I${builddir}/build \
 184     -I${srcdir} -I${srcdir}/build \
 185     ${srcdir}/build/smb_build/main.pl || exit $?
 186 ],
 187 [
 188 srcdir="$srcdir"
 189 builddir="$builddir"
 190 PERL="$PERL"
 191
 192 export PERL
 193 export srcdir
 194 export builddir
 195 ])
 196 AC_OUTPUT
 197
 198 cmp include/config_tmp.h include/config.h >/dev/null 2>&1
 199 CMP_RET=$?
 200 if test $CMP_RET != 0; then
 201         cp include/config_tmp.h include/config.h
 202 fi