selftest/selftest.pl

   1 #!/usr/bin/perl
   2 # Bootstrap Samba and run a number of tests against it.
   3 # Copyright (C) 2005-2010 Jelmer Vernooij <jelmer@samba.org>
   4 # Copyright (C) 2007-2009 Stefan Metzmacher <metze@samba.org>
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 use strict;
  20
  21 use FindBin qw($RealBin $Script);
  22 use File::Spec;
  23 use File::Temp qw(tempfile);
  24 use Getopt::Long;
  25 use POSIX;
  26 use Cwd qw(abs_path);
  27 use lib "$RealBin";
  28 use Subunit;
  29 use SocketWrapper;
  30 use target::Samba;
  31
  32 eval {
  33 require Time::HiRes;
  34 Time::HiRes->import("time");
  35 };
  36 if ($@) {
  37         print "You don't have Time::Hires installed !\n";
  38 }
  39
  40 my $opt_help = 0;
  41 my $opt_target = "samba";
  42 my $opt_quick = 0;
  43 my $opt_socket_wrapper = 0;
  44 my $opt_socket_wrapper_pcap = undef;
  45 my $opt_socket_wrapper_keep_pcap = undef;
  46 my $opt_random_order = 0;
  47 my $opt_one = 0;
  48 my @opt_exclude = ();
  49 my @opt_include = ();
  50 my @opt_exclude_env = ();
  51 my @opt_include_env = ();
  52 my $opt_testenv = 0;
  53 my $opt_list = 0;
  54 my $opt_mitkrb5 = 0;
  55 my $ldap = undef;
  56 my $opt_resetup_env = undef;
  57 my $opt_load_list = undef;
  58 my $opt_libnss_wrapper_so_path = "";
  59 my $opt_libresolv_wrapper_so_path = "";
  60 my $opt_libsocket_wrapper_so_path = "";
  61 my $opt_libuid_wrapper_so_path = "";
  62 my $opt_use_dns_faking = 0;
  63 my @testlists = ();
  64
  65 my $srcdir = ".";
  66 my $bindir = "./bin";
  67 my $prefix = "./st";
  68
  69 my @includes = ();
  70 my @excludes = ();
  71
  72 sub find_in_list($$)
  73 {
  74         my ($list, $fullname) = @_;
  75
  76         foreach (@$list) {
  77                 if ($fullname =~ /$$_[0]/) {
  78                          return ($$_[1]) if ($$_[1]);
  79                          return "";
  80                 }
  81         }
  82
  83         return undef;
  84 }
  85
  86 sub skip
  87 {
  88         my ($name, $envname) = @_;
  89         my ($env_basename, $env_localpart) = split(/:/, $envname);
  90
  91         if ($opt_target eq "samba3" && $Samba::ENV_NEEDS_AD_DC{$env_basename}) {
  92                 return "environment $envname is disabled as this build does not include an AD DC";
  93         }
  94
  95         return find_in_list(\@excludes, $name);
  96 }
  97
  98 sub getlog_env($);
  99
 100 sub setup_pcap($)
 101 {
 102         my ($name) = @_;
 103
 104         return unless ($opt_socket_wrapper_pcap);
 105         return unless defined($ENV{SOCKET_WRAPPER_PCAP_DIR});
 106
 107         my $fname = $name;
 108         $fname =~ s%[^abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789\-]%_%g;
 109
 110         my $pcap_file = "$ENV{SOCKET_WRAPPER_PCAP_DIR}/$fname.pcap";
 111
 112         SocketWrapper::setup_pcap($pcap_file);
 113
 114         return $pcap_file;
 115 }
 116
 117 sub cleanup_pcap($$)
 118 {
 119         my ($pcap_file, $exitcode) = @_;
 120
 121         return unless ($opt_socket_wrapper_pcap);
 122         return if ($opt_socket_wrapper_keep_pcap);
 123         return unless ($exitcode == 0);
 124         return unless defined($pcap_file);
 125
 126         unlink($pcap_file);
 127 }
 128
 129 # expand strings from %ENV
 130 sub expand_environment_strings($)
 131 {
 132         my $s = shift;
 133         # we use a reverse sort so we do the longer ones first
 134         foreach my $k (sort { $b cmp $a } keys %ENV) {
 135                 $s =~ s/\$$k/$ENV{$k}/g;
 136         }
 137         return $s;
 138 }
 139
 140 sub run_testsuite($$$$$)
 141 {
 142         my ($envname, $name, $cmd, $i, $totalsuites) = @_;
 143         my $pcap_file = setup_pcap($name);
 144
 145         Subunit::start_testsuite($name);
 146         Subunit::progress_push();
 147         Subunit::report_time(time());
 148         system($cmd);
 149         Subunit::report_time(time());
 150         Subunit::progress_pop();
 151
 152         if ($? == -1) {
 153                 print "command: $cmd\n";
 154                 printf "expanded command: %s\n", expand_environment_strings($cmd);
 155                 Subunit::end_testsuite($name, "error", "Unable to run $cmd: $!");
 156                 exit(1);
 157         } elsif ($? & 127) {
 158                 print "command: $cmd\n";
 159                 printf "expanded command: %s\n", expand_environment_strings($cmd);
 160                 Subunit::end_testsuite($name, "error",
 161                         sprintf("%s died with signal %d, %s coredump\n", $cmd, ($? & 127),  ($? & 128) ? 'with' : 'without'));
 162                 exit(1);
 163         }
 164
 165         my $exitcode = $? >> 8;
 166
 167         my $envlog = getlog_env($envname);
 168         if ($envlog ne "") {
 169                 print "envlog: $envlog\n";
 170         }
 171
 172         print "command: $cmd\n";
 173         printf "expanded command: %s\n", expand_environment_strings($cmd);
 174
 175         if ($exitcode == 0) {
 176                 Subunit::end_testsuite($name, "success");
 177         } else {
 178                 Subunit::end_testsuite($name, "failure", "Exit code was $exitcode");
 179         }
 180
 181         cleanup_pcap($pcap_file, $exitcode);
 182
 183         if (not $opt_socket_wrapper_keep_pcap and defined($pcap_file)) {
 184                 print "PCAP FILE: $pcap_file\n";
 185         }
 186
 187         if ($exitcode != 0) {
 188                 exit(1) if ($opt_one);
 189         }
 190
 191         return $exitcode;
 192 }
 193
 194 sub ShowHelp()
 195 {
 196         print "Samba test runner
 197 Copyright (C) Jelmer Vernooij <jelmer\@samba.org>
 198 Copyright (C) Stefan Metzmacher <metze\@samba.org>
 199
 200 Usage: $Script [OPTIONS] TESTNAME-REGEX [TESTNAME-REGEX...]
 201
 202 Generic options:
 203  --help                     this help page
 204  --target=samba[3]|win      Samba version to target
 205  --testlist=FILE            file to read available tests from
 206  --exclude=FILE             Exclude tests listed in the file
 207  --include=FILE             Include tests listed in the file
 208  --exclude-env=ENV          Exclude tests for the specified environment
 209  --include-env=ENV          Include tests for the specified environment
 210
 211 Paths:
 212  --prefix=DIR               prefix to run tests in [st]
 213  --srcdir=DIR               source directory [.]
 214  --bindir=DIR               binaries directory [./bin]
 215
 216 Preload cwrap:
 217  --nss_wrapper_so_path=FILE the nss_wrapper library to preload
 218  --resolv_wrapper_so_path=FILE the resolv_wrapper library to preload
 219  --socket_wrapper_so_path=FILE the socket_wrapper library to preload
 220  --uid_wrapper_so_path=FILE the uid_wrapper library to preload
 221
 222 DNS:
 223   --use-dns-faking          Fake DNS entries rather than talking to our
 224                             DNS implementation.
 225
 226 Target Specific:
 227  --socket-wrapper-pcap      save traffic to pcap directories
 228  --socket-wrapper-keep-pcap keep all pcap files, not just those for tests that
 229                             failed
 230  --socket-wrapper           enable socket wrapper
 231
 232 Samba4 Specific:
 233  --ldap=openldap|fedora-ds  back samba onto specified ldap server
 234
 235 Behaviour:
 236  --quick                    run quick overall test
 237  --one                      abort when the first test fails
 238  --testenv                  run a shell in the requested test environment
 239  --list                     list available tests
 240 ";
 241         exit(0);
 242 }
 243
 244 my $result = GetOptions (
 245                 'help|h|?' => \$opt_help,
 246                 'target=s' => \$opt_target,
 247                 'prefix=s' => \$prefix,
 248                 'socket-wrapper' => \$opt_socket_wrapper,
 249                 'socket-wrapper-pcap' => \$opt_socket_wrapper_pcap,
 250                 'socket-wrapper-keep-pcap' => \$opt_socket_wrapper_keep_pcap,
 251                 'quick' => \$opt_quick,
 252                 'one' => \$opt_one,
 253                 'exclude=s' => \@opt_exclude,
 254                 'include=s' => \@opt_include,
 255                 'exclude-env=s' => \@opt_exclude_env,
 256                 'include-env=s' => \@opt_include_env,
 257                 'srcdir=s' => \$srcdir,
 258                 'bindir=s' => \$bindir,
 259                 'testenv' => \$opt_testenv,
 260                 'list' => \$opt_list,
 261                 'mitkrb5' => \$opt_mitkrb5,
 262                 'ldap:s' => \$ldap,
 263                 'resetup-environment' => \$opt_resetup_env,
 264                 'testlist=s' => \@testlists,
 265                 'random-order' => \$opt_random_order,
 266                 'load-list=s' => \$opt_load_list,
 267                 'nss_wrapper_so_path=s' => \$opt_libnss_wrapper_so_path,
 268                 'resolv_wrapper_so_path=s' => \$opt_libresolv_wrapper_so_path,
 269                 'socket_wrapper_so_path=s' => \$opt_libsocket_wrapper_so_path,
 270                 'uid_wrapper_so_path=s' => \$opt_libuid_wrapper_so_path,
 271                 'use-dns-faking' => \$opt_use_dns_faking
 272             );
 273
 274 exit(1) if (not $result);
 275
 276 ShowHelp() if ($opt_help);
 277
 278 die("--list and --testenv are mutually exclusive") if ($opt_list and $opt_testenv);
 279
 280 # we want unbuffered output
 281 $| = 1;
 282
 283 my @tests = @ARGV;
 284
 285 # quick hack to disable rpc validation when using valgrind - its way too slow
 286 unless (defined($ENV{VALGRIND})) {
 287         $ENV{VALIDATE} = "validate";
 288         $ENV{MALLOC_CHECK_} = 3;
 289 }
 290
 291 # make all our python scripts unbuffered
 292 $ENV{PYTHONUNBUFFERED} = 1;
 293
 294 my $bindir_abs = abs_path($bindir);
 295
 296 # Backwards compatibility:
 297 if (defined($ENV{TEST_LDAP}) and $ENV{TEST_LDAP} eq "yes") {
 298         if (defined($ENV{FEDORA_DS_ROOT})) {
 299                 $ldap = "fedora-ds";
 300         } else {
 301                 $ldap = "openldap";
 302         }
 303 }
 304
 305 my $torture_maxtime = ($ENV{TORTURE_MAXTIME} or 1200);
 306 if ($ldap) {
 307         # LDAP is slow
 308         $torture_maxtime *= 2;
 309 }
 310
 311 $prefix =~ s+//+/+;
 312 $prefix =~ s+/./+/+;
 313 $prefix =~ s+/$++;
 314
 315 die("using an empty prefix isn't allowed") unless $prefix ne "";
 316
 317 # Ensure we have the test prefix around.
 318 #
 319 # We need restrictive
 320 # permissions on this as some subdirectories in this tree will have
 321 # wider permissions (ie 0777) and this would allow other users on the
 322 # host to subvert the test process.
 323 umask 0077;
 324 mkdir($prefix, 0700) unless -d $prefix;
 325 chmod 0700, $prefix;
 326 # We need to have no umask limitations for the tests.
 327 umask 0000;
 328
 329 my $prefix_abs = abs_path($prefix);
 330 my $tmpdir_abs = abs_path("$prefix/tmp");
 331 mkdir($tmpdir_abs, 0777) unless -d $tmpdir_abs;
 332
 333 my $srcdir_abs = abs_path($srcdir);
 334
 335 die("using an empty absolute prefix isn't allowed") unless $prefix_abs ne "";
 336 die("using '/' as absolute prefix isn't allowed") unless $prefix_abs ne "/";
 337
 338 $ENV{SAMBA_SELFTEST} = "1";
 339
 340 $ENV{PREFIX} = $prefix;
 341 $ENV{PREFIX_ABS} = $prefix_abs;
 342 $ENV{SRCDIR} = $srcdir;
 343 $ENV{SRCDIR_ABS} = $srcdir_abs;
 344 $ENV{GNUPGHOME} = "$srcdir_abs/selftest/gnupg";
 345 $ENV{BINDIR} = $bindir_abs;
 346
 347 my $tls_enabled = not $opt_quick;
 348 $ENV{TLS_ENABLED} = ($tls_enabled?"yes":"no");
 349
 350 sub prefix_pathvar($$)
 351 {
 352         my ($name, $newpath) = @_;
 353         if (defined($ENV{$name})) {
 354                 $ENV{$name} = "$newpath:$ENV{$name}";
 355         } else {
 356                 $ENV{$name} = $newpath;
 357         }
 358 }
 359 prefix_pathvar("PKG_CONFIG_PATH", "$bindir_abs/pkgconfig");
 360 prefix_pathvar("PYTHONPATH", "$bindir_abs/python");
 361
 362 if ($opt_socket_wrapper_keep_pcap) {
 363         # Socket wrapper keep pcap implies socket wrapper pcap
 364         $opt_socket_wrapper_pcap = 1;
 365 }
 366
 367 if ($opt_socket_wrapper_pcap) {
 368         # Socket wrapper pcap implies socket wrapper
 369         $opt_socket_wrapper = 1;
 370 }
 371
 372 my $ld_preload = $ENV{LD_PRELOAD};
 373
 374 if ($opt_libnss_wrapper_so_path) {
 375         if ($ld_preload) {
 376                 $ld_preload = "$ld_preload:$opt_libnss_wrapper_so_path";
 377         } else {
 378                 $ld_preload = "$opt_libnss_wrapper_so_path";
 379         }
 380 }
 381
 382 if ($opt_libresolv_wrapper_so_path) {
 383         if ($ld_preload) {
 384                 $ld_preload = "$ld_preload:$opt_libresolv_wrapper_so_path";
 385         } else {
 386                 $ld_preload = "$opt_libresolv_wrapper_so_path";
 387         }
 388 }
 389
 390 if ($opt_libsocket_wrapper_so_path) {
 391         if ($ld_preload) {
 392                 $ld_preload = "$ld_preload:$opt_libsocket_wrapper_so_path";
 393         } else {
 394                 $ld_preload = "$opt_libsocket_wrapper_so_path";
 395         }
 396 }
 397
 398 if ($opt_libuid_wrapper_so_path) {
 399         if ($ld_preload) {
 400                 $ld_preload = "$ld_preload:$opt_libuid_wrapper_so_path";
 401         } else {
 402                 $ld_preload = "$opt_libuid_wrapper_so_path";
 403         }
 404 }
 405
 406 $ENV{LD_PRELOAD} = $ld_preload;
 407 print "LD_PRELOAD=$ENV{LD_PRELOAD}\n";
 408
 409 # Enable uid_wrapper globally
 410 $ENV{UID_WRAPPER} = 1;
 411
 412 # Disable RTLD_DEEPBIND hack for Samba bind dlz module
 413 #
 414 # This is needed in order to allow the ldb_*ldap module
 415 # to work with a preloaded socket wrapper.
 416 $ENV{LDB_MODULES_DISABLE_DEEPBIND} = 1;
 417
 418 my $socket_wrapper_dir;
 419 if ($opt_socket_wrapper) {
 420         $socket_wrapper_dir = SocketWrapper::setup_dir("$prefix_abs/w", $opt_socket_wrapper_pcap);
 421         print "SOCKET_WRAPPER_DIR=$socket_wrapper_dir\n";
 422 } elsif (not $opt_list) {
 423          unless ($< == 0) {
 424                  warn("not using socket wrapper, but also not running as root. Will not be able to listen on proper ports");
 425          }
 426 }
 427
 428 if ($opt_use_dns_faking) {
 429         print "DNS: Faking nameserver\n";
 430         $ENV{SAMBA_DNS_FAKING} = 1;
 431 }
 432
 433 my $target;
 434 my $testenv_default = "none";
 435
 436 if ($opt_mitkrb5 == 1) {
 437         $ENV{MITKRB5} = $opt_mitkrb5;
 438 }
 439
 440 # After this many seconds, the server will self-terminate.  All tests
 441 # must terminate in this time, and testenv will only stay alive this
 442 # long
 443
 444 my $server_maxtime;
 445 if ($opt_testenv) {
 446     # 1 year should be enough :-)
 447     $server_maxtime = 365 * 24 * 60 * 60;
 448 } else {
 449     # make test should run under 5 hours
 450     $server_maxtime = 5 * 60 * 60;
 451 }
 452
 453 if (defined($ENV{SMBD_MAXTIME}) and $ENV{SMBD_MAXTIME} ne "") {
 454     $server_maxtime = $ENV{SMBD_MAXTIME};
 455 }
 456
 457 $target = new Samba($bindir, $ldap, $srcdir, $server_maxtime);
 458 unless ($opt_list) {
 459         if ($opt_target eq "samba") {
 460                 $testenv_default = "ad_dc";
 461         } elsif ($opt_target eq "samba3") {
 462                 $testenv_default = "nt4_member";
 463         }
 464 }
 465
 466 sub read_test_regexes($)
 467 {
 468         my ($name) = @_;
 469         my @ret = ();
 470         open(LF, "<$name") or die("unable to read $name: $!");
 471         while (<LF>) {
 472                 chomp;
 473                 next if (/^#/);
 474                 if (/^(.*?)([ \t]+)\#([\t ]*)(.*?)$/) {
 475                         push (@ret, [$1, $4]);
 476                 } else {
 477                         s/^(.*?)([ \t]+)\#([\t ]*)(.*?)$//;
 478                         push (@ret, [$_, undef]);
 479                 }
 480         }
 481         close(LF);
 482         return @ret;
 483 }
 484
 485 foreach (@opt_exclude) {
 486         push (@excludes, read_test_regexes($_));
 487 }
 488
 489 foreach (@opt_include) {
 490         push (@includes, read_test_regexes($_));
 491 }
 492
 493 my $interfaces = join(',', ("127.0.0.11/8",
 494                             "127.0.0.12/8",
 495                             "127.0.0.13/8",
 496                             "127.0.0.14/8",
 497                             "127.0.0.15/8",
 498                             "127.0.0.16/8"));
 499
 500 my $clientdir = "$prefix_abs/client";
 501
 502 my $conffile = "$clientdir/client.conf";
 503 $ENV{SMB_CONF_PATH} = $conffile;
 504
 505 sub write_clientconf($$$)
 506 {
 507         my ($conffile, $clientdir, $vars) = @_;
 508
 509         mkdir("$clientdir", 0777) unless -d "$clientdir";
 510
 511         if ( -d "$clientdir/private" ) {
 512                 unlink <$clientdir/private/*>;
 513         } else {
 514                 mkdir("$clientdir/private", 0777);
 515         }
 516
 517         if ( -d "$clientdir/bind-dns" ) {
 518                 unlink <$clientdir/bind-dns/*>;
 519         } else {
 520                 mkdir("$clientdir/bind-dns", 0777);
 521         }
 522
 523         if ( -d "$clientdir/lockdir" ) {
 524                 unlink <$clientdir/lockdir/*>;
 525         } else {
 526                 mkdir("$clientdir/lockdir", 0777);
 527         }
 528
 529         if ( -d "$clientdir/statedir" ) {
 530                 unlink <$clientdir/statedir/*>;
 531         } else {
 532                 mkdir("$clientdir/statedir", 0777);
 533         }
 534
 535         if ( -d "$clientdir/cachedir" ) {
 536                 unlink <$clientdir/cachedir/*>;
 537         } else {
 538                 mkdir("$clientdir/cachedir", 0777);
 539         }
 540
 541         # this is ugly, but the ncalrpcdir needs exactly 0755
 542         # otherwise tests fail.
 543         my $mask = umask;
 544         umask 0022;
 545         if ( -d "$clientdir/ncalrpcdir/np" ) {
 546                 unlink <$clientdir/ncalrpcdir/np/*>;
 547                 rmdir "$clientdir/ncalrpcdir/np";
 548         }
 549         if ( -d "$clientdir/ncalrpcdir" ) {
 550                 unlink <$clientdir/ncalrpcdir/*>;
 551                 rmdir "$clientdir/ncalrpcdir";
 552         }
 553         mkdir("$clientdir/ncalrpcdir", 0755);
 554         umask $mask;
 555
 556         my $cadir = "$ENV{SRCDIR_ABS}/selftest/manage-ca/CA-samba.example.com";
 557         my $cacert = "$cadir/Public/CA-samba.example.com-cert.pem";
 558         my $cacrl_pem = "$cadir/Public/CA-samba.example.com-crl.pem";
 559         my $ca_users_dir = "$cadir/Users";
 560
 561         if ( -d "$clientdir/pkinit" ) {
 562                 unlink <$clientdir/pkinit/*>;
 563         } else {
 564                 mkdir("$clientdir/pkinit", 0700);
 565         }
 566
 567         # each user has a USER-${USER_PRINCIPAL_NAME}-cert.pem and
 568         # USER-${USER_PRINCIPAL_NAME}-private-key.pem symlink
 569         # We make a copy here and make the certificated easily
 570         # accessable in the client environment.
 571         my $mask = umask;
 572         umask 0077;
 573         opendir USERS, "${ca_users_dir}" or die "Could not open dir '${ca_users_dir}': $!";
 574         for my $d (readdir USERS) {
 575                 my $user_dir = "${ca_users_dir}/${d}";
 576                 next if ${d} =~ /^\./;
 577                 next if (! -d "${user_dir}");
 578                 opendir USER, "${user_dir}" or die "Could not open dir '${user_dir}': $!";
 579                 for my $l (readdir USER) {
 580                         my $user_link = "${user_dir}/${l}";
 581                         next if ${l} =~ /^\./;
 582                         next if (! -l "${user_link}");
 583
 584                         my $dest = "${clientdir}/pkinit/${l}";
 585                         Samba::copy_file_content(${user_link}, ${dest});
 586                 }
 587                 closedir USER;
 588         }
 589         closedir USERS;
 590         umask $mask;
 591
 592         open(CF, ">$conffile");
 593         print CF "[global]\n";
 594         print CF "\tnetbios name = client\n";
 595         if (defined($vars->{DOMAIN})) {
 596                 print CF "\tworkgroup = $vars->{DOMAIN}\n";
 597         }
 598         if (defined($vars->{REALM})) {
 599                 print CF "\trealm = $vars->{REALM}\n";
 600         }
 601         if ($opt_socket_wrapper) {
 602                 print CF "\tinterfaces = $interfaces\n";
 603         }
 604         print CF "
 605         private dir = $clientdir/private
 606         binddns dir = $clientdir/bind-dns
 607         lock dir = $clientdir/lockdir
 608         state directory = $clientdir/statedir
 609         cache directory = $clientdir/cachedir
 610         ncalrpc dir = $clientdir/ncalrpcdir
 611         panic action = $RealBin/gdb_backtrace \%d
 612         max xmit = 32K
 613         notify:inotify = false
 614         ldb:nosync = true
 615         system:anonymous = true
 616         client lanman auth = Yes
 617         log level = 1
 618         torture:basedir = $clientdir
 619 #We don't want to pass our self-tests if the PAC code is wrong
 620         gensec:require_pac = true
 621 #We don't want to run 'speed' tests for very long
 622         torture:timelimit = 1
 623         winbind separator = /
 624         tls cafile = ${cacert}
 625         tls crlfile = ${cacrl_pem}
 626         tls verify peer = no_check
 627         include system krb5 conf = no
 628 ";
 629         close(CF);
 630 }
 631
 632 my @todo = ();
 633
 634 sub should_run_test($)
 635 {
 636         my $name = shift;
 637         if ($#tests == -1) {
 638                 return 1;
 639         }
 640         for (my $i=0; $i <= $#tests; $i++) {
 641                 if ($name =~ /$tests[$i]/i) {
 642                         return 1;
 643                 }
 644         }
 645         return 0;
 646 }
 647
 648 sub read_testlist($)
 649 {
 650         my ($filename) = @_;
 651
 652         my @ret = ();
 653         open(IN, $filename) or die("Unable to open $filename: $!");
 654
 655         while (<IN>) {
 656                 if (/-- TEST(-LOADLIST|) --\n/) {
 657                         my $supports_loadlist = (defined($1) and $1 eq "-LOADLIST");
 658                         my $name = <IN>;
 659                         $name =~ s/\n//g;
 660                         my $env = <IN>;
 661                         $env =~ s/\n//g;
 662                         my $loadlist;
 663                         if ($supports_loadlist) {
 664                                 $loadlist = <IN>;
 665                                 $loadlist =~ s/\n//g;
 666                         }
 667                         my $cmdline = <IN>;
 668                         $cmdline =~ s/\n//g;
 669                         if (should_run_test($name) == 1) {
 670                                 push (@ret, [$name, $env, $cmdline, $loadlist]);
 671                         }
 672                 } else {
 673                         print;
 674                 }
 675         }
 676         close(IN) or die("Error creating recipe from $filename");
 677         return @ret;
 678 }
 679
 680 if ($#testlists == -1) {
 681         die("No testlists specified");
 682 }
 683
 684 $ENV{SELFTEST_PREFIX} = "$prefix_abs";
 685 $ENV{SELFTEST_TMPDIR} = "$tmpdir_abs";
 686 $ENV{TMPDIR} = "$tmpdir_abs";
 687 $ENV{TEST_DATA_PREFIX} = "$tmpdir_abs";
 688 if ($opt_socket_wrapper) {
 689         $ENV{SELFTEST_INTERFACES} = $interfaces;
 690 } else {
 691         $ENV{SELFTEST_INTERFACES} = "";
 692 }
 693 if ($opt_quick) {
 694         $ENV{SELFTEST_QUICK} = "1";
 695 } else {
 696         $ENV{SELFTEST_QUICK} = "";
 697 }
 698 $ENV{SELFTEST_MAXTIME} = $torture_maxtime;
 699
 700 my $selftest_krbt_ccache_path = "$tmpdir_abs/selftest.krb5_ccache";
 701 $ENV{KRB5CCNAME} = "FILE:${selftest_krbt_ccache_path}.global";
 702
 703 my @available = ();
 704 foreach my $fn (@testlists) {
 705         foreach (read_testlist($fn)) {
 706                 my $name = $$_[0];
 707                 next if (@includes and not defined(find_in_list(\@includes, $name)));
 708                 push (@available, $_);
 709         }
 710 }
 711
 712 my $restricted = undef;
 713 my $restricted_used = {};
 714
 715 if ($opt_load_list) {
 716         $restricted = [];
 717         open(LOAD_LIST, "<$opt_load_list") or die("Unable to open $opt_load_list");
 718         while (<LOAD_LIST>) {
 719                 chomp;
 720                 push (@$restricted, $_);
 721         }
 722         close(LOAD_LIST);
 723 }
 724
 725 my $individual_tests = undef;
 726 $individual_tests = {};
 727
 728 foreach my $testsuite (@available) {
 729         my $name = $$testsuite[0];
 730         my $skipreason = skip(@$testsuite);
 731         if (defined($restricted)) {
 732                 # Find the testsuite for this test
 733                 my $match = undef;
 734                 foreach my $r (@$restricted) {
 735                         if ($r eq $name) {
 736                                 $individual_tests->{$name} = [];
 737                                 $match = $r;
 738                                 $restricted_used->{$r} = 1;
 739                         } elsif (substr($r, 0, length($name)+1) eq "$name.") {
 740                                 push(@{$individual_tests->{$name}}, $r);
 741                                 $match = $r;
 742                                 $restricted_used->{$r} = 1;
 743                         }
 744                 }
 745                 if ($match) {
 746                         if (defined($skipreason)) {
 747                                 if (not $opt_list) {
 748                                         Subunit::skip_testsuite($name, $skipreason);
 749                                 }
 750                         } else {
 751                                 push(@todo, $testsuite);
 752                         }
 753                 }
 754         } elsif (defined($skipreason)) {
 755                 if (not $opt_list) {
 756                         Subunit::skip_testsuite($name, $skipreason);
 757                 }
 758         } else {
 759                 push(@todo, $testsuite);
 760         }
 761 }
 762
 763 if (defined($restricted)) {
 764         foreach (@$restricted) {
 765                 unless (defined($restricted_used->{$_})) {
 766                         print "No test or testsuite found matching $_\n";
 767                 }
 768         }
 769 } elsif ($#todo == -1) {
 770         print STDERR "No tests to run\n";
 771         exit(1);
 772 }
 773
 774 my $suitestotal = $#todo + 1;
 775
 776 unless ($opt_list) {
 777         Subunit::progress($suitestotal);
 778         Subunit::report_time(time());
 779 }
 780
 781 my $i = 0;
 782 $| = 1;
 783
 784 my %running_envs = ();
 785
 786 sub get_running_env($)
 787 {
 788         my ($name) = @_;
 789
 790         my $envname = $name;
 791
 792         $envname =~ s/:.*//;
 793
 794         return $running_envs{$envname};
 795 }
 796
 797 my @exported_envvars = (
 798         # domain stuff
 799         "DOMAIN",
 800         "REALM",
 801
 802         # stuff related to a trusted domain
 803         "TRUST_SERVER",
 804         "TRUST_SERVER_IP",
 805         "TRUST_SERVER_IPV6",
 806         "TRUST_NETBIOSNAME",
 807         "TRUST_USERNAME",
 808         "TRUST_PASSWORD",
 809         "TRUST_DOMAIN",
 810         "TRUST_REALM",
 811
 812         # domain controller stuff
 813         "DC_SERVER",
 814         "DC_SERVER_IP",
 815         "DC_SERVER_IPV6",
 816         "DC_NETBIOSNAME",
 817         "DC_NETBIOSALIAS",
 818
 819         # domain member
 820         "MEMBER_SERVER",
 821         "MEMBER_SERVER_IP",
 822         "MEMBER_SERVER_IPV6",
 823         "MEMBER_NETBIOSNAME",
 824         "MEMBER_NETBIOSALIAS",
 825
 826         # rpc proxy controller stuff
 827         "RPC_PROXY_SERVER",
 828         "RPC_PROXY_SERVER_IP",
 829         "RPC_PROXY_SERVER_IPV6",
 830         "RPC_PROXY_NETBIOSNAME",
 831         "RPC_PROXY_NETBIOSALIAS",
 832
 833         # domain controller stuff for Vampired DC
 834         "VAMPIRE_DC_SERVER",
 835         "VAMPIRE_DC_SERVER_IP",
 836         "VAMPIRE_DC_SERVER_IPV6",
 837         "VAMPIRE_DC_NETBIOSNAME",
 838         "VAMPIRE_DC_NETBIOSALIAS",
 839
 840         # domain controller stuff for RODC
 841         "RODC_DC_SERVER",
 842         "RODC_DC_SERVER_IP",
 843         "RODC_DC_SERVER_IPV6",
 844         "RODC_DC_NETBIOSNAME",
 845
 846         # domain controller stuff for FL 2000 Vampired DC
 847         "VAMPIRE_2000_DC_SERVER",
 848         "VAMPIRE_2000_DC_SERVER_IP",
 849         "VAMPIRE_2000_DC_SERVER_IPV6",
 850         "VAMPIRE_2000_DC_NETBIOSNAME",
 851         "VAMPIRE_2000_DC_NETBIOSALIAS",
 852
 853         "PROMOTED_DC_SERVER",
 854         "PROMOTED_DC_SERVER_IP",
 855         "PROMOTED_DC_SERVER_IPV6",
 856         "PROMOTED_DC_NETBIOSNAME",
 857         "PROMOTED_DC_NETBIOSALIAS",
 858
 859         # server stuff
 860         "SERVER",
 861         "SERVER_IP",
 862         "SERVER_IPV6",
 863         "NETBIOSNAME",
 864         "NETBIOSALIAS",
 865
 866         # user stuff
 867         "USERNAME",
 868         "USERID",
 869         "PASSWORD",
 870         "DC_USERNAME",
 871         "DC_PASSWORD",
 872
 873         # UID/GID for rfc2307 mapping tests
 874         "UID_RFC2307TEST",
 875         "GID_RFC2307TEST",
 876
 877         # misc stuff
 878         "KRB5_CONFIG",
 879         "KRB5CCNAME",
 880         "SELFTEST_WINBINDD_SOCKET_DIR",
 881         "NMBD_SOCKET_DIR",
 882         "LOCAL_PATH",
 883         "DNS_FORWARDER1",
 884         "DNS_FORWARDER2",
 885         "RESOLV_CONF",
 886         "UNACCEPTABLE_PASSWORD",
 887         "LOCK_DIR",
 888         "SMBD_TEST_LOG",
 889
 890         # nss_wrapper
 891         "NSS_WRAPPER_PASSWD",
 892         "NSS_WRAPPER_GROUP",
 893         "NSS_WRAPPER_HOSTS",
 894         "NSS_WRAPPER_HOSTNAME",
 895         "NSS_WRAPPER_MODULE_SO_PATH",
 896         "NSS_WRAPPER_MODULE_FN_PREFIX",
 897
 898         # resolv_wrapper
 899         "RESOLV_WRAPPER_CONF",
 900         "RESOLV_WRAPPER_HOSTS",
 901 );
 902
 903 sub sighandler($)
 904 {
 905         my $signame = shift;
 906
 907         $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = 'DEFAULT';
 908         $SIG{PIPE} = 'IGNORE';
 909
 910         open(STDOUT, ">&STDERR") or die "can't dup STDOUT to STDERR: $!";
 911
 912         print "$0: PID[$$]: Got SIG${signame} teardown environments.\n";
 913         teardown_env($_) foreach(keys %running_envs);
 914         system("pstree -p $$");
 915         print "$0: PID[$$]: Exiting...\n";
 916         exit(1);
 917 };
 918
 919 $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = $SIG{PIPE} = \&sighandler;
 920
 921 sub setup_env($$)
 922 {
 923         my ($name, $prefix) = @_;
 924
 925         my $testenv_vars = undef;
 926
 927         my $envname = $name;
 928         my $option = $name;
 929
 930         $envname =~ s/:.*//;
 931         $option =~ s/^[^:]*//;
 932         $option =~ s/^://;
 933
 934         $option = "client" if $option eq "";
 935
 936         $ENV{KRB5CCNAME} = "FILE:${selftest_krbt_ccache_path}.${envname}/ignore";
 937
 938         if (defined(get_running_env($envname))) {
 939                 $testenv_vars = get_running_env($envname);
 940                 if (not $testenv_vars->{target}->check_env($testenv_vars)) {
 941                         print $testenv_vars->{target}->getlog_env($testenv_vars);
 942                         $testenv_vars = undef;
 943                 }
 944         } else {
 945                 $testenv_vars = $target->setup_env($envname, $prefix);
 946                 if (defined($testenv_vars) and $testenv_vars eq "UNKNOWN") {
 947                     return $testenv_vars;
 948                 } elsif (defined($testenv_vars) && not defined($testenv_vars->{target})) {
 949                         $testenv_vars->{target} = $target;
 950                 }
 951                 if (not defined($testenv_vars)) {
 952                         warn("$opt_target can't start up known environment '$envname'");
 953                 }
 954         }
 955
 956         return undef unless defined($testenv_vars);
 957
 958         $running_envs{$envname} = $testenv_vars;
 959
 960         if ($option eq "local") {
 961                 SocketWrapper::set_default_iface($testenv_vars->{SOCKET_WRAPPER_DEFAULT_IFACE});
 962                 $ENV{SMB_CONF_PATH} = $testenv_vars->{SERVERCONFFILE};
 963         } elsif ($option eq "client") {
 964                 SocketWrapper::set_default_iface(11);
 965                 write_clientconf($conffile, $clientdir, $testenv_vars);
 966                 $ENV{SMB_CONF_PATH} = $conffile;
 967         } else {
 968                 die("Unknown option[$option] for envname[$envname]");
 969         }
 970
 971         foreach (@exported_envvars) {
 972                 if (defined($testenv_vars->{$_})) {
 973                         $ENV{$_} = $testenv_vars->{$_};
 974                 } else {
 975                         delete $ENV{$_};
 976                 }
 977         }
 978
 979         my $krb5_ccache_path = "${selftest_krbt_ccache_path}.${envname}.${option}";
 980         unlink($krb5_ccache_path);
 981         $ENV{KRB5CCNAME} = "FILE:${krb5_ccache_path}";
 982         return $testenv_vars;
 983 }
 984
 985 sub exported_envvars_str($)
 986 {
 987         my ($testenv_vars) = @_;
 988         my $out = "";
 989
 990         foreach (@exported_envvars) {
 991                 next unless defined($testenv_vars->{$_});
 992                 $out .= $_."=".$testenv_vars->{$_}."\n";
 993         }
 994
 995         return $out;
 996 }
 997
 998 sub getlog_env($)
 999 {
1000         my ($envname) = @_;
1001         return "" if ($envname eq "none");
1002         my $env = get_running_env($envname);
1003         return $env->{target}->getlog_env($env);
1004 }
1005
1006 sub check_env($)
1007 {
1008         my ($envname) = @_;
1009         my $env = get_running_env($envname);
1010         return $env->{target}->check_env($env);
1011 }
1012
1013 sub teardown_env($)
1014 {
1015         my ($envname) = @_;
1016         return if ($envname eq "none");
1017         print STDERR "teardown_env($envname)\n";
1018         my $env = get_running_env($envname);
1019         $env->{target}->teardown_env($env);
1020         delete $running_envs{$envname};
1021 }
1022
1023 # This 'global' file needs to be empty when we start
1024 unlink("$prefix_abs/dns_host_file");
1025 unlink("$prefix_abs/hosts");
1026
1027 if ($opt_random_order) {
1028         require List::Util;
1029         my @newtodo = List::Util::shuffle(@todo);
1030         @todo = @newtodo;
1031 }
1032
1033 if ($opt_testenv) {
1034         my $testenv_name = $ENV{SELFTEST_TESTENV};
1035         $testenv_name = $testenv_default unless defined($testenv_name);
1036
1037         my $testenv_vars = setup_env($testenv_name, $prefix);
1038
1039         if (not $testenv_vars or $testenv_vars eq "UNKNOWN") {
1040                 die("Unable to setup environment $testenv_name");
1041         }
1042
1043         $ENV{PIDDIR} = $testenv_vars->{PIDDIR};
1044         $ENV{ENVNAME} = $testenv_name;
1045
1046         my $envvarstr = exported_envvars_str($testenv_vars);
1047
1048         my @term_args = ("echo -e \"
1049 Welcome to the Samba4 Test environment '$testenv_name'
1050
1051 This matches the client environment used in make test
1052 server is pid `cat \$PIDDIR/samba.pid`
1053
1054 Some useful environment variables:
1055 TORTURE_OPTIONS=\$TORTURE_OPTIONS
1056 SMB_CONF_PATH=\$SMB_CONF_PATH
1057
1058 $envvarstr
1059 \" && LD_LIBRARY_PATH=$ENV{LD_LIBRARY_PATH} bash");
1060         my @term = ();
1061         if ($ENV{TERMINAL}) {
1062             @term = ($ENV{TERMINAL});
1063         } else {
1064             @term = ("xterm", "-e");
1065             unshift(@term_args, ("bash", "-c"));
1066         }
1067
1068         system(@term, @term_args);
1069
1070         teardown_env($testenv_name);
1071 } elsif ($opt_list) {
1072         foreach (@todo) {
1073                 my $name = $$_[0];
1074                 my $envname = $$_[1];
1075                 my $cmd = $$_[2];
1076                 my $listcmd = $$_[3];
1077
1078                 unless (defined($listcmd)) {
1079                         warn("Unable to list tests in $name");
1080                         # Rather than ignoring this testsuite altogether, just pretend the entire testsuite is
1081                         # a single "test".
1082                         print "$name\n";
1083                         next;
1084                 }
1085
1086                 system($listcmd);
1087
1088                 if ($? == -1) {
1089                         die("Unable to run $listcmd: $!");
1090                 } elsif ($? & 127) {
1091                         die(sprintf("%s died with signal %d, %s coredump\n", $listcmd, ($? & 127),  ($? & 128) ? 'with' : 'without'));
1092                 }
1093
1094                 my $exitcode = $? >> 8;
1095                 if ($exitcode != 0) {
1096                         die("$cmd exited with exit code $exitcode");
1097                 }
1098         }
1099 } else {
1100         foreach (@todo) {
1101                 $i++;
1102                 my $cmd = $$_[2];
1103                 my $name = $$_[0];
1104                 my $envname = $$_[1];
1105                 my ($env_basename, $env_localpart) = split(/:/, $envname);
1106                 my $envvars = "SKIP";
1107
1108                 if (@opt_include_env) {
1109                     foreach my $env (@opt_include_env) {
1110                         if ($env_basename eq $env) {
1111                             $envvars = setup_env($envname, $prefix);
1112                         }
1113                     }
1114                 } elsif (@opt_exclude_env) {
1115                     my $excluded = 0;
1116                     foreach my $env (@opt_exclude_env) {
1117                         if ($env_basename eq $env) {
1118                             $excluded = 1;
1119                         }
1120                     }
1121                     if ($excluded == 0) {
1122                         $envvars = setup_env($envname, $prefix);
1123                     }
1124                 } else {
1125                     $envvars = setup_env($envname, $prefix);
1126                 }
1127
1128                 if (not defined($envvars)) {
1129                         Subunit::start_testsuite($name);
1130                         Subunit::end_testsuite($name, "error",
1131                                 "unable to set up environment $envname - exiting");
1132                         next;
1133                 } elsif ($envvars eq "SKIP") {
1134                         Subunit::start_testsuite($name);
1135                         Subunit::end_testsuite($name, "skip",
1136                                 "environment $envname is disabled (via --exclude-env / --include-env command line options) in this test run - skipping");
1137                         next;
1138                 } elsif ($envvars eq "UNKNOWN") {
1139                         Subunit::start_testsuite($name);
1140                         Subunit::end_testsuite($name, "skip",
1141                                 "environment $envname is unknown in this test backend - skipping");
1142                         next;
1143                 }
1144
1145                 # Generate a file with the individual tests to run, if the
1146                 # test runner for this test suite supports it.
1147                 if ($individual_tests and $individual_tests->{$name}) {
1148                         if ($$_[3]) {
1149                                 my ($fh, $listid_file) = tempfile(UNLINK => 0);
1150                                 foreach my $test (@{$individual_tests->{$name}}) {
1151                                         print $fh substr($test, length($name)+1) . "\n";
1152                                 }
1153                                 $cmd =~ s/\$LOADLIST/--load-list=$listid_file/g;
1154                         } else {
1155                                 warn("Unable to run individual tests in $name, it does not support --loadlist.");
1156                         }
1157                 }
1158
1159                 run_testsuite($envname, $name, $cmd, $i, $suitestotal);
1160
1161                 teardown_env($envname) if ($opt_resetup_env);
1162         }
1163 }
1164
1165 print "\n";
1166
1167 teardown_env($_) foreach (keys %running_envs);
1168
1169 my $failed = 0;
1170
1171 # if there were any valgrind failures, show them
1172 foreach (<$prefix/valgrind.log*>) {
1173         next unless (-s $_);
1174         print "VALGRIND FAILURE\n";
1175         $failed++;
1176         system("cat $_");
1177 }
1178 exit 0;