r9705: r9685@blu: tridge | 2005-08-27 19:43:44 +1000
[bbaumbach/samba-autobuild/.git] / source4 / lib / socket / config.m4
1 AC_CHECK_HEADERS(sys/socket.h sys/sockio.h sys/un.h)
2
3 AC_CACHE_CHECK([for socklen_t type],samba_cv_socklen_t, [
4     AC_TRY_COMPILE([
5 #include <sys/types.h>
6 #if STDC_HEADERS
7 #include <stdlib.h>
8 #include <stddef.h>
9 #endif
10 #include <sys/socket.h>],[socklen_t i = 0],
11         samba_cv_socklen_t=yes,samba_cv_socklen_t=no)])
12 if test x"$samba_cv_socklen_t" = x"yes"; then
13    AC_DEFINE(HAVE_SOCKLEN_T_TYPE,1,[Whether we have the variable type socklen_t])
14 fi
15
16 AC_CACHE_CHECK([for sin_len in sock],samba_cv_HAVE_SOCK_SIN_LEN,[
17 AC_TRY_COMPILE([#include <sys/types.h>
18 #include <sys/socket.h>
19 #include <netinet/in.h>],
20 [struct sockaddr_in sock; sock.sin_len = sizeof(sock);],
21 samba_cv_HAVE_SOCK_SIN_LEN=yes,samba_cv_HAVE_SOCK_SIN_LEN=no)])
22 if test x"$samba_cv_HAVE_SOCK_SIN_LEN" = x"yes"; then
23     AC_DEFINE(HAVE_SOCK_SIN_LEN,1,[Whether the sockaddr_in struct has a sin_len property])
24 fi
25
26 # The following test taken from the cvs sources
27 # If we can't find connect, try looking in -lsocket, -lnsl, and -linet.
28 # The Irix 5 libc.so has connect and gethostbyname, but Irix 5 also has
29 # libsocket.so which has a bad implementation of gethostbyname (it
30 # only looks in /etc/hosts), so we only look for -lsocket if we need
31 # it.
32 AC_CHECK_FUNCS(connect)
33 if test x"$ac_cv_func_connect" = x"no"; then
34     case "$LIBS $SOCKET_LIBS" in
35     *-lnsl*) ;;
36     *) AC_CHECK_LIB_EXT(nsl_s, SOCKET_LIBS, printf) ;;
37     esac
38     case "$LIBS $SOCKET_LIBS" in
39     *-lnsl*) ;;
40     *) AC_CHECK_LIB_EXT(nsl, SOCKET_LIBS, printf) ;;
41     esac
42     case "$LIBS $SOCKET_LIBS" in
43     *-lsocket*) ;;
44     *) AC_CHECK_LIB_EXT(socket,  SOCKET_LIBS, connect) ;;
45     esac
46     case "$LIBS $SOCKET_LIBS" in
47     *-linet*) ;;
48     *) AC_CHECK_LIB_EXT(inet, SOCKET_LIBS, connect) ;;
49     esac
50     dnl We can't just call AC_CHECK_FUNCS(connect) here, because the value
51     dnl has been cached.
52     if test x"$ac_cv_lib_ext_socket_connect" = x"yes" ||
53        test x"$ac_cv_lib_ext_inet_connect" = x"yes"; then
54         # ac_cv_func_connect=yes
55         # don't!  it would cause AC_CHECK_FUNC to succeed next time configure is run
56         AC_DEFINE(HAVE_CONNECT,1,[Whether the system has connect()])
57     fi
58 fi
59 SMB_EXT_LIB(SOCKET,[${SOCKET_LIBS}],[${SOCKET_CFLAGS}],[${SOCKET_CPPFLAGS}],[${SOCKET_LDFLAGS}])
60
61 ############################################
62 # check for unix domain sockets
63 AC_CACHE_CHECK([for unix domain sockets],samba_cv_unixsocket, [
64     AC_TRY_COMPILE([
65 #include <sys/types.h>
66 #include <stdlib.h>
67 #include <stddef.h>
68 #include <sys/socket.h>
69 #include <sys/un.h>],
70 [
71   struct sockaddr_un sunaddr; 
72   sunaddr.sun_family = AF_UNIX;
73 ],
74         samba_cv_unixsocket=yes,samba_cv_unixsocket=no)])
75 SMB_MODULE_DEFAULT(socket_unix, NOT)
76 if test x"$samba_cv_unixsocket" = x"yes"; then
77     SMB_MODULE_DEFAULT(socket_unix, STATIC)
78     AC_DEFINE(HAVE_UNIXSOCKET,1,[If we need to build with unixscoket support])
79 fi
80
81 AC_CACHE_CHECK([for AF_LOCAL socket support], samba_cv_HAVE_WORKING_AF_LOCAL, [
82 AC_TRY_RUN([#include "${srcdir-.}/build/tests/unixsock.c"],
83            samba_cv_HAVE_WORKING_AF_LOCAL=yes,
84            samba_cv_HAVE_WORKING_AF_LOCAL=no,
85            samba_cv_HAVE_WORKING_AF_LOCAL=cross)])
86 if test x"$samba_cv_HAVE_WORKING_AF_LOCAL" != xno
87 then
88     AC_DEFINE(HAVE_WORKING_AF_LOCAL, 1, [Define if you have working AF_LOCAL sockets])
89 fi
90
91 dnl test for ipv6 using the gethostbyname2() function. That should be sufficient
92 dnl for now
93 AC_CHECK_FUNCS(gethostbyname2, have_ipv6=true, have_ipv6=false)
94 SMB_MODULE_DEFAULT(socket_ipv6, NOT)
95 if $have_ipv6 = true; then
96     SMB_MODULE_DEFAULT(socket_ipv6, STATIC)
97     AC_DEFINE(HAVE_SOCKET_IPV6,1,[Whether the system has ipv6 support])
98 fi
99 dnl don't build ipv6 by default, unless the above test enables it, or
100 dnl the configure uses --with-static-modules=socket_ipv6