source4/configure.ac

   1 dnl -*- mode: m4-mode -*-
   2 dnl Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.54)
   5
   6 AC_INIT([samba],[4],[samba-technical@samba.org])
   7
   8 AC_CONFIG_SRCDIR([include/includes.h])
   9 AC_CONFIG_HEADER(include/config_tmp.h)
  10 AC_DEFINE(CONFIG_H_IS_FROM_SAMBA,1,[Marker for samba's config.h])
  11
  12 # Configuration rules.
  13 m4_include(build/m4/env.m4)
  14 m4_include(../lib/replace/samba.m4)
  15 m4_include(lib/smbreadline/readline.m4)
  16 m4_include(heimdal_build/config.m4)
  17 m4_include(../lib/util/fault.m4)
  18 m4_include(../lib/util/signal.m4)
  19 m4_include(../lib/util/util.m4)
  20 m4_include(../lib/util/fsusage.m4)
  21 m4_include(../lib/util/xattr.m4)
  22 m4_include(../lib/util/capability.m4)
  23 m4_include(../lib/util/time.m4)
  24 m4_include(../lib/popt/samba.m4)
  25 m4_include(../lib/util/charset/config.m4)
  26 m4_include(lib/socket/config.m4)
  27 m4_include(../lib/zlib/zlib.m4)
  28 AC_ZLIB([
  29 SMB_EXT_LIB(ZLIB, [${ZLIB_LIBS}])
  30 ],[
  31 SMB_INCLUDE_MK(lib/zlib.mk)
  32 ])
  33 m4_include(../nsswitch/nsstest.m4)
  34 m4_include(../pidl/config.m4)
  35
  36 AC_CONFIG_FILES(lib/registry/registry.pc)
  37 AC_CONFIG_FILES(librpc/dcerpc.pc)
  38 AC_CONFIG_FILES(../librpc/ndr.pc)
  39 AC_CONFIG_FILES(../lib/torture/torture.pc)
  40 AC_CONFIG_FILES(auth/gensec/gensec.pc)
  41 AC_CONFIG_FILES(param/samba-hostconfig.pc)
  42 AC_CONFIG_FILES(librpc/dcerpc_samr.pc)
  43 AC_CONFIG_FILES(librpc/dcerpc_atsvc.pc)
  44
  45 SMB_EXT_LIB_FROM_PKGCONFIG(LIBTALLOC, talloc >= 1.2.0,
  46         [],
  47         [
  48                 m4_include(../lib/talloc/libtalloc.m4)
  49                 SMB_INCLUDE_MK(../lib/talloc/config.mk)
  50         ]
  51 )
  52
  53 SMB_EXT_LIB_FROM_PKGCONFIG(LIBTDB, tdb >= 1.1.3,
  54         [],
  55         [
  56                 m4_include(../lib/tdb/libtdb.m4)
  57                 SMB_INCLUDE_MK(../lib/tdb/config.mk)
  58         ]
  59 )
  60
  61 SMB_INCLUDE_MK(../lib/tdb/python.mk)
  62
  63 SMB_EXT_LIB_FROM_PKGCONFIG(LIBTEVENT, tevent >= 0.9.2,
  64         [],[m4_include(../lib/tevent/samba.m4)]
  65 )
  66
  67 SMB_INCLUDE_MK(../lib/tevent/python.mk)
  68
  69 SMB_EXT_LIB_FROM_PKGCONFIG(LIBLDB, ldb = 0.9.1,
  70         [
  71                 SMB_INCLUDE_MK(lib/ldb/ldb_ildap/config.mk)
  72                 SMB_INCLUDE_MK(lib/ldb/tools/config.mk)
  73                 define_ldb_modulesdir=no
  74         ],
  75         [
  76                 # Here we need to do some tricks
  77                 # with AC_CONFIG_COMMANDS_PRE
  78                 # as that's the deferrs the commands
  79                 # to location after $prefix and $exec_prefix
  80                 # have usefull values and directly before
  81                 # creating config.status.
  82                 #
  83                 # The 'eval eval echo' trick is used to
  84                 # actually get the raw absolute directory
  85                 # path as this is needed in config.h
  86                 define_ldb_modulesdir=yes
  87                 AC_CONFIG_COMMANDS_PRE([
  88                 if test x"$define_ldb_modulesdir" = x"yes";then
  89                         LDB_MODULESDIR=`eval eval echo ${modulesdir}/ldb`
  90                         AC_DEFINE_UNQUOTED(LDB_MODULESDIR, "${LDB_MODULESDIR}" , [ldb Modules directory])
  91                 fi
  92                 ])
  93                 ldbdir=lib/ldb
  94                 AC_SUBST(ldbdir)
  95                 m4_include(lib/ldb/sqlite3.m4)
  96                 m4_include(lib/ldb/libldb.m4)
  97                 SMB_INCLUDE_MK(lib/ldb/config.mk)
  98                 AC_CONFIG_FILES(lib/ldb/ldb.pc)
  99         ]
 100 )
 101 SMB_INCLUDE_MK(lib/ldb/python.mk)
 102
 103 m4_include(lib/tls/config.m4)
 104
 105 dnl m4_include(auth/kerberos/config.m4)
 106 m4_include(auth/gensec/config.m4)
 107 m4_include(smbd/process_model.m4)
 108 m4_include(ntvfs/posix/config.m4)
 109 m4_include(ntvfs/unixuid/config.m4)
 110 m4_include(../lib/socket_wrapper/config.m4)
 111 m4_include(../lib/nss_wrapper/config.m4)
 112 m4_include(auth/config.m4)
 113 m4_include(kdc/config.m4)
 114 m4_include(ntvfs/sysdep/config.m4)
 115 m4_include(../nsswitch/config.m4)
 116
 117 #################################################
 118 # add *_CFLAGS only for the real build
 119 CFLAGS="${CFLAGS} ${DEVELOPER_CFLAGS}"
 120
 121 #################################################
 122 # final configure stuff
 123
 124 AC_MSG_CHECKING([configure summary])
 125 AC_TRY_RUN([#include "${srcdir-.}/../tests/summary.c"],
 126            AC_MSG_RESULT(yes),
 127            AC_MSG_ERROR([summary failure. Aborting config]); exit 1;,
 128            AC_MSG_WARN([cannot run when cross-compiling]))
 129
 130 LIBS=`echo $LIBS | sed -e 's/ *//g'`
 131 if test x"$LIBS" != x""; then
 132         echo "LIBS: $LIBS"
 133         AC_MSG_WARN([the global \$LIBS variable contains some libraries!])
 134         AC_MSG_WARN([this should not happen, please report to samba-technical@lists.samba.org!])
 135         AC_MSG_ERROR([only _EXT macros from aclocal.m4 should be used!])
 136 fi
 137
 138 dnl Remove -L/usr/lib/? from LDFLAGS and LIBS
 139 LIB_REMOVE_USR_LIB(LDFLAGS)
 140 LIB_REMOVE_USR_LIB(LIBS)
 141
 142 dnl Remove -I/usr/include/? from CFLAGS and CPPFLAGS
 143 CFLAGS_REMOVE_USR_INCLUDE(CFLAGS)
 144 CFLAGS_REMOVE_USR_INCLUDE(CPPFLAGS)
 145
 146 AC_SUBST(ac_default_prefix)
 147
 148 for d in build/smb_build bin include ; do
 149     test -d ${builddir}/$d || AS_MKDIR_P(${builddir}/$d)
 150 done
 151
 152 AC_SUBST(INTERN_LDFLAGS)
 153 AC_SUBST(INSTALL_LINK_FLAGS)
 154 if test $USESHARED = "true";
 155 then
 156         INTERN_LDFLAGS="-L\$(shliboutputdir) -L\${builddir}/bin/static"
 157         INSTALL_LINK_FLAGS="-Wl,-rpath-link,\$(shliboutputdir)";
 158 else
 159         INTERN_LDFLAGS="-L\${builddir}/bin/static -L\$(shliboutputdir)"
 160 fi
 161
 162 builddir_headers=""
 163
 164 if test "x$ac_abs_srcdir" != "x$ac_abs_builddir"
 165 then
 166         builddir_headers="-I\$(builddir)/include -I\$(builddir) -I\$(builddir)/lib ";
 167 fi
 168
 169 CPPFLAGS="$builddir_headers-I\$(srcdir)/include -I\$(srcdir) -I\$(srcdir)/lib -I\$(srcdir)/../lib/replace -I\$(srcdir)/../lib/talloc -I\$(srcdir)/.. -D_SAMBA_BUILD_=4 -DHAVE_CONFIG_H $CPPFLAGS"
 170
 171 SMB_WRITE_PERLVARS(build/smb_build/config.pm)
 172
 173 echo "configure: creating config.mk"
 174 cat >config.mk<<CEOF
 175 # config.mk - Autogenerated by configure, DO NOT EDIT!
 176 $SMB_INFO_EXT_LIBS
 177 $SMB_INFO_SUBSYSTEMS
 178 $SMB_INFO_LIBRARIES
 179 CEOF
 180
 181 SMB_BUILD_RUN(data.mk)
 182 AC_OUTPUT
 183
 184 cmp include/config_tmp.h include/config.h >/dev/null 2>&1
 185 CMP_RET=$?
 186 if test $CMP_RET != 0; then
 187         cp include/config_tmp.h include/config.h
 188 fi
 189
 190 SMB_WRITE_MAKEVARS(mkconfig.mk)
 191
 192 if test $USESHARED = true
 193 then
 194         echo "To run binaries without installing, set the following environment variable:"
 195         echo "$LIB_PATH_VAR=$builddir/bin/shared"
 196 fi
 197
 198 echo
 199 echo "To build Samba, run $MAKE"