selftest/subunit: Remove prefix command.
[garming/samba-autobuild/.git] / selftest / Subunit.pm
1 # Perl module for parsing and generating the Subunit protocol
2 # Copyright (C) 2008-2009 Jelmer Vernooij <jelmer@samba.org>
3 #
4 # This program is free software; you can redistribute it and/or modify
5 # it under the terms of the GNU General Public License as published by
6 # the Free Software Foundation; either version 3 of the License, or
7 # (at your option) any later version.
8
9 # This program is distributed in the hope that it will be useful,
10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
12 # GNU General Public License for more details.
13
14 # You should have received a copy of the GNU General Public License
15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
16
17 package Subunit;
18 use POSIX;
19
20 require Exporter;
21 @ISA = qw(Exporter);
22 @EXPORT_OK = qw(parse_results);
23
24 use strict;
25
26 sub parse_results($$$$)
27 {
28         my ($msg_ops, $statistics, $fh, $open_tests) = @_;
29         my $unexpected_ok = 0;
30         my $expected_fail = 0;
31         my $unexpected_fail = 0;
32         my $unexpected_err = 0;
33         my $orig_open_len = $#$open_tests;
34
35         while(<$fh>) {
36                 if (/^test: (.+)\n/) {
37                         $msg_ops->control_msg($_);
38                         $msg_ops->start_test($open_tests, $1);
39                         push (@$open_tests, $1);
40                 } elsif (/^time: (\d+)-(\d+)-(\d+) (\d+):(\d+):(\d+)Z\n/) {
41                         $msg_ops->report_time(mktime($6, $5, $4, $3, $2, $1));
42                 } elsif (/^(success|successful|failure|fail|skip|knownfail|error|xfail): (.*?)( \[)?([ \t]*)\n/) {
43                         $msg_ops->control_msg($_);
44                         my $result = $1;
45                         my $testname = $2;
46                         my $reason = undef;
47                         if ($3) {
48                                 $reason = "";
49                                 # reason may be specified in next lines
50                                 my $terminated = 0;
51                                 while(<$fh>) {
52                                         $msg_ops->control_msg($_);
53                                         if ($_ eq "]\n") { $terminated = 1; last; } else { $reason .= $_; }
54                                 }
55                                 
56                                 unless ($terminated) {
57                                         $statistics->{TESTS_ERROR}++;
58                                         $msg_ops->end_test($testname, $result, 1, "reason interrupted");
59                                         return 1;
60                                 }
61                         }
62                         if ($result eq "success" or $result eq "successful") {
63                                 pop(@$open_tests); #FIXME: Check that popped value == $testname 
64                                 $statistics->{TESTS_EXPECTED_OK}++;
65                                 $msg_ops->end_test($testname, $result, 0, $reason);
66                         } elsif ($result eq "xfail" or $result eq "knownfail") {
67                                 pop(@$open_tests); #FIXME: Check that popped value == $testname
68                                 $statistics->{TESTS_EXPECTED_FAIL}++;
69                                 $msg_ops->end_test($testname, $result, 0, $reason);
70                                 $expected_fail++;
71                         } elsif ($result eq "failure" or $result eq "fail") {
72                                 pop(@$open_tests); #FIXME: Check that popped value == $testname
73                                 $statistics->{TESTS_UNEXPECTED_FAIL}++;
74                                 $msg_ops->end_test($testname, $result, 1, $reason);
75                                 $unexpected_fail++;
76                         } elsif ($result eq "skip") {
77                                 $statistics->{TESTS_SKIP}++;
78                                 my $last = pop(@$open_tests);
79                                 if (defined($last) and $last ne $testname) {
80                                         push (@$open_tests, $testname);
81                                 }
82                                 $msg_ops->end_test($testname, $result, 0, $reason);
83                         } elsif ($result eq "error") {
84                                 $statistics->{TESTS_ERROR}++;
85                                 pop(@$open_tests); #FIXME: Check that popped value == $testname
86                                 $msg_ops->end_test($testname, $result, 1, $reason);
87                                 $unexpected_err++;
88                         }
89                 } else {
90                         $msg_ops->output_msg($_);
91                 }
92         }
93
94         while ($#$open_tests > $orig_open_len) {
95                 $msg_ops->end_test($open_tests, pop(@$open_tests), "error", 1,
96                                    "was started but never finished!");
97                 $statistics->{TESTS_ERROR}++;
98                 $unexpected_err++;
99         }
100
101         return 1 if $unexpected_err > 0;
102         return 1 if $unexpected_fail > 0;
103         return 1 if $unexpected_ok > 0 and $expected_fail > 0;
104         return 0 if $unexpected_ok > 0 and $expected_fail == 0;
105         return 0 if $expected_fail > 0;
106         return 1;
107 }
108
109 sub start_test($)
110 {
111         my ($testname) = @_;
112         print "test: $testname\n";
113 }
114
115 sub end_test($$;$)
116 {
117         my $name = shift;
118         my $result = shift;
119         my $reason = shift;
120         if ($reason) {
121                 print "$result: $name [";
122                 print "$reason";
123                 print "]\n";
124         } else {
125                 print "$result: $name\n";
126         }
127 }
128
129 sub report_time($)
130 {
131         my ($time) = @_;
132         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday, $isdst) = localtime($time);
133         printf "time: %04d-%02d-%02d %02d:%02d:%02dZ\n", $year+1900, $mon, $mday, $hour, $min, $sec;
134 }
135
136 1;