configure.in

   1 # $Id: configure.in,v 1.23 1999/05/01 05:19:23 gram Exp $
   2 dnl Process this file with autoconf to produce a configure script.
   3 AC_INIT(etypes.h)
   4
   5 AM_INIT_AUTOMAKE(ethereal, 0.6.1)
   6
   7 dnl Check for CPU / vendor / OS
   8 AC_CANONICAL_HOST
   9
  10 dnl Checks for programs.
  11 AC_PROG_CC
  12 AC_PROG_RANLIB
  13
  14 # If we're running gcc, add '-Wall' to CFLAGS.
  15 AC_MSG_CHECKING(to see if we can add '-Wall' to CFLAGS)
  16 if test x$GCC != x ; then
  17   CFLAGS="-Wall $CFLAGS"
  18   AC_MSG_RESULT(yes)
  19 else
  20   AC_MSG_RESULT(no)
  21 fi
  22
  23 # Create DATAFILE_DIR #define for config.h
  24 DATAFILE_DIR=$sysconfdir
  25 DATAFILE_DIR=`(
  26     test "x$prefix" = xNONE && prefix=$ac_default_prefix
  27     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
  28     eval echo "$DATAFILE_DIR"
  29 )`
  30 AC_DEFINE_UNQUOTED(DATAFILE_DIR,"$DATAFILE_DIR")
  31 AC_SUBST(DATAFILE_DIR)
  32
  33 # If we're running Solaris, and LD_LIBRARY_PATH is defined, add it as a
  34 # link directory.
  35 case "$host_os" in
  36   solaris*)
  37     AC_MSG_CHECKING(for LD_LIBRARY_PATH, since you appear to be running Solaris)
  38     if test x$LD_LIBRARY_PATH != x ; then
  39       LIBS="$LIBS -R$LD_LIBRARY_PATH"
  40       AC_MSG_RESULT(yes -- added LD_LIBRARY_PATH to run-time linker path)
  41     else
  42       AC_MSG_RESULT(no -- this may be a problem in a few seconds)
  43     fi
  44   ;;
  45 esac
  46
  47 # GTK checks
  48 AM_PATH_GTK(1.0.0, CFLAGS="$CFLAGS $GTK_CFLAGS" LIBS="$LIBS $GTK_LIBS",
  49                    AC_MSG_ERROR(GTK+ distribution not found.))
  50
  51 # Evidently, some systems have pcap.h, etc. in */include/pcap
  52 AC_MSG_CHECKING(for extraneous pcap header directories)
  53 found_pcap_dir=""
  54 for pcap_dir in /usr/include/pcap /usr/local/include/pcap
  55 do
  56   if test -d $pcap_dir ; then
  57     LIBS="$LIBS -L$pcap_dir"
  58     CFLAGS="$CFLAGS -I$pcap_dir"
  59     CPPFLAGS="$CPPFLAGS -I$pcap_dir"
  60     found_pcap_dir=" $found_pcap_dir -L$pcap_dir"
  61   fi
  62 done
  63
  64 if test "$found_pcap_dir" != "" ; then
  65   AC_MSG_RESULT(found --$found_pcap_dir added to LIBS)
  66 else
  67   AC_MSG_RESULT(not found)
  68 fi
  69
  70 # Pcap checks
  71 AC_CHECK_HEADER(net/bpf.h,, AC_MSG_ERROR(Header file net/bpf.h not found.))
  72 AC_CHECK_HEADER(pcap.h,, AC_MSG_ERROR(Header file pcap.h not found.))
  73 AC_CHECK_LIB(pcap, pcap_open_offline,, AC_MSG_ERROR(Library libpcap not found.))
  74
  75 # Wiretap check
  76 AC_MSG_CHECKING(whether to include wiretap library)
  77 AC_ARG_WITH(wiretap,
  78 [  --with-wiretap          Include wiretap library.
  79   --without-wiretap       Don't include wiretap library (default)],
  80         [ case "$withval" in
  81                 yes)
  82                         AC_MSG_RESULT(yes)
  83                         AC_DEFINE(WITH_WIRETAP)
  84                         WIRETAP_DIR="wiretap"
  85                         if test x$WIRETAP_DIR != x ; then
  86                                 CFLAGS="$CFLAGS -Iwiretap"
  87                                 LIBWIRETAP_A="wiretap/libwiretap.a"
  88                                 SUBDIRS="$SUBDIRS wiretap"
  89                         fi
  90                         ;;
  91                 *)
  92                         AC_MSG_RESULT(no)
  93                         LIBWIRETAP_A=""
  94                         WIRETAP_DIR=""
  95                         ;;
  96         esac ],
  97         AC_MSG_RESULT(no)
  98 )
  99 AC_SUBST(LIBWIRETAP_A)
 100 AC_SUBST(SUBDIRS)
 101
 102 dnl ipv6 check
 103 AC_ARG_ENABLE(ipv6,
 104 [  --enable-ipv6           use ipv6 name resolution, if available.  [default=yes]],,enable_ipv6=yes)
 105
 106 AC_MSG_CHECKING(whether to enable ipv6 name resolution if available)
 107 if test "x$enable_ipv6" = "xno" ; then
 108         AC_MSG_RESULT(no)
 109 else
 110         AC_MSG_RESULT(yes)
 111         AC_ETHEREAL_IPV6_STACK
 112 fi
 113
 114
 115 dnl Checks for header files.
 116 AC_HEADER_STDC
 117 AC_CHECK_HEADERS(fcntl.h sys/ioctl.h sys/time.h unistd.h stdarg.h)
 118
 119 AC_CHECK_HEADERS(sys/sockio.h sys/types.h netinet/in.h)
 120
 121 dnl Checks for typedefs, structures, and compiler characteristics.
 122 # AC_C_CONST
 123
 124 # We need to know whether "struct sockaddr" has an "sa_len" member
 125 # for get_interface_list().
 126
 127 AC_ETHEREAL_STRUCT_SA_LEN
 128
 129 # We must know our byte order
 130 AC_C_BIGENDIAN
 131
 132 dnl Checks for library functions.
 133 AC_PROG_GCC_TRADITIONAL
 134 AC_CHECK_FUNC(socket,, AC_MSG_ERROR(Function 'socket' not found.))
 135
 136 # If there's a system out there that has snprintf and _doesn't_ have vsnprintf,
 137 # then this won't work.
 138 SNPRINTF_C=""
 139 SNPRINTF_O=""
 140 AC_CHECK_FUNC(snprintf, SNPRINTF_O="",
 141   SNPRINTF_O="snprintf.o" [AC_DEFINE(NEED_SNPRINTF_H)])
 142 if test "$ac_cv_func_snprintf" = no ; then
 143   SNPRINTF_C="snprintf.c"
 144   SNPRINTF_O="snprintf.o"
 145 fi
 146 AC_SUBST(SNPRINTF_C)
 147 AC_SUBST(SNPRINTF_O)
 148
 149 AM_CONFIG_HEADER(config.h)
 150 if test x$WIRETAP_DIR != x ; then
 151         AC_CONFIG_SUBDIRS($WIRETAP_DIR)
 152 fi
 153 AC_OUTPUT(Makefile)