source4/build/m4/check_ld.m4

   1 dnl SMB Build Environment LD Checks
   2 dnl -------------------------------------------------------
   3 dnl  Copyright (C) Stefan (metze) Metzmacher 2004
   4 dnl  Copyright (C) Jelmer Vernooij 2006
   5 dnl  Released under the GNU GPL
   6 dnl -------------------------------------------------------
   7 dnl
   8
   9 AC_PATH_PROG(PROG_LD,ld)
  10 LD=${PROG_LD}
  11 AC_PROG_LD_GNU
  12 LD=""
  13 AC_PATH_PROG(PROG_AR, ar)
  14
  15 AC_SUBST(STLD)
  16 AC_SUBST(STLD_FLAGS)
  17 AC_SUBST(BLDSHARED)
  18 AC_SUBST(LD)
  19 AC_SUBST(LDFLAGS)
  20 AC_SUBST(SHLD)
  21 AC_SUBST(SHLD_UNDEF_FLAGS)
  22 AC_SUBST(SONAMEFLAG)
  23
  24 # Assume non-shared by default and override below
  25 # these are the defaults, good for lots of systems
  26 STLD=${PROG_AR}
  27 STLD_FLAGS="-rcs"
  28 BLDSHARED="false"
  29 LD="${CC}"
  30 SHLD="${CC}"
  31 SONAMEFLAG=""
  32 PICFLAG=""
  33
  34 # allow for --with-hostld=gcc
  35 AC_ARG_WITH(hostld,[  --with-hostld=linker    choose host linker],
  36 [HOSTLD=$withval],
  37 [
  38 if test z"$cross_compiling" = "yes"; then
  39         HOSTLD='$(HOSTCC)'
  40 else
  41         HOSTLD='$(LD)'
  42 fi
  43 ])
  44
  45 AC_MSG_CHECKING([whether to try to build shared libraries on $host_os])
  46
  47 # and these are for particular systems
  48 case "$host_os" in
  49         *linux*)
  50                 BLDSHARED="true"
  51                 SHLD_UNDEF_FLAGS="-Wl,--allow-shlib-undefined"
  52                 LDFLAGS="$LDFLAGS -Wl,--export-dynamic"
  53                 SONAMEFLAG="-Wl,-soname="
  54                 ;;
  55         *solaris*)
  56                 BLDSHARED="true"
  57                 SONAMEFLAG="-h "
  58                 if test "${GCC}" = "yes"; then
  59                         SONAMEFLAG="-Wl,-soname="
  60                         if test "${ac_cv_prog_gnu_ld}" = "yes"; then
  61                                 LDFLAGS="$LDFLAGS -Wl,-E"
  62                         fi
  63                 fi
  64                 ;;
  65         *sunos*)
  66                 BLDSHARED="true"
  67                 SONAMEFLAG="-Wl,-h,"
  68                 ;;
  69         *netbsd* | *freebsd* | *dragonfly* )
  70                 BLDSHARED="true"
  71                 LDFLAGS="$LDFLAGS -Wl,--export-dynamic"
  72                 SONAMEFLAG="-Wl,-soname,"
  73                 ;;
  74         *openbsd*)
  75                 BLDSHARED="true"
  76                 LDFLAGS="$LDFLAGS -Wl,-Bdynamic"
  77                 SONAMEFLAG="-Wl,-soname,"
  78                 ;;
  79         *irix*)
  80                 BLDSHARED="true"
  81                 SONAMEFLAG="-soname "
  82                 SHLD="${PROG_LD}"
  83                 ;;
  84         *aix*)
  85                 BLDSHARED="true"
  86                 LDFLAGS="$LDFLAGS -Wl,-brtl,-bexpall,-bbigtoc"
  87                 ;;
  88         *hpux*)
  89                 # Use special PIC flags for the native HP-UX compiler.
  90                 if test $ac_cv_prog_cc_Ae = yes; then
  91                         SONAMEFLAG="-Wl,+h "
  92                 elif test "${GCC}" = "yes"; then
  93                 fi
  94                 BLDSHARED="true" # I hope this is correct
  95                 if test "$host_cpu" = "ia64"; then
  96                         LDFLAGS="$LDFLAGS -Wl,-E,+b/usr/local/lib/hpux32:/usr/lib/hpux32"
  97                 else
  98                         LDFLAGS="$LDFLAGS -Wl,-E,+b/usr/local/lib:/usr/lib"
  99                 fi
 100                 ;;
 101         *osf*)
 102                 BLDSHARED="true"
 103                 SONAMEFLAG="-Wl,-soname,"
 104                 ;;
 105         *unixware*)
 106                 BLDSHARED="true"
 107                 SONAMEFLAG="-Wl,-soname,"
 108                 ;;
 109         *darwin*)
 110                 BLDSHARED="true"
 111                 ;;
 112 esac
 113
 114 AC_MSG_RESULT($BLDSHARED)
 115
 116 AC_MSG_CHECKING([LD])
 117 AC_MSG_RESULT([$LD])
 118 AC_MSG_CHECKING([LDFLAGS])
 119 AC_MSG_RESULT([$LDFLAGS])
 120
 121 AC_SUBST(HOSTLD)
 122
 123 AC_MSG_CHECKING([STLD])
 124 AC_MSG_RESULT([$STLD])
 125 AC_MSG_CHECKING([STLD_FLAGS])
 126 AC_MSG_RESULT([$STLD_FLAGS])
 127
 128 AC_LD_PICFLAG
 129 AC_LD_EXPORT_DYNAMIC
 130 AC_LD_SHLDFLAGS
 131 AC_LD_SHLIBEXT
 132
 133 AC_ARG_ENABLE(shared,
 134 [  --disable-shared        Disable testing for building shared libraries],
 135 [],[enable_shared=yes])
 136
 137 if test x"$enable_shared" = x"no" -o x"$enable_shared" = x"false"; then
 138         BLDSHARED=false
 139 fi
 140
 141 #######################################################
 142 # test whether building a shared library actually works
 143 if test $BLDSHARED = true; then
 144
 145         AC_MSG_CHECKING([SHLD])
 146         AC_MSG_RESULT([$SHLD])
 147         AC_MSG_CHECKING([SHLD_FLAGS])
 148         AC_MSG_RESULT([$SHLD_FLAGS])
 149
 150         AC_MSG_CHECKING([SHLIBEXT])
 151         AC_MSG_RESULT([$SHLIBEXT])
 152         AC_MSG_CHECKING([SONAMEFLAG])
 153         AC_MSG_RESULT([$SONAMEFLAG])
 154
 155         AC_MSG_CHECKING([PICFLAG])
 156         AC_MSG_RESULT([$PICFLAG])
 157
 158         AC_CACHE_CHECK([whether building shared libraries actually works],
 159                        [ac_cv_shlib_works],[
 160                         ac_cv_shlib_works=no
 161                         # try building a trivial shared library
 162                         ${CC} ${CFLAGS} ${PICFLAG} -c ${srcdir-.}/build/tests/shlib.c -o shlib.o &&
 163                                 ${SHLD} `eval echo ${SHLD_FLAGS} ` -o shlib.${SHLIBEXT} shlib.o &&
 164                                 ac_cv_shlib_works=yes
 165                         rm -f shlib.${SHLIBEXT} shlib.o
 166         ])
 167         if test $ac_cv_shlib_works = no; then
 168                 BLDSHARED=false
 169         fi
 170 fi
 171
 172 if test $BLDSHARED != true; then
 173         SHLD="shared-libraries-disabled"
 174         SHLD_FLAGS="shared-libraries-disabled"
 175         SHLIBEXT="shared_libraries_disabled"
 176         SONAMEFLAG="shared-libraries-disabled"
 177         PICFLAG=""
 178         AC_MSG_CHECKING([SHLD])
 179         AC_MSG_RESULT([$SHLD])
 180         AC_MSG_CHECKING([SHLD_FLAGS])
 181         AC_MSG_RESULT([$SHLD_FLAGS])
 182
 183         AC_MSG_CHECKING([SHLIBEXT])
 184         AC_MSG_RESULT([$SHLIBEXT])
 185         AC_MSG_CHECKING([SONAMEFLAG])
 186         AC_MSG_RESULT([$SONAMEFLAG])
 187
 188         AC_MSG_CHECKING([PICFLAG])
 189         AC_MSG_RESULT([$PICFLAG])
 190 fi
 191
 192 AC_DEFINE_UNQUOTED(SHLIBEXT, "$SHLIBEXT", [Shared library extension])
 193
 194 AC_MSG_CHECKING([if we can link using the selected flags])
 195 AC_TRY_RUN([#include "${srcdir-.}/build/tests/trivial.c"],
 196             AC_MSG_RESULT(yes),
 197             AC_MSG_ERROR([we cannot link with the selected cc and ld flags. Aborting configure]),
 198             AC_MSG_WARN([cannot run when cross-compiling]))
 199
 200
 201 USESHARED=false
 202 AC_SUBST(USESHARED)
 203
 204 AC_ARG_ENABLE(dso,
 205 [  --enable-dso                   Enable using shared libraries internally (experimental)],
 206 [],[enable_dso=no])
 207
 208 if test x"$enable_dso" = x"yes" -a x"$BLDSHARED" != x"true"; then
 209         AC_MSG_ERROR([--enable-dso: no support for shared libraries])
 210 fi
 211
 212 if test x"$enable_dso" != x"no"; then
 213         USESHARED=$BLDSHARED
 214 fi
 215
 216 AC_MSG_CHECKING([if binaries will use shared libraries])
 217 AC_MSG_RESULT([$USESHARED])