configure.in

   1 # $Id: configure.in,v 1.183 2002/10/22 20:06:15 jmayer Exp $
   2 dnl
   3 dnl Process this file with autoconf 2.13 or later to produce a
   4 dnl configure script; 2.12 doesn't generate a "configure" script that
   5 dnl defines SHELL, and "Makefile.in" has
   6 dnl
   7 dnl     SHELL = @SHELL@
   8 dnl
   9 dnl which requires it to be defined - and there may be other problems
  10 dnl with pre-2.13 "autoconf" as well.
  11 dnl
  12 AC_INIT(etypes.h)
  13
  14 AC_PREREQ(2.13)
  15
  16 dnl Check for CPU / vendor / OS
  17 AC_CANONICAL_HOST
  18 AC_CANONICAL_TARGET
  19
  20 AM_INIT_AUTOMAKE(ethereal, 0.9.7)
  21
  22 dnl Checks for programs.
  23 AC_PROG_CC
  24 AC_PROG_CPP
  25 AC_LIBTOOL_DLOPEN
  26 AC_PROG_LIBTOOL
  27 AC_PROG_YACC
  28 AM_PROG_LEX
  29 AC_PATH_PROG(PERL, perl)
  30 AC_PATH_PROG(POD2MAN, pod2man)
  31 AC_PATH_PROG(LEX, flex)
  32 AC_PATH_PROG(PYTHON, python)
  33
  34 AC_SUBST(PERL)
  35 AC_SUBST(LEX)
  36 AC_SUBST(PYTHON)
  37
  38 # Check for packaging utilities
  39 # For now, we check to see if the various packaging utilites are in our
  40 # path.  I'm too lazy to write code to go hunt for them.  -  Gerald
  41 AC_CHECK_PROG(HAVE_PKGPROTO, pkgproto, "yes", "no")
  42 AC_CHECK_PROG(HAVE_PKGMK, pkgmk, "yes", "no")
  43 AC_CHECK_PROG(HAVE_PKGTRANS, pkgtrans, "yes", "no")
  44
  45 if test x$HAVE_PKGPROTO = xyes -a x$HAVE_PKGMK = xyes \
  46      -a x$HAVE_PKGTRANS = xyes ; then
  47   HAVE_SVR4_PACKAGING=yes
  48 else
  49   HAVE_SVR4_PACKAGING=no
  50 fi
  51 AC_SUBST(HAVE_SVR4_PACKAGING)
  52
  53 AC_ETHEREAL_RPM_CHECK
  54 AC_SUBST(HAVE_RPM)
  55
  56 #
  57 # If we're running gcc, add '-Wall -W' to CFLAGS, and add
  58 # '-D_U_="__attribute__((unused))"' as well, so we can use _U_ to
  59 # flag unused function arguments and not get warnings about them.
  60 #
  61 # Otherwise, add '-D_U_=""', so that _U_ used to flag an unused function
  62 # argument will compile with non-GCC compilers.
  63 #
  64 AC_MSG_CHECKING(to see if we can add '-Wall -W' to CFLAGS)
  65 if test x$GCC != x ; then
  66   CFLAGS="-D_U_=\"__attribute__((unused))\" -Wall -W $CFLAGS"
  67   AC_MSG_RESULT(yes)
  68 else
  69   CFLAGS="-D_U_=\"\" $CFLAGS"
  70   AC_MSG_RESULT(no)
  71 fi
  72
  73 #
  74 # Add any platform-specific compiler flags needed.
  75 #
  76 AC_MSG_CHECKING(for platform-specific compiler flags)
  77 if test "x$GCC" = x
  78 then
  79         #
  80         # Not GCC - assume it's the vendor's compiler.
  81         #
  82         case "$host_os" in
  83         hpux*)
  84                 #
  85                 # HP's ANSI C compiler; flags suggested by Jost Martin.
  86                 # "-Ae" for ANSI C plus extensions such as "long long".
  87                 # "+O2", for optimization.  XXX - works with "-g"?
  88                 #
  89                 CFLAGS="-Ae +O2 $CFLAGS"
  90                 AC_MSG_RESULT(HP ANSI C compiler - added -Ae +O2)
  91                 ;;
  92         darwin*)
  93                 #
  94                 # It may be called "cc", but it's really a GCC derivative
  95                 # with a problematic special precompiler and precompiled
  96                 # headers; turn off the special precompiler, as some
  97                 # apparently-legal code won't compile with its precompiled
  98                 # headers.
  99                 #
 100                 CFLAGS="-no-cpp-precomp $CFLAGS"
 101                 AC_MSG_RESULT(Apple GCC - added -no-cpp-precomp)
 102                 ;;
 103         *)
 104                 AC_MSG_RESULT(none needed)
 105                 ;;
 106         esac
 107 else
 108         case "$host_os" in
 109         solaris*)
 110                 # the X11 headers don't automatically include prototype info
 111                 # and a lot don't include the return type
 112                 CFLAGS="$CFLAGS -Wno-return-type -DFUNCPROTO=15"
 113                 AC_MSG_RESULT(GCC on Solaris - added -Wno-return-type -DFUNCPROTO=15)
 114                 ;;
 115         darwin*)
 116                 #
 117                 # See comments above about Apple's lovely C compiler.
 118                 #
 119                 CFLAGS="-no-cpp-precomp $CFLAGS"
 120                 AC_MSG_RESULT(Apple GCC - added -no-cpp-precomp)
 121                 ;;
 122         *)
 123                 AC_MSG_RESULT(none needed)
 124                 ;;
 125         esac
 126 fi
 127
 128 CFLAGS="$CFLAGS -I\$(top_srcdir) -I\$(top_srcdir)/wiretap"
 129 CPPFLAGS="$CPPFLAGS -I\$(top_srcdir) -I\$(top_srcdir)/wiretap"
 130
 131 dnl Look in /usr/local for header files and libraries ?
 132 AC_ARG_ENABLE(usr-local,
 133 [  --enable-usr-local      look for headers and libs in /usr/local tree.  [default=yes]],enable_usr_local=$enableval,enable_usr_local=yes)
 134
 135 AC_MSG_CHECKING(whether to use /usr/local for headers and libraries)
 136 if test "x$enable_usr_local" = "xyes" ; then
 137         AC_MSG_RESULT(yes)
 138         #
 139         # Arrange that we search for header files in the source directory
 140         # and in its "wiretap" subdirectory, as well as in "/usr/local/include",
 141         # as various packages we use ("libpcap", "zlib", an SNMP library)
 142         # may have been installed under "/usr/local/include".
 143         #
 144         CFLAGS="$CFLAGS -I/usr/local/include"
 145         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 146
 147         #
 148         # Arrange that we search for libraries in "/usr/local/lib".
 149         #
 150         AC_ETHEREAL_ADD_DASH_L(LDFLAGS, /usr/local/lib)
 151 else
 152         AC_MSG_RESULT(no)
 153 fi
 154
 155 # Create DATAFILE_DIR #define for config.h
 156 DATAFILE_DIR=$sysconfdir
 157 DATAFILE_DIR=`(
 158     test "x$prefix" = xNONE && prefix=$ac_default_prefix
 159     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
 160     eval echo "$DATAFILE_DIR"
 161 )`
 162 AC_DEFINE_UNQUOTED(DATAFILE_DIR,"$DATAFILE_DIR")
 163 AC_SUBST(DATAFILE_DIR)
 164
 165 #
 166 # If we're running Solaris, and LD_LIBRARY_PATH is defined, add it as a
 167 # link directory.
 168 #
 169 case "$host_os" in
 170   solaris*)
 171     AC_MSG_CHECKING(for LD_LIBRARY_PATH, since you appear to be running Solaris)
 172     if test x$LD_LIBRARY_PATH != x ; then
 173       LIBS="$LIBS -R$LD_LIBRARY_PATH"
 174       AC_MSG_RESULT(yes -- added LD_LIBRARY_PATH to run-time linker path)
 175     else
 176       AC_MSG_RESULT(no -- this may be a problem in a few seconds)
 177     fi
 178   ;;
 179 esac
 180
 181 #
 182 # Check for versions of "sed" inadequate to handle, in libtool, a list
 183 # of object files as large as the list in Ethereal.
 184 #
 185 # On Solaris, we check for "/bin/sed", "/usr/bin/sed", and "/usr/ucb/sed",
 186 # as both "/usr/bin/sed" (which is also "/bin/sed", as "/bin" is just a
 187 # symlink to "/usr/bin", but people may have "/bin" before "/usr/bin" in
 188 # their search path) and "/usr/ucb/sed" are inadequate; "/usr/xpg4/bin/sed"
 189 # is the only "sed" that comes with Solaris that can handle Ethereal.
 190 #
 191 # Add any checks here that are necessary for other OSes.
 192 #
 193 AC_ETHEREAL_GNU_SED_CHECK
 194 if test "$HAVE_GNU_SED" = no ; then
 195         case "$host_os" in
 196         solaris*)
 197                 AC_MSG_CHECKING(whether one of /usr/bin/sed or /bin/sed or /usr/ucb/sed will be used)
 198                 case `which sed` in
 199                         /bin/sed|/usr/bin/sed|/usr/ucb/sed)
 200                         AC_MSG_RESULT(yes)
 201                         AC_MSG_ERROR([change your path to search /usr/xpg4/bin or directory containing GNU sed before /usr/bin (and /bin and /usr/ucb)])
 202                         ;;
 203
 204                         *)
 205                         AC_MSG_RESULT(no)
 206                         ;;
 207                 esac
 208                 ;;
 209
 210         *)
 211                 :
 212                 ;;
 213         esac
 214 fi
 215
 216 # Enable/disable tethereal
 217
 218 AC_ARG_ENABLE(ethereal,
 219 [  --enable-ethereal       build GTK+-based ethereal.  [default=yes]],,enable_ethereal=yes)
 220
 221 AC_ARG_ENABLE(gtk2,
 222 [  --enable-gtk2           build Glib2/Gtk2+-based (t)ethereal.  [default=no]],enable_gtk2=yes,enable_gtk2=no)
 223 AM_CONDITIONAL(USE_GTK2, test x$enable_gtk2 = xyes)
 224
 225 # GTK checks
 226 # We don't add $GLIB_LIBS to LIBS, because we don't want to force all
 227 # programs to be built with GTK+.
 228 #
 229 if test "x$enable_gtk2" = "xyes" -a "x$enable_ethereal" = "xyes" ; then
 230         GTK_OK=two
 231         AM_PATH_GTK_2_0(2.0.0, CFLAGS="$CFLAGS $GTK_CFLAGS", GTK_OK=no, gthread)
 232 elif test "x$enable_gtk2" = "xno" -a "x$enable_ethereal" = "xyes" ; then
 233         GTK_OK=one
 234         AM_PATH_GTK(1.2.0, CFLAGS="$CFLAGS $GTK_CFLAGS", GTK_OK=no )
 235 else
 236         GTK_OK=no
 237 fi
 238
 239 # GLib checks
 240 # This doesn't add GLIB_CFLAGS to CFLAGS, because AM_PATH_GTK will add
 241 # GTK_CFLAGS to CFLAGS, and GTK_CFLAGS is a superset of CFLAGS.
 242 # However, this means that both @GLIB_LIBS@ and @GTK_LIBS@ will be
 243 # set when generating the Makefile, so we can make programs that require
 244 # only GLib link with @GLIB_LIBS@ and make programs that require GTK+
 245 # link with @GTK_LIBS@ (which includes @GLIB_LIBS@).
 246 # We don't add $GLIB_LIBS to LIBS, because we don't want to force all
 247 # programs to be built with GLib.
 248 #
 249 if test "$GTK_OK" = "two" ; then
 250         ethereal_bin="ethereal"
 251         ethereal_man="ethereal.1"
 252         ethereal_SUBDIRS="gtk2"
 253
 254         # Ignore GLIB_CFLAGS
 255         AM_PATH_GLIB_2_0(2.0.0, , AC_MSG_ERROR(GLib distribution not found.), gmodule)
 256 elif test "$GTK_OK" = "one" ; then
 257         ethereal_bin="ethereal"
 258         ethereal_man="ethereal.1"
 259         ethereal_SUBDIRS="gtk"
 260
 261         # Ignore GLIB_CFLAGS
 262         AM_PATH_GLIB(1.2.0, , AC_MSG_ERROR(GLib distribution not found.), gmodule)
 263 else
 264         enable_ethereal="no"
 265         ethereal_bin=""
 266         ethereal_man=""
 267         # Honor GLIB_CFLAGS
 268         if test "x$enable_gtk2" = "xyes" ; then
 269                 AM_PATH_GLIB_2_0(2.0.0, CFLAGS="$CFLAGS $GLIB_CFLAGS", AC_MSG_ERROR(GLib distribution not found.), gmodule)
 270         else
 271                 AM_PATH_GLIB(1.2.0, CFLAGS="$CFLAGS $GLIB_CFLAGS", AC_MSG_ERROR(GLib distribution not found.), gmodule)
 272         fi
 273 fi
 274
 275 #
 276 # Check whether GLib modules are supported, to determine whether we
 277 # can support plugins.
 278 #
 279 AC_MSG_CHECKING(whether GLib supports loadable modules)
 280 ac_save_CFLAGS="$CFLAGS"
 281 ac_save_LIBS="$LIBS"
 282 CFLAGS="$CFLAGS $GLIB_CFLAGS"
 283 LIBS="$GLIB_LIBS $LIBS"
 284 AC_TRY_RUN([
 285 #include <glib.h>
 286 #include <gmodule.h>
 287 #include <stdio.h>
 288 #include <stdlib.h>
 289
 290 int
 291 main ()
 292 {
 293   if (g_module_supported())
 294     return 0;   /* success */
 295   else
 296     return 1;   /* failure */
 297 }
 298 ], ac_cv_glib_supports_modules=yes, ac_cv_glib_supports_modules=no,
 299    [echo $ac_n "cross compiling; assumed OK... $ac_c"])
 300 CFLAGS="$ac_save_CFLAGS"
 301 LIBS="$ac_save_LIBS"
 302 if test "$ac_cv_glib_supports_modules" = yes ; then
 303   AC_MSG_RESULT(yes)
 304   have_plugins=yes
 305 else
 306   AC_MSG_RESULT(no)
 307   have_plugins=no
 308 fi
 309
 310
 311 AC_SUBST(ethereal_bin)
 312 AC_SUBST(ethereal_man)
 313
 314
 315
 316 # Enable/disable tethereal
 317
 318 AC_ARG_ENABLE(tethereal,
 319 [  --enable-tethereal      build tethereal.  [default=yes]],,enable_tethereal=yes)
 320
 321 if test "x$enable_tethereal" = "xyes" ; then
 322         tethereal_bin="tethereal"
 323         tethereal_man="tethereal.1"
 324 else
 325         tethereal_bin=""
 326         tethereal_man=""
 327 fi
 328 AC_SUBST(tethereal_bin)
 329 AC_SUBST(tethereal_man)
 330
 331
 332
 333 # Enable/disable editcap
 334
 335 AC_ARG_ENABLE(editcap,
 336 [  --enable-editcap        build editcap.  [default=yes]],,enable_editcap=yes)
 337
 338 if test "x$enable_editcap" = "xyes" ; then
 339         editcap_bin="editcap"
 340         editcap_man="editcap.1"
 341 else
 342         editcap_bin=""
 343         editcap_man=""
 344 fi
 345 AC_SUBST(editcap_bin)
 346 AC_SUBST(editcap_man)
 347
 348
 349 # Enable/disable mergecap
 350
 351 AC_ARG_ENABLE(mergecap,
 352 [  --enable-mergecap       build mergecap.  [default=yes]],,enable_mergecap=yes)
 353
 354 if test "x$enable_mergecap" = "xyes" ; then
 355         mergecap_bin="mergecap"
 356         mergecap_man="mergecap.1"
 357 else
 358         mergecap_bin=""
 359         mergecap_man=""
 360 fi
 361 AC_SUBST(mergecap_bin)
 362 AC_SUBST(mergecap_man)
 363
 364
 365 # Enable/disable text2pcap
 366
 367 AC_ARG_ENABLE(text2pcap,
 368 [  --enable-text2pcap      build text2pcap.  [default=yes]],,enable_text2pcap=yes)
 369
 370 if test "x$enable_text2pcap" = "xyes" ; then
 371         text2pcap_bin="text2pcap"
 372         text2pcap_man="text2pcap.1"
 373 else
 374         text2pcap_bin=""
 375         text2pcap_man=""
 376 fi
 377 AC_SUBST(text2pcap_bin)
 378 AC_SUBST(text2pcap_man)
 379
 380 # Enable/disable idl2eth
 381
 382 AC_ARG_ENABLE(idl2eth,
 383 [  --enable-idl2eth        build idl2eth.  [default=yes]],,enable_idl2eth=yes)
 384
 385 if test "x$enable_idl2eth" = "xyes" ; then
 386         idl2eth_bin="idl2eth"
 387         idl2eth_man="idl2eth.1"
 388 else
 389         idl2eth_bin=""
 390         idl2eth_man=""
 391 fi
 392 AC_SUBST(idl2eth_bin)
 393 AC_SUBST(idl2eth_man)
 394
 395
 396 # Enable/disable dftest
 397
 398 AC_ARG_ENABLE(dftest,
 399 [  --enable-dftest         build dftest.  [default=no]],,enable_dftest=no)
 400
 401 if test "x$enable_dftest" = "xyes" ; then
 402         dftest_bin="dftest"
 403 else
 404         dftest_bin=""
 405 fi
 406 AC_SUBST(dftest_bin)
 407
 408
 409 # Enable/disable randpkt
 410
 411 AC_ARG_ENABLE(randpkt,
 412 [  --enable-randpkt        build randpkt.  [default=no]],,enable_randpkt=no)
 413
 414 if test "x$enable_randpkt" = "xyes" ; then
 415         randpkt_bin="randpkt"
 416 else
 417         randpkt_bin=""
 418 fi
 419 AC_SUBST(randpkt_bin)
 420
 421
 422 dnl Checks for "gethostbyname()" - and "-lnsl", if we need it to get
 423 dnl "gethostbyname()".
 424 AC_ETHEREAL_GETHOSTBY_LIB_CHECK
 425
 426 dnl Checks for "connect()", used as a proxy for "socket()" - and
 427 dnl "-lsocket", if we need it to get "connect()".
 428 AC_ETHEREAL_SOCKET_LIB_CHECK
 429
 430 dnl pcap check
 431 AC_MSG_CHECKING(whether to use libpcap for packet capture)
 432
 433 AC_ARG_WITH(pcap,
 434 [  --with-pcap[=DIR]       use libpcap for packet capturing.  [default=yes]],
 435 [
 436         if test $withval = no
 437         then
 438                 want_pcap=no
 439         elif test $withval = yes
 440         then
 441                 want_pcap=yes
 442         else
 443                 want_pcap=yes
 444                 pcap_dir=$withval
 445         fi
 446 ],[
 447         want_pcap=yes
 448         pcap_dir=
 449 ])
 450 if test "x$want_pcap" = "xno" ; then
 451         AC_MSG_RESULT(no)
 452 else
 453         AC_MSG_RESULT(yes)
 454         AC_ETHEREAL_PCAP_CHECK
 455         AC_ETHEREAL_PCAP_VERSION_CHECK
 456 fi
 457
 458 dnl zlib check
 459 AC_MSG_CHECKING(whether to use zlib for reading compressed capture files)
 460
 461 AC_ARG_WITH(zlib,
 462 [  --with-zlib[=DIR]       use zlib (located in directory DIR, if supplied) to read compressed data.  [default=yes, if present]],
 463 [
 464         if test $withval = no
 465         then
 466                 want_zlib=no
 467         elif test $withval = yes
 468         then
 469                 want_zlib=yes
 470         else
 471                 want_zlib=yes
 472                 zlib_dir=$withval
 473         fi
 474 ],[
 475         #
 476         # Use zlib if it's present, otherwise don't.
 477         #
 478         want_zlib=ifpresent
 479         zlib_dir=
 480 ])
 481 if test "x$want_zlib" = "xno" ; then
 482         AC_MSG_RESULT(no)
 483 else
 484         AC_MSG_RESULT(yes)
 485         AC_ETHEREAL_ZLIB_CHECK
 486         if test "x$want_zlib" = "xno" ; then
 487                 AC_MSG_RESULT(zlib not found - disabling compressed capture file support)
 488         fi
 489 fi
 490
 491
 492 dnl ipv6 check
 493 AC_ARG_ENABLE(ipv6,
 494 [  --enable-ipv6           use ipv6 name resolution, if available.  [default=yes]],,enable_ipv6=yes)
 495
 496 AC_MSG_CHECKING(whether to enable ipv6 name resolution if available)
 497 if test "x$enable_ipv6" = "xno" ; then
 498         AC_MSG_RESULT(no)
 499 else
 500         AC_MSG_RESULT(yes)
 501         AC_ETHEREAL_IPV6_STACK
 502 fi
 503
 504
 505 dnl Check if ethereal should be installed setuid
 506 AC_ARG_ENABLE(setuid-install,
 507 [  --enable-setuid-install install ethereal as setuid. DANGEROUS!!! [default=no]],,enable_setuid_install=no)
 508
 509 AC_MSG_CHECKING(whether to install ethereal setuid)
 510 if test "x$enable_setuid_install" = "xno" ; then
 511         AC_MSG_RESULT(no)
 512 else
 513         AC_MSG_RESULT(yes)
 514 fi
 515
 516 AM_CONDITIONAL(SETUID_INSTALL, test x$enable_setuid_install = xyes)
 517
 518 dnl Checks for header files.
 519 AC_HEADER_STDC
 520 AC_CHECK_HEADERS(fcntl.h sys/ioctl.h sys/time.h unistd.h stdarg.h netdb.h)
 521 AC_CHECK_HEADERS(sys/stat.h sys/sockio.h sys/types.h sys/socket.h)
 522 AC_CHECK_HEADERS(sys/wait.h)
 523 AC_CHECK_HEADERS(netinet/in.h)
 524 AC_CHECK_HEADERS(stddef.h)
 525 AC_CHECK_HEADERS(arpa/inet.h)
 526 AC_CHECK_HEADERS(iconv.h)
 527
 528 dnl SSL Check
 529 SSL_LIBS=''
 530 AC_MSG_CHECKING(whether to use SSL library if available)
 531 if test "x$enable_ssl" = "xno" ; then
 532         AC_MSG_RESULT(no)
 533 else
 534         AC_MSG_RESULT(yes)
 535         AC_ETHEREAL_SSL_CHECK
 536 fi
 537 AC_SUBST(SSL_LIBS)
 538
 539 dnl UCD SNMP Check
 540 SNMP_LIBS=''
 541 AC_MSG_CHECKING(whether to use UCD SNMP/NET-SNMP library if available)
 542
 543 AC_ARG_WITH(net-snmp,
 544 [  --with-net-snmp=PATH  use PATH as thee location of the net-snmp-config shell script that comes with the net-snmp package.],
 545 [netsnmpconfig=$withval]
 546 )
 547
 548 AC_ARG_WITH(ucdsnmp,
 549 [  --with-ucdsnmp[=DIR]    use UCD SNMP/NET-SNMP client library (located in directory DIR, if supplied).  [default=yes, if present]],
 550 [
 551         if test $withval = no
 552         then
 553                 want_ucdsnmp=no
 554         elif test $withval = yes
 555         then
 556                 want_ucdsnmp=yes
 557         else
 558                 want_ucdsnmp=yes
 559                 ucdsnmp_dir=$withval
 560         fi
 561 ],[
 562         #
 563         # Set "want_ucdsnmp" to "ifpresent" to make the default "use it
 564         # if you find it, otherwise don't".
 565         #
 566         want_ucdsnmp=ifpresent
 567         ucdsnmp_dir=
 568 ])
 569
 570 dnl try net-snmp first
 571 if test "x$netsnmpconfig" != "xno" ; then
 572         dnl get the net-snmp-config binary
 573         if test "x$netsnmpconfig" = "xyes" -o "x$netsnmpconfig" = "x" ; then
 574                 dnl search for it
 575                 AC_PATH_PROG(NETSNMPCONFIG,net-snmp-config)
 576         else
 577                 ac_cv_prog_NETSNMPCONFIG=$netsnmpconfig
 578                 if test ! -x $ac_cv_prog_NETSNMPCONFIG ; then
 579                         AC_MSG_ERROR(Invalid net-snmp-config: $ac_cv_prog_NETSNMPCONFIG)
 580                 fi
 581         fi
 582 fi
 583
 584 if test "x$ac_cv_prog_NETSNMPCONFIG" != "xno" -a "x$ac_cv_prog_NETSNMPCONFIG" != "x" -a -x "$ac_cv_prog_NETSNMPCONFIG" ; then
 585         dnl other choices for flags to use here: could also use
 586         dnl --prefix or --exec-prefix if you don't want the full list.
 587         CFLAGS="$CFLAGS `net-snmp-config --cflags`"
 588         CPPFLAGS="$CPPLAGS `net-snmp-config --cflags`"
 589         SNMP_LIBS=`net-snmp-config --libs`
 590
 591         # XXX: make sure we can find net-snmp/net-snmp-config.h
 592         # XXX: make sure we can find net-snmp/net-snmp-includes.h
 593         AC_DEFINE(HAVE_NET_SNMP)
 594         AC_MSG_RESULT(yes (net-snmp))
 595 else
 596         if test "x$want_ucdsnmp" = "xno" ; then
 597                 AC_MSG_RESULT(no)
 598         else
 599                 AC_MSG_RESULT(yes (ucd-snmp))
 600                 AC_ETHEREAL_UCDSNMP_CHECK
 601         fi
 602 fi
 603
 604 AC_SUBST(SNMP_LIBS)
 605
 606 dnl Checks for typedefs, structures, and compiler characteristics.
 607 # AC_C_CONST
 608
 609 # We need to know whether "struct sockaddr" has an "sa_len" member
 610 # for get_interface_list().
 611
 612 AC_ETHEREAL_STRUCT_SA_LEN
 613
 614 # We must know our byte order
 615 AC_C_BIGENDIAN
 616
 617 # Checks whether "-traditional" is needed when using "ioctl".
 618 # XXX - do we need this?
 619 AC_PROG_GCC_TRADITIONAL
 620
 621 # If there's a system out there that has snprintf and _doesn't_ have vsnprintf,
 622 # then this won't work.
 623 SNPRINTF_C=""
 624 SNPRINTF_O=""
 625 AC_CHECK_FUNC(snprintf, SNPRINTF_O="",
 626   SNPRINTF_O="snprintf.o" [AC_DEFINE(NEED_SNPRINTF_H)])
 627 if test "$ac_cv_func_snprintf" = no ; then
 628   SNPRINTF_C="snprintf.c"
 629   SNPRINTF_O="snprintf.o"
 630 fi
 631 AC_SUBST(SNPRINTF_C)
 632 AC_SUBST(SNPRINTF_O)
 633
 634 AC_CHECK_FUNC(strerror, STRERROR_O="",
 635   STRERROR_O="strerror.o" [AC_DEFINE(NEED_STRERROR_H)])
 636 if test "$ac_cv_func_strerror" = no ; then
 637   STRERROR_C="strerror.c"
 638   STRERROR_O="strerror.o"
 639 fi
 640 AC_SUBST(STRERROR_C)
 641 AC_SUBST(STRERROR_O)
 642
 643 AC_CHECK_FUNC(strcasecmp, STRCASECMP_O="",
 644   STRCASECMP_O="strcasecmp.o")
 645 if test "$ac_cv_func_strcasecmp" = no ; then
 646   STRCASECMP_C="strcasecmp.c"
 647   STRCASECMP_O="strcasecmp.o"
 648 fi
 649 AC_SUBST(STRCASECMP_C)
 650 AC_SUBST(STRCASECMP_O)
 651
 652 AC_CHECK_FUNC(strncasecmp, STRNCASECMP_O="",
 653   STRNCASECMP_O="strncasecmp.o")
 654 if test "$ac_cv_func_strncasecmp" = no ; then
 655   STRNCASECMP_C="strncasecmp.c"
 656   STRNCASECMP_O="strncasecmp.o"
 657 fi
 658 AC_SUBST(STRNCASECMP_C)
 659 AC_SUBST(STRNCASECMP_O)
 660
 661 AC_CHECK_FUNC(mkstemp, MKSTEMP_O="",
 662   MKSTEMP_O="mkstemp.o")
 663 if test "$ac_cv_func_mkstemp" = no ; then
 664   MKSTEMP_C="mkstemp.c"
 665   MKSTEMP_O="mkstemp.o"
 666 fi
 667 AC_SUBST(MKSTEMP_C)
 668 AC_SUBST(MKSTEMP_O)
 669
 670 AC_CHECK_FUNC(strptime, STRPTIME_O="",
 671   STRPTIME_O="strptime.o" [AC_DEFINE(NEED_STRPTIME_H)])
 672 if test "$ac_cv_func_strptime" = no ; then
 673   STRPTIME_C="strptime.c"
 674   STRPTIME_O="strptime.o"
 675 fi
 676 AC_SUBST(STRPTIME_C)
 677 AC_SUBST(STRPTIME_O)
 678
 679 AC_CHECK_FUNCS(getprotobynumber gethostbyname2)
 680
 681 dnl blank for now, but will be used in future
 682 AC_SUBST(ethereal_SUBDIRS)
 683
 684 dnl
 685 dnl check whether plugins should be enabled and, if they should be,
 686 dnl check for plugins directory - stolen from Amanda's configure.in
 687 dnl
 688 plugindir="$libdir/ethereal/plugins/$VERSION"
 689 PLUGIN_DIR="$plugindir"
 690 AC_ARG_WITH(plugins,
 691   [  --with-plugins[=DIR]    support plugins (installed in DIR, if supplied).],
 692   [
 693   case "$withval" in
 694   "" | y | ye | yes )
 695     if test x$have_plugins = xno
 696     then
 697       AC_MSG_ERROR([GLib on this platform doesn't support loadable modules, so you can't enable plugins.])
 698     fi
 699     ;;
 700   n | no)
 701     have_plugins=no
 702     ;;
 703   *)
 704     if test x$have_plugins = xno
 705     then
 706       AC_MSG_ERROR([GLib on this platform doesn't support loadable modules, so you can't enable plugins.])
 707     fi
 708     PLUGIN_DIR="$withval"
 709     ;;
 710   esac
 711   ]
 712 )
 713
 714 AM_CONDITIONAL(HAVE_PLUGINS, test x$have_plugins = xyes)
 715 if test x$have_plugins = xyes
 716 then
 717   AC_DEFINE(HAVE_PLUGINS)
 718   PLUGIN_DIR=`(
 719     test "x$prefix" = xNONE && prefix=$ac_default_prefix
 720     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
 721     eval echo "$PLUGIN_DIR"
 722   )`
 723   AC_DEFINE_UNQUOTED(PLUGIN_DIR,"$PLUGIN_DIR", [Plugin installation directory])
 724 else
 725   AC_DEFINE(PLUGIN_DIR,NULL)
 726 fi
 727 AC_SUBST(PLUGIN_DIR)
 728 AC_SUBST(plugindir)
 729
 730 dnl libtool defs
 731 AM_PROG_LIBTOOL
 732 AC_SUBST(LIBTOOL_DEPS)
 733
 734 AM_CONFIG_HEADER(config.h)
 735 AC_CONFIG_SUBDIRS(epan wiretap)
 736 AC_OUTPUT(
 737   Makefile
 738   doc/Makefile
 739   gtk/Makefile
 740   gtk2/Makefile
 741   packaging/Makefile
 742   packaging/nsis/Makefile
 743   packaging/rpm/Makefile
 744   packaging/rpm/SPECS/Makefile
 745   packaging/rpm/SPECS/ethereal.spec
 746   packaging/svr4/Makefile
 747   packaging/svr4/checkinstall
 748   packaging/svr4/pkginfo
 749   plugins/Makefile
 750   plugins/docsis/Makefile
 751   plugins/giop/Makefile
 752   plugins/gryphon/Makefile
 753   plugins/mgcp/Makefile
 754   plugins/pcli/Makefile
 755   tools/Makefile
 756   tools/lemon/Makefile
 757   ,)
 758
 759
 760 # Pretty messages
 761
 762 if test "x$enable_setuid_install" = "xyes" ; then
 763         setuid_message="yes (DANGEROUS!!!)"
 764 else
 765         setuid_message="no"
 766 fi
 767
 768 if test "x$want_zlib" = "xno" ; then
 769         zlib_message="no"
 770 else
 771         zlib_message="yes"
 772 fi
 773
 774 if test "x$ac_cv_prog_NETSNMPCONFIG" != "xno" -a "x$ac_cv_prog_NETSNMPCONFIG" != "x" -a -x "$ac_cv_prog_NETSNMPCONFIG" ; then
 775         snmp_libs_message="yes (net-snmp)"
 776 elif test "x$SNMP_LIBS" = "x" ; then
 777         snmp_libs_message="no"
 778 else
 779         snmp_libs_message="yes (ucd-snmp)"
 780 fi
 781
 782 echo ""
 783 echo "The Ethereal package has been configured with the following options."
 784 echo "                    Build ethereal : $enable_ethereal"
 785 echo "                   Build tethereal : $enable_tethereal"
 786 echo "                     Build editcap : $enable_editcap"
 787 echo "                    Build mergecap : $enable_mergecap"
 788 echo "                   Build text2pcap : $enable_text2pcap"
 789 echo "                     Build idl2eth : $enable_idl2eth"
 790 echo "                     Build randpkt : $enable_randpkt"
 791 echo "                      Build dftest : $enable_dftest"
 792 echo ""
 793 echo "                    Install setuid : $setuid_message"
 794 echo "                       Use plugins : $have_plugins"
 795 echo "               Use GTK+ v2 library : $enable_gtk2"
 796 echo "                  Use pcap library : $want_pcap"
 797 echo "                  Use zlib library : $zlib_message"
 798 echo "          Use IPv6 name resolution : $enable_ipv6"
 799 echo "              Use UCD SNMP library : $snmp_libs_message"