epan/dtd_parse.l

   1 /*
   2  * We want to stop processing when we get to the end of the input.
   3  */
   4 %option noyywrap
   5
   6 /*
   7  * We don't use unput, so don't generate code for it.
   8  */
   9 %option nounput
  10
  11 /*
  12  * We don't read from the terminal.
  13  */
  14 %option never-interactive
  15
  16 /*
  17  * Prefix scanner routines with "Dtd_Parse_" rather than "yy", so this scanner
  18  * can coexist with other scanners.
  19  */
  20 %option prefix="Dtd_Parse_"
  21
  22 %option outfile="dtd_parse.c"
  23
  24 %{
  25
  26         /* dtd_parse.l
  27         * an XML dissector for Wireshark
  28         * lexical analyzer for DTDs
  29         *
  30         * Copyright 2004, Luis E. Garcia Ontanon <luis.ontanon@gmail.com>
  31         *
  32         * $Id$
  33         *
  34         * Wireshark - Network traffic analyzer
  35         * By Gerald Combs <gerald@wireshark.org>
  36         * Copyright 1998 Gerald Combs
  37         *
  38         * This program is free software; you can redistribute it and/or
  39         * modify it under the terms of the GNU General Public License
  40         * as published by the Free Software Foundation; either version 2
  41         * of the License, or (at your option) any later version.
  42         *
  43         * This program is distributed in the hope that it will be useful,
  44         * but WITHOUT ANY WARRANTY; without even the implied warranty of
  45         * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  46         * GNU General Public License for more details.
  47         *
  48         * You should have received a copy of the GNU General Public License
  49         * along with this program; if not, write to the Free Software
  50         * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
  51         */
  52
  53 #include <glib.h>
  54 #include <string.h>
  55
  56 #include "dtd.h"
  57 #include "dtd_grammar.h"
  58 #include "dtd_parse.h"
  59
  60         struct _proto_xmlpi_attr {
  61                 gchar* name;
  62                 void (*act)(gchar*);
  63         };
  64
  65         static void* pParser;
  66         static GString* input_string;
  67         static guint offset;
  68         static guint len;
  69         static gchar* location;
  70         static gchar* attr_name;
  71
  72         static int my_yyinput(char* buff,guint size);
  73
  74         static dtd_token_data_t* new_token(gchar*);
  75
  76         static dtd_build_data_t* build_data;
  77
  78         static void set_proto_name (gchar* val) { if(build_data->proto_name) g_free(build_data->proto_name); build_data->proto_name = g_strdup(val); }
  79         static void set_media_type (gchar* val) { if(build_data->media_type) g_free(build_data->media_type); build_data->media_type = g_strdup(val); }
  80         static void set_proto_root (gchar* val) { if(build_data->proto_root) g_free(build_data->proto_root); build_data->proto_root = g_strdup(val); }
  81         static void set_description (gchar* val) { if(build_data->description) g_free(build_data->description); build_data->description = g_strdup(val); }
  82         static void set_recursive (gchar* val) { build_data->recursion = ( g_strcasecmp(val,"yes") == 0 ) ? TRUE : FALSE; }
  83
  84         static struct _proto_xmlpi_attr proto_attrs[] =
  85         {
  86                 { "proto_name", set_proto_name },
  87                 { "media", set_media_type },
  88                 { "root", set_proto_root },
  89                 { "description", set_description },
  90                 { "hierarchy", set_recursive },
  91                 {NULL,NULL}
  92         };
  93
  94 #ifdef DEBUG_DTD_PARSER
  95 #define DEBUG_DTD_TOKEN fprintf(stderr,"->%s (%i)%s\n",location,token_type,yytext)
  96 #else
  97 #define DEBUG_DTD_TOKEN
  98 #endif
  99
 100 #define DTD_PARSE(token_type) \
 101         {   DEBUG_DTD_TOKEN; \
 102                 DtdParse(pParser, (token_type), new_token(yytext), build_data); \
 103                 if(build_data->error->len > 0) yyterminate(); \
 104         }
 105
 106
 107 #define YY_INPUT(buff,result,max_size) ( (result) = my_yyinput((buff),(max_size)) )
 108
 109 %}
 110
 111 comment_start "<!--"
 112 comment_stop "-->"
 113
 114 start_xmlpi "<?"
 115
 116 location_xmlpi "wireshark:location"
 117 protocol_xmlpi "wireshark:protocol"
 118
 119 get_attr_quote =[:blank:]*["]
 120 avoid_editor_bug ["]
 121
 122 get_location_xmlpi  [^[:blank:]]+
 123
 124 stop_xmlpi "?>"
 125
 126 notation_tag       "<!"[:blank:]*NOTATION
 127
 128 special_start  "<!"
 129 special_stop   ">"
 130 whitespace     [[:blank:]\r\n]+
 131 newline        \n
 132 attlist_kw     ATTLIST
 133 doctype_kw     DOCTYPE
 134 element_kw     ELEMENT
 135
 136 pcdata         #PCDATA
 137 any            ANY
 138 cdata          #CDATA
 139
 140 iD             ID
 141 idref          IDREF
 142 idrefs         IDREFS
 143 nmtoken        NMTOKEN
 144 nmtokens       NMTOKENS
 145 entity         ENTITY
 146 entities       ENTITIES
 147 notation       NOTATION
 148 cdata_t        CDATA
 149
 150 empty          EMPTY
 151 defaulT        #DEFAULT
 152 fixed          #FIXED
 153 required       #REQUIRED
 154 implied        #IMPLIED
 155
 156 star           "*"
 157 question       "?"
 158 plus           "+"
 159 open_parens    "("
 160 close_parens   ")"
 161 open_bracket   "["
 162 close_bracket  "]"
 163 comma          ","
 164 pipe           "|"
 165 dquote         ["]
 166
 167 name           [A-Za-z0-9][-a-zA-Z0-9_]*
 168 dquoted        ["][^\"]*["]
 169 squoted        ['][^\']*[']
 170
 171 %START DTD XMLPI LOCATION DONE PROTOCOL GET_ATTR_QUOTE GET_ATTR_VAL GET_ATTR_CLOSE_QUOTE IN_COMMENT IN_NOTATION
 172 %%
 173
 174 {whitespace}            ;
 175
 176
 177 <DTD>{comment_start}            { BEGIN IN_COMMENT; }
 178 <IN_COMMENT>[^-]?                               |
 179 <IN_COMMENT>[-]                                 ;
 180 <IN_COMMENT>{comment_stop}              { BEGIN DTD; }
 181
 182 <DTD>{notation_tag} { BEGIN IN_NOTATION; }
 183 <IN_NOTATION>[^>]  ;
 184 <IN_NOTATION>{special_stop} { BEGIN DTD; }
 185
 186 <DTD>{start_xmlpi}              {
 187         BEGIN XMLPI;
 188 }
 189
 190 <XMLPI>{location_xmlpi} {
 191         BEGIN LOCATION;
 192 }
 193
 194 <XMLPI>{protocol_xmlpi} {
 195         BEGIN PROTOCOL;
 196 }
 197
 198 <XMLPI><.> ;
 199 <XMLPI>{stop_xmlpi} BEGIN DTD;
 200
 201 <LOCATION>{get_location_xmlpi} {
 202     if(location) g_free(location);
 203         location = g_strdup(yytext);
 204         BEGIN DONE;
 205 }
 206
 207 <DONE>{stop_xmlpi}  BEGIN DTD;
 208
 209 <PROTOCOL>{name} {
 210         attr_name = g_strdup(yytext);
 211         g_strdown(attr_name);
 212         BEGIN GET_ATTR_QUOTE;
 213 }
 214
 215 <GET_ATTR_QUOTE>{get_attr_quote} { BEGIN GET_ATTR_VAL; }
 216
 217 <GET_ATTR_QUOTE>. {
 218         g_string_sprintfa(build_data->error,
 219                                         "error in wireshark:protocol xmpli at %s : could not find attribute value!",
 220                                         location);
 221         yyterminate();
 222 }
 223
 224 <GET_ATTR_VAL>[^"]+ {
 225         /*"*/
 226         struct _proto_xmlpi_attr* pa;
 227         gboolean got_it = FALSE;
 228
 229         for(pa = proto_attrs; pa->name; pa++) {
 230                 if (g_strcasecmp(attr_name,pa->name) == 0) {
 231                         pa->act(yytext);
 232                         got_it = TRUE;
 233                         break;
 234                 }
 235         }
 236
 237         if (! got_it) {
 238                 g_string_sprintfa(build_data->error,
 239                                                 "error in wireshark:protocol xmpli at %s : no such parameter %s!",
 240                                                 location, attr_name);
 241                 g_free(attr_name);
 242                 yyterminate();
 243         }
 244
 245         g_free(attr_name);
 246
 247         BEGIN GET_ATTR_CLOSE_QUOTE;
 248 }
 249
 250 <GET_ATTR_CLOSE_QUOTE>{dquote} { BEGIN PROTOCOL;}
 251
 252 <PROTOCOL>{stop_xmlpi} BEGIN DTD;
 253
 254 <DTD>{special_start}         { DTD_PARSE(TOKEN_TAG_START); }
 255 <DTD>{special_stop}          { DTD_PARSE(TOKEN_TAG_STOP); }
 256
 257 <DTD>{attlist_kw}            { DTD_PARSE(TOKEN_ATTLIST_KW); }
 258 <DTD>{element_kw}            { DTD_PARSE(TOKEN_ELEMENT_KW); }
 259 <DTD>{doctype_kw}            { DTD_PARSE(TOKEN_DOCTYPE_KW); }
 260
 261 <DTD>{pcdata}                { DTD_PARSE(TOKEN_ELEM_DATA); }
 262 <DTD>{any}                   { DTD_PARSE(TOKEN_ELEM_DATA); }
 263 <DTD>{cdata}                 { DTD_PARSE(TOKEN_ELEM_DATA); }
 264 <DTD>{empty}                             { DTD_PARSE(TOKEN_EMPTY_KW); }
 265
 266 <DTD>{iD}                                { DTD_PARSE(TOKEN_ATT_TYPE); }
 267 <DTD>{idref}                 { DTD_PARSE(TOKEN_ATT_TYPE); }
 268 <DTD>{idrefs}                { DTD_PARSE(TOKEN_ATT_TYPE); }
 269 <DTD>{nmtoken}               { DTD_PARSE(TOKEN_ATT_TYPE); }
 270 <DTD>{nmtokens}              { DTD_PARSE(TOKEN_ATT_TYPE); }
 271 <DTD>{entity}                { DTD_PARSE(TOKEN_ATT_TYPE); }
 272 <DTD>{entities}              { DTD_PARSE(TOKEN_ATT_TYPE); }
 273 <DTD>{notation}              { DTD_PARSE(TOKEN_ATT_TYPE); }
 274 <DTD>{cdata_t}               { DTD_PARSE(TOKEN_ATT_TYPE); }
 275 <DTD>{defaulT}               { DTD_PARSE(TOKEN_ATT_DEF_WITH_VALUE); }
 276 <DTD>{fixed}                 { DTD_PARSE(TOKEN_ATT_DEF_WITH_VALUE); }
 277 <DTD>{required}              { DTD_PARSE(TOKEN_ATT_DEF); }
 278 <DTD>{implied}               { DTD_PARSE(TOKEN_ATT_DEF); }
 279
 280 <DTD>{star}                  { DTD_PARSE(TOKEN_STAR); }
 281 <DTD>{question}              { DTD_PARSE(TOKEN_QUESTION); }
 282 <DTD>{plus}                  { DTD_PARSE(TOKEN_PLUS); }
 283 <DTD>{comma}                  { DTD_PARSE(TOKEN_COMMA); }
 284 <DTD>{open_parens}           { DTD_PARSE(TOKEN_OPEN_PARENS); }
 285 <DTD>{close_parens}          { DTD_PARSE(TOKEN_CLOSE_PARENS); }
 286 <DTD>{open_bracket}          { DTD_PARSE(TOKEN_OPEN_BRACKET); }
 287 <DTD>{close_bracket}         { DTD_PARSE(TOKEN_CLOSE_BRACKET); }
 288 <DTD>{pipe}                  { DTD_PARSE(TOKEN_PIPE); }
 289
 290 <DTD>{dquoted}               |
 291 <DTD>{squoted}               { DTD_PARSE(TOKEN_QUOTED); }
 292 <DTD>{name}                  { DTD_PARSE(TOKEN_NAME); }
 293
 294 %%
 295
 296 static dtd_token_data_t* new_token(gchar* text) {
 297         dtd_token_data_t* t = g_malloc(sizeof(dtd_token_data_t));
 298
 299         t->text = g_strdup(text);
 300         t->location = g_strdup(location);
 301
 302         return t;
 303 }
 304
 305
 306 static int my_yyinput(char* buff, guint size) {
 307
 308         if (offset >= len ) {
 309                 return YY_NULL;
 310         } else if ( offset + size <= len ) {
 311                 memcpy(buff, input_string->str + offset,size);
 312                 offset += size;
 313                 return size;
 314         } else {
 315                 size = len - offset;
 316                 memcpy(buff, input_string->str + offset,size);
 317                 offset = len;
 318                 return size;
 319         }
 320 }
 321
 322 extern dtd_build_data_t* dtd_parse(GString* s) {
 323
 324         input_string = s;
 325         offset = 0;
 326         len = input_string->len;
 327
 328         pParser = DtdParseAlloc(g_malloc);
 329
 330 #ifdef DEBUG_DTD_PARSER
 331         DtdParseTrace(stderr, ">>");
 332 #endif
 333
 334         build_data = g_malloc(sizeof(dtd_build_data_t));
 335
 336         build_data->proto_name = NULL;
 337         build_data->media_type = NULL;
 338         build_data->description = NULL;
 339         build_data->proto_root = NULL;
 340         build_data->recursion = FALSE;
 341
 342         build_data->elements = g_ptr_array_new();
 343         build_data->attributes = g_ptr_array_new();
 344
 345         build_data->error = g_string_new("");
 346
 347         location = NULL;
 348
 349         BEGIN DTD;
 350
 351         yylex();
 352
 353         DtdParse(pParser, 0, NULL,build_data);
 354
 355         yyrestart(NULL);
 356
 357         if (location) g_free(location);
 358
 359         location = NULL;
 360
 361         DtdParseFree(pParser, g_free );
 362
 363         return build_data;
 364 }