source3/samba4.m4

   1 AC_SUBST(BLDSHARED)
   2 smbtorture4_path="bin/smbtorture4"
   3 smbtorture4_option="-t bin/smbtorture4"
   4 m4_include(build/m4/public.m4)
   5
   6 m4_include(../m4/check_python.m4)
   7
   8 AC_SAMBA_PYTHON_DEVEL([
   9 SMB_EXT_LIB(EXT_LIB_PYTHON, [$PYTHON_LDFLAGS], [$PYTHON_CFLAGS])
  10 SMB_ENABLE(EXT_LIB_PYTHON,YES)
  11 SMB_ENABLE(LIBPYTHON,YES)
  12 ],[
  13 AC_MSG_ERROR([Python not found. Please install Python 2.x and its development headers/libraries.])
  14 ])
  15
  16 AC_MSG_CHECKING(python library directory)
  17 pythondir=`$PYTHON -c "from distutils import sysconfig; print sysconfig.get_python_lib(1, 0, '\\${prefix}')"`
  18 AC_MSG_RESULT($pythondir)
  19
  20 AC_SUBST(pythondir)
  21
  22 SMB_EXT_LIB(LIBREPLACE_EXT, [${LIBDL} ${CRYPT_LIBS}])
  23 SMB_ENABLE(LIBREPLACE_EXT)
  24
  25 SMB_EXT_LIB(LIBREPLACE_NETWORK, [${LIBREPLACE_NETWORK_LIBS}])
  26 SMB_ENABLE(LIBREPLACE_NETWORK)
  27
  28 SMB_SUBSYSTEM(LIBREPLACE,
  29         [${LIBREPLACE_OBJS}],
  30         [LIBREPLACE_EXT LIBREPLACE_NETWORK],
  31         [-I../lib/replace])
  32
  33 LIBREPLACE_HOSTCC_OBJS=`echo ${LIBREPLACE_OBJS} |sed -e 's/\.o/\.ho/g'`
  34
  35 SMB_SUBSYSTEM(LIBREPLACE_HOSTCC,
  36         [${LIBREPLACE_HOSTCC_OBJS}],
  37         [],
  38         [-I../lib/replace])
  39
  40 m4_include(lib/smbreadline/readline.m4)
  41 m4_include(heimdal_build/internal.m4)
  42 m4_include(../lib/util/fault.m4)
  43 m4_include(../lib/util/signal.m4)
  44 m4_include(../lib/util/util.m4)
  45 m4_include(../lib/util/fsusage.m4)
  46 m4_include(../lib/util/xattr.m4)
  47 m4_include(../lib/util/capability.m4)
  48 m4_include(../lib/util/time.m4)
  49 m4_include(../lib/popt/samba.m4)
  50 m4_include(../lib/util/charset/config.m4)
  51 m4_include(lib/socket/config.m4)
  52 m4_include(../nsswitch/nsstest.m4)
  53 m4_include(../pidl/config.m4)
  54 AC_ZLIB([
  55 SMB_EXT_LIB(ZLIB, [${ZLIB_LIBS}])
  56 ],[
  57 SMB_INCLUDE_MK(lib/zlib.mk)
  58 ])
  59
  60
  61 AC_CONFIG_FILES(../source4/lib/registry/registry.pc)
  62 AC_CONFIG_FILES(../source4/librpc/dcerpc.pc)
  63 AC_CONFIG_FILES(../librpc/ndr.pc)
  64 AC_CONFIG_FILES(../lib/torture/torture.pc)
  65 AC_CONFIG_FILES(../source4/auth/gensec/gensec.pc)
  66 AC_CONFIG_FILES(../source4/param/samba-hostconfig.pc)
  67 AC_CONFIG_FILES(../source4/librpc/dcerpc_samr.pc)
  68 AC_CONFIG_FILES(../source4/librpc/dcerpc_atsvc.pc)
  69
  70 SMB_EXT_LIB_FROM_PKGCONFIG(LIBTALLOC, talloc >= 1.2.0,
  71         [],
  72         [
  73                 SMB_INCLUDE_MK(../lib/talloc/config.mk)
  74         ]
  75 )
  76
  77 SMB_EXT_LIB_FROM_PKGCONFIG(LIBTDB, tdb >= 1.1.3,
  78         [],
  79         [
  80                 m4_include(../lib/tdb/libtdb.m4)
  81                 SMB_INCLUDE_MK(../lib/tdb/config.mk)
  82         ]
  83 )
  84
  85 SMB_INCLUDE_MK(../lib/tdb/python.mk)
  86
  87 SMB_EXT_LIB_FROM_PKGCONFIG(LIBTEVENT, tevent = 0.9.4,
  88         [],[m4_include(../lib/tevent/samba.m4)]
  89 )
  90
  91 SMB_INCLUDE_MK(../lib/tevent/python.mk)
  92
  93 SMB_EXT_LIB_FROM_PKGCONFIG(LIBLDB, ldb = 0.9.3,
  94         [
  95                 SMB_INCLUDE_MK(lib/ldb/ldb_ildap/config.mk)
  96                 SMB_INCLUDE_MK(lib/ldb/tools/config.mk)
  97                 define_ldb_modulesdir=no
  98         ],
  99         [
 100                 # Here we need to do some tricks
 101                 # with AC_CONFIG_COMMANDS_PRE
 102                 # as that's the deferrs the commands
 103                 # to location after $prefix and $exec_prefix
 104                 # have usefull values and directly before
 105                 # creating config.status.
 106                 #
 107                 # The 'eval eval echo' trick is used to
 108                 # actually get the raw absolute directory
 109                 # path as this is needed in config.h
 110                 define_ldb_modulesdir=yes
 111                 AC_CONFIG_COMMANDS_PRE([
 112                 if test x"$define_ldb_modulesdir" = x"yes";then
 113                         LDB_MODULESDIR=`eval eval echo ${modulesdir}/ldb`
 114                         AC_DEFINE_UNQUOTED(LDB_MODULESDIR, "${LDB_MODULESDIR}" , [ldb Modules directory])
 115                 fi
 116                 ])
 117                 ldbdir="\$(abspath \$(srcdir)/../source4/lib/ldb)"
 118                 AC_SUBST(ldbdir)
 119                 m4_include(lib/ldb/sqlite3.m4)
 120                 m4_include(lib/ldb/libldb.m4)
 121                 SMB_INCLUDE_MK(lib/ldb/config.mk)
 122                 AC_CONFIG_FILES(../source4/lib/ldb/ldb.pc)
 123         ]
 124 )
 125 SMB_INCLUDE_MK(lib/ldb/python.mk)
 126
 127 # Not sure why we need this..
 128 SMB_ENABLE(swig_ldb,YES)
 129
 130 m4_include(lib/tls/config.m4)
 131
 132 dnl m4_include(auth/kerberos/config.m4)
 133 m4_include(auth/gensec/config.m4)
 134 m4_include(smbd/process_model.m4)
 135 m4_include(ntvfs/posix/config.m4)
 136 m4_include(ntvfs/unixuid/config.m4)
 137 m4_include(auth/config.m4)
 138 m4_include(kdc/config.m4)
 139 m4_include(ntvfs/sysdep/config.m4)
 140 m4_include(../nsswitch/config.m4)
 141
 142 AC_SUBST(INTERN_LDFLAGS)
 143 AC_SUBST(INSTALL_LINK_FLAGS)
 144 if test $USESHARED = "true";
 145 then
 146         INTERN_LDFLAGS="-L\$(shliboutputdir) -L\${builddir}/bin/static"
 147         INSTALL_LINK_FLAGS="-Wl,-rpath-link,\$(shliboutputdir)";
 148 else
 149         INTERN_LDFLAGS="-L\${builddir}/bin/static -L\$(shliboutputdir)"
 150 fi
 151
 152 dnl Samba 4 files
 153 AC_SUBST(LD)
 154 AC_LIBREPLACE_SHLD_FLAGS
 155 dnl Remove -L/usr/lib/? from LDFLAGS and LIBS
 156 LIB_REMOVE_USR_LIB(LDFLAGS)
 157 LIB_REMOVE_USR_LIB(LIBS)
 158 LIB_REMOVE_USR_LIB(KRB5_LIBS)
 159
 160 dnl Remove -I/usr/include/? from CFLAGS and CPPFLAGS
 161 CFLAGS_REMOVE_USR_INCLUDE(CFLAGS)
 162 CFLAGS_REMOVE_USR_INCLUDE(CPPFLAGS)
 163 SMB_WRITE_MAKEVARS(samba4-config.mk, [prefix exec_prefix CPPFLAGS LDSHFLAGS POPT_OBJ CFLAGS TALLOC_OBJ POPT_LIBS srcdir builddir])
 164
 165 oldbuilddir="$builddir"
 166 builddir="$builddir/../source4"
 167 oldsrcdir="$srcdir"
 168 srcdir="$srcdir/../source4"
 169 AC_SUBST(srcdir)
 170 AC_SUBST(builddir)
 171 SMB_WRITE_PERLVARS(../source4/build/smb_build/config.pm)
 172 builddir="$oldbuilddir"
 173 srcdir="$oldsrcdir"
 174
 175 echo "configure: creating ../source4/config.mk"
 176 cat >../source4/config.mk<<CEOF
 177 # config.mk - Autogenerated by configure, DO NOT EDIT!
 178 $SMB_INFO_EXT_LIBS
 179 $SMB_INFO_SUBSYSTEMS
 180 $SMB_INFO_LIBRARIES
 181 CEOF
 182
 183 AC_OUTPUT_COMMANDS([
 184 cd ${srcdir}/../source4
 185 $PERL -I${builddir} -I${builddir}/build \
 186     -I. -Ibuild \
 187     build/smb_build/main.pl --output=../source3/samba4-data.mk main.mk || exit $?
 188 cd ../source3
 189 ],[
 190 srcdir="$srcdir"
 191 builddir="$builddir"
 192 PERL="$PERL"
 193
 194 export PERL
 195 export srcdir
 196 export builddir
 197 ])
 198
 199 AC_CONFIG_COMMANDS([Makefile-samba4], [
 200 echo "include samba4.mk" >> ${builddir}/Makefile
 201 ])
 202