pidl: added union padding for NDR64
[ira/wip.git] / pidl / lib / Parse / Pidl / NDR.pm
1 ###################################################
2 # Samba4 NDR info tree generator
3 # Copyright tridge@samba.org 2000-2003
4 # Copyright tpot@samba.org 2001
5 # Copyright jelmer@samba.org 2004-2006
6 # released under the GNU GPL
7
8 =pod
9
10 =head1 NAME
11
12 Parse::Pidl::NDR - NDR parsing information generator
13
14 =head1 DESCRIPTION
15
16 Return a table describing the order in which the parts of an element
17 should be parsed
18 Possible level types:
19  - POINTER
20  - ARRAY
21  - SUBCONTEXT
22  - SWITCH
23  - DATA
24
25 =head1 AUTHOR
26
27 Jelmer Vernooij <jelmer@samba.org>
28
29 =cut
30
31 package Parse::Pidl::NDR;
32
33 require Exporter;
34 use vars qw($VERSION);
35 $VERSION = '0.01';
36 @ISA = qw(Exporter);
37 @EXPORT = qw(GetPrevLevel GetNextLevel ContainsDeferred ContainsString);
38 @EXPORT_OK = qw(GetElementLevelTable ParseElement ValidElement align_type mapToScalar ParseType can_contain_deferred is_charset_array);
39
40 use strict;
41 use Parse::Pidl qw(warning fatal);
42 use Parse::Pidl::Typelist qw(hasType getType expandAlias);
43 use Parse::Pidl::Util qw(has_property property_matches);
44
45 # Alignment of the built-in scalar types
46 my $scalar_alignment = {
47         'void' => 0,
48         'char' => 1,
49         'int8' => 1,
50         'uint8' => 1,
51         'int16' => 2,
52         'uint16' => 2,
53         'int32' => 4,
54         'uint32' => 4,
55         'hyper' => 8,
56         'double' => 8,
57         'pointer' => 8,
58         'dlong' => 4,
59         'udlong' => 4,
60         'udlongr' => 4,
61         'DATA_BLOB' => 4,
62         'string' => 4,
63         'string_array' => 4, #???
64         'time_t' => 4,
65         'NTTIME' => 4,
66         'NTTIME_1sec' => 4,
67         'NTTIME_hyper' => 8,
68         'WERROR' => 4,
69         'NTSTATUS' => 4,
70         'COMRESULT' => 4,
71         'nbt_string' => 4,
72         'wrepl_nbt_name' => 4,
73         'ipv4address' => 4
74 };
75
76 sub GetElementLevelTable($$)
77 {
78         my ($e, $pointer_default) = @_;
79
80         my $order = [];
81         my $is_deferred = 0;
82         my @bracket_array = ();
83         my @length_is = ();
84         my @size_is = ();
85         my $pointer_idx = 0;
86
87         if (has_property($e, "size_is")) {
88                 @size_is = split /,/, has_property($e, "size_is");
89         }
90
91         if (has_property($e, "length_is")) {
92                 @length_is = split /,/, has_property($e, "length_is");
93         }
94
95         if (defined($e->{ARRAY_LEN})) {
96                 @bracket_array = @{$e->{ARRAY_LEN}};
97         }
98
99         if (has_property($e, "out")) {
100                 my $needptrs = 1;
101
102                 if (has_property($e, "string")) { $needptrs++; }
103                 if ($#bracket_array >= 0) { $needptrs = 0; }
104
105                 warning($e, "[out] argument `$e->{NAME}' not a pointer") if ($needptrs > $e->{POINTERS});
106         }
107
108         # Parse the [][][][] style array stuff
109         for my $i (0 .. $#bracket_array) {
110                 my $d = $bracket_array[$#bracket_array - $i];
111                 my $size = $d;
112                 my $length = $d;
113                 my $is_surrounding = 0;
114                 my $is_varying = 0;
115                 my $is_conformant = 0;
116                 my $is_string = 0;
117                 my $is_fixed = 0;
118                 my $is_inline = 0;
119
120                 if ($d eq "*") {
121                         $is_conformant = 1;
122                         if ($size = shift @size_is) {
123                         } elsif ((scalar(@size_is) == 0) and has_property($e, "string")) {
124                                 $is_string = 1;
125                                 delete($e->{PROPERTIES}->{string});
126                         } else {
127                                 fatal($e, "Must specify size_is() for conformant array!")
128                         }
129
130                         if (($length = shift @length_is) or $is_string) {
131                                 $is_varying = 1;
132                         } else {
133                                 $length = $size;
134                         }
135
136                         if ($e == $e->{PARENT}->{ELEMENTS}[-1] 
137                                 and $e->{PARENT}->{TYPE} ne "FUNCTION") {
138                                 $is_surrounding = 1;
139                         }
140                 }
141
142                 $is_fixed = 1 if (not $is_conformant and Parse::Pidl::Util::is_constant($size));
143                 $is_inline = 1 if (not $is_conformant and not Parse::Pidl::Util::is_constant($size));
144
145                 if ($i == 0 and $is_fixed and has_property($e, "string")) {
146                         $is_fixed = 0;
147                         $is_varying = 1;
148                         $is_string = 1;
149                         delete($e->{PROPERTIES}->{string});
150                 }
151
152                 push (@$order, {
153                         TYPE => "ARRAY",
154                         SIZE_IS => $size,
155                         LENGTH_IS => $length,
156                         IS_DEFERRED => $is_deferred,
157                         IS_SURROUNDING => $is_surrounding,
158                         IS_ZERO_TERMINATED => $is_string,
159                         IS_VARYING => $is_varying,
160                         IS_CONFORMANT => $is_conformant,
161                         IS_FIXED => $is_fixed,
162                         IS_INLINE => $is_inline
163                 });
164         }
165
166         # Next, all the pointers
167         foreach my $i (1..$e->{POINTERS}) {
168                 my $level = "EMBEDDED";
169                 # Top level "ref" pointers do not have a referrent identifier
170                 $level = "TOP" if ($i == 1 and $e->{PARENT}->{TYPE} eq "FUNCTION");
171
172                 my $pt;
173                 #
174                 # Only the first level gets the pointer type from the
175                 # pointer property, the others get them from
176                 # the pointer_default() interface property
177                 #
178                 # see http://msdn2.microsoft.com/en-us/library/aa378984(VS.85).aspx
179                 # (Here they talk about the rightmost pointer, but testing shows
180                 #  they mean the leftmost pointer.)
181                 #
182                 # --metze
183                 #
184                 $pt = pointer_type($e);
185                 if ($i > 1) {
186                         $is_deferred = 1 if ($pt ne "ref" and $e->{PARENT}->{TYPE} eq "FUNCTION");
187                         $pt = $pointer_default;
188                 }
189
190                 push (@$order, { 
191                         TYPE => "POINTER",
192                         POINTER_TYPE => $pt,
193                         POINTER_INDEX => $pointer_idx,
194                         IS_DEFERRED => "$is_deferred",
195                         LEVEL => $level
196                 });
197
198                 warning($e, "top-level \[out\] pointer `$e->{NAME}' is not a \[ref\] pointer") 
199                         if ($i == 1 and $pt ne "ref" and
200                                 $e->{PARENT}->{TYPE} eq "FUNCTION" and 
201                                 not has_property($e, "in"));
202
203                 $pointer_idx++;
204                 
205                 # everything that follows will be deferred
206                 $is_deferred = 1 if ($level ne "TOP");
207
208                 my $array_size = shift @size_is;
209                 my $array_length;
210                 my $is_varying;
211                 my $is_conformant;
212                 my $is_string = 0;
213                 if ($array_size) {
214                         $is_conformant = 1;
215                         if ($array_length = shift @length_is) {
216                                 $is_varying = 1;
217                         } else {
218                                 $array_length = $array_size;
219                                 $is_varying =0;
220                         }
221                 } 
222                 
223                 if (scalar(@size_is) == 0 and has_property($e, "string") and 
224                     $i == $e->{POINTERS}) {
225                         $is_string = 1;
226                         $is_varying = $is_conformant = has_property($e, "noheader")?0:1;
227                         delete($e->{PROPERTIES}->{string});
228                 }
229
230                 if ($array_size or $is_string) {
231                         push (@$order, {
232                                 TYPE => "ARRAY",
233                                 SIZE_IS => $array_size,
234                                 LENGTH_IS => $array_length,
235                                 IS_DEFERRED => $is_deferred,
236                                 IS_SURROUNDING => 0,
237                                 IS_ZERO_TERMINATED => $is_string,
238                                 IS_VARYING => $is_varying,
239                                 IS_CONFORMANT => $is_conformant,
240                                 IS_FIXED => 0,
241                                 IS_INLINE => 0
242                         });
243
244                         $is_deferred = 0;
245                 } 
246         }
247
248         if (defined(has_property($e, "subcontext"))) {
249                 my $hdr_size = has_property($e, "subcontext");
250                 my $subsize = has_property($e, "subcontext_size");
251                 if (not defined($subsize)) { 
252                         $subsize = -1; 
253                 }
254                 
255                 push (@$order, {
256                         TYPE => "SUBCONTEXT",
257                         HEADER_SIZE => $hdr_size,
258                         SUBCONTEXT_SIZE => $subsize,
259                         IS_DEFERRED => $is_deferred,
260                         COMPRESSION => has_property($e, "compression"),
261                 });
262         }
263
264         if (my $switch = has_property($e, "switch_is")) {
265                 push (@$order, {
266                         TYPE => "SWITCH", 
267                         SWITCH_IS => $switch,
268                         IS_DEFERRED => $is_deferred
269                 });
270         }
271
272         if (scalar(@size_is) > 0) {
273                 fatal($e, "size_is() on non-array element");
274         }
275
276         if (scalar(@length_is) > 0) {
277                 fatal($e, "length_is() on non-array element");
278         }
279
280         if (has_property($e, "string")) {
281                 fatal($e, "string() attribute on non-array element");
282         }
283
284         push (@$order, {
285                 TYPE => "DATA",
286                 DATA_TYPE => $e->{TYPE},
287                 IS_DEFERRED => $is_deferred,
288                 CONTAINS_DEFERRED => can_contain_deferred($e->{TYPE}),
289                 IS_SURROUNDING => 0 #FIXME
290         });
291
292         my $i = 0;
293         foreach (@$order) { $_->{LEVEL_INDEX} = $i; $i+=1; }
294
295         return $order;
296 }
297
298 sub GetTypedefLevelTable($$$)
299 {
300         my ($e, $data, $pointer_default) = @_;
301
302         my $order = [];
303
304         push (@$order, {
305                 TYPE => "TYPEDEF"
306         });
307
308         my $i = 0;
309         foreach (@$order) { $_->{LEVEL_INDEX} = $i; $i+=1; }
310
311         return $order;
312 }
313
314 #####################################################################
315 # see if a type contains any deferred data 
316 sub can_contain_deferred($)
317 {
318         sub can_contain_deferred($);
319         my ($type) = @_;
320
321         return 1 unless (hasType($type)); # assume the worst
322
323         $type = getType($type);
324
325         return 0 if (Parse::Pidl::Typelist::is_scalar($type));
326
327         return can_contain_deferred($type->{DATA}) if ($type->{TYPE} eq "TYPEDEF");
328
329         return 0 unless defined($type->{ELEMENTS});
330
331         foreach (@{$type->{ELEMENTS}}) {
332                 return 1 if ($_->{POINTERS});
333                 return 1 if (can_contain_deferred ($_->{TYPE}));
334         }
335         
336         return 0;
337 }
338
339 sub pointer_type($)
340 {
341         my $e = shift;
342
343         return undef unless $e->{POINTERS};
344         
345         return "ref" if (has_property($e, "ref"));
346         return "full" if (has_property($e, "ptr"));
347         return "sptr" if (has_property($e, "sptr"));
348         return "unique" if (has_property($e, "unique"));
349         return "relative" if (has_property($e, "relative"));
350         return "ignore" if (has_property($e, "ignore"));
351
352         return undef;
353 }
354
355 #####################################################################
356 # work out the correct alignment for a structure or union
357 sub find_largest_alignment($)
358 {
359         my $s = shift;
360
361         my $align = 1;
362         for my $e (@{$s->{ELEMENTS}}) {
363                 my $a = 1;
364
365                 if ($e->{POINTERS}) {
366                         # this is a hack for NDR64
367                         # the NDR layer translates this into
368                         # an alignment of 4 for NDR and 8 for NDR64
369                         $a = 5;
370                 } elsif (has_property($e, "subcontext")) { 
371                         $a = 1;
372                 } elsif (has_property($e, "transmit_as")) {
373                         $a = align_type($e->{PROPERTIES}->{transmit_as});
374                 } else {
375                         $a = align_type($e->{TYPE}); 
376                 }
377
378                 $align = $a if ($align < $a);
379         }
380
381         return $align;
382 }
383
384 #####################################################################
385 # align a type
386 sub align_type($)
387 {
388         sub align_type($);
389         my ($e) = @_;
390
391         if (ref($e) eq "HASH" and $e->{TYPE} eq "SCALAR") {
392                 return $scalar_alignment->{$e->{NAME}};
393         }
394
395         return 0 if ($e eq "EMPTY");
396
397         unless (hasType($e)) {
398             # it must be an external type - all we can do is guess 
399                 # warning($e, "assuming alignment of unknown type '$e' is 4");
400             return 4;
401         }
402
403         my $dt = getType($e);
404
405         if ($dt->{TYPE} eq "TYPEDEF") {
406                 return align_type($dt->{DATA});
407         } elsif ($dt->{TYPE} eq "ENUM") {
408                 return align_type(Parse::Pidl::Typelist::enum_type_fn($dt));
409         } elsif ($dt->{TYPE} eq "BITMAP") {
410                 return align_type(Parse::Pidl::Typelist::bitmap_type_fn($dt));
411         } elsif (($dt->{TYPE} eq "STRUCT") or ($dt->{TYPE} eq "UNION")) {
412                 # Struct/union without body: assume 4
413                 return 4 unless (defined($dt->{ELEMENTS}));
414                 return find_largest_alignment($dt);
415         }
416
417         die("Unknown data type type $dt->{TYPE}");
418 }
419
420 sub ParseElement($$)
421 {
422         my ($e, $pointer_default) = @_;
423
424         $e->{TYPE} = expandAlias($e->{TYPE});
425
426         if (ref($e->{TYPE}) eq "HASH") {
427                 $e->{TYPE} = ParseType($e->{TYPE}, $pointer_default);
428         }
429
430         return {
431                 NAME => $e->{NAME},
432                 TYPE => $e->{TYPE},
433                 PROPERTIES => $e->{PROPERTIES},
434                 LEVELS => GetElementLevelTable($e, $pointer_default),
435                 REPRESENTATION_TYPE => ($e->{PROPERTIES}->{represent_as} or $e->{TYPE}),
436                 ALIGN => align_type($e->{TYPE}),
437                 ORIGINAL => $e
438         };
439 }
440
441 sub ParseStruct($$)
442 {
443         my ($struct, $pointer_default) = @_;
444         my @elements = ();
445         my $surrounding = undef;
446
447         return {
448                 TYPE => "STRUCT",
449                 NAME => $struct->{NAME},
450                 SURROUNDING_ELEMENT => undef,
451                 ELEMENTS => undef,
452                 PROPERTIES => $struct->{PROPERTIES},
453                 ORIGINAL => $struct,
454                 ALIGN => undef
455         } unless defined($struct->{ELEMENTS});
456
457         CheckPointerTypes($struct, $pointer_default);
458
459         foreach my $x (@{$struct->{ELEMENTS}}) 
460         {
461                 my $e = ParseElement($x, $pointer_default);
462                 if ($x != $struct->{ELEMENTS}[-1] and 
463                         $e->{LEVELS}[0]->{IS_SURROUNDING}) {
464                         fatal($x, "conformant member not at end of struct");
465                 }
466                 push @elements, $e;
467         }
468
469         my $e = $elements[-1];
470         if (defined($e) and defined($e->{LEVELS}[0]->{IS_SURROUNDING}) and
471                 $e->{LEVELS}[0]->{IS_SURROUNDING}) {
472                 $surrounding = $e;
473         }
474
475         if (defined $e->{TYPE} && $e->{TYPE} eq "string"
476             &&  property_matches($e, "flag", ".*LIBNDR_FLAG_STR_CONFORMANT.*")) {
477                 $surrounding = $struct->{ELEMENTS}[-1];
478         }
479
480         my $align = undef;
481         if ($struct->{NAME}) {
482                 $align = align_type($struct->{NAME});
483         }
484                 
485         return {
486                 TYPE => "STRUCT",
487                 NAME => $struct->{NAME},
488                 SURROUNDING_ELEMENT => $surrounding,
489                 ELEMENTS => \@elements,
490                 PROPERTIES => $struct->{PROPERTIES},
491                 ORIGINAL => $struct,
492                 ALIGN => $align
493         };
494 }
495
496 sub ParseUnion($$)
497 {
498         my ($e, $pointer_default) = @_;
499         my @elements = ();
500         my $hasdefault = 0;
501         my $switch_type = has_property($e, "switch_type");
502         unless (defined($switch_type)) { $switch_type = "uint32"; }
503         if (has_property($e, "nodiscriminant")) { $switch_type = undef; }
504
505         return {
506                 TYPE => "UNION",
507                 NAME => $e->{NAME},
508                 SWITCH_TYPE => $switch_type,
509                 ELEMENTS => undef,
510                 PROPERTIES => $e->{PROPERTIES},
511                 HAS_DEFAULT => $hasdefault,
512                 ORIGINAL => $e,
513                 ALIGN => undef
514         } unless defined($e->{ELEMENTS});
515
516         CheckPointerTypes($e, $pointer_default);
517
518         foreach my $x (@{$e->{ELEMENTS}}) 
519         {
520                 my $t;
521                 if ($x->{TYPE} eq "EMPTY") {
522                         $t = { TYPE => "EMPTY" };
523                 } else {
524                         $t = ParseElement($x, $pointer_default);
525                 }
526                 if (has_property($x, "default")) {
527                         $t->{CASE} = "default";
528                         $hasdefault = 1;
529                 } elsif (defined($x->{PROPERTIES}->{case})) {
530                         $t->{CASE} = "case $x->{PROPERTIES}->{case}";
531                 } else {
532                         die("Union element $x->{NAME} has neither default nor case property");
533                 }
534                 push @elements, $t;
535         }
536
537         my $align = undef;
538         if ($e->{NAME}) {
539                 $align = align_type($e->{NAME});
540         }
541
542         return {
543                 TYPE => "UNION",
544                 NAME => $e->{NAME},
545                 SWITCH_TYPE => $switch_type,
546                 ELEMENTS => \@elements,
547                 PROPERTIES => $e->{PROPERTIES},
548                 HAS_DEFAULT => $hasdefault,
549                 ORIGINAL => $e,
550                 ALIGN => $align
551         };
552 }
553
554 sub ParseEnum($$)
555 {
556         my ($e, $pointer_default) = @_;
557
558         return {
559                 TYPE => "ENUM",
560                 NAME => $e->{NAME},
561                 BASE_TYPE => Parse::Pidl::Typelist::enum_type_fn($e),
562                 ELEMENTS => $e->{ELEMENTS},
563                 PROPERTIES => $e->{PROPERTIES},
564                 ORIGINAL => $e
565         };
566 }
567
568 sub ParseBitmap($$)
569 {
570         my ($e, $pointer_default) = @_;
571
572         return {
573                 TYPE => "BITMAP",
574                 NAME => $e->{NAME},
575                 BASE_TYPE => Parse::Pidl::Typelist::bitmap_type_fn($e),
576                 ELEMENTS => $e->{ELEMENTS},
577                 PROPERTIES => $e->{PROPERTIES},
578                 ORIGINAL => $e
579         };
580 }
581
582 sub ParseType($$)
583 {
584         my ($d, $pointer_default) = @_;
585
586         my $data = {
587                 STRUCT => \&ParseStruct,
588                 UNION => \&ParseUnion,
589                 ENUM => \&ParseEnum,
590                 BITMAP => \&ParseBitmap,
591                 TYPEDEF => \&ParseTypedef,
592         }->{$d->{TYPE}}->($d, $pointer_default);
593
594         return $data;
595 }
596
597 sub ParseTypedef($$)
598 {
599         my ($d, $pointer_default) = @_;
600
601         if (defined($d->{DATA}->{PROPERTIES}) && !defined($d->{PROPERTIES})) {
602                 $d->{PROPERTIES} = $d->{DATA}->{PROPERTIES};
603         }
604
605         my $data = ParseType($d->{DATA}, $pointer_default);
606         $data->{ALIGN} = align_type($d->{NAME});
607
608         return {
609                 NAME => $d->{NAME},
610                 TYPE => $d->{TYPE},
611                 PROPERTIES => $d->{PROPERTIES},
612                 LEVELS => GetTypedefLevelTable($d, $data, $pointer_default),
613                 DATA => $data,
614                 ORIGINAL => $d
615         };
616 }
617
618 sub ParseConst($$)
619 {
620         my ($ndr,$d) = @_;
621
622         return $d;
623 }
624
625 sub ParseFunction($$$)
626 {
627         my ($ndr,$d,$opnum) = @_;
628         my @elements = ();
629         my $rettype = undef;
630         my $thisopnum = undef;
631
632         CheckPointerTypes($d, "ref");
633
634         if (not defined($d->{PROPERTIES}{noopnum})) {
635                 $thisopnum = ${$opnum};
636                 ${$opnum}++;
637         }
638
639         foreach my $x (@{$d->{ELEMENTS}}) {
640                 my $e = ParseElement($x, $ndr->{PROPERTIES}->{pointer_default});
641                 push (@{$e->{DIRECTION}}, "in") if (has_property($x, "in"));
642                 push (@{$e->{DIRECTION}}, "out") if (has_property($x, "out"));
643
644                 push (@elements, $e);
645         }
646
647         if ($d->{RETURN_TYPE} ne "void") {
648                 $rettype = expandAlias($d->{RETURN_TYPE});
649         }
650         
651         my $async = 0;
652         if (has_property($d, "async")) { $async = 1; }
653         
654         return {
655                         NAME => $d->{NAME},
656                         TYPE => "FUNCTION",
657                         OPNUM => $thisopnum,
658                         ASYNC => $async,
659                         RETURN_TYPE => $rettype,
660                         PROPERTIES => $d->{PROPERTIES},
661                         ELEMENTS => \@elements,
662                         ORIGINAL => $d
663                 };
664 }
665
666 sub CheckPointerTypes($$)
667 {
668         my ($s,$default) = @_;
669
670         return unless defined($s->{ELEMENTS});
671
672         foreach my $e (@{$s->{ELEMENTS}}) {
673                 if ($e->{POINTERS} and not defined(pointer_type($e))) {
674                         $e->{PROPERTIES}->{$default} = '1';
675                 }
676         }
677 }
678
679 sub FindNestedTypes($$)
680 {
681         sub FindNestedTypes($$);
682         my ($l, $t) = @_;
683
684         return unless defined($t->{ELEMENTS});
685         return if ($t->{TYPE} eq "ENUM");
686         return if ($t->{TYPE} eq "BITMAP");
687
688         foreach (@{$t->{ELEMENTS}}) {
689                 if (ref($_->{TYPE}) eq "HASH") {
690                         push (@$l, $_->{TYPE}) if (defined($_->{TYPE}->{NAME}));
691                         FindNestedTypes($l, $_->{TYPE});
692                 }
693         }
694 }
695
696 sub ParseInterface($)
697 {
698         my $idl = shift;
699         my @types = ();
700         my @consts = ();
701         my @functions = ();
702         my @endpoints;
703         my $opnum = 0;
704         my $version;
705
706         if (not has_property($idl, "pointer_default")) {
707                 # MIDL defaults to "ptr" in DCE compatible mode (/osf)
708                 # and "unique" in Microsoft Extensions mode (default)
709                 $idl->{PROPERTIES}->{pointer_default} = "unique";
710         }
711
712         foreach my $d (@{$idl->{DATA}}) {
713                 if ($d->{TYPE} eq "FUNCTION") {
714                         push (@functions, ParseFunction($idl, $d, \$opnum));
715                 } elsif ($d->{TYPE} eq "CONST") {
716                         push (@consts, ParseConst($idl, $d));
717                 } else {
718                         push (@types, ParseType($d, $idl->{PROPERTIES}->{pointer_default}));
719                         FindNestedTypes(\@types, $d);
720                 }
721         }
722
723         $version = "0.0";
724
725         if(defined $idl->{PROPERTIES}->{version}) { 
726                 my @if_version = split(/\./, $idl->{PROPERTIES}->{version});
727                 if ($if_version[0] == $idl->{PROPERTIES}->{version}) {
728                                 $version = $idl->{PROPERTIES}->{version};
729                 } else {
730                                 $version = $if_version[1] << 16 | $if_version[0];
731                 }
732         }
733
734         # If no endpoint is set, default to the interface name as a named pipe
735         if (!defined $idl->{PROPERTIES}->{endpoint}) {
736                 push @endpoints, "\"ncacn_np:[\\\\pipe\\\\" . $idl->{NAME} . "]\"";
737         } else {
738                 @endpoints = split /,/, $idl->{PROPERTIES}->{endpoint};
739         }
740
741         return { 
742                 NAME => $idl->{NAME},
743                 UUID => lc(has_property($idl, "uuid")),
744                 VERSION => $version,
745                 TYPE => "INTERFACE",
746                 PROPERTIES => $idl->{PROPERTIES},
747                 FUNCTIONS => \@functions,
748                 CONSTS => \@consts,
749                 TYPES => \@types,
750                 ENDPOINTS => \@endpoints
751         };
752 }
753
754 # Convert a IDL tree to a NDR tree
755 # Gives a result tree describing all that's necessary for easily generating
756 # NDR parsers / generators
757 sub Parse($)
758 {
759         my $idl = shift;
760
761         return undef unless (defined($idl));
762
763         Parse::Pidl::NDR::Validate($idl);
764         
765         my @ndr = ();
766
767         foreach (@{$idl}) {
768                 ($_->{TYPE} eq "CPP_QUOTE") && push(@ndr, $_);
769                 ($_->{TYPE} eq "INTERFACE") && push(@ndr, ParseInterface($_));
770                 ($_->{TYPE} eq "IMPORT") && push(@ndr, $_);
771         }
772
773         return \@ndr;
774 }
775
776 sub GetNextLevel($$)
777 {
778         my $e = shift;
779         my $fl = shift;
780
781         my $seen = 0;
782
783         foreach my $l (@{$e->{LEVELS}}) {
784                 return $l if ($seen);
785                 ($seen = 1) if ($l == $fl);
786         }
787
788         return undef;
789 }
790
791 sub GetPrevLevel($$)
792 {
793         my ($e,$fl) = @_;
794         my $prev = undef;
795
796         foreach my $l (@{$e->{LEVELS}}) {
797                 (return $prev) if ($l == $fl);
798                 $prev = $l;
799         }
800
801         return undef;
802 }
803
804 sub ContainsString($)
805 {
806         my ($e) = @_;
807
808         foreach my $l (@{$e->{LEVELS}}) {
809                 return 1 if ($l->{TYPE} eq "ARRAY" and $l->{IS_ZERO_TERMINATED});
810         }
811
812         return 0;
813 }
814
815 sub ContainsDeferred($$)
816 {
817         my ($e,$l) = @_;
818
819         return 1 if ($l->{CONTAINS_DEFERRED});
820
821         while ($l = GetNextLevel($e,$l))
822         {
823                 return 1 if ($l->{IS_DEFERRED}); 
824                 return 1 if ($l->{CONTAINS_DEFERRED});
825         } 
826         
827         return 0;
828 }
829
830 sub el_name($)
831 {
832         my $e = shift;
833         my $name = "<ANONYMOUS>";
834
835         $name = $e->{NAME} if defined($e->{NAME});
836
837         if (defined($e->{PARENT}) and defined($e->{PARENT}->{NAME})) {
838                 return "$e->{PARENT}->{NAME}.$name";
839         }
840
841         if (defined($e->{PARENT}) and
842             defined($e->{PARENT}->{PARENT}) and
843             defined($e->{PARENT}->{PARENT}->{NAME})) {
844                 return "$e->{PARENT}->{PARENT}->{NAME}.$name";
845         }
846
847         return $name;
848 }
849
850 ###################################
851 # find a sibling var in a structure
852 sub find_sibling($$)
853 {
854         my($e,$name) = @_;
855         my($fn) = $e->{PARENT};
856
857         if ($name =~ /\*(.*)/) {
858                 $name = $1;
859         }
860
861         for my $e2 (@{$fn->{ELEMENTS}}) {
862                 return $e2 if ($e2->{NAME} eq $name);
863         }
864
865         return undef;
866 }
867
868 my %property_list = (
869         # interface
870         "helpstring"            => ["INTERFACE", "FUNCTION"],
871         "version"               => ["INTERFACE"],
872         "uuid"                  => ["INTERFACE"],
873         "endpoint"              => ["INTERFACE"],
874         "pointer_default"       => ["INTERFACE"],
875         "helper"                => ["INTERFACE"],
876         "pyhelper"              => ["INTERFACE"],
877         "authservice"           => ["INTERFACE"],
878         "restricted"    => ["INTERFACE"],
879
880         # dcom
881         "object"                => ["INTERFACE"],
882         "local"                 => ["INTERFACE", "FUNCTION"],
883         "iid_is"                => ["ELEMENT"],
884         "call_as"               => ["FUNCTION"],
885         "idempotent"            => ["FUNCTION"],
886
887         # function
888         "noopnum"               => ["FUNCTION"],
889         "in"                    => ["ELEMENT"],
890         "out"                   => ["ELEMENT"],
891         "async"                 => ["FUNCTION"],
892
893         # pointer
894         "ref"                   => ["ELEMENT"],
895         "ptr"                   => ["ELEMENT"],
896         "unique"                => ["ELEMENT"],
897         "ignore"                => ["ELEMENT"],
898         "relative"              => ["ELEMENT"],
899         "null_is_ffffffff" => ["ELEMENT"],
900         "relative_base"         => ["TYPEDEF", "STRUCT", "UNION"],
901
902         "gensize"               => ["TYPEDEF", "STRUCT", "UNION"],
903         "value"                 => ["ELEMENT"],
904         "flag"                  => ["ELEMENT", "TYPEDEF", "STRUCT", "UNION", "ENUM", "BITMAP"],
905
906         # generic
907         "public"                => ["FUNCTION", "TYPEDEF", "STRUCT", "UNION", "ENUM", "BITMAP"],
908         "nopush"                => ["FUNCTION", "TYPEDEF", "STRUCT", "UNION", "ENUM", "BITMAP"],
909         "nopull"                => ["FUNCTION", "TYPEDEF", "STRUCT", "UNION", "ENUM", "BITMAP"],
910         "nosize"                => ["FUNCTION", "TYPEDEF", "STRUCT", "UNION", "ENUM", "BITMAP"],
911         "noprint"               => ["FUNCTION", "TYPEDEF", "STRUCT", "UNION", "ENUM", "BITMAP", "ELEMENT"],
912         "todo"                  => ["FUNCTION"],
913
914         # union
915         "switch_is"             => ["ELEMENT"],
916         "switch_type"           => ["ELEMENT", "UNION"],
917         "nodiscriminant"        => ["UNION"],
918         "case"                  => ["ELEMENT"],
919         "default"               => ["ELEMENT"],
920
921         "represent_as"          => ["ELEMENT"],
922         "transmit_as"           => ["ELEMENT"],
923
924         # subcontext
925         "subcontext"            => ["ELEMENT"],
926         "subcontext_size"       => ["ELEMENT"],
927         "compression"           => ["ELEMENT"],
928
929         # enum
930         "enum8bit"              => ["ENUM"],
931         "enum16bit"             => ["ENUM"],
932         "v1_enum"               => ["ENUM"],
933
934         # bitmap
935         "bitmap8bit"            => ["BITMAP"],
936         "bitmap16bit"           => ["BITMAP"],
937         "bitmap32bit"           => ["BITMAP"],
938         "bitmap64bit"           => ["BITMAP"],
939
940         # array
941         "range"                 => ["ELEMENT", "PIPE"],
942         "size_is"               => ["ELEMENT"],
943         "string"                => ["ELEMENT"],
944         "noheader"              => ["ELEMENT"],
945         "charset"               => ["ELEMENT"],
946         "length_is"             => ["ELEMENT"],
947 );
948
949 #####################################################################
950 # check for unknown properties
951 sub ValidProperties($$)
952 {
953         my ($e,$t) = @_;
954
955         return unless defined $e->{PROPERTIES};
956
957         foreach my $key (keys %{$e->{PROPERTIES}}) {
958                 warning($e, el_name($e) . ": unknown property '$key'")
959                         unless defined($property_list{$key});
960
961                 fatal($e, el_name($e) . ": property '$key' not allowed on '$t'")
962                         unless grep(/^$t$/, @{$property_list{$key}});
963         }
964 }
965
966 sub mapToScalar($)
967 {
968         sub mapToScalar($);
969         my $t = shift;
970         return $t->{NAME} if (ref($t) eq "HASH" and $t->{TYPE} eq "SCALAR");
971         my $ti = getType($t);
972
973         if (not defined ($ti)) {
974                 return undef;
975         } elsif ($ti->{TYPE} eq "TYPEDEF") {
976                 return mapToScalar($ti->{DATA});
977         } elsif ($ti->{TYPE} eq "ENUM") {
978                 return Parse::Pidl::Typelist::enum_type_fn($ti);
979         } elsif ($ti->{TYPE} eq "BITMAP") {
980                 return Parse::Pidl::Typelist::bitmap_type_fn($ti);
981         }
982
983         return undef;
984 }
985
986 #####################################################################
987 # validate an element
988 sub ValidElement($)
989 {
990         my $e = shift;
991
992         ValidProperties($e,"ELEMENT");
993
994         # Check whether switches are used correctly.
995         if (my $switch = has_property($e, "switch_is")) {
996                 my $e2 = find_sibling($e, $switch);
997                 my $type = getType($e->{TYPE});
998
999                 if (defined($type) and $type->{DATA}->{TYPE} ne "UNION") {
1000                         fatal($e, el_name($e) . ": switch_is() used on non-union type $e->{TYPE} which is a $type->{DATA}->{TYPE}");
1001                 }
1002
1003                 if (not has_property($type->{DATA}, "nodiscriminant") and defined($e2)) {
1004                         my $discriminator_type = has_property($type->{DATA}, "switch_type");
1005                         $discriminator_type = "uint32" unless defined ($discriminator_type);
1006
1007                         my $t1 = mapToScalar($discriminator_type);
1008
1009                         if (not defined($t1)) {
1010                                 fatal($e, el_name($e) . ": unable to map discriminator type '$discriminator_type' to scalar");
1011                         }
1012
1013                         my $t2 = mapToScalar($e2->{TYPE});
1014                         if (not defined($t2)) {
1015                                 fatal($e, el_name($e) . ": unable to map variable used for switch_is() to scalar");
1016                         }
1017
1018                         if ($t1 ne $t2) {
1019                                 warning($e, el_name($e) . ": switch_is() is of type $e2->{TYPE} ($t2), while discriminator type for union $type->{NAME} is $discriminator_type ($t1)");
1020                         }
1021                 }
1022         }
1023
1024         if (has_property($e, "subcontext") and has_property($e, "represent_as")) {
1025                 fatal($e, el_name($e) . " : subcontext() and represent_as() can not be used on the same element");
1026         }
1027
1028         if (has_property($e, "subcontext") and has_property($e, "transmit_as")) {
1029                 fatal($e, el_name($e) . " : subcontext() and transmit_as() can not be used on the same element");
1030         }
1031
1032         if (has_property($e, "represent_as") and has_property($e, "transmit_as")) {
1033                 fatal($e, el_name($e) . " : represent_as() and transmit_as() can not be used on the same element");
1034         }
1035
1036         if (has_property($e, "represent_as") and has_property($e, "value")) {
1037                 fatal($e, el_name($e) . " : represent_as() and value() can not be used on the same element");
1038         }
1039
1040         if (has_property($e, "subcontext")) {
1041                 warning($e, "subcontext() is deprecated. Use represent_as() or transmit_as() instead");
1042         }
1043
1044         if (defined (has_property($e, "subcontext_size")) and not defined(has_property($e, "subcontext"))) {
1045                 fatal($e, el_name($e) . " : subcontext_size() on non-subcontext element");
1046         }
1047
1048         if (defined (has_property($e, "compression")) and not defined(has_property($e, "subcontext"))) {
1049                 fatal($e, el_name($e) . " : compression() on non-subcontext element");
1050         }
1051
1052         if (!$e->{POINTERS} && (
1053                 has_property($e, "ptr") or
1054                 has_property($e, "unique") or
1055                 has_property($e, "relative") or
1056                 has_property($e, "ref"))) {
1057                 fatal($e, el_name($e) . " : pointer properties on non-pointer element\n");      
1058         }
1059 }
1060
1061 #####################################################################
1062 # validate an enum
1063 sub ValidEnum($)
1064 {
1065         my ($enum) = @_;
1066
1067         ValidProperties($enum, "ENUM");
1068 }
1069
1070 #####################################################################
1071 # validate a bitmap
1072 sub ValidBitmap($)
1073 {
1074         my ($bitmap) = @_;
1075
1076         ValidProperties($bitmap, "BITMAP");
1077 }
1078
1079 #####################################################################
1080 # validate a struct
1081 sub ValidStruct($)
1082 {
1083         my($struct) = shift;
1084
1085         ValidProperties($struct, "STRUCT");
1086
1087         return unless defined($struct->{ELEMENTS});
1088
1089         foreach my $e (@{$struct->{ELEMENTS}}) {
1090                 $e->{PARENT} = $struct;
1091                 ValidElement($e);
1092         }
1093 }
1094
1095 #####################################################################
1096 # parse a union
1097 sub ValidUnion($)
1098 {
1099         my($union) = shift;
1100
1101         ValidProperties($union,"UNION");
1102
1103         if (has_property($union->{PARENT}, "nodiscriminant") and 
1104                 has_property($union->{PARENT}, "switch_type")) {
1105                 fatal($union->{PARENT}, $union->{PARENT}->{NAME} . ": switch_type(" . $union->{PARENT}->{PROPERTIES}->{switch_type} . ") on union without discriminant");
1106         }
1107
1108         return unless defined($union->{ELEMENTS});
1109
1110         foreach my $e (@{$union->{ELEMENTS}}) {
1111                 $e->{PARENT} = $union;
1112
1113                 if (defined($e->{PROPERTIES}->{default}) and 
1114                         defined($e->{PROPERTIES}->{case})) {
1115                         fatal($e, "Union member $e->{NAME} can not have both default and case properties!");
1116                 }
1117                 
1118                 unless (defined ($e->{PROPERTIES}->{default}) or 
1119                                 defined ($e->{PROPERTIES}->{case})) {
1120                         fatal($e, "Union member $e->{NAME} must have default or case property");
1121                 }
1122
1123                 if (has_property($e, "ref")) {
1124                         fatal($e, el_name($e) . ": embedded ref pointers are not supported yet\n");
1125                 }
1126
1127
1128                 ValidElement($e);
1129         }
1130 }
1131
1132 #####################################################################
1133 # validate a pipe
1134 sub ValidPipe($)
1135 {
1136         my ($pipe) = @_;
1137         my $data = $pipe->{DATA};
1138
1139         ValidProperties($pipe, "PIPE");
1140
1141         fatal($pipe, $pipe->{NAME} . ": 'pipe' is not yet supported by pidl");
1142 }
1143
1144 #####################################################################
1145 # parse a typedef
1146 sub ValidTypedef($)
1147 {
1148         my($typedef) = shift;
1149         my $data = $typedef->{DATA};
1150
1151         ValidProperties($typedef, "TYPEDEF");
1152
1153         $data->{PARENT} = $typedef;
1154
1155         $data->{FILE} = $typedef->{FILE} unless defined($data->{FILE});
1156         $data->{LINE} = $typedef->{LINE} unless defined($data->{LINE});
1157
1158         ValidType($data) if (ref($data) eq "HASH");
1159 }
1160
1161 #####################################################################
1162 # validate a function
1163 sub ValidFunction($)
1164 {
1165         my($fn) = shift;
1166
1167         ValidProperties($fn,"FUNCTION");
1168
1169         foreach my $e (@{$fn->{ELEMENTS}}) {
1170                 $e->{PARENT} = $fn;
1171                 if (has_property($e, "ref") && !$e->{POINTERS}) {
1172                         fatal($e, "[ref] variables must be pointers ($fn->{NAME}/$e->{NAME})");
1173                 }
1174                 ValidElement($e);
1175         }
1176 }
1177
1178 #####################################################################
1179 # validate a type
1180 sub ValidType($)
1181 {
1182         my ($t) = @_;
1183
1184         { 
1185                 TYPEDEF => \&ValidTypedef,
1186                 STRUCT => \&ValidStruct,
1187                 UNION => \&ValidUnion,
1188                 ENUM => \&ValidEnum,
1189                 BITMAP => \&ValidBitmap,
1190                 PIPE => \&ValidPipe
1191         }->{$t->{TYPE}}->($t);
1192 }
1193
1194 #####################################################################
1195 # parse the interface definitions
1196 sub ValidInterface($)
1197 {
1198         my($interface) = shift;
1199         my($data) = $interface->{DATA};
1200
1201         if (has_property($interface, "helper")) {
1202                 warning($interface, "helper() is pidl-specific and deprecated. Use `include' instead");
1203         }
1204
1205         ValidProperties($interface,"INTERFACE");
1206
1207         if (has_property($interface, "pointer_default")) {
1208                 if (not grep (/$interface->{PROPERTIES}->{pointer_default}/, 
1209                                         ("ref", "unique", "ptr"))) {
1210                         fatal($interface, "Unknown default pointer type `$interface->{PROPERTIES}->{pointer_default}'");
1211                 }
1212         }
1213
1214         if (has_property($interface, "object")) {
1215                 if (has_property($interface, "version") && 
1216                         $interface->{PROPERTIES}->{version} != 0) {
1217                         fatal($interface, "Object interfaces must have version 0.0 ($interface->{NAME})");
1218                 }
1219
1220                 if (!defined($interface->{BASE}) && 
1221                         not ($interface->{NAME} eq "IUnknown")) {
1222                         fatal($interface, "Object interfaces must all derive from IUnknown ($interface->{NAME})");
1223                 }
1224         }
1225                 
1226         foreach my $d (@{$data}) {
1227                 ($d->{TYPE} eq "FUNCTION") && ValidFunction($d);
1228                 ($d->{TYPE} eq "TYPEDEF" or 
1229                  $d->{TYPE} eq "STRUCT" or
1230                  $d->{TYPE} eq "UNION" or 
1231                  $d->{TYPE} eq "ENUM" or
1232                  $d->{TYPE} eq "BITMAP" or
1233                  $d->{TYPE} eq "PIPE") && ValidType($d);
1234         }
1235
1236 }
1237
1238 #####################################################################
1239 # Validate an IDL structure
1240 sub Validate($)
1241 {
1242         my($idl) = shift;
1243
1244         foreach my $x (@{$idl}) {
1245                 ($x->{TYPE} eq "INTERFACE") && 
1246                     ValidInterface($x);
1247                 ($x->{TYPE} eq "IMPORTLIB") &&
1248                         fatal($x, "importlib() not supported");
1249         }
1250 }
1251
1252 sub is_charset_array($$)
1253 {
1254         my ($e,$l) = @_;
1255
1256         return 0 if ($l->{TYPE} ne "ARRAY");
1257
1258         my $nl = GetNextLevel($e,$l);
1259
1260         return 0 unless ($nl->{TYPE} eq "DATA");
1261
1262         return has_property($e, "charset");
1263 }
1264
1265
1266
1267 1;