pidl/lib/Parse/Pidl/Samba4/Header.pm

   1 ###################################################
   2 # create C header files for an IDL structure
   3 # Copyright tridge@samba.org 2000
   4 # Copyright jelmer@samba.org 2005
   5 # released under the GNU GPL
   6
   7 package Parse::Pidl::Samba4::Header;
   8
   9 require Exporter;
  10
  11 @ISA = qw(Exporter);
  12 @EXPORT_OK = qw(GenerateFunctionInEnv GenerateFunctionOutEnv EnvSubstituteValue GenerateStructEnv);
  13
  14 use strict;
  15 use Parse::Pidl qw(fatal);
  16 use Parse::Pidl::Typelist qw(mapTypeName scalar_is_reference);
  17 use Parse::Pidl::Util qw(has_property is_constant unmake_str ParseExpr);
  18 use Parse::Pidl::Samba4 qw(is_intree ElementStars ArrayBrackets choose_header);
  19
  20 use vars qw($VERSION);
  21 $VERSION = '0.01';
  22
  23 my($res);
  24 my($tab_depth);
  25
  26 sub pidl($) { $res .= shift; }
  27
  28 sub tabs()
  29 {
  30         my $res = "";
  31         $res .="\t" foreach (1..$tab_depth);
  32         return $res;
  33 }
  34
  35 #####################################################################
  36 # parse a properties list
  37 sub HeaderProperties($$)
  38 {
  39         my($props,$ignores) = @_;
  40         my $ret = "";
  41
  42         foreach my $d (keys %{$props}) {
  43                 next if (grep(/^$d$/, @$ignores));
  44                 if($props->{$d} ne "1") {
  45                         $ret.= "$d($props->{$d}),";
  46                 } else {
  47                         $ret.="$d,";
  48                 }
  49         }
  50
  51         if ($ret) {
  52                 pidl "/* [" . substr($ret, 0, -1) . "] */";
  53         }
  54 }
  55
  56 #####################################################################
  57 # parse a structure element
  58 sub HeaderElement($)
  59 {
  60         my($element) = shift;
  61
  62         pidl tabs();
  63         if (has_property($element, "represent_as")) {
  64                 pidl mapTypeName($element->{PROPERTIES}->{represent_as})." ";
  65         } else {
  66                 if (ref($element->{TYPE}) eq "HASH") {
  67                         HeaderType($element, $element->{TYPE}, $element->{TYPE}->{NAME});
  68                 } else {
  69                         HeaderType($element, $element->{TYPE}, "");
  70                 }
  71                 pidl " ".ElementStars($element);
  72         }
  73         pidl $element->{NAME};
  74         pidl ArrayBrackets($element);
  75
  76         pidl ";";
  77         if (defined $element->{PROPERTIES}) {
  78                 HeaderProperties($element->{PROPERTIES}, ["in", "out"]);
  79         }
  80         pidl "\n";
  81 }
  82
  83 #####################################################################
  84 # parse a struct
  85 sub HeaderStruct($$;$)
  86 {
  87         my($struct,$name,$tail) = @_;
  88         pidl "struct $name";
  89         pidl $tail if defined($tail) and not defined($struct->{ELEMENTS});
  90         return if (not defined($struct->{ELEMENTS}));
  91         pidl " {\n";
  92         $tab_depth++;
  93         my $el_count=0;
  94         foreach (@{$struct->{ELEMENTS}}) {
  95                 HeaderElement($_);
  96                 $el_count++;
  97         }
  98         if ($el_count == 0) {
  99                 # some compilers can't handle empty structures
 100                 pidl tabs()."char _empty_;\n";
 101         }
 102         $tab_depth--;
 103         pidl tabs()."}";
 104         if (defined $struct->{PROPERTIES}) {
 105                 HeaderProperties($struct->{PROPERTIES}, []);
 106         }
 107         pidl $tail if defined($tail);
 108 }
 109
 110 #####################################################################
 111 # parse a enum
 112 sub HeaderEnum($$;$)
 113 {
 114         my($enum,$name,$tail) = @_;
 115         my $first = 1;
 116
 117         pidl "enum $name";
 118         if (defined($enum->{ELEMENTS})) {
 119                 pidl "\n#ifndef USE_UINT_ENUMS\n";
 120                 pidl " {\n";
 121                 $tab_depth++;
 122                 foreach my $e (@{$enum->{ELEMENTS}}) {
 123                         unless ($first) { pidl ",\n"; }
 124                         $first = 0;
 125                         pidl tabs();
 126                         pidl $e;
 127                 }
 128                 pidl "\n";
 129                 $tab_depth--;
 130                 pidl "}";
 131                 pidl "\n";
 132                 pidl "#else\n";
 133                 my $count = 0;
 134                 my $with_val = 0;
 135                 my $without_val = 0;
 136                 pidl " { __donnot_use_enum_$name=0x7FFFFFFF}\n";
 137                 foreach my $e (@{$enum->{ELEMENTS}}) {
 138                         my $t = "$e";
 139                         my $name;
 140                         my $value;
 141                         if ($t =~ /(.*)=(.*)/) {
 142                                 $name = $1;
 143                                 $value = $2;
 144                                 $with_val = 1;
 145                                 fatal($e->{ORIGINAL}, "you can't mix enum member with values and without values!")
 146                                         unless ($without_val == 0);
 147                         } else {
 148                                 $name = $t;
 149                                 $value = $count++;
 150                                 $without_val = 1;
 151                                 fatal($e->{ORIGINAL}, "you can't mix enum member with values and without values!")
 152                                         unless ($with_val == 0);
 153                         }
 154                         pidl "#define $name ( $value )\n";
 155                 }
 156                 pidl "#endif\n";
 157         }
 158         pidl $tail if defined($tail);
 159 }
 160
 161 #####################################################################
 162 # parse a bitmap
 163 sub HeaderBitmap($$)
 164 {
 165         my($bitmap,$name) = @_;
 166
 167         return unless defined($bitmap->{ELEMENTS});
 168
 169         pidl "/* bitmap $name */\n";
 170         pidl "#define $_\n" foreach (@{$bitmap->{ELEMENTS}});
 171         pidl "\n";
 172 }
 173
 174 #####################################################################
 175 # parse a union
 176 sub HeaderUnion($$;$)
 177 {
 178         my($union,$name,$tail) = @_;
 179         my %done = ();
 180
 181         pidl "union $name";
 182         pidl $tail if defined($tail) and not defined($union->{ELEMENTS});
 183         return if (not defined($union->{ELEMENTS}));
 184         pidl " {\n";
 185         $tab_depth++;
 186         foreach my $e (@{$union->{ELEMENTS}}) {
 187                 if ($e->{TYPE} ne "EMPTY") {
 188                         if (! defined $done{$e->{NAME}}) {
 189                                 HeaderElement($e);
 190                         }
 191                         $done{$e->{NAME}} = 1;
 192                 }
 193         }
 194         $tab_depth--;
 195         pidl "}";
 196
 197         if (defined $union->{PROPERTIES}) {
 198                 HeaderProperties($union->{PROPERTIES}, []);
 199         }
 200         pidl $tail if defined($tail);
 201 }
 202
 203 #####################################################################
 204 # parse a type
 205 sub HeaderType($$$;$)
 206 {
 207         my($e,$data,$name,$tail) = @_;
 208         if (ref($data) eq "HASH") {
 209                 ($data->{TYPE} eq "ENUM") && HeaderEnum($data, $name, $tail);
 210                 ($data->{TYPE} eq "BITMAP") && HeaderBitmap($data, $name);
 211                 ($data->{TYPE} eq "STRUCT") && HeaderStruct($data, $name, $tail);
 212                 ($data->{TYPE} eq "UNION") && HeaderUnion($data, $name, $tail);
 213                 return;
 214         }
 215
 216         if (has_property($e, "charset")) {
 217                 pidl "const char";
 218         } else {
 219                 pidl mapTypeName($e->{TYPE});
 220         }
 221         pidl $tail if defined($tail);
 222 }
 223
 224 #####################################################################
 225 # parse a typedef
 226 sub HeaderTypedef($;$)
 227 {
 228         my($typedef,$tail) = @_;
 229         # Don't print empty "enum foo;", since some compilers don't like it.
 230         return if ($typedef->{DATA}->{TYPE} eq "ENUM" and not defined($typedef->{DATA}->{ELEMENTS}));
 231         HeaderType($typedef, $typedef->{DATA}, $typedef->{NAME}, $tail) if defined ($typedef->{DATA});
 232 }
 233
 234 #####################################################################
 235 # parse a const
 236 sub HeaderConst($)
 237 {
 238         my($const) = shift;
 239         if (!defined($const->{ARRAY_LEN}[0])) {
 240                 pidl "#define $const->{NAME}\t( $const->{VALUE} )\n";
 241         } else {
 242                 pidl "#define $const->{NAME}\t $const->{VALUE}\n";
 243         }
 244 }
 245
 246 sub ElementDirection($)
 247 {
 248         my ($e) = @_;
 249
 250         return "inout" if (has_property($e, "in") and has_property($e, "out"));
 251         return "in" if (has_property($e, "in"));
 252         return "out" if (has_property($e, "out"));
 253         return "inout";
 254 }
 255
 256 #####################################################################
 257 # parse a function
 258 sub HeaderFunctionInOut($$)
 259 {
 260         my($fn,$prop) = @_;
 261
 262         return unless defined($fn->{ELEMENTS});
 263
 264         foreach my $e (@{$fn->{ELEMENTS}}) {
 265                 HeaderElement($e) if (ElementDirection($e) eq $prop);
 266         }
 267 }
 268
 269 #####################################################################
 270 # determine if we need an "in" or "out" section
 271 sub HeaderFunctionInOut_needed($$)
 272 {
 273         my($fn,$prop) = @_;
 274
 275         return 1 if ($prop eq "out" && defined($fn->{RETURN_TYPE}));
 276
 277         return undef unless defined($fn->{ELEMENTS});
 278
 279         foreach my $e (@{$fn->{ELEMENTS}}) {
 280                 return 1 if (ElementDirection($e) eq $prop);
 281         }
 282
 283         return undef;
 284 }
 285
 286 my %headerstructs;
 287
 288 #####################################################################
 289 # parse a function
 290 sub HeaderFunction($)
 291 {
 292         my($fn) = shift;
 293
 294         return if ($headerstructs{$fn->{NAME}});
 295
 296         $headerstructs{$fn->{NAME}} = 1;
 297
 298         pidl "\nstruct $fn->{NAME} {\n";
 299         $tab_depth++;
 300         my $needed = 0;
 301
 302         if (HeaderFunctionInOut_needed($fn, "in") or
 303             HeaderFunctionInOut_needed($fn, "inout")) {
 304                 pidl tabs()."struct {\n";
 305                 $tab_depth++;
 306                 HeaderFunctionInOut($fn, "in");
 307                 HeaderFunctionInOut($fn, "inout");
 308                 $tab_depth--;
 309                 pidl tabs()."} in;\n\n";
 310                 $needed++;
 311         }
 312
 313         if (HeaderFunctionInOut_needed($fn, "out") or
 314             HeaderFunctionInOut_needed($fn, "inout")) {
 315                 pidl tabs()."struct {\n";
 316                 $tab_depth++;
 317                 HeaderFunctionInOut($fn, "out");
 318                 HeaderFunctionInOut($fn, "inout");
 319                 if (defined($fn->{RETURN_TYPE})) {
 320                         pidl tabs().mapTypeName($fn->{RETURN_TYPE}) . " result;\n";
 321                 }
 322                 $tab_depth--;
 323                 pidl tabs()."} out;\n\n";
 324                 $needed++;
 325         }
 326
 327         if (!$needed) {
 328                 # sigh - some compilers don't like empty structures
 329                 pidl tabs()."int _dummy_element;\n";
 330         }
 331
 332         $tab_depth--;
 333         pidl "};\n\n";
 334 }
 335
 336 sub HeaderImport
 337 {
 338         my @imports = @_;
 339         foreach my $import (@imports) {
 340                 $import = unmake_str($import);
 341                 $import =~ s/\.idl$//;
 342                 pidl choose_header("librpc/gen_ndr/$import\.h", "gen_ndr/$import.h") . "\n";
 343         }
 344 }
 345
 346 sub HeaderInclude
 347 {
 348         my @includes = @_;
 349         foreach (@includes) {
 350                 pidl "#include $_\n";
 351         }
 352 }
 353
 354 #####################################################################
 355 # parse the interface definitions
 356 sub HeaderInterface($)
 357 {
 358         my($interface) = shift;
 359
 360         pidl "#ifndef _HEADER_$interface->{NAME}\n";
 361         pidl "#define _HEADER_$interface->{NAME}\n\n";
 362
 363         foreach my $c (@{$interface->{CONSTS}}) {
 364                 HeaderConst($c);
 365         }
 366
 367         foreach my $t (@{$interface->{TYPES}}) {
 368                 HeaderTypedef($t, ";\n\n") if ($t->{TYPE} eq "TYPEDEF");
 369                 HeaderStruct($t, $t->{NAME}, ";\n\n") if ($t->{TYPE} eq "STRUCT");
 370                 HeaderUnion($t, $t->{NAME}, ";\n\n") if ($t->{TYPE} eq "UNION");
 371                 HeaderEnum($t, $t->{NAME}, ";\n\n") if ($t->{TYPE} eq "ENUM");
 372                 HeaderBitmap($t, $t->{NAME}) if ($t->{TYPE} eq "BITMAP");
 373         }
 374
 375         foreach my $fn (@{$interface->{FUNCTIONS}}) {
 376                 HeaderFunction($fn);
 377         }
 378
 379         pidl "#endif /* _HEADER_$interface->{NAME} */\n";
 380 }
 381
 382 sub HeaderQuote($)
 383 {
 384         my($quote) = shift;
 385
 386         pidl unmake_str($quote->{DATA}) . "\n";
 387 }
 388
 389 #####################################################################
 390 # parse a parsed IDL into a C header
 391 sub Parse($)
 392 {
 393         my($ndr) = shift;
 394         $tab_depth = 0;
 395
 396         $res = "";
 397         %headerstructs = ();
 398         pidl "/* header auto-generated by pidl */\n\n";
 399         if (!is_intree()) {
 400                 pidl "#include <util/data_blob.h>\n";
 401         }
 402         pidl "#include <stdint.h>\n";
 403         pidl "\n";
 404
 405         foreach (@{$ndr}) {
 406                 ($_->{TYPE} eq "CPP_QUOTE") && HeaderQuote($_);
 407                 ($_->{TYPE} eq "INTERFACE") && HeaderInterface($_);
 408                 ($_->{TYPE} eq "IMPORT") && HeaderImport(@{$_->{PATHS}});
 409                 ($_->{TYPE} eq "INCLUDE") && HeaderInclude(@{$_->{PATHS}});
 410         }
 411
 412         return $res;
 413 }
 414
 415 sub GenerateStructEnv($$)
 416 {
 417         my ($x, $v) = @_;
 418         my %env;
 419
 420         foreach my $e (@{$x->{ELEMENTS}}) {
 421                 $env{$e->{NAME}} = "$v->$e->{NAME}";
 422         }
 423
 424         $env{"this"} = $v;
 425
 426         return \%env;
 427 }
 428
 429 sub EnvSubstituteValue($$)
 430 {
 431         my ($env,$s) = @_;
 432
 433         # Substitute the value() values in the env
 434         foreach my $e (@{$s->{ELEMENTS}}) {
 435                 next unless (defined(my $v = has_property($e, "value")));
 436
 437                 $env->{$e->{NAME}} = ParseExpr($v, $env, $e);
 438         }
 439
 440         return $env;
 441 }
 442
 443 sub GenerateFunctionInEnv($;$)
 444 {
 445         my ($fn, $base) = @_;
 446         my %env;
 447
 448         $base = "r->" unless defined($base);
 449
 450         foreach my $e (@{$fn->{ELEMENTS}}) {
 451                 if (grep (/in/, @{$e->{DIRECTION}})) {
 452                         $env{$e->{NAME}} = $base."in.$e->{NAME}";
 453                 }
 454         }
 455
 456         return \%env;
 457 }
 458
 459 sub GenerateFunctionOutEnv($;$)
 460 {
 461         my ($fn, $base) = @_;
 462         my %env;
 463
 464         $base = "r->" unless defined($base);
 465
 466         foreach my $e (@{$fn->{ELEMENTS}}) {
 467                 if (grep (/out/, @{$e->{DIRECTION}})) {
 468                         $env{$e->{NAME}} = $base."out.$e->{NAME}";
 469                 } elsif (grep (/in/, @{$e->{DIRECTION}})) {
 470                         $env{$e->{NAME}} = $base."in.$e->{NAME}";
 471                 }
 472         }
 473
 474         return \%env;
 475 }
 476
 477 1;