python: Fix python code for winreg, add test.
[ira/wip.git] / source / pidl / lib / Parse / Pidl / Samba4 / Python.pm
1 ###################################################
2 # Python function wrapper generator
3 # Copyright jelmer@samba.org 2007-2008
4 # released under the GNU GPL
5
6 package Parse::Pidl::Samba4::Python;
7
8 use Exporter;
9 @ISA = qw(Exporter);
10
11 use strict;
12 use Parse::Pidl::Typelist qw(hasType resolveType getType mapTypeName expandAlias);
13 use Parse::Pidl::Util qw(has_property ParseExpr);
14 use Parse::Pidl::NDR qw(GetPrevLevel GetNextLevel ContainsDeferred is_charset_array);
15 use Parse::Pidl::CUtil qw(get_value_of get_pointer_to);
16 use Parse::Pidl::Samba4::Header qw(GenerateFunctionInEnv GenerateFunctionOutEnv EnvSubstituteValue GenerateStructEnv);
17
18 use vars qw($VERSION);
19 $VERSION = '0.01';
20
21 sub new($) {
22         my ($class) = @_;
23         my $self = { res => "", res_hdr => "", tabs => "", constants => {},
24                      module_methods => []};
25         bless($self, $class);
26 }
27
28 sub pidl_hdr ($$)
29 {
30         my $self = shift;
31         $self->{res_hdr} .= shift;
32 }
33
34 sub pidl($$)
35 {
36         my ($self, $d) = @_;
37         if ($d) {
38                 $self->{res} .= $self->{tabs};
39                 $self->{res} .= $d;
40         }
41         $self->{res} .= "\n";
42 }
43
44 sub indent($)
45 {
46         my ($self) = @_;
47         $self->{tabs} .= "\t";
48 }
49
50 sub deindent($)
51 {
52         my ($self) = @_;
53         $self->{tabs} = substr($self->{tabs}, 0, -1);
54 }
55
56 sub Import
57 {
58         my $self = shift;
59         my @imports = @_;
60         foreach (@imports) {
61                 s/\.idl\"$//;
62                 s/^\"//;
63                 $self->pidl_hdr("#include \"librpc/gen_ndr/py_$_\.h\"\n");
64         }
65 }
66
67 sub Const($$)
68 {
69     my ($self, $const) = @_;
70         $self->register_constant($const->{NAME}, $const->{DTYPE}, $const->{VALUE});
71 }
72
73 sub register_constant($$$$)
74 {
75         my ($self, $name, $type, $value) = @_;
76
77         $self->{constants}->{$name} = [$type, $value];
78 }
79
80 sub EnumAndBitmapConsts($$$)
81 {
82         my ($self, $name, $d) = @_;
83
84         return unless (defined($d->{ELEMENTS}));
85
86         foreach my $e (@{$d->{ELEMENTS}}) {
87                 $e =~ /^([A-Za-z0-9_]+)/;
88                 my $cname = $1;
89                 
90                 $self->register_constant($cname, $d, $cname);
91         }
92 }
93
94 sub FromUnionToPythonFunction($$$$)
95 {
96         my ($self, $mem_ctx, $type, $switch, $name) = @_;
97
98         $self->pidl("PyObject *ret;");
99         $self->pidl("");
100
101         $self->pidl("switch ($switch) {");
102         $self->indent;
103
104         foreach my $e (@{$type->{ELEMENTS}}) {
105                 if (defined($e->{CASE})) {
106                         $self->pidl("$e->{CASE}:");
107                 } else {
108                         $self->pidl("default:");
109                 }
110
111                 $self->indent;
112
113                 if ($e->{NAME}) {
114                         $self->ConvertObjectToPython($mem_ctx, {}, $e, "$name->$e->{NAME}", "ret");
115                 } else {
116                         $self->pidl("ret = Py_None;");
117                 }
118
119                 $self->pidl("return ret;");
120                 $self->pidl("");
121
122                 $self->deindent;
123         }
124
125         $self->deindent;
126         $self->pidl("}");
127
128         $self->pidl("PyErr_SetString(PyExc_TypeError, \"unknown union level\");");
129         $self->pidl("return NULL;");
130 }
131
132 sub FromPythonToUnionFunction($$$$$)
133 {
134         my ($self, $type, $typename, $switch, $mem_ctx, $name) = @_;
135
136         my $has_default = 0;
137
138         $self->pidl("$typename *ret = talloc_zero($mem_ctx, $typename);");
139
140         $self->pidl("switch ($switch) {");
141         $self->indent;
142
143         foreach my $e (@{$type->{ELEMENTS}}) {
144                 if (defined($e->{CASE})) {
145                         $self->pidl("$e->{CASE}:");
146                 } else {
147                         $has_default = 1;
148                         $self->pidl("default:");
149                 }
150                 $self->indent;
151                 if ($e->{NAME}) {
152                         $self->ConvertObjectFromPython({}, $mem_ctx, $e, $name, "ret->$e->{NAME}", "talloc_free(ret); return NULL;");
153                 }
154                 $self->pidl("break;");
155                 $self->deindent;
156                 $self->pidl("");
157         }
158
159         if (!$has_default) {
160                 $self->pidl("default:");
161                 $self->indent;
162                 $self->pidl("PyErr_SetString(PyExc_TypeError, \"invalid union level value\");");
163                 $self->pidl("talloc_free(ret);");
164                 $self->pidl("ret = NULL;");
165                 $self->deindent;
166         }
167
168         $self->deindent;
169         $self->pidl("}");
170         $self->pidl("");
171         $self->pidl("return ret;");
172 }
173
174 sub PythonStruct($$$$)
175 {
176         my ($self, $name, $cname, $d) = @_;
177
178         my $env = GenerateStructEnv($d, "object");
179
180         $self->pidl("");
181
182         $self->pidl("static PyObject *py_$name\_getattr(PyObject *obj, char *name)");
183         $self->pidl("{");
184         $self->indent;
185         $self->pidl("$cname *object = py_talloc_get_ptr(obj);");
186         foreach my $e (@{$d->{ELEMENTS}}) {
187                 $self->pidl("if (!strcmp(name, \"$e->{NAME}\")) {");
188                 my $varname = "object->$e->{NAME}";
189                 $self->indent;
190                 $self->pidl("PyObject *py_$e->{NAME};");
191                 $self->ConvertObjectToPython("py_talloc_get_mem_ctx(obj)", $env, $e, $varname, "py_$e->{NAME}");
192                 $self->pidl("return py_$e->{NAME};");
193                 $self->deindent;
194                 $self->pidl("}");
195         }
196         $self->pidl("PyErr_SetString(PyExc_AttributeError, \"no such attribute\");");
197         $self->pidl("return NULL;");
198         $self->deindent;
199         $self->pidl("}");
200         $self->pidl("");
201
202         $self->pidl("static int py_$name\_setattr(PyObject *py_obj, char *name, PyObject *value)");
203         $self->pidl("{");
204         $self->indent;
205         $self->pidl("$cname *object = py_talloc_get_ptr(py_obj);");
206         my $mem_ctx = "py_talloc_get_mem_ctx(py_obj)";
207         foreach my $e (@{$d->{ELEMENTS}}) {
208                 $self->pidl("if (!strcmp(name, \"$e->{NAME}\")) {");
209                 my $varname = "object->$e->{NAME}";
210                 $self->indent;
211                 if ($e->{ORIGINAL}->{POINTERS} > 0) {
212                         $self->pidl("talloc_free($varname);");
213                 }
214                 $self->ConvertObjectFromPython($env, $mem_ctx, $e, "value", $varname, "return -1;");
215                 $self->pidl("return 0;");
216                 $self->deindent;
217                 $self->pidl("}");
218         }
219         $self->pidl("PyErr_SetString(PyExc_AttributeError, \"no such attribute\");");
220         $self->pidl("return -1;");
221         $self->deindent;
222         $self->pidl("}");
223         $self->pidl("");
224
225         $self->pidl_hdr("PyAPI_DATA(PyTypeObject) $name\_Type;\n");
226         $self->pidl_hdr("#define $name\_Check(op) PyObject_TypeCheck(op, &$name\_Type)\n");
227         $self->pidl_hdr("#define $name\_CheckExact(op) ((op)->ob_type == &$name\_Type)\n");
228         $self->pidl_hdr("\n");
229         $self->pidl("PyTypeObject $name\_Type = {");
230         $self->indent;
231         $self->pidl("PyObject_HEAD_INIT(NULL) 0,");
232         $self->pidl(".tp_name = \"$name\",");
233         $self->pidl(".tp_basicsize = sizeof(py_talloc_Object),");
234         $self->pidl(".tp_dealloc = py_talloc_dealloc,");
235         $self->pidl(".tp_getattr = py_$name\_getattr,");
236         $self->pidl(".tp_setattr = py_$name\_setattr,");
237         $self->pidl(".tp_repr = py_talloc_default_repr,");
238         $self->deindent;
239         $self->pidl("};");
240
241         $self->pidl("");
242
243         my $py_fnname = "py_$name";
244         $self->pidl("static PyObject *$py_fnname(PyObject *self, PyObject *args)");
245         $self->pidl("{");
246         $self->indent;
247         $self->pidl("$cname *ret = talloc_zero(NULL, $cname);");
248         $self->pidl("return py_talloc_import(&$name\_Type, ret);");
249         $self->deindent;
250         $self->pidl("}");
251         $self->pidl("");
252
253         return $py_fnname;
254 }
255
256 sub PythonFunction($$$)
257 {
258         my ($self, $fn, $iface) = @_;
259
260         $self->pidl("static PyObject *py_$fn->{NAME}(PyObject *self, PyObject *args, PyObject *kwargs)");
261         $self->pidl("{");
262         $self->indent;
263         $self->pidl("$iface\_InterfaceObject *iface = ($iface\_InterfaceObject *)self;");
264         $self->pidl("NTSTATUS status;");
265         $self->pidl("TALLOC_CTX *mem_ctx = talloc_new(NULL);");
266         $self->pidl("struct $fn->{NAME} *r = talloc_zero(mem_ctx, struct $fn->{NAME});");
267         $self->pidl("PyObject *result = Py_None;");
268         
269         my $env = GenerateFunctionInEnv($fn, "r->");
270         my $result_size = 0;
271
272         my $args_format = "";
273         my $args_string = "";
274         my $args_names = "";
275
276         foreach my $e (@{$fn->{ELEMENTS}}) {
277                 $self->pidl("PyObject *py_$e->{NAME};");
278                 if (grep(/out/,@{$e->{DIRECTION}})) {
279                         $result_size++;
280                 }
281                 if (grep(/in/,@{$e->{DIRECTION}})) {
282                         $args_format .= "O";
283                         $args_string .= ", &py_$e->{NAME}";
284                         $args_names .= "\"$e->{NAME}\", ";
285                 }
286         }
287         $self->pidl("const char *kwnames[] = {");
288         $self->indent;
289         $self->pidl($args_names . "NULL");
290         $self->deindent;
291         $self->pidl("};");
292
293         $self->pidl("");
294         $self->pidl("if (!PyArg_ParseTupleAndKeywords(args, kwargs, \"$args_format:$fn->{NAME}\", discard_const_p(char *, kwnames)$args_string)) {");
295         $self->indent;
296         $self->pidl("return NULL;");
297         $self->deindent;
298         $self->pidl("}");
299
300         if ($fn->{RETURN_TYPE}) {
301                 $result_size++;
302         }
303
304         foreach my $e (@{$fn->{ELEMENTS}}) {
305                 if (grep(/in/,@{$e->{DIRECTION}})) {
306                         $self->ConvertObjectFromPython($env, "mem_ctx", $e, "py_$e->{NAME}", "r->in.$e->{NAME}", "talloc_free(mem_ctx); return NULL;");
307                 }
308         }
309         $self->pidl("status = dcerpc_$fn->{NAME}(iface->pipe, mem_ctx, r);");
310         $self->handle_ntstatus("status", "NULL", "mem_ctx");
311
312         $env = GenerateFunctionOutEnv($fn, "r->");
313         my $i = 0;
314
315         if ($result_size > 1) {
316                 $self->pidl("result = PyTuple_New($result_size);");
317         }
318
319         foreach my $e (@{$fn->{ELEMENTS}}) {
320                 my $py_name = "py_$e->{NAME}";
321                 if (grep(/out/,@{$e->{DIRECTION}})) {
322                         $self->ConvertObjectToPython("r", $env, $e, "r->out.$e->{NAME}", $py_name);
323                         if ($result_size > 1) {
324                                 $self->pidl("PyTuple_SetItem(result, $i, $py_name);");
325                                 $i++;
326                         } else {
327                                 $self->pidl("result = $py_name;");
328                         }
329                 }
330         }
331
332         if (defined($fn->{RETURN_TYPE})) {
333                 my $conv = $self->ConvertObjectToPythonData("r", $fn->{RETURN_TYPE}, "r->out.result");
334                 if ($result_size > 1) {
335                         $self->pidl("PyTuple_SetItem(result, $i, $conv);");
336                 } else {
337                         $self->pidl("result = $conv;");
338                 }
339         }
340
341         $self->pidl("talloc_free(mem_ctx);");
342         $self->pidl("return result;");
343         $self->deindent;
344         $self->pidl("}");
345         $self->pidl("");
346 }
347
348 sub handle_ntstatus($$$$)
349 {
350         my ($self, $var, $retval, $mem_ctx) = @_;
351
352         $self->pidl("if (NT_STATUS_IS_ERR($var)) {");
353         $self->indent;
354         $self->pidl("PyErr_SetString(PyExc_RuntimeError, nt_errstr($var));");
355         $self->pidl("talloc_free($mem_ctx);") if ($mem_ctx);
356         $self->pidl("return $retval;");
357         $self->deindent;
358         $self->pidl("}");
359         $self->pidl("");
360 }
361
362 sub PythonType($$$)
363 {
364         my ($self, $d, $interface, $basename) = @_;
365
366         my $actual_ctype = $d;
367         if ($actual_ctype->{TYPE} eq "TYPEDEF") {
368                 $actual_ctype = $actual_ctype->{DATA};
369         }
370
371         if ($actual_ctype->{TYPE} eq "STRUCT") {
372                 my $py_fnname;
373                 if ($d->{TYPE} eq "STRUCT") {
374                         $py_fnname = $self->PythonStruct($d->{NAME}, mapTypeName($d), $d);
375                 } else {
376                         $py_fnname = $self->PythonStruct($d->{NAME}, mapTypeName($d), $d->{DATA});
377                 }
378
379                 my $fn_name = $d->{NAME};
380
381                 $fn_name =~ s/^$interface->{NAME}_//;
382                 $fn_name =~ s/^$basename\_//;
383
384                 $self->register_module_method($fn_name, $py_fnname, "METH_NOARGS", "NULL");
385         }
386
387         if ($d->{TYPE} eq "ENUM" or $d->{TYPE} eq "BITMAP") {
388                 $self->EnumAndBitmapConsts($d->{NAME}, $d);
389         }
390
391         if ($d->{TYPE} eq "TYPEDEF" and ($d->{DATA}->{TYPE} eq "ENUM" or $d->{DATA}->{TYPE} eq "BITMAP")) {
392                 $self->EnumAndBitmapConsts($d->{NAME}, $d->{DATA});
393         }
394
395         if ($actual_ctype->{TYPE} eq "UNION" and defined($actual_ctype->{ELEMENTS})) {
396                 $self->pidl("PyObject *py_import_$d->{NAME}(TALLOC_CTX *mem_ctx, int level, " .mapTypeName($d) . " *in)");
397                 $self->pidl("{");
398                 $self->indent;
399                 $self->FromUnionToPythonFunction("mem_ctx", $actual_ctype, "level", "in") if ($actual_ctype->{TYPE} eq "UNION");
400                 $self->deindent;
401                 $self->pidl("}");
402                 $self->pidl("");
403
404                 $self->pidl(mapTypeName($d) . " *py_export_$d->{NAME}(TALLOC_CTX *mem_ctx, int level, PyObject *in)");
405                 $self->pidl("{");
406                 $self->indent;
407                 $self->FromPythonToUnionFunction($actual_ctype, mapTypeName($d), "level", "mem_ctx", "in") if ($actual_ctype->{TYPE} eq "UNION");
408                 $self->deindent;
409                 $self->pidl("}");
410                 $self->pidl("");
411         }
412 }
413
414 sub Interface($$$)
415 {
416         my($self,$interface,$basename) = @_;
417
418         $self->pidl_hdr("#ifndef _HEADER_PYTHON_$interface->{NAME}\n");
419         $self->pidl_hdr("#define _HEADER_PYTHON_$interface->{NAME}\n\n");
420
421         $self->pidl_hdr("\n");
422
423         $self->Const($_) foreach (@{$interface->{CONSTS}});
424
425         foreach my $d (@{$interface->{TYPES}}) {
426                 next if has_property($d, "nopython");
427
428                 $self->PythonType($d, $interface, $basename);
429         }
430
431         if (defined $interface->{PROPERTIES}->{uuid}) {
432                 $self->pidl_hdr("PyAPI_DATA(PyTypeObject) $interface->{NAME}_InterfaceType;\n");
433                 $self->pidl("typedef struct {");
434                 $self->indent;
435                 $self->pidl("PyObject_HEAD");
436                 $self->pidl("struct dcerpc_pipe *pipe;");
437                 $self->deindent;
438                 $self->pidl("} $interface->{NAME}_InterfaceObject;");
439
440                 $self->pidl("");
441
442                 foreach my $d (@{$interface->{FUNCTIONS}}) {
443                         next if not defined($d->{OPNUM});
444                         next if has_property($d, "nopython");
445
446                         $self->PythonFunction($d, $interface->{NAME});
447                 }
448
449                 $self->pidl("static PyMethodDef interface_$interface->{NAME}\_methods[] = {");
450                 $self->indent;
451                 foreach my $d (@{$interface->{FUNCTIONS}}) {
452                         next if not defined($d->{OPNUM});
453                         next if has_property($d, "nopython");
454
455                         my $fn_name = $d->{NAME};
456
457                         $fn_name =~ s/^$interface->{NAME}_//;
458                         $fn_name =~ s/^$basename\_//;
459
460                         $self->pidl("{ \"$fn_name\", (PyCFunction)py_$d->{NAME}, METH_VARARGS|METH_KEYWORDS, NULL },");
461                 }
462                 $self->pidl("{ NULL, NULL, 0, NULL }");
463                 $self->deindent;
464                 $self->pidl("};");
465                 $self->pidl("");
466
467                 $self->pidl("static void interface_$interface->{NAME}_dealloc(PyObject* self)");
468                 $self->pidl("{");
469                 $self->indent;
470                 $self->pidl("$interface->{NAME}_InterfaceObject *interface = ($interface->{NAME}_InterfaceObject *)self;");
471                 $self->pidl("talloc_free(interface->pipe);");
472                 $self->pidl("PyObject_Del(self);");
473                 $self->deindent;
474                 $self->pidl("}");
475                 $self->pidl("");
476
477                 $self->pidl("static PyObject *interface_$interface->{NAME}_getattr(PyObject *obj, char *name)");
478                 $self->pidl("{");
479                 $self->indent;
480                 $self->pidl("return Py_FindMethod(interface_$interface->{NAME}\_methods, obj, name);");
481                 $self->deindent;
482                 $self->pidl("}");
483
484                 $self->pidl("");
485
486                 $self->pidl("PyTypeObject $interface->{NAME}_InterfaceType = {");
487                 $self->indent;
488                 $self->pidl("PyObject_HEAD_INIT(NULL) 0,");
489                 $self->pidl(".tp_name = \"$interface->{NAME}\",");
490                 $self->pidl(".tp_basicsize = sizeof($interface->{NAME}_InterfaceObject),");
491                 $self->pidl(".tp_dealloc = interface_$interface->{NAME}_dealloc,");
492                 $self->pidl(".tp_getattr = interface_$interface->{NAME}_getattr,");
493                 $self->deindent;
494                 $self->pidl("};");
495
496                 $self->pidl("");
497
498                 $self->register_module_method($interface->{NAME}, "interface_$interface->{NAME}", "METH_VARARGS|METH_KEYWORDS", "NULL");
499                 $self->pidl("static PyObject *interface_$interface->{NAME}(PyObject *self, PyObject *args, PyObject *kwargs)");
500                 $self->pidl("{");
501                 $self->indent;
502                 $self->pidl("$interface->{NAME}_InterfaceObject *ret;");
503                 $self->pidl("const char *binding_string;");
504                 $self->pidl("struct cli_credentials *credentials;");
505                 $self->pidl("struct loadparm_context *lp_ctx = NULL;");
506                 $self->pidl("PyObject *py_lp_ctx = NULL, *py_credentials = Py_None;");
507                 $self->pidl("TALLOC_CTX *mem_ctx = NULL;");
508                 $self->pidl("NTSTATUS status;");
509                 $self->pidl("");
510                 $self->pidl("const char *kwnames[] = {");
511                 $self->indent;
512                 $self->pidl("\"binding\", \"lp_ctx\", \"credentials\", NULL");
513                 $self->deindent;
514                 $self->pidl("};");
515                 $self->pidl("extern struct loadparm_context *lp_from_py_object(PyObject *py_obj);");
516                 $self->pidl("extern struct cli_credentials *cli_credentials_from_py_object(PyObject *py_obj);");
517                 $self->pidl("");
518                 $self->pidl("if (!PyArg_ParseTupleAndKeywords(args, kwargs, \"sO|O:$interface->{NAME}\", discard_const_p(char *, kwnames), &binding_string, &py_lp_ctx, &py_credentials)) {");
519                 $self->indent;
520                 $self->pidl("return NULL;");
521                 $self->deindent;
522                 $self->pidl("}");
523                 $self->pidl("");
524                 $self->pidl("if (py_lp_ctx != NULL) {");
525                 $self->indent;
526                 $self->pidl("lp_ctx = lp_from_py_object(py_lp_ctx);");
527                 $self->pidl("if (lp_ctx == NULL) {");
528                 $self->indent;
529                 $self->pidl("PyErr_SetString(PyExc_TypeError, \"Expected loadparm context\");");
530                 $self->pidl("return NULL;");
531                 $self->deindent;
532                 $self->pidl("}");
533                 $self->deindent;
534                 $self->pidl("}");
535                 $self->pidl("");
536
537                 $self->pidl("credentials = cli_credentials_from_py_object(py_credentials);");
538                 $self->pidl("if (credentials == NULL) {");
539                 $self->indent;
540                 $self->pidl("PyErr_SetString(PyExc_TypeError, \"Expected credentials\");");
541                 $self->pidl("return NULL;");
542                 $self->deindent;
543                 $self->pidl("}");
544
545                 $self->pidl("ret = PyObject_New($interface->{NAME}_InterfaceObject, &$interface->{NAME}_InterfaceType);");
546                 $self->pidl("");
547
548                 $self->pidl("status = dcerpc_pipe_connect(NULL, &ret->pipe, binding_string, ");
549                 $self->pidl("             &ndr_table_$interface->{NAME}, credentials, NULL, lp_ctx);");
550                 $self->handle_ntstatus("status", "NULL", "mem_ctx");
551
552                 $self->pidl("ret->pipe->conn->flags |= DCERPC_NDR_REF_ALLOC;");
553
554                 $self->pidl("return (PyObject *)ret;");
555                 $self->deindent;
556                 $self->pidl("}");
557                 
558                 $self->pidl("");
559         }
560
561         $self->pidl_hdr("\n");
562         $self->pidl_hdr("#endif /* _HEADER_NDR_$interface->{NAME} */\n");
563 }
564
565 sub register_module_method($$$$$)
566 {
567         my ($self, $fn_name, $pyfn_name, $flags, $doc) = @_;
568
569         push (@{$self->{module_methods}}, [$fn_name, $pyfn_name, $flags, $doc])
570 }
571
572 sub assign($$$)
573 {
574         my ($self, $dest, $src) = @_;
575         if ($dest =~ /^\&/) {
576                 $self->pidl("memcpy($dest, $src, sizeof(*$dest));");
577         } else {
578                 $self->pidl("$dest = $src;");
579         }
580 }
581
582 sub ConvertObjectFromPythonData($$$$$$)
583 {
584         my ($self, $mem_ctx, $cvar, $ctype, $target, $fail) = @_;
585
586         die("undef type for $cvar") unless(defined($ctype));
587
588         $ctype = resolveType($ctype);
589
590         if (ref($ctype) ne "HASH") {
591                 $self->pidl("$target = FIXME($cvar);");
592                 return;
593         }
594
595         my $actual_ctype = $ctype;
596         if ($ctype->{TYPE} eq "TYPEDEF") {
597                 $actual_ctype = $ctype->{DATA};
598         }
599
600         if ($actual_ctype->{TYPE} eq "ENUM" or $actual_ctype->{TYPE} eq "BITMAP" or 
601                 $actual_ctype->{TYPE} eq "SCALAR" and (
602                 expandAlias($actual_ctype->{NAME}) =~ /^(u?int[0-9]+|hyper|NTTIME|time_t|NTTIME_hyper|NTTIME_1sec|dlong|udlong|udlongr)$/)) {
603                 $self->pidl("PY_CHECK_TYPE(PyInt, $cvar, $fail);");
604                 $self->pidl("$target = PyInt_AsLong($cvar);");
605                 return;
606         }
607
608         if ($actual_ctype->{TYPE} eq "STRUCT") {
609                 $self->pidl("PY_CHECK_TYPE($ctype->{NAME}, $cvar, $fail);");
610                 $self->assign($target, "py_talloc_get_ptr($cvar)");
611                 return;
612         }
613
614         if ($actual_ctype->{TYPE} eq "SCALAR" and $actual_ctype->{NAME} eq "DATA_BLOB") {
615                 $self->pidl("$target = data_blob_talloc($mem_ctx, PyString_AsString($cvar), PyString_Size($cvar));");
616                 return;
617         }
618
619         if ($actual_ctype->{TYPE} eq "SCALAR" and 
620                 ($actual_ctype->{NAME} eq "string" or $actual_ctype->{NAME} eq "nbt_string" or $actual_ctype->{NAME} eq "nbt_name" or $actual_ctype->{NAME} eq "wrepl_nbt_name")) {
621                 $self->pidl("$target = talloc_strdup($mem_ctx, PyString_AsString($cvar));");
622                 return;
623         }
624
625         if ($actual_ctype->{TYPE} eq "SCALAR" and $actual_ctype->{NAME} eq "ipv4address") {
626                 $self->pidl("$target = FIXME($cvar);");
627                 return;
628                 }
629
630
631         if ($actual_ctype->{TYPE} eq "SCALAR" and $actual_ctype->{NAME} eq "NTSTATUS") {
632                 $self->pidl("$target = PyInt_AsLong($cvar);");
633                 return;
634         }
635
636         if ($actual_ctype->{TYPE} eq "SCALAR" and $actual_ctype->{NAME} eq "WERROR") {
637                 $self->pidl("$target = PyInt_AsLong($cvar);");
638                 return;
639         }
640
641         if ($actual_ctype->{TYPE} eq "SCALAR" and $actual_ctype->{NAME} eq "string_array") {
642                 $self->pidl("$target = FIXME($cvar);");
643                 return;
644         }
645
646         if ($actual_ctype->{TYPE} eq "SCALAR" and $actual_ctype->{NAME} eq "pointer") {
647                 $self->assign($target, "PyCObject_AsVoidPtr($cvar)");
648                 return;
649         }
650
651         die("unknown type ".mapTypeName($ctype) . ": $cvar");
652
653 }
654
655 sub ConvertObjectFromPythonLevel($$$$$$$$)
656 {
657         my ($self, $env, $mem_ctx, $py_var, $e, $l, $var_name, $fail) = @_;
658
659         if ($l->{TYPE} eq "POINTER") {
660                 if ($l->{POINTER_TYPE} ne "ref") {
661                         $self->pidl("if ($py_var == Py_None) {");
662                         $self->indent;
663                         $self->pidl("$var_name = NULL;");
664                         $self->deindent;
665                         $self->pidl("} else {");
666                         $self->indent;
667                 }
668                 $self->pidl("$var_name = talloc_ptrtype($mem_ctx, $var_name);");
669                 $self->ConvertObjectFromPythonLevel($env, $mem_ctx, $py_var, $e, GetNextLevel($e, $l), get_value_of($var_name), $fail);
670                 if ($l->{POINTER_TYPE} ne "ref") {
671                         $self->deindent;
672                         $self->pidl("}");
673                 }
674         } elsif ($l->{TYPE} eq "ARRAY") {
675                 if (is_charset_array($e, $l)) {
676                         $self->pidl("PY_CHECK_TYPE(PyUnicode, $py_var, $fail);");
677                         # FIXME: Use Unix charset setting rather than utf-8
678                         $self->pidl(get_pointer_to($var_name) . " = PyString_AsString(PyUnicode_AsEncodedString($py_var, \"utf-8\", \"ignore\"));");
679                 } else {
680                         my $pl = GetPrevLevel($e, $l);
681                         if ($pl && $pl->{TYPE} eq "POINTER") {
682                                 $var_name = get_pointer_to($var_name);
683                         }
684
685                         my $counter = "$e->{NAME}_cntr_$l->{LEVEL_INDEX}";
686                         $self->pidl("PY_CHECK_TYPE(PyList, $py_var, $fail);");
687                         $self->pidl("{");
688                         $self->indent;
689                         $self->pidl("int $counter;");
690                         if (!$l->{IS_FIXED}) {
691                                 $self->pidl("$var_name = talloc_array_ptrtype($mem_ctx, $var_name, PyList_Size($py_var));");
692                         }
693                         $self->pidl("for ($counter = 0; $counter < PyList_Size($py_var); $counter++) {");
694                         $self->indent;
695                         $self->ConvertObjectFromPythonLevel($env, $var_name, "PyList_GetItem($py_var, $counter)", $e, GetNextLevel($e, $l), $var_name."[$counter]", $fail);
696                         $self->deindent;
697                         $self->pidl("}");
698                         $self->deindent;
699                         $self->pidl("}");
700                 }
701         } elsif ($l->{TYPE} eq "DATA") {
702
703                 if (not Parse::Pidl::Typelist::is_scalar($l->{DATA_TYPE})) {
704                         $var_name = get_pointer_to($var_name);
705                 }
706                 $self->ConvertObjectFromPythonData($mem_ctx, $py_var, $l->{DATA_TYPE}, $var_name, $fail);
707         } elsif ($l->{TYPE} eq "SWITCH") {
708                 $var_name = get_pointer_to($var_name);
709                 my $switch = ParseExpr($l->{SWITCH_IS}, $env, $e);
710                 $self->pidl("$var_name = py_export_" . GetNextLevel($e, $l)->{DATA_TYPE} . "($mem_ctx, $switch, $py_var);");
711         } elsif ($l->{TYPE} eq "SUBCONTEXT") {
712                 $self->pidl("#error Subcontext not yet supported");
713         } else {
714                 die("unknown level type $l->{TYPE}");
715         }
716 }
717
718 sub ConvertObjectFromPython($$$$$$$)
719 {
720         my ($self, $env, $mem_ctx, $ctype, $cvar, $target, $fail) = @_;
721
722         $self->ConvertObjectFromPythonLevel($env, $mem_ctx, $cvar, $ctype, $ctype->{LEVELS}[0], $target, $fail);
723 }
724
725 sub ConvertScalarToPython($$$)
726 {
727         my ($self, $ctypename, $cvar) = @_;
728
729         die("expected string for $cvar, not $ctypename") if (ref($ctypename) eq "HASH");
730
731         $ctypename = expandAlias($ctypename);
732
733         if ($ctypename =~ /^(int|long|char|u?int[0-9]+|hyper|dlong|udlong|udlongr|time_t|NTTIME_hyper|NTTIME|NTTIME_1sec)$/) {
734                 return "PyInt_FromLong($cvar)";
735         }
736
737         if ($ctypename eq "DATA_BLOB") {
738                 return "PyString_FromStringAndSize($cvar->data, $cvar->length)";
739         }
740
741         if ($ctypename eq "NTSTATUS") {
742                 return "PyInt_FromLong(NT_STATUS_V($cvar))";
743         }
744
745         if ($ctypename eq "WERROR") {
746                 return "PyInt_FromLong(W_ERROR_V($cvar))";
747         }
748
749         if (($ctypename eq "string" or $ctypename eq "nbt_string" or $ctypename eq "nbt_name" or $ctypename eq "wrepl_nbt_name")) {
750                 return "PyString_FromString($cvar)";
751         }
752
753         # Not yet supported
754         if ($ctypename eq "string_array") { return "PyCObject_FromVoidPtr($cvar)"; }
755         if ($ctypename eq "ipv4address") { return "PyCObject_FromVoidPtr($cvar)"; }
756         if ($ctypename eq "pointer") {
757                 return "PyCObject_FromVoidPtr($cvar, talloc_free)";
758         }
759
760         die("Unknown scalar type $ctypename");
761 }
762
763 sub ConvertObjectToPythonData($$$$$)
764 {
765         my ($self, $mem_ctx, $ctype, $cvar) = @_;
766
767         die("undef type for $cvar") unless(defined($ctype));
768
769         $ctype = resolveType($ctype);
770
771         my $actual_ctype = $ctype;
772         if ($ctype->{TYPE} eq "TYPEDEF") {
773                 $actual_ctype = $ctype->{DATA};
774         } 
775         
776         if ($actual_ctype->{TYPE} eq "ENUM") {
777                 return $self->ConvertScalarToPython(Parse::Pidl::Typelist::enum_type_fn($actual_ctype), $cvar);
778         } elsif ($actual_ctype->{TYPE} eq "BITMAP") {
779                 return $self->ConvertScalarToPython(Parse::Pidl::Typelist::bitmap_type_fn($actual_ctype), $cvar);
780         } elsif ($actual_ctype->{TYPE} eq "SCALAR") {
781                 return $self->ConvertScalarToPython($actual_ctype->{NAME}, $cvar);
782         } elsif ($actual_ctype->{TYPE} eq "STRUCT") {
783                 return "py_talloc_import_ex(&$ctype->{NAME}_Type, $mem_ctx, $cvar)";
784         }
785
786         die("unknown type ".mapTypeName($ctype) . ": $cvar");
787 }
788
789 sub ConvertObjectToPythonLevel($$$$$)
790 {
791         my ($self, $mem_ctx, $env, $e, $l, $var_name, $py_var) = @_;
792
793         if ($l->{TYPE} eq "POINTER") {
794                 if ($l->{POINTER_TYPE} ne "ref") {
795                         $self->pidl("if ($var_name == NULL) {");
796                         $self->indent;
797                         $self->pidl("$py_var = Py_None;");
798                         $self->deindent;
799                         $self->pidl("} else {");
800                         $self->indent;
801                 }
802                 $self->ConvertObjectToPythonLevel($var_name, $env, $e, GetNextLevel($e, $l), get_value_of($var_name), $py_var);
803                 if ($l->{POINTER_TYPE} ne "ref") {
804                         $self->deindent;
805                         $self->pidl("}");
806                 }
807         } elsif ($l->{TYPE} eq "ARRAY") {
808                 if (is_charset_array($e, $l)) {
809                         $var_name = get_pointer_to($var_name);
810                         # FIXME: Use Unix charset setting rather than utf-8
811                         $self->pidl("$py_var = PyUnicode_Decode($var_name, strlen($var_name), \"utf-8\", \"ignore\");");
812                 } else {
813                         my $pl = GetPrevLevel($e, $l);
814                         if ($pl && $pl->{TYPE} eq "POINTER") {
815                                 $var_name = get_pointer_to($var_name);
816                         }
817
818                         die("No SIZE_IS for array $var_name") unless (defined($l->{SIZE_IS}));
819                         my $length = $l->{SIZE_IS};
820                         if (defined($l->{LENGTH_IS})) {
821                                 $length = $l->{LENGTH_IS};
822                         }
823
824                         $length = ParseExpr($length, $env, $e);
825                         $self->pidl("$py_var = PyList_New($length);");
826                         $self->pidl("{");
827                         $self->indent;
828                         my $counter = "$e->{NAME}_cntr_$l->{LEVEL_INDEX}";
829                         $self->pidl("int $counter;");
830                         $self->pidl("for ($counter = 0; $counter < $length; $counter++) {");
831                         $self->indent;
832                         my $member_var = "py_$e->{NAME}_$l->{LEVEL_INDEX}";
833                         $self->pidl("PyObject *$member_var;");
834                         $self->ConvertObjectToPythonLevel($var_name, $env, $e, GetNextLevel($e, $l), $var_name."[$counter]", $member_var);
835                         $self->pidl("PyList_SetItem($py_var, $counter, $member_var);");
836                         $self->deindent;
837                         $self->pidl("}");
838                         $self->deindent;
839                         $self->pidl("}");
840                 }
841         } elsif ($l->{TYPE} eq "SWITCH") {
842                 $var_name = get_pointer_to($var_name);
843                 my $switch = ParseExpr($l->{SWITCH_IS}, $env, $e);
844                 $self->pidl("$py_var = py_import_" . GetNextLevel($e, $l)->{DATA_TYPE} . "($mem_ctx, $switch, $var_name);");
845         } elsif ($l->{TYPE} eq "DATA") {
846                 if (not Parse::Pidl::Typelist::is_scalar($l->{DATA_TYPE})) {
847                         $var_name = get_pointer_to($var_name);
848                 }
849                 my $conv = $self->ConvertObjectToPythonData($mem_ctx, $l->{DATA_TYPE}, $var_name);
850                 $self->pidl("$py_var = $conv;");
851         } elsif ($l->{TYPE} eq "SUBCONTEXT") {
852                 $self->pidl("FIXME");
853         } else {
854                 die("Unknown level type $l->{TYPE} $var_name");
855         }
856 }
857
858 sub ConvertObjectToPython($$$$$$)
859 {
860         my ($self, $mem_ctx, $env, $ctype, $cvar, $py_var) = @_;
861
862         $self->ConvertObjectToPythonLevel($mem_ctx, $env, $ctype, $ctype->{LEVELS}[0], $cvar, $py_var);
863 }
864
865 sub Parse($$$$$)
866 {
867     my($self,$basename,$ndr,$ndr_hdr,$hdr) = @_;
868     
869     my $py_hdr = $hdr;
870     $py_hdr =~ s/ndr_([^\/]+)$/py_$1/g;
871
872     $self->pidl_hdr("/* header auto-generated by pidl */\n\n");
873         
874     $self->pidl("
875 /* Python wrapper functions auto-generated by pidl */
876 #include \"includes.h\"
877 #include <Python.h>
878 #include \"librpc/rpc/dcerpc.h\"
879 #include \"scripting/python/pytalloc.h\"
880 #include \"$hdr\"
881 #include \"$ndr_hdr\"
882 #include \"$py_hdr\"
883
884 #define PY_CHECK_TYPE(type, var, fail) \\
885         if (!type ## _Check(var)) {\\
886                 PyErr_Format(PyExc_TypeError, \"Expected type %s\", type ## _Type.tp_name); \\
887                 fail; \\
888         }
889 ");
890
891         foreach my $x (@$ndr) {
892             ($x->{TYPE} eq "INTERFACE") && $self->Interface($x, $basename);
893                 ($x->{TYPE} eq "IMPORT") && $self->Import(@{$x->{PATHS}});
894         }
895         
896         $self->pidl("static PyMethodDef $basename\_methods[] = {");
897         $self->indent;
898         foreach (@{$self->{module_methods}}) {
899                 my ($fn_name, $pyfn_name, $flags, $doc) = @$_;
900                 $self->pidl("{ \"$fn_name\", (PyCFunction)$pyfn_name, $flags, $doc },");
901         }
902         
903         $self->pidl("{ NULL, NULL, 0, NULL }");
904         $self->deindent;
905         $self->pidl("};");
906
907         $self->pidl("");
908
909         $self->pidl("void init$basename(void)");
910         $self->pidl("{");
911         $self->indent;
912         $self->pidl("PyObject *m;");
913         $self->pidl("m = Py_InitModule(\"$basename\", $basename\_methods);");
914         foreach my $name (keys %{$self->{constants}}) {
915                 my $py_obj;
916                 my ($ctype, $cvar) = @{$self->{constants}->{$name}};
917                 if ($cvar =~ /^[0-9]+$/ or $cvar =~ /^0x[0-9a-fA-F]+$/) {
918                         $py_obj = "PyInt_FromLong($cvar)";
919                 } elsif ($cvar =~ /^".*"$/) {
920                         $py_obj = "PyString_FromString($cvar)";
921                 } else {
922                         $py_obj = $self->ConvertObjectToPythonData("NULL", $ctype, $cvar);
923                 }
924
925                 $self->pidl("PyModule_AddObject(m, \"$name\", $py_obj);");
926         }
927         $self->deindent;
928         $self->pidl("}");
929     return ($self->{res_hdr}, $self->{res});
930 }
931
932 1;