source4/lib/talloc/config.m4

   1 dnl find the talloc sources. This is meant to work both for
   2 dnl talloc standalone builds, and builds of packages using talloc
   3 tallocdir=""
   4 for d in "$srcdir" "$srcdir/lib/talloc" "$srcdir/talloc" "$srcdir/../talloc"; do
   5         if test -f "$d/talloc.c"; then
   6                 tallocdir="$d"
   7                 AC_SUBST(tallocdir)
   8                 break;
   9         fi
  10 done
  11 TALLOCOBJ="talloc.o"
  12 AC_SUBST(TALLOCOBJ)
  13
  14 AC_CHECK_HEADERS(stdarg.h vararg.h)
  15
  16 dnl VA_COPY
  17 AC_CACHE_CHECK([for va_copy],samba_cv_HAVE_VA_COPY,[
  18 AC_TRY_LINK([#include <stdarg.h>
  19 va_list ap1,ap2;], [va_copy(ap1,ap2);],
  20 samba_cv_HAVE_VA_COPY=yes,samba_cv_HAVE_VA_COPY=no)])
  21 if test x"$samba_cv_HAVE_VA_COPY" = x"yes"; then
  22     AC_DEFINE(HAVE_VA_COPY,1,[Whether va_copy() is available])
  23 fi
  24
  25 if test x"$samba_cv_HAVE_VA_COPY" != x"yes"; then
  26 AC_CACHE_CHECK([for __va_copy],samba_cv_HAVE___VA_COPY,[
  27 AC_TRY_LINK([#include <stdarg.h>
  28 va_list ap1,ap2;], [__va_copy(ap1,ap2);],
  29 samba_cv_HAVE___VA_COPY=yes,samba_cv_HAVE___VA_COPY=no)])
  30 if test x"$samba_cv_HAVE___VA_COPY" = x"yes"; then
  31     AC_DEFINE(HAVE___VA_COPY,1,[Whether __va_copy() is available])
  32 fi
  33 fi
  34
  35 AC_CHECK_TYPE(intptr_t, unsigned long long)
  36 AC_CHECK_SIZEOF(size_t,cross)
  37 AC_CHECK_SIZEOF(void *,cross)
  38
  39 if test $ac_cv_sizeof_size_t -lt $ac_cv_sizeof_void_p; then
  40         AC_WARN([size_t cannot represent the amount of used memory of a process])
  41         AC_WARN([please report this to <samba-technical@samba.org>])
  42         AC_WARN([sizeof(size_t) = $ac_cv_sizeof_size_t])
  43         AC_WARN([sizeof(void *) = $ac_cv_sizeof_void_p])
  44         AC_ERROR([sizeof(size_t) < sizeof(void *)])
  45 fi