arch/blackfin/lib/memcpy.S

   1 /*
   2  * File:         arch/blackfin/lib/memcpy.S
   3  * Based on:
   4  * Author:
   5  *
   6  * Created:
   7  * Description:  internal version of memcpy(), issued by the compiler
   8  *               to copy blocks of data around.
   9  *               This is really memmove() - it has to be able to deal with
  10  *               possible overlaps, because that ambiguity is when the compiler
  11  *               gives up and calls a function. We have our own, internal version
  12  *               so that we get something we trust, even if the user has redefined
  13  *               the normal symbol.
  14  *
  15  * Modified:
  16  *               Copyright 2004-2006 Analog Devices Inc.
  17  *
  18  * Bugs:         Enter bugs at http://blackfin.uclinux.org/
  19  *
  20  * This program is free software; you can redistribute it and/or modify
  21  * it under the terms of the GNU General Public License as published by
  22  * the Free Software Foundation; either version 2 of the License, or
  23  * (at your option) any later version.
  24  *
  25  * This program is distributed in the hope that it will be useful,
  26  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  27  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  28  * GNU General Public License for more details.
  29  *
  30  * You should have received a copy of the GNU General Public License
  31  * along with this program; if not, see the file COPYING, or write
  32  * to the Free Software Foundation, Inc.,
  33  * 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
  34  */
  35
  36 #include <linux/linkage.h>
  37
  38 /* void *memcpy(void *dest, const void *src, size_t n);
  39  * R0 = To Address (dest) (leave unchanged to form result)
  40  * R1 = From Address (src)
  41  * R2 = count
  42  *
  43  * Note: Favours word alignment
  44  */
  45
  46 #ifdef CONFIG_MEMCPY_L1
  47 .section .l1.text
  48 #else
  49 .text
  50 #endif
  51
  52 .align 2
  53
  54 ENTRY(_memcpy)
  55         CC = R2 <=  0;  /* length not positive? */
  56         IF CC JUMP .L_P1L2147483647;    /* Nothing to do */
  57
  58         P0 = R0 ;       /* dst*/
  59         P1 = R1 ;       /* src*/
  60         P2 = R2 ;       /* length */
  61
  62         /* check for overlapping data */
  63         CC = R1 < R0;   /* src < dst */
  64         IF !CC JUMP .Lno_overlap;
  65         R3 = R1 + R2;
  66         CC = R0 < R3;   /* and dst < src+len */
  67         IF CC JUMP .Lhas_overlap;
  68
  69 .Lno_overlap:
  70         /* Check for aligned data.*/
  71
  72         R3 = R1 | R0;
  73         R0 = 0x3;
  74         R3 = R3 & R0;
  75         CC = R3;        /* low bits set on either address? */
  76         IF CC JUMP .Lnot_aligned;
  77
  78         /* Both addresses are word-aligned, so we can copy
  79         at least part of the data using word copies.*/
  80         P2 = P2 >> 2;
  81         CC = P2 <= 2;
  82         IF !CC JUMP .Lmore_than_seven;
  83         /* less than eight bytes... */
  84         P2 = R2;
  85         LSETUP(.Lthree_start, .Lthree_end) LC0=P2;
  86         R0 = R1;        /* setup src address for return */
  87 .Lthree_start:
  88         R3 = B[P1++] (X);
  89 .Lthree_end:
  90         B[P0++] = R3;
  91
  92         RTS;
  93
  94 .Lmore_than_seven:
  95         /* There's at least eight bytes to copy. */
  96         P2 += -1;       /* because we unroll one iteration */
  97         LSETUP(.Lword_loops, .Lword_loope) LC0=P2;
  98         R0 = R1;
  99         I1 = P1;
 100         R3 = [I1++];
 101 #if ANOMALY_05000202
 102 .Lword_loops:
 103         [P0++] = R3;
 104 .Lword_loope:
 105         R3 = [I1++];
 106 #else
 107 .Lword_loops:
 108 .Lword_loope:
 109         MNOP || [P0++] = R3 || R3 = [I1++];
 110 #endif
 111         [P0++] = R3;
 112         /* Any remaining bytes to copy? */
 113         R3 = 0x3;
 114         R3 = R2 & R3;
 115         CC = R3 == 0;
 116         P1 = I1;        /* in case there's something left, */
 117         IF !CC JUMP .Lbytes_left;
 118         RTS;
 119 .Lbytes_left:   P2 = R3;
 120 .Lnot_aligned:
 121         /* From here, we're copying byte-by-byte. */
 122         LSETUP (.Lbyte_start, .Lbyte_end) LC0=P2;
 123         R0 = R1;        /* Save src address for return */
 124 .Lbyte_start:
 125         R1 = B[P1++] (X);
 126 .Lbyte_end:
 127         B[P0++] = R1;
 128
 129 .L_P1L2147483647:
 130         RTS;
 131
 132 .Lhas_overlap:
 133         /* Need to reverse the copying, because the
 134          * dst would clobber the src.
 135          * Don't bother to work out alignment for
 136          * the reverse case.
 137          */
 138         R0 = R1;        /* save src for later. */
 139         P0 = P0 + P2;
 140         P0 += -1;
 141         P1 = P1 + P2;
 142         P1 += -1;
 143         LSETUP(.Lover_start, .Lover_end) LC0=P2;
 144 .Lover_start:
 145         R1 = B[P1--] (X);
 146 .Lover_end:
 147         B[P0--] = R1;
 148
 149         RTS;
 150
 151 ENDPROC(_memcpy)