docs-xml/xslt/expand-smbconfdoc.xsl

   1 <?xml version='1.0'?>
   2 <!--
   3         smb.conf-documentation specific stylesheets
   4         Published under the GNU GPL
   5
   6         (C) Jelmer Vernooij                                     2002-2004
   7         (C) Alexander Bokovoy                                   2002-2004
   8 -->
   9 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  10         xmlns:samba="http://www.samba.org/samba/DTD/samba-doc"
  11         version="1.1">
  12
  13         <xsl:template match="description"><xsl:apply-templates/></xsl:template>
  14
  15         <xsl:template match="value"><xsl:element name="literal"><xsl:apply-templates/></xsl:element></xsl:template>
  16
  17         <xsl:template match="command"><xsl:element name="literal"><xsl:apply-templates/></xsl:element></xsl:template>
  18
  19         <xsl:template match="synonym"><xsl:apply-templates/></xsl:template>
  20
  21         <xsl:template match="related"><xsl:element name="para"><xsl:text>Related command</xsl:text><xsl:apply-templates/></xsl:element></xsl:template>
  22
  23         <xsl:template match="samba:parameterlist">
  24                 <xsl:apply-templates>
  25                         <xsl:sort select="samba:parameter/@name"/>
  26                 </xsl:apply-templates>
  27         </xsl:template>
  28
  29         <xsl:template match="value/comment">
  30                 <xsl:text>&#10;# </xsl:text>
  31                 <xsl:apply-templates/>
  32         </xsl:template>
  33
  34         <xsl:template match="samba:parameter">
  35                 <xsl:variable name="cname"><xsl:value-of select="translate(translate(string(@name),' ',''),
  36                                 'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ')"/>
  37                 </xsl:variable>
  38
  39                 <xsl:variable name="name"><xsl:value-of select="@name"/></xsl:variable>
  40
  41                 <xsl:variable name="anchor">
  42                         <xsl:element name="anchor">
  43                                 <xsl:attribute name="id">
  44                                         <xsl:value-of select="$cname"/>
  45                                 </xsl:attribute>
  46                         </xsl:element>
  47                 </xsl:variable>
  48
  49                 <xsl:variable name="context">
  50                         <xsl:text> (</xsl:text>
  51                         <xsl:value-of select="@context"/>
  52                         <xsl:text>)</xsl:text>
  53                 </xsl:variable>
  54
  55                 <xsl:variable name="term">
  56                         <xsl:element name="indexterm">
  57                                 <xsl:copy-of select="$anchor"/>
  58                                 <xsl:value-of select="@name"/>
  59                                 <xsl:value-of select="$context"/>
  60                         </xsl:element>
  61                 </xsl:variable>
  62
  63
  64                 <!-- Generate list of examples -->
  65                 <xsl:variable name="examples">
  66                         <xsl:for-each select="value">
  67                                 <xsl:if test="@type = 'example'">
  68                                         <xsl:element name="para">
  69                                                 <xsl:text>Example: </xsl:text>
  70                                                 <xsl:element name="emphasis">
  71                                                         <xsl:element name="parameter">
  72                                                                 <xsl:copy-of select="$name"/>
  73                                                         </xsl:element>
  74                                                         <xsl:text> = </xsl:text>
  75                                                         <xsl:apply-templates select="."/>
  76                                                         <xsl:text>&#10;</xsl:text>
  77                                                 </xsl:element>
  78                                                 <xsl:text>&#10;</xsl:text>
  79                                         </xsl:element>
  80                                 </xsl:if>
  81                         </xsl:for-each>
  82                 </xsl:variable>
  83
  84                 <xsl:variable name="tdefault">
  85                         <xsl:for-each select="value">
  86                                 <xsl:if test="@type = 'default'">
  87                                         <xsl:element name="para">
  88                                                 <xsl:text>Default: </xsl:text>
  89                                                 <xsl:element name="emphasis">
  90                                                         <xsl:element name="parameter">
  91                                                                 <xsl:copy-of select="$name"/>
  92                                                         </xsl:element>
  93                                                         <xsl:text> = </xsl:text>
  94                                                         <xsl:apply-templates select="."/>
  95                                                         <xsl:text>&#10;</xsl:text>
  96                                                 </xsl:element>
  97                                                 <xsl:text>&#10;</xsl:text>
  98                                         </xsl:element>
  99                                 </xsl:if>
 100                         </xsl:for-each>
 101                 </xsl:variable>
 102
 103                 <xsl:variable name="default">
 104                         <xsl:choose>
 105                                 <xsl:when test="$tdefault = ''">
 106                                         <xsl:element name="para">
 107                                                 <xsl:element name="emphasis">
 108                                                         <xsl:text>No default</xsl:text>
 109                                                 </xsl:element>
 110                                         </xsl:element>
 111                                 </xsl:when>
 112                                 <xsl:otherwise>
 113                                         <xsl:copy-of select="$tdefault"/>
 114                                 </xsl:otherwise>
 115                         </xsl:choose>
 116                 </xsl:variable>
 117
 118                 <xsl:variable name="content">
 119                         <xsl:apply-templates select="description"/>
 120                 </xsl:variable>
 121
 122                 <xsl:for-each select="synonym">
 123                         <xsl:element name="varlistentry">
 124                                 <xsl:text>&#10;</xsl:text>
 125                                 <xsl:element name="indexterm">
 126                                         <xsl:attribute name="significance">
 127                                                 <xsl:text>preferred</xsl:text>
 128                                         </xsl:attribute>
 129                                         <xsl:element name="primary">
 130                                                 <xsl:value-of select="."/>
 131                                         </xsl:element>
 132                                         <xsl:element name="see">
 133                                                 <xsl:value-of select="$name"/>
 134                                         </xsl:element>
 135                                 </xsl:element>
 136                                 <xsl:element name="term">
 137                                         <xsl:element name="anchor">
 138                                                 <xsl:attribute name="id">
 139                                                         <xsl:value-of select="translate(translate(string(.),' ',''), 'abcdefghijklmnopqrstuvwxyz','ABCDEFGHIJKLMNOPQRSTUVWXYZ')"/>
 140                                                 </xsl:attribute>
 141                                         </xsl:element>
 142                                         <xsl:value-of select="."/>
 143                                 </xsl:element>
 144                                 <xsl:element name="listitem">
 145                                         <xsl:element name="para"><xsl:text>This parameter is a synonym for </xsl:text><xsl:copy-of select="$name"/><xsl:text>.</xsl:text></xsl:element>
 146                                 </xsl:element>
 147                         </xsl:element>
 148                 </xsl:for-each>
 149
 150                 <xsl:element name="varlistentry">
 151                         <xsl:text>&#10;</xsl:text>
 152                         <xsl:element name="indexterm">
 153                                 <xsl:attribute name="significance">
 154                                         <xsl:text>preferred</xsl:text>
 155                                 </xsl:attribute>
 156                                 <xsl:element name="primary">
 157                                         <xsl:value-of select="@name"/>
 158                                 </xsl:element>
 159                         </xsl:element>
 160                         <xsl:copy-of select="$term"/>
 161                         <xsl:element name="listitem">
 162                                 <xsl:copy-of select="$content"/> <xsl:text>&#10;</xsl:text>
 163                                 <xsl:copy-of select="$default"/> <xsl:text>&#10;</xsl:text>
 164                                 <xsl:copy-of select="$examples"/> <xsl:text>&#10;</xsl:text>
 165                         </xsl:element>
 166                 </xsl:element>
 167         </xsl:template>
 168 </xsl:stylesheet>