configure.in

   1 # $Id$
   2 #
   3 AC_INIT(etypes.h)
   4
   5 AC_PREREQ(2.52)
   6
   7 dnl Check for CPU / vendor / OS
   8 AC_CANONICAL_HOST
   9 AC_CANONICAL_TARGET
  10
  11 AM_INIT_AUTOMAKE(ethereal, 0.10.6)
  12
  13 AM_DISABLE_STATIC
  14
  15 dnl Checks for programs.
  16 AC_PROG_CC
  17 AC_PROG_CPP
  18 dnl Work around libtool bug (fixed in the version 1.5a?)
  19 AC_DEFUN([AC_PROVIDE_AC_LIBTOOL_DLOPEN], )
  20 AC_LIBTOOL_DLOPEN
  21 AC_PROG_LIBTOOL
  22 AC_PROG_YACC
  23 AM_PROG_LEX
  24 AC_PATH_PROG(PERL, perl)
  25 AC_PATH_PROG(POD2MAN, pod2man)
  26 if test "x$POD2MAN" = x
  27 then
  28         #
  29         # The alternative is not to build the man pages....
  30         #
  31         AC_MSG_ERROR(I couldn't find pod2man; make sure it's installed and in your path)
  32 fi
  33 AC_PATH_PROG(POD2HTML, pod2html)
  34 if test "x$POD2HTML" = x
  35 then
  36         #
  37         # The alternative is not to build the HTML man pages....
  38         #
  39         AC_MSG_ERROR(I couldn't find pod2html; make sure it's installed and in your path)
  40 fi
  41 AC_PATH_PROG(LEX, flex)
  42 AC_PATH_PROG(PYTHON, python)
  43
  44 AC_SUBST(PERL)
  45 AC_SUBST(POD2MAN)
  46 AC_SUBST(POD2HTML)
  47 AC_SUBST(LEX)
  48 AC_SUBST(FLEX_PATH)
  49 AC_SUBST(PYTHON)
  50
  51 # Check for doxygen
  52 AC_PATH_PROG(DOXYGEN, doxygen)
  53 AC_CHECK_PROG(HAVE_DOXYGEN, doxygen, "yes", "no")
  54 AM_CONDITIONAL(HAVE_DOXYGEN, test x$HAVE_DOXYGEN = xyes)
  55
  56 # Check for packaging utilities
  57 # For now, we check to see if the various packaging utilites are in our
  58 # path.  I'm too lazy to write code to go hunt for them.  -  Gerald
  59 AC_CHECK_PROG(HAVE_PKGPROTO, pkgproto, "yes", "no")
  60 AC_CHECK_PROG(HAVE_PKGMK, pkgmk, "yes", "no")
  61 AC_CHECK_PROG(HAVE_PKGTRANS, pkgtrans, "yes", "no")
  62
  63 if test x$HAVE_PKGPROTO = xyes -a x$HAVE_PKGMK = xyes \
  64      -a x$HAVE_PKGTRANS = xyes ; then
  65   HAVE_SVR4_PACKAGING=yes
  66 else
  67   HAVE_SVR4_PACKAGING=no
  68 fi
  69 AC_SUBST(HAVE_SVR4_PACKAGING)
  70
  71 AC_ETHEREAL_RPM_CHECK
  72 AC_SUBST(HAVE_RPM)
  73
  74 #
  75 # If we're running gcc, add '-Wall -W' to CFLAGS, and add
  76 # '-D_U_="__attribute__((unused))"' as well, so we can use _U_ to
  77 # flag unused function arguments and not get warnings about them.
  78 # If "--with-extra-gcc-checks" was specified, add "-Wcast-qual
  79 # -Wcast-align" as well.  (Add more checks here in the future?)
  80 #
  81 # Otherwise, add '-D_U_=""', so that _U_ used to flag an unused function
  82 # argument will compile with non-GCC compilers.
  83 #
  84 AC_ARG_WITH(extra-gcc-checks,
  85 [  --with-extra-gcc-checks Do additional -W checks in GCC.  [default=no]],
  86 [
  87         if test $withval != no
  88         then
  89                 ethereal_extra_gcc_flags=" -Wcast-qual -Wcast-align -Wbad-function-cast -pedantic -Wstrict-prototypes"
  90         fi
  91 ],)
  92 AC_MSG_CHECKING(to see if we can add '-Wall -W$ethereal_extra_gcc_flags' to CFLAGS)
  93 if test x$GCC != x ; then
  94   CFLAGS="-D_U_=\"__attribute__((unused))\" -Wall -W$ethereal_extra_gcc_flags $CFLAGS"
  95   AC_MSG_RESULT(yes)
  96 else
  97   CFLAGS="-D_U_=\"\" $CFLAGS"
  98   AC_MSG_RESULT(no)
  99 fi
 100
 101 #
 102 # Add any platform-specific compiler flags needed.
 103 #
 104 AC_MSG_CHECKING(for platform-specific compiler flags)
 105 if test "x$GCC" = x
 106 then
 107         #
 108         # Not GCC - assume it's the vendor's compiler.
 109         #
 110         case "$host_os" in
 111         hpux*)
 112                 #
 113                 # HP's ANSI C compiler; flags suggested by Jost Martin.
 114                 # "-Ae" for ANSI C plus extensions such as "long long".
 115                 # "+O2", for optimization.  XXX - works with "-g"?
 116                 #
 117                 CFLAGS="-Ae +O2 $CFLAGS"
 118                 AC_MSG_RESULT(HP ANSI C compiler - added -Ae +O2)
 119                 ;;
 120         darwin*)
 121                 #
 122                 # It may be called "cc", but it's really a GCC derivative
 123                 # with a problematic special precompiler and precompiled
 124                 # headers; turn off the special precompiler, as some
 125                 # apparently-legal code won't compile with its precompiled
 126                 # headers.
 127                 #
 128                 CFLAGS="-no-cpp-precomp $CFLAGS"
 129                 AC_MSG_RESULT(Apple GCC - added -no-cpp-precomp)
 130                 ;;
 131         *)
 132                 AC_MSG_RESULT(none needed)
 133                 ;;
 134         esac
 135 else
 136         case "$host_os" in
 137         solaris*)
 138                 # the X11 headers don't automatically include prototype info
 139                 # and a lot don't include the return type
 140                 CFLAGS="$CFLAGS -Wno-return-type -DFUNCPROTO=15"
 141                 AC_MSG_RESULT(GCC on Solaris - added -Wno-return-type -DFUNCPROTO=15)
 142                 ;;
 143         darwin*)
 144                 #
 145                 # See comments above about Apple's lovely C compiler.
 146                 #
 147                 CFLAGS="-no-cpp-precomp $CFLAGS"
 148                 AC_MSG_RESULT(Apple GCC - added -no-cpp-precomp)
 149                 ;;
 150         cygwin*)
 151                 #
 152                 # Shared libraries in cygwin/Win32 must never contain
 153                 # undefined symbols.
 154                 #
 155                 LDFLAGS="$LDFLAGS -no-undefined"
 156                 AC_MSG_RESULT(CygWin GCC - added -no-undefined to LDFLAGS)
 157                 ;;
 158         *)
 159                 AC_MSG_RESULT(none needed)
 160                 ;;
 161         esac
 162 fi
 163
 164 #
 165 # On OS X, if we find the headers for Core Foundation and Launch Services,
 166 # add -framework options to link with Application Services (of which
 167 # Launch Services is a subframework) and Core Foundation (required by
 168 # the Launch Services APIs), so we can use that to launch a Web browser
 169 # from the Help menu.
 170 #
 171 # (Do those headers exist on pure Darwin?  If so, does the CoreFoundation
 172 # *and* Launch Services code exist there, or are those headers just stubs?
 173 # If the frameworks aren't present on Darwin, how *should* we check for
 174 # their existence?)
 175 #
 176 case "$host_os" in
 177
 178 darwin*)
 179         AC_MSG_CHECKING(whether we can build with Core Foundation and Launch Services)
 180         ac_save_LIBS="$LIBS"
 181         ac_frameworks="-framework ApplicationServices -framework CoreFoundation"
 182         LIBS="$LIBS $ac_frameworks"
 183         AC_TRY_LINK(
 184            [
 185 #       include <CoreFoundation/CFBase.h>
 186 #       include <CoreFoundation/CFString.h>
 187 #       include <CoreFoundation/CFURL.h>
 188 #       include <ApplicationServices/ApplicationServices.h>
 189            ],
 190            [
 191         CFStringRef url_CFString;
 192         CFURLRef url_CFURL;
 193         OSStatus status;
 194
 195         url_CFString = CFStringCreateWithCString(NULL, "", kCFStringEncodingASCII);
 196         url_CFURL = CFURLCreateWithString(NULL, url_CFString, NULL);
 197         status = LSOpenCFURLRef(url_CFURL, NULL);
 198            ],
 199            ac_cv_can_use_cf_and_ls=yes,
 200            ac_cv_can_use_cf_and_ls=no,
 201            [echo $ac_n "cross compiling; assumed OK... $ac_c"])
 202         if test "$ac_cv_can_use_cf_and_ls" = yes ; then
 203                 AC_DEFINE(HAVE_OS_X_FRAMEWORKS, 1, [Define to 1 if you have OS X frameworks])
 204                 FRAMEWORKS="$ac_frameworks"
 205                 AC_MSG_RESULT(yes)
 206         else
 207                 AC_MSG_RESULT(no)
 208         fi
 209         LIBS="$ac_save_LIBS"
 210         ;;
 211 esac
 212 AC_SUBST(FRAMEWORKS)
 213
 214 dnl Look in /usr/local for header files and libraries ?
 215 dnl XXX FIXME don't include /usr/local if it is already in the system
 216 dnl search path as this causes gcc 3.2 on Linux to complain about a change
 217 dnl of the system search order for includes
 218 AC_ARG_ENABLE(usr-local,
 219 [  --enable-usr-local      look for headers and libs in /usr/local tree.  [default=yes]],ac_cv_enable_usr_local=$enableval,ac_cv_enable_usr_local=yes)
 220
 221 AC_MSG_CHECKING(whether to use /usr/local for headers and libraries)
 222 if test "x$ac_cv_enable_usr_local" = "xyes" ; then
 223         AC_MSG_RESULT(yes)
 224         #
 225         # Arrange that we search for header files in the source directory
 226         # and in its "wiretap" subdirectory, as well as in "/usr/local/include",
 227         # as various packages we use ("libpcap", "zlib", an SNMP library)
 228         # may have been installed under "/usr/local/include".
 229         #
 230         CFLAGS="$CFLAGS -I/usr/local/include"
 231         CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 232
 233         #
 234         # Arrange that we search for libraries in "/usr/local/lib".
 235         #
 236         AC_ETHEREAL_ADD_DASH_L(LDFLAGS, /usr/local/lib)
 237 else
 238         AC_MSG_RESULT(no)
 239 fi
 240
 241 #
 242 # If we're running Solaris, and LD_LIBRARY_PATH is defined, add it as a
 243 # link directory.
 244 #
 245 case "$host_os" in
 246   solaris*)
 247     AC_MSG_CHECKING(for LD_LIBRARY_PATH, since you appear to be running Solaris)
 248     if test x$LD_LIBRARY_PATH != x ; then
 249       LIBS="$LIBS -R$LD_LIBRARY_PATH"
 250       AC_MSG_RESULT(yes -- added LD_LIBRARY_PATH to run-time linker path)
 251     else
 252       AC_MSG_RESULT(no -- this may be a problem in a few seconds)
 253     fi
 254   ;;
 255 esac
 256
 257 #
 258 # Check for versions of "sed" inadequate to handle, in libtool, a list
 259 # of object files as large as the list in Ethereal.
 260 #
 261 # On Solaris, we check for "/bin/sed", "/usr/bin/sed", and "/usr/ucb/sed",
 262 # as both "/usr/bin/sed" (which is also "/bin/sed", as "/bin" is just a
 263 # symlink to "/usr/bin", but people may have "/bin" before "/usr/bin" in
 264 # their search path) and "/usr/ucb/sed" are inadequate; "/usr/xpg4/bin/sed"
 265 # is the only "sed" that comes with Solaris that can handle Ethereal.
 266 #
 267 # Add any checks here that are necessary for other OSes.
 268 #
 269 AC_ETHEREAL_GNU_SED_CHECK
 270 if test "$HAVE_GNU_SED" = no ; then
 271         case "$host_os" in
 272         solaris*)
 273                 AC_MSG_CHECKING(whether one of /usr/bin/sed or /bin/sed or /usr/ucb/sed will be used)
 274                 case `which sed` in
 275                         /bin/sed|/usr/bin/sed|/usr/ucb/sed)
 276                         AC_MSG_RESULT(yes)
 277                         AC_MSG_ERROR([change your path to search /usr/xpg4/bin or directory containing GNU sed before /usr/bin (and /bin and /usr/ucb)])
 278                         ;;
 279
 280                         *)
 281                         AC_MSG_RESULT(no)
 282                         ;;
 283                 esac
 284                 ;;
 285
 286         *)
 287                 :
 288                 ;;
 289         esac
 290 fi
 291
 292 # Enable/disable tethereal
 293
 294 AC_ARG_ENABLE(ethereal,
 295 [  --enable-ethereal       build GTK+-based ethereal.  [default=yes]],enable_ethereal=$enableval,enable_ethereal=yes)
 296
 297 AC_ARG_ENABLE(gtk2,
 298 [  --disable-gtk2          build Glib1/Gtk1+-based (t)ethereal.  [default=no]],enable_gtk2=$enableval,enable_gtk2=yes)
 299 AM_CONDITIONAL(USE_GTK2, test x$enable_gtk2 = xyes)
 300
 301 AC_ARG_ENABLE(threads,
 302 [  --enable-threads        use threads in ethereal.  [default=no]],enable_threads=$enableval,enable_threads=no)
 303 AM_CONDITIONAL(USE_THREADS, test x$enable_threads = xyes)
 304
 305 AC_ARG_ENABLE(profile-build,
 306 [  --enable-profile-build  build profile-ready binaries.  [default=no]],enable_profile_build=$enableval,enable_profile_build=no)
 307 AM_CONDITIONAL(USE_PROFILE_BUILD, test x$enable_profile_build = xyes)
 308 AC_MSG_CHECKING(if profile builds must be generated)
 309 if test "x$enable_profile_build" = "xyes" ; then
 310         if test -n "$GCC" ; then
 311                 AC_MSG_RESULT(yes)
 312                 CFLAGS=" -pg $CFLAGS"
 313         else
 314                 AC_MSG_RESULT(no)
 315                 echo "Building profile binaries currently only supported for GCC."
 316         fi
 317 else
 318         AC_MSG_RESULT(no)
 319 fi
 320
 321 # Create DATAFILE_DIR #define for config.h
 322 datafiledir=$datadir/ethereal
 323 datafiledir=`(
 324     test "x$prefix" = xNONE && prefix=$ac_default_prefix
 325     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
 326     eval echo "$datafiledir"
 327 )`
 328 AC_DEFINE_UNQUOTED(DATAFILE_DIR,"$datafiledir", [Directory for data])
 329
 330 # GTK checks
 331 # We don't add $GLIB_LIBS to LIBS, because we don't want to force all
 332 # programs to be built with GTK+.
 333 #
 334 if test "x$enable_gtk2" = "xyes" -a "x$enable_ethereal" = "xyes" ; then
 335         GTK_OK=two
 336         AM_PATH_GTK_2_0(2.0.0, CFLAGS="$CFLAGS $GTK_CFLAGS", GTK_OK=no, gthread)
 337 elif test "x$enable_gtk2" != "xyes" -a "x$enable_ethereal" = "xyes" ; then
 338         GTK_OK=one
 339         AM_PATH_GTK(1.2.0, CFLAGS="$CFLAGS $GTK_CFLAGS", GTK_OK=no )
 340 else
 341         GTK_OK=no
 342 fi
 343
 344 # GLib checks
 345 # This doesn't add GLIB_CFLAGS to CFLAGS, because AM_PATH_GTK will add
 346 # GTK_CFLAGS to CFLAGS, and GTK_CFLAGS is a superset of CFLAGS.
 347 # However, this means that both @GLIB_LIBS@ and @GTK_LIBS@ will be
 348 # set when generating the Makefile, so we can make programs that require
 349 # only GLib link with @GLIB_LIBS@ and make programs that require GTK+
 350 # link with @GTK_LIBS@ (which includes @GLIB_LIBS@).
 351 # We don't add $GLIB_LIBS to LIBS, because we don't want to force all
 352 # programs to be built with GLib.
 353 #
 354 if test "$GTK_OK" = "no" ; then
 355         enable_ethereal="no"
 356         ethereal_bin=""
 357         ethereal_man=""
 358         # Honor GLIB_CFLAGS
 359         if test "x$enable_gtk2" = "xyes" ; then
 360                 AM_PATH_GLIB_2_0(2.0.0, CFLAGS="$CFLAGS $GLIB_CFLAGS", AC_MSG_ERROR(GLib distribution not found.), gmodule)
 361         else
 362                 AM_PATH_GLIB(1.2.0, CFLAGS="$CFLAGS $GLIB_CFLAGS", AC_MSG_ERROR(GLib distribution not found.), gmodule)
 363         fi
 364 else
 365         ethereal_bin="ethereal\$(EXEEXT)"
 366         ethereal_man="ethereal.1"
 367         ethereal_SUBDIRS="gtk"
 368         # Honor GLIB_CFLAGS
 369         if test "$GTK_OK" = "two" ; then
 370                 AM_PATH_GLIB_2_0(2.0.0, , AC_MSG_ERROR(GLib distribution not found.), gmodule)
 371         else
 372                 AM_PATH_GLIB(1.2.0, , AC_MSG_ERROR(GLib distribution not found.), gmodule)
 373         fi
 374 fi
 375
 376 #
 377 # Check whether GLib modules are supported, to determine whether we
 378 # can support plugins.
 379 #
 380 AC_MSG_CHECKING(whether GLib supports loadable modules)
 381 ac_save_CFLAGS="$CFLAGS"
 382 ac_save_LIBS="$LIBS"
 383 CFLAGS="$CFLAGS $GLIB_CFLAGS"
 384 LIBS="$GLIB_LIBS $LIBS"
 385 AC_TRY_RUN([
 386 #include <glib.h>
 387 #include <gmodule.h>
 388 #include <stdio.h>
 389 #include <stdlib.h>
 390
 391 int
 392 main ()
 393 {
 394   if (g_module_supported())
 395     return 0;   /* success */
 396   else
 397     return 1;   /* failure */
 398 }
 399 ], ac_cv_glib_supports_modules=yes, ac_cv_glib_supports_modules=no,
 400    [echo $ac_n "cross compiling; assumed OK... $ac_c"
 401     ac_cv_glib_supports_modules=yes])
 402 CFLAGS="$ac_save_CFLAGS"
 403 LIBS="$ac_save_LIBS"
 404 if test "$ac_cv_glib_supports_modules" = yes ; then
 405   AC_MSG_RESULT(yes)
 406   have_plugins=yes
 407 else
 408   AC_MSG_RESULT(no)
 409   have_plugins=no
 410 fi
 411
 412 #
 413 # We can't just check for <inttypes.h> - some systems have one that
 414 # doesn't define all the PRI[doxu]64 macros.
 415 #
 416 AC_CHECK_HEADERS(inttypes.h,
 417   [
 418     #
 419     # OK, we have inttypes.h, but does it define those macros?
 420     #
 421     AC_MSG_CHECKING([[whether inttypes.h defines the PRI[doxu]64 macros]])
 422     AC_COMPILE_IFELSE(
 423       [
 424         AC_LANG_SOURCE(
 425           [[
 426             #include <inttypes.h>
 427             #include <glib.h>
 428             #include <stdio.h>
 429             #include <sys/types.h>
 430
 431             main()
 432             {
 433               printf("%" PRId64 "\n", (gint64)1);
 434               printf("%" PRIo64 "\n", (guint64)1);
 435               printf("%" PRIx64 "\n", (guint64)1);
 436               printf("%" PRIu64 "\n", (guint64)1);
 437             }
 438           ]])
 439       ],
 440       [
 441         AC_MSG_RESULT(yes)
 442         ac_ethereal_inttypes_h_defines_formats=yes
 443       ],
 444       [
 445         AC_MSG_RESULT(no)
 446         ac_ethereal_inttypes_h_defines_formats=no
 447       ])
 448   ],
 449   [
 450     #
 451     # We don't have inttypes.h, so it obviously can't define those
 452     # macros.
 453     #
 454     ac_ethereal_inttypes_h_defines_formats=no
 455   ])
 456 if test "$ac_ethereal_inttypes_h_defines_formats" = yes; then
 457   AC_DEFINE(INTTYPES_H_DEFINES_FORMATS,,[Define if <inttypes.h> defines PRI[doxu]64 macros])
 458 else
 459   AC_ETHEREAL_CHECK_64BIT_FORMAT(ll,
 460     [
 461       AC_ETHEREAL_CHECK_64BIT_FORMAT(L,
 462         [
 463           AC_ETHEREAL_CHECK_64BIT_FORMAT(q,
 464             [
 465               AC_MSG_ERROR([neither %llx nor %Lx nor %qx worked on a 64-bit integer])
 466             ])
 467         ])
 468     ])
 469 fi
 470
 471 AC_CHECK_FUNC(strtoull,,
 472   [
 473     #
 474     # No strtoull - do we have strtouq?
 475     #
 476     AC_CHECK_FUNC(strtouq,
 477       [
 478         #
 479         # Yes - define strtoull to be strtouq.
 480         #
 481         AC_DEFINE(strtoull, strtouq,
 482           [Define as a function that behaves like strtoull])
 483       ],
 484       [
 485         AC_MSG_ERROR([This platform has neither strtoull nor strtouq.])
 486       ])
 487   ])
 488
 489 AC_SUBST(ethereal_bin)
 490 AC_SUBST(ethereal_man)
 491
 492 rdps_bin="rdps\$(EXEEXT)"
 493 AC_SUBST(rdps_bin)
 494
 495
 496 # Enable/disable tethereal
 497
 498 AC_ARG_ENABLE(tethereal,
 499 [  --enable-tethereal      build tethereal.  [default=yes]],tethereal=$enableval,enable_tethereal=yes)
 500
 501 if test "x$enable_tethereal" = "xyes" ; then
 502         tethereal_bin="tethereal\$(EXEEXT)"
 503         tethereal_man="tethereal.1"
 504         etherealfilter_man="ethereal-filter.4"
 505 else
 506         tethereal_bin=""
 507         tethereal_man=""
 508 fi
 509 AC_SUBST(tethereal_bin)
 510 AC_SUBST(tethereal_man)
 511 AC_SUBST(etherealfilter_man)
 512
 513
 514
 515 # Enable/disable editcap
 516
 517 AC_ARG_ENABLE(editcap,
 518 [  --enable-editcap        build editcap.  [default=yes]],enable_editcap=$enableval,enable_editcap=yes)
 519
 520 if test "x$enable_editcap" = "xyes" ; then
 521         editcap_bin="editcap\$(EXEEXT)"
 522         editcap_man="editcap.1"
 523 else
 524         editcap_bin=""
 525         editcap_man=""
 526 fi
 527 AC_SUBST(editcap_bin)
 528 AC_SUBST(editcap_man)
 529
 530
 531 # Enable/disable capinfo
 532
 533 AC_ARG_ENABLE(capinfo,
 534 [  --enable-capinfo        build capinfo.  [default=yes]],enable_capinfo=$enableval,enable_capinfo=yes)
 535
 536 if test "x$enable_capinfo" = "xyes" ; then
 537         capinfo_bin="capinfo\$(EXEEXT)"
 538         capinfo_man="capinfo.1"
 539 else
 540         capinfo_bin=""
 541         capinfo_man=""
 542 fi
 543 AC_SUBST(capinfo_bin)
 544 AC_SUBST(capinfo_man)
 545
 546
 547 # Enable/disable mergecap
 548
 549 AC_ARG_ENABLE(mergecap,
 550 [  --enable-mergecap       build mergecap.  [default=yes]],enable_mergecap=$enableval,enable_mergecap=yes)
 551
 552 if test "x$enable_mergecap" = "xyes" ; then
 553         mergecap_bin="mergecap\$(EXEEXT)"
 554         mergecap_man="mergecap.1"
 555 else
 556         mergecap_bin=""
 557         mergecap_man=""
 558 fi
 559 AC_SUBST(mergecap_bin)
 560 AC_SUBST(mergecap_man)
 561
 562
 563 # Enable/disable text2pcap
 564
 565 AC_ARG_ENABLE(text2pcap,
 566 [  --enable-text2pcap      build text2pcap.  [default=yes]],text2pcap=$enableval,enable_text2pcap=yes)
 567
 568 if test "x$enable_text2pcap" = "xyes" ; then
 569         text2pcap_bin="text2pcap\$(EXEEXT)"
 570         text2pcap_man="text2pcap.1"
 571 else
 572         text2pcap_bin=""
 573         text2pcap_man=""
 574 fi
 575 AC_SUBST(text2pcap_bin)
 576 AC_SUBST(text2pcap_man)
 577
 578 # Enable/disable idl2eth
 579
 580 AC_ARG_ENABLE(idl2eth,
 581 [  --enable-idl2eth        build idl2eth.  [default=yes]],enable_idl2eth=$enableval,enable_idl2eth=yes)
 582
 583 if test "x$enable_idl2eth" = "xyes" ; then
 584         idl2eth_bin="idl2eth"
 585         idl2eth_man="idl2eth.1"
 586 else
 587         idl2eth_bin=""
 588         idl2eth_man=""
 589 fi
 590 AC_SUBST(idl2eth_bin)
 591 AC_SUBST(idl2eth_man)
 592
 593
 594 # Enable/disable dftest
 595
 596 AC_ARG_ENABLE(dftest,
 597 [  --enable-dftest         build dftest.  [default=yes]],enable_dftest=$enableval,enable_dftest=yes)
 598
 599 if test "x$enable_dftest" = "xyes" ; then
 600         dftest_bin="dftest\$(EXEEXT)"
 601 else
 602         dftest_bin=""
 603 fi
 604 AC_SUBST(dftest_bin)
 605
 606
 607 # Enable/disable randpkt
 608
 609 AC_ARG_ENABLE(randpkt,
 610 [  --enable-randpkt        build randpkt.  [default=no]],enable_randpkt=$enableval,enable_randpkt=no)
 611
 612 if test "x$enable_randpkt" = "xyes" ; then
 613         randpkt_bin="randpkt\$(EXEEXT)"
 614 else
 615         randpkt_bin=""
 616 fi
 617 AC_SUBST(randpkt_bin)
 618
 619
 620 dnl Checks for "gethostbyname()" - and "-lnsl", if we need it to get
 621 dnl "gethostbyname()".
 622 AC_ETHEREAL_GETHOSTBY_LIB_CHECK
 623
 624 dnl Checks for "connect()", used as a proxy for "socket()" - and
 625 dnl "-lsocket", if we need it to get "connect()".
 626 AC_ETHEREAL_SOCKET_LIB_CHECK
 627
 628 dnl pcap check
 629 AC_MSG_CHECKING(whether to use libpcap for packet capture)
 630
 631 AC_ARG_WITH(pcap,
 632 changequote(<<, >>)dnl
 633 <<  --with-pcap[=DIR]       use libpcap for packet capturing.  [default=yes]>>,
 634 changequote([, ])dnl
 635 [
 636         if test $withval = no
 637         then
 638                 want_pcap=no
 639         elif test $withval = yes
 640         then
 641                 want_pcap=yes
 642         else
 643                 want_pcap=yes
 644                 pcap_dir=$withval
 645         fi
 646 ],[
 647         want_pcap=yes
 648         pcap_dir=
 649 ])
 650 if test "x$want_pcap" = "xno" ; then
 651         AC_MSG_RESULT(no)
 652 else
 653         AC_MSG_RESULT(yes)
 654         AC_ETHEREAL_PCAP_CHECK
 655 fi
 656
 657 dnl zlib check
 658 AC_MSG_CHECKING(whether to use zlib for reading compressed capture files)
 659
 660 AC_ARG_WITH(zlib,
 661 changequote(<<, >>)dnl
 662 <<  --with-zlib[=DIR]       use zlib (located in directory DIR, if supplied) to read compressed data.  [default=yes, if present]>>,
 663 changequote([, ])dnl
 664 [
 665         if test $withval = no
 666         then
 667                 want_zlib=no
 668         elif test $withval = yes
 669         then
 670                 want_zlib=yes
 671         else
 672                 want_zlib=yes
 673                 zlib_dir=$withval
 674         fi
 675 ],[
 676         #
 677         # Use zlib if it's present, otherwise don't.
 678         #
 679         want_zlib=ifpresent
 680         zlib_dir=
 681 ])
 682 if test "x$want_zlib" = "xno" ; then
 683         AC_MSG_RESULT(no)
 684 else
 685         AC_MSG_RESULT(yes)
 686         AC_ETHEREAL_ZLIB_CHECK
 687         if test "x$want_zlib" = "xno" ; then
 688                 AC_MSG_RESULT(zlib not found - disabling compressed capture file support)
 689         fi
 690 fi
 691
 692
 693 dnl pcre check
 694 AC_MSG_CHECKING(whether to use libpcre for regular expressions in dfilters)
 695
 696 AC_ARG_WITH(pcre,
 697 changequote(<<, >>)dnl
 698 <<  --with-pcre[=DIR]       use libpcre (located in directory DIR, if supplied) to use in dfilter regular expressions.  [default=yes, if present]>>,
 699 changequote([, ])dnl
 700 [
 701         if test $withval = no
 702         then
 703                 want_pcre=no
 704         elif test $withval = yes
 705         then
 706                 want_pcre=yes
 707         else
 708                 want_pcre=yes
 709                 pcre_dir=$withval
 710         fi
 711 ],[
 712         #
 713         # Use libpcre if it's present, otherwise don't.
 714         #
 715         want_pcre=ifpresent
 716         pcre_dir=
 717 ])
 718 if test "x$want_pcre" = "xno" ; then
 719         AC_MSG_RESULT(no)
 720 else
 721         AC_MSG_RESULT(yes)
 722         AC_ETHEREAL_LIBPCRE_CHECK
 723         if test "x$want_pcre" = "xno" ; then
 724                 AC_MSG_RESULT(libpcre not found - disabling support for perl compatible regular expressions in dfilters)
 725         fi
 726 fi
 727
 728
 729 dnl ipv6 check
 730 AC_ARG_ENABLE(ipv6,
 731 [  --enable-ipv6           use ipv6 name resolution, if available.  [default=yes]],enable_ipv6=$enableval,enable_ipv6=yes)
 732
 733 AC_MSG_CHECKING(whether to enable ipv6 name resolution if available)
 734 if test "x$enable_ipv6" = "xno" ; then
 735         AC_MSG_RESULT(no)
 736 else
 737         AC_MSG_RESULT(yes)
 738         AC_ETHEREAL_IPV6_STACK
 739 fi
 740
 741
 742 dnl Check if ethereal should be installed setuid
 743 AC_ARG_ENABLE(setuid-install,
 744 [  --enable-setuid-install install ethereal as setuid. DANGEROUS!!! [default=no]],enable_setuid_install=$enableval,enable_setuid_install=no)
 745
 746 AC_MSG_CHECKING(whether to install ethereal setuid)
 747 if test "x$enable_setuid_install" = "xno" ; then
 748         AC_MSG_RESULT(no)
 749 else
 750         AC_MSG_RESULT(yes)
 751 fi
 752
 753 AM_CONDITIONAL(SETUID_INSTALL, test x$enable_setuid_install = xyes)
 754
 755 dnl Checks for header files.
 756 AC_HEADER_STDC
 757 AC_CHECK_HEADERS(direct.h dirent.h fcntl.h netdb.h stdarg.h stddef.h unistd.h)
 758 AC_CHECK_HEADERS(sys/ioctl.h sys/param.h sys/socket.h sys/sockio.h sys/stat.h sys/time.h sys/types.h sys/utsname.h sys/wait.h)
 759 AC_CHECK_HEADERS(netinet/in.h)
 760 AC_CHECK_HEADERS(arpa/inet.h arpa/nameser.h)
 761 AC_CHECK_HEADERS(iconv.h)
 762
 763 dnl SSL Check
 764 SSL_LIBS=''
 765 AC_MSG_CHECKING(whether to use SSL library if available)
 766 if test "x$enable_ssl" = "xno" ; then
 767         AC_MSG_RESULT(no)
 768 else
 769         AC_MSG_RESULT(yes)
 770         AC_MSG_CHECKING(whether SSL library is available)
 771         AC_ETHEREAL_SSL_CHECK
 772 fi
 773 AC_SUBST(SSL_LIBS)
 774
 775 dnl UCD SNMP/NET-SNMP Check
 776 SNMP_LIBS=''
 777
 778 AC_ARG_WITH(net-snmp,
 779 changequote(<<, >>)dnl
 780 <<  --with-net-snmp=PATH    use NET-SNMP library, with PATH as the location of the net-snmp-config shell script that comes with the net-snmp package.>>,
 781 changequote([, ])dnl
 782 [netsnmpconfig=$withval]
 783 )
 784
 785 AC_ARG_WITH(ucd-snmp,
 786 changequote(<<, >>)dnl
 787 <<  --with-ucd-snmp[=DIR]   use UCD SNMP client library (located in directory DIR, if supplied).  [default=yes, if present]>>,
 788 changequote([, ])dnl
 789 [
 790         if test $withval = no
 791         then
 792                 want_ucdsnmp=no
 793         elif test $withval = yes
 794         then
 795                 want_ucdsnmp=yes
 796         else
 797                 want_ucdsnmp=yes
 798                 ucdsnmp_dir=$withval
 799         fi
 800 ],[
 801         #
 802         # Set "want_ucdsnmp" to "ifpresent" to make the default "use it
 803         # if you find it, otherwise don't".
 804         #
 805         want_ucdsnmp=ifpresent
 806         ucdsnmp_dir=
 807 ])
 808
 809 dnl try net-snmp first
 810 AC_MSG_CHECKING(whether to use NET-SNMP library if available)
 811 if test "x$netsnmpconfig" != "xno" ; then
 812         AC_MSG_RESULT(yes)
 813         dnl get the net-snmp-config binary
 814         if test "x$netsnmpconfig" = "xyes" -o "x$netsnmpconfig" = "x" ; then
 815                 dnl search for it
 816                 AC_PATH_PROG(NETSNMPCONFIG,net-snmp-config)
 817         else
 818                 NETSNMPCONFIG=$netsnmpconfig
 819                 if test ! -x $NETSNMPCONFIG -o ! -f $NETSNMPCONFIG ; then
 820                         NETSNMPCONFIG=$netsnmpconfig/bin/net-snmp-config
 821                         if test ! -x $NETSNMPCONFIG -o ! -f $NETSNMPCONFIG ; then
 822                                 AC_MSG_ERROR(Invalid net-snmp-config: $netsnmpconfig)
 823                         fi
 824                 fi
 825         fi
 826 else
 827         AC_MSG_RESULT(no)
 828 fi
 829
 830 if test "x$NETSNMPCONFIG" != "xno" -a "x$NETSNMPCONFIG" != "x" -a -x "$NETSNMPCONFIG" ; then
 831         dnl other choices for flags to use here: could also use
 832         dnl --prefix or --exec-prefix if you don't want the full list.
 833
 834         #
 835         # Save the current settings of CFLAGS and CPPFLAGS, and add
 836         # the output of "$NETSNMPCONFIG --cflags" to it, so that when
 837         # searching for the Net-SNMP headers, we look in whatever
 838         # directory that output specifies.
 839         #
 840         ethereal_save_CFLAGS="$CFLAGS"
 841         ethereal_save_CPPFLAGS="$CPPFLAGS"
 842         CFLAGS="$CFLAGS `$NETSNMPCONFIG --cflags`"
 843         CPPFLAGS="$CPPFLAGS `$NETSNMPCONFIG --cflags`"
 844
 845         AC_CHECK_HEADERS(net-snmp/net-snmp-config.h net-snmp/library/default_store.h)
 846         if test "x$ac_cv_header_net_snmp_net_snmp_config_h" = "xyes" -a "x$ac_cv_header_net_snmp_library_default_store_h" = "xyes" ; then
 847                 SNMP_LIBS=`$NETSNMPCONFIG --libs`
 848                 if echo "$SNMP_LIBS" | grep crypto >/dev/null  && test "x$SSL_LIBS" = "x"; then
 849                         AC_MSG_RESULT(Net-SNMP requires openssl but ssl not enabled - disabling Net-SNMP)
 850                         CFLAGS="$ethereal_save_CFLAGS"
 851                         CPPFLAGS="$ethereal_save_CPPFLAGS"
 852                         SNMP_LIBS=
 853                         NETSNMPCONFIG="no"
 854                 else
 855                         AC_DEFINE(HAVE_NET_SNMP, 1, [Define to enable support for NET-SNMP])
 856                         have_net_snmp="yes"
 857                 fi
 858         else
 859                 # technically, we should retry ucd-snmp but it's
 860                 # unlikely they have installed net-snmp-config and not
 861                 # the net-snmp headers but do have the ucd-snmp
 862                 # headers.  This would likely be a broken system to
 863                 # try and use anyway.
 864                 NETSNMPCONFIG="no"
 865
 866                 #
 867                 # Restore the versions of CFLAGS and CPPFLAGS before
 868                 # we added the output of '$NETSNMPCONFIG --cflags",
 869                 # as we didn't actually find Net-SNMP there.
 870                 #
 871                 CFLAGS="$ethereal_save_CFLAGS"
 872                 CPPFLAGS="$ethereal_save_CPPFLAGS"
 873         fi
 874 else
 875         AC_MSG_CHECKING(whether to use UCD SNMP library if available)
 876         if test "x$want_ucdsnmp" = "xno" ; then
 877                 AC_MSG_RESULT(no)
 878         else
 879                 AC_MSG_RESULT(yes)
 880                 AC_ETHEREAL_UCDSNMP_CHECK
 881         fi
 882 fi
 883
 884 if test "x$have_net_snmp" = "xyes" || test "x$have_ucd_snmp" = "xyes"; then
 885         AC_DEFINE(HAVE_SOME_SNMP, 1, [Define to if some SNMP support is to be used])
 886 fi
 887
 888 AC_SUBST(SNMP_LIBS)
 889
 890
 891 dnl kerberos/heimdal check
 892 AC_MSG_CHECKING(whether to use kerberos/heimdal)
 893
 894 AC_ARG_WITH(krb5,
 895 changequote(<<, >>)dnl
 896 <<  --with-krb5[=DIR]       use kerberos/heimdal (located in directory DIR, if supplied) to use in kerberos dissection  [default=yes]>>,
 897 changequote([, ])dnl
 898 [
 899         if test $withval = no
 900         then
 901                 want_krb5=no
 902         elif test $withval = yes
 903         then
 904                 want_krb5=yes
 905         else
 906                 want_krb5=yes
 907                 krb5_dir=$withval
 908         fi
 909 ],[
 910         #
 911         # Use kerberos/heimdal if specified, otherwise don't.
 912         #
 913         want_krb5=ifpresent
 914         krb5_dir=
 915 ])
 916 if test "x$want_krb5" = "xno" ; then
 917         AC_MSG_RESULT(no)
 918 else
 919         AC_MSG_RESULT(yes)
 920         AC_ETHEREAL_KRB5_CHECK
 921         if test "x$want_krb5" = "xno" ; then
 922                 AC_MSG_RESULT(heimdal not found - disabling dissection for some kerberos data in packet decoding)
 923         fi
 924 fi
 925
 926
 927 dnl ADNS Check
 928 ADNS_LIBS=''
 929 AC_MSG_CHECKING(whether to use the GNU ADNS library if available)
 930 if test "x$with_adns" = "xno" ; then
 931         AC_MSG_RESULT(no)
 932 else
 933         AC_MSG_RESULT(yes)
 934         AC_ETHEREAL_ADNS_CHECK
 935 fi
 936 AC_SUBST(ADNS_LIBS)
 937
 938 #
 939 # Define ETH_VAR_IMPORT appropriately for declarations of external
 940 # variables exported from dynamically-linked libraries.
 941 #
 942 AC_DEFINE(ETH_VAR_IMPORT, extern, [Define as the string to precede external variable declarations in dynamically-linked libraries])
 943
 944 dnl Checks for typedefs, structures, and compiler characteristics.
 945 # AC_C_CONST
 946
 947 # We need to know whether "struct sockaddr" has an "sa_len" member
 948 # for get_interface_list().
 949
 950 AC_ETHEREAL_STRUCT_SA_LEN
 951
 952 # We must know our byte order
 953 AC_C_BIGENDIAN
 954
 955 # Checks whether "-traditional" is needed when using "ioctl".
 956 # XXX - do we need this?
 957 AC_PROG_GCC_TRADITIONAL
 958
 959 # If there's a system out there that has snprintf and _doesn't_ have vsnprintf,
 960 # then this won't work.
 961 SNPRINTF_C=""
 962 SNPRINTF_O=""
 963 AC_CHECK_FUNC(snprintf, SNPRINTF_O="",
 964   [SNPRINTF_O="snprintf.o"
 965    AC_DEFINE(NEED_SNPRINTF_H, 1, [Define if sprintf.h needs to be included])
 966 ])
 967 if test "$ac_cv_func_snprintf" = no ; then
 968   SNPRINTF_C="snprintf.c"
 969   SNPRINTF_O="snprintf.o"
 970 fi
 971 AC_SUBST(SNPRINTF_C)
 972 AC_SUBST(SNPRINTF_O)
 973
 974 AC_CHECK_FUNC(strerror, STRERROR_O="",
 975   [STRERROR_O="strerror.o"
 976    AC_DEFINE(NEED_STRERROR_H, 1, [Define if strerror.h needs to be included])
 977 ])
 978 if test "$ac_cv_func_strerror" = no ; then
 979   STRERROR_C="strerror.c"
 980   STRERROR_O="strerror.o"
 981 fi
 982 AC_SUBST(STRERROR_C)
 983 AC_SUBST(STRERROR_O)
 984
 985 AC_CHECK_FUNC(strcasecmp, STRCASECMP_O="",
 986   STRCASECMP_O="strcasecmp.o")
 987 if test "$ac_cv_func_strcasecmp" = no ; then
 988   STRCASECMP_C="strcasecmp.c"
 989   STRCASECMP_O="strcasecmp.o"
 990 fi
 991 AC_SUBST(STRCASECMP_C)
 992 AC_SUBST(STRCASECMP_O)
 993
 994 AC_CHECK_FUNC(strncasecmp, STRNCASECMP_O="",
 995   STRNCASECMP_O="strncasecmp.o")
 996 if test "$ac_cv_func_strncasecmp" = no ; then
 997   STRNCASECMP_C="strncasecmp.c"
 998   STRNCASECMP_O="strncasecmp.o"
 999 fi
1000 AC_SUBST(STRNCASECMP_C)
1001 AC_SUBST(STRNCASECMP_O)
1002
1003 AC_CHECK_FUNC(mkstemp, MKSTEMP_O="",
1004   MKSTEMP_O="mkstemp.o")
1005 if test "$ac_cv_func_mkstemp" = no ; then
1006   MKSTEMP_C="mkstemp.c"
1007   MKSTEMP_O="mkstemp.o"
1008 fi
1009 AC_SUBST(MKSTEMP_C)
1010 AC_SUBST(MKSTEMP_O)
1011
1012 AC_CHECK_FUNC(inet_aton, INET_ATON_O="",
1013   INET_ATON_O="inet_aton.lo")
1014 if test "$ac_cv_func_inet_aton" = no ; then
1015   INET_ATON_C="inet_aton.c"
1016   INET_ATON_O="inet_aton.lo"
1017   AC_DEFINE(NEED_INET_ATON_H, 1, [Define if inet/aton.h needs to be included])
1018 fi
1019 AC_SUBST(INET_ATON_C)
1020 AC_SUBST(INET_ATON_O)
1021
1022 AC_SEARCH_LIBS(inet_pton, [socket nsl], [
1023   dnl check for pre-BIND82 inet_pton() bug.
1024   AC_MSG_CHECKING(for broken inet_pton)
1025   AC_TRY_RUN([#include <sys/types.h>
1026 #include <sys/socket.h>
1027 #include <netinet/in.h>
1028 #include <arpa/inet.h>
1029 int main()
1030 {
1031 #ifdef AF_INET6
1032   char buf[16];
1033   /* this should return 0 (error) */
1034   return inet_pton(AF_INET6, "0:1:2:3:4:5:6:7:", buf);
1035 #else
1036   return 1;
1037 #endif
1038 }], [AC_MSG_RESULT(ok);
1039 have_inet_pton=yes], [AC_MSG_RESULT(broken);
1040 have_inet_pton=no], [AC_MSG_RESULT(cross compiling, assume it is broken);
1041 have_inet_pton=no])],
1042 have_inet_pton=no)
1043 if test "$have_inet_pton" = no; then
1044   INET_PTON_C="inet_pton.c"
1045   INET_PTON_O="inet_pton.lo"
1046 else
1047   INET_PTON_C=""
1048   INET_PTON_O=""
1049 fi
1050 AC_SUBST(INET_PTON_C)
1051 AC_SUBST(INET_PTON_O)
1052
1053 AC_SEARCH_LIBS(inet_ntop, [socket nsl], [
1054   AC_MSG_CHECKING([for inet_ntop prototype])
1055   AC_TRY_COMPILE([#include <stdio.h>
1056 #include <sys/types.h>
1057 #include <sys/socket.h>
1058 #include <netinet/in.h>
1059 #include <arpa/inet.h>
1060
1061 extern const char *inet_ntop(int, const void *, char *, size_t);],, [
1062     AC_MSG_RESULT(yes)
1063     AC_DEFINE(HAVE_INET_NTOP_PROTO, 1,
1064     [Define if inet_ntop() prototype exists])], [
1065     AC_TRY_COMPILE([#include <stdio.h>
1066 #include <sys/types.h>
1067 #include <sys/socket.h>
1068 #include <netinet/in.h>
1069 #include <arpa/inet.h>
1070
1071 extern const char *inet_ntop(int, const void *, char *, socklen_t);],, [
1072       AC_MSG_RESULT(yes)
1073       AC_DEFINE(HAVE_INET_NTOP_PROTO, 1,
1074       [Define if inet_ntop() prototype exists])], [
1075       AC_MSG_RESULT(no)])])
1076   INET_NTOP_O=""], [
1077   INET_NTOP_C="inet_ntop.c"
1078   INET_NTOP_O="inet_ntop.lo"
1079   AC_DEFINE(NEED_INET_V6DEFS_H, 1,
1080   [Define if inet/v6defs.h needs to be included])])
1081 AC_SUBST(INET_NTOP_C)
1082 AC_SUBST(INET_NTOP_O)
1083
1084 AC_CHECK_FUNC(strptime, STRPTIME_O="",
1085   [STRPTIME_O="strptime.o"
1086    AC_DEFINE(NEED_STRPTIME_H, 1, [Define if strptime.h needs to be included])
1087 ])
1088 if test "$ac_cv_func_strptime" = no ; then
1089   STRPTIME_C="strptime.c"
1090   STRPTIME_O="strptime.o"
1091 fi
1092 AC_SUBST(STRPTIME_C)
1093 AC_SUBST(STRPTIME_O)
1094
1095 AC_CHECK_FUNCS(getprotobynumber gethostbyname2)
1096
1097 dnl blank for now, but will be used in future
1098 AC_SUBST(ethereal_SUBDIRS)
1099
1100 dnl
1101 dnl check whether plugins should be enabled and, if they should be,
1102 dnl check for plugins directory - stolen from Amanda's configure.in
1103 dnl
1104 plugindir="$libdir/ethereal/plugins/$VERSION"
1105 AC_ARG_WITH(plugins,
1106 changequote(<<, >>)dnl
1107 <<  --with-plugins[=DIR]    support plugins (installed in DIR, if supplied).>>,
1108 changequote([, ])dnl
1109 [
1110   case "$withval" in
1111   "" | y | ye | yes )
1112     if test x$have_plugins = xno
1113     then
1114       AC_MSG_ERROR([GLib on this platform doesn't support loadable modules, so you can't enable plugins.])
1115     fi
1116     ;;
1117   n | no)
1118     have_plugins=no
1119     ;;
1120   *)
1121     if test x$have_plugins = xno
1122     then
1123       AC_MSG_ERROR([GLib on this platform doesn't support loadable modules, so you can't enable plugins.])
1124     fi
1125     plugindir="$withval"
1126     ;;
1127   esac
1128 ])
1129
1130 AM_CONDITIONAL(HAVE_PLUGINS, test x$have_plugins = xyes)
1131 if test x$have_plugins = xyes
1132 then
1133   AC_DEFINE(HAVE_PLUGINS, 1, [Define if plugins are enabled])
1134   plugindir=`(
1135     test "x$prefix" = xNONE && prefix=$ac_default_prefix
1136     test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1137     eval echo "$plugindir"
1138   )`
1139   AC_DEFINE_UNQUOTED(PLUGIN_DIR, "$plugindir", [Plugin installation directory])
1140 else
1141   AC_DEFINE(PLUGIN_DIR, NULL, [Plugin installation directory])
1142 fi
1143 AC_SUBST(plugindir)
1144
1145 #
1146 # The plugin dissectors reside in ./plugins/PROTO/
1147 #
1148 PLUGIN_LIBS="-L../../epan -lethereal $GLIB_LIBS"
1149 AC_SUBST(PLUGIN_LIBS)
1150
1151 dnl libtool defs
1152 #
1153 # Yes, AM_PROG_LIBTOOL is redundant with newer version(s) of some tool(s)
1154 # (autoconf?  automake?  libtool?) - with the newer version(s), it's
1155 # just an alias for AC_PROG_LIBTOOL, which is called earlier.
1156 #
1157 # With older version(s) of those tool(s), however, it's not just an
1158 # alias, and the configure scripts don't work without it.
1159 #
1160 AM_PROG_LIBTOOL
1161 AC_SUBST(LIBTOOL_DEPS)
1162
1163 AM_CONDITIONAL(ENABLE_STATIC, test x$enable_static = xyes)
1164 if test x$enable_static = xyes -a x$have_plugins = xyes
1165 then
1166   AC_DEFINE(ENABLE_STATIC, 1, [Link plugins statically into Ethereal])
1167 fi
1168 AC_SUBST(ENABLE_STATIC)
1169
1170 dnl Save the cacheable configure results to config.cache before recursing
1171 AC_CACHE_SAVE
1172
1173 AM_CONFIG_HEADER(config.h)
1174 AC_CONFIG_SUBDIRS(wiretap)
1175 AC_OUTPUT(
1176   Makefile
1177   doxygen.cfg
1178   doc/Makefile
1179   epan/Makefile
1180   epan/doxygen.cfg
1181   epan/dfilter/Makefile
1182   epan/dissectors/Makefile
1183   epan/ftypes/Makefile
1184   gtk/Makefile
1185   gtk/doxygen.cfg
1186   help/Makefile
1187   packaging/Makefile
1188   packaging/nsis/Makefile
1189   packaging/rpm/Makefile
1190   packaging/rpm/SPECS/Makefile
1191   packaging/rpm/SPECS/ethereal.spec
1192   packaging/svr4/Makefile
1193   packaging/svr4/checkinstall
1194   packaging/svr4/pkginfo
1195   plugins/Makefile
1196   plugins/acn/Makefile
1197   plugins/artnet/Makefile
1198   plugins/asn1/Makefile
1199   plugins/ciscosm/Makefile
1200   plugins/docsis/Makefile
1201   plugins/enttec/Makefile
1202   plugins/giop/Makefile
1203   plugins/gryphon/Makefile
1204   plugins/irda/Makefile
1205   plugins/lwres/Makefile
1206   plugins/megaco/Makefile
1207   plugins/mgcp/Makefile
1208   plugins/opsi/Makefile
1209   plugins/pcli/Makefile
1210   plugins/rdm/Makefile
1211   plugins/rlm/Makefile
1212   plugins/rtnet/Makefile
1213   plugins/rudp/Makefile
1214   plugins/v5ua/Makefile
1215   tools/Makefile
1216   tools/lemon/Makefile
1217   ,)
1218
1219
1220 # Pretty messages
1221
1222 if test "x$enable_setuid_install" = "xyes" ; then
1223         setuid_message="yes (DANGEROUS!!!)"
1224 else
1225         setuid_message="no"
1226 fi
1227
1228 if test "x$want_zlib" = "xno" ; then
1229         zlib_message="no"
1230 else
1231         zlib_message="yes"
1232 fi
1233
1234 if test "x$want_pcre" = "xno" ; then
1235         pcre_message="no"
1236 else
1237         pcre_message="yes"
1238 fi
1239
1240 if test "x$want_krb5" = "xno" ; then
1241         krb5_message="no"
1242 else
1243         krb5_message="yes (heimdal)"
1244 fi
1245
1246 if test "x$have_good_adns" = "xyes" ; then
1247         adns_message="yes"
1248 else
1249         adns_message="no"
1250 fi
1251
1252 if test "x$NETSNMPCONFIG" != "xno" -a "x$NETSNMPCONFIG" != "x" -a -x "$NETSNMPCONFIG" ; then
1253         snmp_libs_message="yes (net-snmp)"
1254 elif test "x$SNMP_LIBS" = "x" ; then
1255         snmp_libs_message="no"
1256 else
1257         snmp_libs_message="yes (ucd-snmp)"
1258 fi
1259
1260 echo ""
1261 echo "The Ethereal package has been configured with the following options."
1262 echo "                    Build ethereal : $enable_ethereal"
1263 echo "                   Build tethereal : $enable_tethereal"
1264 echo "                     Build capinfo : $enable_capinfo"
1265 echo "                     Build editcap : $enable_editcap"
1266 echo "                    Build mergecap : $enable_mergecap"
1267 echo "                   Build text2pcap : $enable_text2pcap"
1268 echo "                     Build idl2eth : $enable_idl2eth"
1269 echo "                     Build randpkt : $enable_randpkt"
1270 echo "                      Build dftest : $enable_dftest"
1271 echo ""
1272 echo "                    Install setuid : $setuid_message"
1273 echo "                       Use plugins : $have_plugins"
1274 echo "               Use GTK+ v2 library : $enable_gtk2"
1275 if test "x$enable_gtk2" = "xyes" ; then
1276 echo "                       Use threads : $enable_threads"
1277 echo "            Build profile binaries : $enable_profile_build"
1278 fi
1279 echo "                  Use pcap library : $want_pcap"
1280 echo "                  Use zlib library : $zlib_message"
1281 echo "                  Use pcre library : $pcre_message"
1282 echo "              Use kerberos library : $krb5_message"
1283 echo "              Use GNU ADNS library : $adns_message"
1284 echo "          Use IPv6 name resolution : $enable_ipv6"
1285 echo "     Use UCD SNMP/NET-SNMP library : $snmp_libs_message"