acinclude.m4

   1 dnl Macros that test for specific features.
   2 dnl This file is part of the Autoconf packaging for Ethereal.
   3 dnl Copyright (C) 1998-2000 by Gerald Combs.
   4 dnl
   5 dnl $Id: acinclude.m4,v 1.54 2003/05/04 18:50:51 gerald Exp $
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2, or (at your option)
  10 dnl any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  20 dnl 02111-1307, USA.
  21 dnl
  22 dnl As a special exception, the Free Software Foundation gives unlimited
  23 dnl permission to copy, distribute and modify the configure scripts that
  24 dnl are the output of Autoconf.  You need not follow the terms of the GNU
  25 dnl General Public License when using or distributing such scripts, even
  26 dnl though portions of the text of Autoconf appear in them.  The GNU
  27 dnl General Public License (GPL) does govern all other use of the material
  28 dnl that constitutes the Autoconf program.
  29 dnl
  30 dnl Certain portions of the Autoconf source text are designed to be copied
  31 dnl (in certain cases, depending on the input) into the output of
  32 dnl Autoconf.  We call these the "data" portions.  The rest of the Autoconf
  33 dnl source text consists of comments plus executable code that decides which
  34 dnl of the data portions to output in any given case.  We call these
  35 dnl comments and executable code the "non-data" portions.  Autoconf never
  36 dnl copies any of the non-data portions into its output.
  37 dnl
  38 dnl This special exception to the GPL applies to versions of Autoconf
  39 dnl released by the Free Software Foundation.  When you make and
  40 dnl distribute a modified version of Autoconf, you may extend this special
  41 dnl exception to the GPL to apply to your modified version as well, *unless*
  42 dnl your modified version has the potential to copy into its output some
  43 dnl of the text that was the non-data portion of the version that you started
  44 dnl with.  (In other words, unless your change moves or copies text from
  45 dnl the non-data portions to the data portions.)  If your modification has
  46 dnl such potential, you must delete any notice of this special exception
  47 dnl to the GPL from your modified version.
  48 dnl
  49 dnl Written by David MacKenzie, with help from
  50 dnl Franc,ois Pinard, Karl Berry, Richard Pixley, Ian Lance Taylor,
  51 dnl Roland McGrath, Noah Friedman, david d zuhn, and many others.
  52
  53 #
  54 # AC_ETHEREAL_ADD_DASH_L
  55 #
  56 # Add to the variable specified as the first argument a "-L" flag for the
  57 # directory specified as the second argument, and, on Solaris, add a
  58 # "-R" flag for it as well.
  59 #
  60 # XXX - IRIX, and other OSes, may require some flag equivalent to
  61 # "-R" here.
  62 #
  63 AC_DEFUN(AC_ETHEREAL_ADD_DASH_L,
  64 [$1="$$1 -L$2"
  65 case "$host_os" in
  66   solaris*)
  67     $1="$$1 -R$2"
  68   ;;
  69 esac
  70 ])
  71
  72
  73 #
  74 # AC_ETHEREAL_STRUCT_SA_LEN
  75 #
  76 dnl AC_STRUCT_ST_BLKSIZE extracted from the file in question,
  77 dnl "acspecific.m4" in GNU Autoconf 2.12, and turned into
  78 dnl AC_ETHEREAL_STRUCT_SA_LEN, which checks if "struct sockaddr"
  79 dnl has the 4.4BSD "sa_len" member, and defines HAVE_SA_LEN; that's
  80 dnl what's in this file.
  81 dnl Done by Guy Harris <guy@alum.mit.edu> on 1998-11-14.
  82
  83 dnl ### Checks for structure members
  84
  85 AC_DEFUN(AC_ETHEREAL_STRUCT_SA_LEN,
  86 [AC_CACHE_CHECK([for sa_len in struct sockaddr], ac_cv_ethereal_struct_sa_len,
  87 [AC_TRY_COMPILE([#include <sys/types.h>
  88 #include <sys/socket.h>], [struct sockaddr s; s.sa_len;],
  89 ac_cv_ethereal_struct_sa_len=yes, ac_cv_ethereal_struct_sa_len=no)])
  90 if test $ac_cv_ethereal_struct_sa_len = yes; then
  91   AC_DEFINE(HAVE_SA_LEN, 1, [Define if sa_len field exists in struct sockaddr])
  92 fi
  93 ])
  94
  95 #
  96 # AC_ETHEREAL_IPV6_STACK
  97 #
  98 # By Jun-ichiro "itojun" Hagino, <itojun@iijlab.net>
  99 #
 100 AC_DEFUN(AC_ETHEREAL_IPV6_STACK,
 101 [
 102         v6type=unknown
 103         v6lib=none
 104
 105         AC_MSG_CHECKING([ipv6 stack type])
 106         for i in v6d toshiba kame inria zeta linux linux-glibc solaris8; do
 107                 case $i in
 108                 v6d)
 109                         AC_EGREP_CPP(yes, [
 110 #include </usr/local/v6/include/sys/types.h>
 111 #ifdef __V6D__
 112 yes
 113 #endif],
 114                                 [v6type=$i; v6lib=v6;
 115                                 v6libdir=/usr/local/v6/lib;
 116                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 117                         ;;
 118                 toshiba)
 119                         AC_EGREP_CPP(yes, [
 120 #include <sys/param.h>
 121 #ifdef _TOSHIBA_INET6
 122 yes
 123 #endif],
 124                                 [v6type=$i; v6lib=inet6;
 125                                 v6libdir=/usr/local/v6/lib;
 126                                 CFLAGS="-DINET6 $CFLAGS"])
 127                         ;;
 128                 kame)
 129                         AC_EGREP_CPP(yes, [
 130 #include <netinet/in.h>
 131 #ifdef __KAME__
 132 yes
 133 #endif],
 134                                 [v6type=$i; v6lib=inet6;
 135                                 v6libdir=/usr/local/v6/lib;
 136                                 CFLAGS="-DINET6 $CFLAGS"])
 137                         ;;
 138                 inria)
 139                         AC_EGREP_CPP(yes, [
 140 #include <netinet/in.h>
 141 #ifdef IPV6_INRIA_VERSION
 142 yes
 143 #endif],
 144                                 [v6type=$i; CFLAGS="-DINET6 $CFLAGS"])
 145                         ;;
 146                 zeta)
 147                         AC_EGREP_CPP(yes, [
 148 #include <sys/param.h>
 149 #ifdef _ZETA_MINAMI_INET6
 150 yes
 151 #endif],
 152                                 [v6type=$i; v6lib=inet6;
 153                                 v6libdir=/usr/local/v6/lib;
 154                                 CFLAGS="-DINET6 $CFLAGS"])
 155                         ;;
 156                 linux)
 157                         if test -d /usr/inet6; then
 158                                 v6type=$i
 159                                 v6lib=inet6
 160                                 v6libdir=/usr/inet6
 161                                 CFLAGS="-DINET6 $CFLAGS"
 162                         fi
 163                         ;;
 164                 linux-glibc)
 165                         AC_EGREP_CPP(yes, [
 166 #include <features.h>
 167 #if defined(__GLIBC__) && defined(__GLIBC_MINOR__)
 168 #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || __GLIBC__ > 2
 169 yes
 170 #endif
 171 #endif],
 172                         [v6type=$i; v6lib=inet6; CFLAGS="-DINET6 $CFLAGS"])
 173                         ;;
 174                 solaris8)
 175                         if test "`uname -s`" = "SunOS" && test "`uname -r`" = "5.8"; then
 176                                 v6type=$i
 177                                 v6lib=inet6
 178                                 [CFLAGS="-DINET6 -DSOLARIS8_INET6 $CFLAGS"]
 179                         fi
 180                         ;;
 181                 esac
 182                 if test "$v6type" != "unknown"; then
 183                         break
 184                 fi
 185         done
 186
 187         if test "$v6lib" != "none"; then
 188                 for dir in $v6libdir /usr/local/v6/lib /usr/local/lib; do
 189                         if test -d $dir -a -f $dir/lib$v6lib.a; then
 190                                 LIBS="-L$dir $LIBS -l$v6lib"
 191                                 break
 192                         fi
 193                 done
 194                 enable_ipv6="yes"
 195         else
 196                 enable_ipv6="no"
 197         fi
 198         AC_MSG_RESULT(["$v6type, $v6lib"])
 199 ])
 200
 201 #
 202 # AC_ETHEREAL_GETHOSTBY_LIB_CHECK
 203 #
 204 # Checks whether we need "-lnsl" to get "gethostby*()", which we use
 205 # in "resolv.c".
 206 #
 207 # Adapted from stuff in the AC_PATH_XTRA macro in "acspecific.m4" in
 208 # GNU Autoconf 2.13; the comment came from there.
 209 # Done by Guy Harris <guy@alum.mit.edu> on 2000-01-14.
 210 #
 211 AC_DEFUN(AC_ETHEREAL_GETHOSTBY_LIB_CHECK,
 212 [
 213     # msh@cis.ufl.edu says -lnsl (and -lsocket) are needed for his 386/AT,
 214     # to get the SysV transport functions.
 215     # chad@anasazi.com says the Pyramid MIS-ES running DC/OSx (SVR4)
 216     # needs -lnsl.
 217     # The nsl library prevents programs from opening the X display
 218     # on Irix 5.2, according to dickey@clark.net.
 219     AC_CHECK_FUNC(gethostbyname, ,
 220         AC_CHECK_LIB(nsl, gethostbyname, NSL_LIBS="-lnsl"))
 221     AC_SUBST(NSL_LIBS)
 222 ])
 223
 224 #
 225 # AC_ETHEREAL_SOCKET_LIB_CHECK
 226 #
 227 # Checks whether we need "-lsocket" to get "socket()", which is used
 228 # by libpcap on some platforms - and, in effect, "gethostby*()" on
 229 # most if not all platforms (so that it can use NIS or DNS or...
 230 # to look up host names).
 231 #
 232 # Adapted from stuff in the AC_PATH_XTRA macro in "acspecific.m4" in
 233 # GNU Autoconf 2.13; the comment came from there.
 234 # Done by Guy Harris <guy@alum.mit.edu> on 2000-01-14.
 235 #
 236 # We use "connect" because that's what AC_PATH_XTRA did.
 237 #
 238 AC_DEFUN(AC_ETHEREAL_SOCKET_LIB_CHECK,
 239 [
 240     # lieder@skyler.mavd.honeywell.com says without -lsocket,
 241     # socket/setsockopt and other routines are undefined under SCO ODT
 242     # 2.0.  But -lsocket is broken on IRIX 5.2 (and is not necessary
 243     # on later versions), says simon@lia.di.epfl.ch: it contains
 244     # gethostby* variants that don't use the nameserver (or something).
 245     # -lsocket must be given before -lnsl if both are needed.
 246     # We assume that if connect needs -lnsl, so does gethostbyname.
 247     AC_CHECK_FUNC(connect, ,
 248       AC_CHECK_LIB(socket, connect, SOCKET_LIBS="-lsocket",
 249                 AC_MSG_ERROR(Function 'socket' not found.), $NSL_LIBS))
 250     AC_SUBST(SOCKET_LIBS)
 251 ])
 252
 253 #
 254 # AC_ETHEREAL_PCAP_CHECK
 255 #
 256 AC_DEFUN(AC_ETHEREAL_PCAP_CHECK,
 257 [
 258         if test -z "$pcap_dir"
 259         then
 260           # Pcap header checks
 261           # XXX need to set a var AC_CHECK_HEADER(pcap.h,,)
 262
 263           #
 264           # The user didn't specify a directory in which libpcap resides;
 265           # we assume that the current library search path will work,
 266           # but we may have to look for the header in a "pcap"
 267           # subdirectory of "/usr/include" or "/usr/local/include",
 268           # as some systems apparently put "pcap.h" in a "pcap"
 269           # subdirectory, and we also check "$prefix/include" - and
 270           # "$prefix/include/pcap", in case $prefix is set to
 271           # "/usr/include" or "/usr/local/include".
 272           #
 273           # XXX - should we just add "$prefix/include" to the include
 274           # search path and "$prefix/lib" to the library search path?
 275           #
 276           AC_MSG_CHECKING(for extraneous pcap header directories)
 277           found_pcap_dir=""
 278           for pcap_dir in /usr/include/pcap $prefix/include/pcap $prefix/include /usr/local/include/pcap
 279           do
 280             if test -d $pcap_dir ; then
 281                 if test x$pcap_dir != x/usr/include -a x$pcap_dir != x/usr/local/include ; then
 282                     CFLAGS="$CFLAGS -I$pcap_dir"
 283                     CPPFLAGS="$CPPFLAGS -I$pcap_dir"
 284                 fi
 285                 found_pcap_dir=" $found_pcap_dir -I$pcap_dir"
 286                 break
 287             fi
 288           done
 289
 290           if test "$found_pcap_dir" != "" ; then
 291             AC_MSG_RESULT(found --$found_pcap_dir added to CFLAGS)
 292           else
 293             AC_MSG_RESULT(not found)
 294           fi
 295         else
 296           #
 297           # The user specified a directory in which libpcap resides,
 298           # so add the "include" subdirectory of that directory to
 299           # the include file search path and the "lib" subdirectory
 300           # of that directory to the library search path.
 301           #
 302           # XXX - if there's also a libpcap in a directory that's
 303           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 304           # make us find the version in the specified directory,
 305           # as the compiler and/or linker will search that other
 306           # directory before it searches the specified directory.
 307           #
 308           CFLAGS="$CFLAGS -I$pcap_dir/include"
 309           CPPFLAGS="$CPPFLAGS -I$pcap_dir/include"
 310           AC_ETHEREAL_ADD_DASH_L(LDFLAGS, $pcap_dir/lib)
 311         fi
 312
 313         # Pcap header check
 314         AC_CHECK_HEADER(pcap.h,,
 315             AC_MSG_ERROR([[Header file pcap.h not found; if you installed libpcap
 316 from source, did you also do \"make install-incl\", and if you installed a
 317 binary package of libpcap, is there also a developer's package of libpcap,
 318 and did you also install that package?]]))
 319
 320         #
 321         # Check to see if we find "pcap_open_live" in "-lpcap".
 322         #
 323         AC_CHECK_LIB(pcap, pcap_open_live,
 324           [
 325             PCAP_LIBS=-lpcap
 326             AC_DEFINE(HAVE_LIBPCAP, 1, [Define to use libpcap library])
 327           ], [AC_MSG_ERROR(Library libpcap not found.)],
 328           $SOCKET_LIBS $NSL_LIBS)
 329         AC_SUBST(PCAP_LIBS)
 330 ])
 331
 332 #
 333 # AC_ETHEREAL_PCAP_VERSION_CHECK
 334 #
 335 # Check whether "pcap_version" is defined by libpcap.
 336 #
 337 AC_DEFUN(AC_ETHEREAL_PCAP_VERSION_CHECK,
 338 [
 339         AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 340         ac_save_LIBS="$LIBS"
 341         LIBS="$PCAP_LIBS $SOCKET_LIBS $NSL_LIBS $LIBS"
 342         AC_TRY_LINK(
 343            [
 344 #       include <stdio.h>
 345         extern char *pcap_version;
 346            ],
 347            [
 348         printf ("%s\n", pcap_version);
 349            ],
 350            ac_cv_pcap_version_defined=yes,
 351            ac_cv_pcap_version_defined=no,
 352            [echo $ac_n "cross compiling; assumed OK... $ac_c"])
 353         LIBS="$ac_save_LIBS"
 354         if test "$ac_cv_pcap_version_defined" = yes ; then
 355                 AC_MSG_RESULT(yes)
 356                 AC_DEFINE(HAVE_PCAP_VERSION, 1, [Define if libpcap version is known])
 357         else
 358                 AC_MSG_RESULT(no)
 359         fi
 360 ])
 361
 362 #
 363 # AC_ETHEREAL_ZLIB_CHECK
 364 #
 365 AC_DEFUN(AC_ETHEREAL_ZLIB_CHECK,
 366 [
 367         if test "x$zlib_dir" != "x"
 368         then
 369           #
 370           # The user specified a directory in which zlib resides,
 371           # so add the "include" subdirectory of that directory to
 372           # the include file search path and the "lib" subdirectory
 373           # of that directory to the library search path.
 374           #
 375           # XXX - if there's also a zlib in a directory that's
 376           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 377           # make us find the version in the specified directory,
 378           # as the compiler and/or linker will search that other
 379           # directory before it searches the specified directory.
 380           #
 381           ethereal_save_CFLAGS="$CFLAGS"
 382           CFLAGS="$CFLAGS -I$zlib_dir/include"
 383           ethereal_save_CPPLAGS="$CPPLAGS"
 384           CPPFLAGS="$CPPFLAGS -I$zlib_dir/include"
 385           ethereal_save_LIBS="$LIBS"
 386           AC_ETHEREAL_ADD_DASH_L(LIBS, $zlib_dir/lib)
 387         fi
 388
 389         #
 390         # Make sure we have "zlib.h".  If we don't, it means we probably
 391         # don't have zlib, so don't use it.
 392         #
 393         AC_CHECK_HEADER(zlib.h,,
 394           [
 395             if test "x$zlib_dir" != "x"
 396             then
 397               #
 398               # The user used "--with-zlib=" to specify a directory
 399               # containing zlib, but we didn't find the header file
 400               # there; that either means they didn't specify the
 401               # right directory or are confused about whether zlib
 402               # is, in fact, installed.  Report the error and give up.
 403               #
 404               AC_MSG_ERROR([zlib header not found in directory specified in --with-zlib])
 405             else
 406               if test "x$want_zlib" = "xyes"
 407               then
 408                 #
 409                 # The user tried to force us to use the library, but we
 410                 # couldn't find the header file; report an error.
 411                 #
 412                 AC_MSG_ERROR(Header file zlib.h not found.)
 413               else
 414                 #
 415                 # We couldn't find the header file; don't use the
 416                 # library, as it's probably not present.
 417                 #
 418                 want_zlib=no
 419               fi
 420             fi
 421           ])
 422
 423         if test "x$want_zlib" != "xno"
 424         then
 425                 #
 426                 # Well, we at least have the zlib header file.
 427                 #
 428                 # Check for "gzgets()" in zlib, because we need it, but
 429                 # some older versions of zlib don't have it.  It appears
 430                 # from the zlib ChangeLog that any released version of zlib
 431                 # with "gzgets()" should have the other routines we
 432                 # depend on, such as "gzseek()", "gztell()", and "zError()".
 433                 #
 434                 # Another reason why we require "gzgets()" is that
 435                 # some versions of zlib that didn't have it, such
 436                 # as 1.0.8, had a bug in "gzseek()" that meant that it
 437                 # doesn't work correctly on uncompressed files; this
 438                 # means we cannot use version 1.0.8.  (Unfortunately,
 439                 # that's the version that comes with recent X11 source,
 440                 # and many people who install XFree86 on their Slackware
 441                 # boxes don't realize that they should configure it to
 442                 # use the native zlib rather than building and installing
 443                 # the crappy old version that comes with XFree86.)
 444                 #
 445                 # I.e., we can't just avoid using "gzgets()", as
 446                 # versions of zlib without "gzgets()" are likely to have
 447                 # a broken "gzseek()".
 448                 #
 449                 AC_CHECK_LIB(z, gzgets,
 450                 [
 451                         if test "x$zlib_dir" != "x"
 452                         then
 453                                 #
 454                                 # Put the "-I" and "-L" flags for zlib at
 455                                 # the beginning of CFLAGS, CPPFLAGS, and
 456                                 # LIBS.
 457                                 #
 458                                 LIBS=""
 459                                 AC_ETHEREAL_ADD_DASH_L(LIBS, $zlib_dir/lib)
 460                                 LIBS="$LIBS -lz $ethereal_save_LIBS"
 461                         else
 462                                 LIBS="-lz $LIBS"
 463                         fi
 464                         AC_DEFINE(HAVE_LIBZ, 1, [Define to use libz library])
 465                 ],[
 466                         if test "x$zlib_dir" != "x"
 467                         then
 468                                 #
 469                                 # Restore the versions of CFLAGS, CPPFLAGS,
 470                                 # and LIBS before we added the "-with-zlib="
 471                                 # directory, as we didn't actually find
 472                                 # zlib there, or didn't find a zlib that
 473                                 # contains gzgets there.
 474                                 #
 475                                 CFLAGS="$ethereal_save_CFLAGS"
 476                                 CPPFLAGS="$ethereal_save_CPPLAGS"
 477                                 LIBS="$ethereal_save_LIBS"
 478                         fi
 479                         want_zlib=no
 480                 ])
 481         fi
 482
 483         if test "x$want_zlib" != "xno"
 484         then
 485                 #
 486                 # Well, we at least have the zlib header file and a zlib
 487                 # with "gzgets()".
 488                 #
 489                 # Now check for "gzgets()" in zlib when linking with the
 490                 # linker flags for GTK+ applications; people often grab
 491                 # XFree86 source and build and install it on their systems,
 492                 # and they appear sometimes to misconfigure XFree86 so that,
 493                 # even on systems with zlib, it assumes there is no zlib,
 494                 # so the XFree86 build process builds and installs its
 495                 # own zlib in the X11 library directory.
 496                 #
 497                 # The XFree86 zlib is an older version that lacks
 498                 # "gzgets()", and that's the zlib with which Ethereal
 499                 # gets linked, so the build of Ethereal fails.
 500                 #
 501                 ac_save_CFLAGS="$CFLAGS"
 502                 ac_save_LIBS="$LIBS"
 503                 CFLAGS="$CFLAGS $GTK_CFLAGS"
 504                 LIBS="$GTK_LIBS -lz $LIBS"
 505                 AC_MSG_CHECKING([for gzgets missing when linking with X11])
 506                 AC_TRY_LINK_FUNC(gzgets, AC_MSG_RESULT(no),
 507                   [
 508                     AC_MSG_RESULT(yes)
 509                     AC_MSG_ERROR(old zlib found when linking with X11 - get rid of old zlib.)
 510                   ])
 511                 CFLAGS="$ac_save_CFLAGS"
 512                 LIBS="$ac_save_LIBS"
 513         fi
 514 ])
 515
 516 #
 517 # AC_ETHEREAL_UCDSNMP_CHECK
 518 #
 519 AC_DEFUN(AC_ETHEREAL_UCDSNMP_CHECK,
 520 [
 521         if test "x$ucdsnmp_dir" != "x"
 522         then
 523                 #
 524                 # The user specified a directory in which UCD SNMP resides,
 525                 # so add the "include" subdirectory of that directory to
 526                 # the include file search path and the "lib" subdirectory
 527                 # of that directory to the library search path.
 528                 #
 529                 # XXX - if there's also a libpcap in a directory that's
 530                 # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 531                 # make us find the version in the specified directory,
 532                 # as the compiler and/or linker will search that other
 533                 # directory before it searches the specified directory.
 534                 #
 535                 CFLAGS="$CFLAGS -I$ucdsnmp_dir/include"
 536                 CPPFLAGS="$CPPFLAGS -I$ucdsnmp_dir/include"
 537                 AC_ETHEREAL_ADD_DASH_L(LDFLAGS, $ucdsnmp_dir/lib)
 538         fi
 539
 540         #
 541         # Check for one of the UCD SNMP header files we include,
 542         # to see whether we have UCD SNMP installed.
 543         #
 544         AC_CHECK_HEADER(ucd-snmp/ucd-snmp-config.h,
 545         [
 546                 #
 547                 # UCD SNMP may require "-lkstat" on Solaris, sigh.
 548                 # XXX - it may also require "-lcrypto" on some platforms;
 549                 # we should check for that as well, rather than requiring
 550                 # users to explicitly indicate whether it's required.
 551                 #
 552                 AC_CHECK_LIB(snmp, sprint_realloc_objid,
 553                   SNMP_LIBS=-lsnmp,
 554                   [
 555                     #
 556                     # Throw away the cached "we didn't find it" answer.
 557                     #
 558                     unset ac_cv_lib_snmp_sprint_realloc_objid
 559                     AC_CHECK_LIB(snmp, sprint_realloc_objid,
 560                       [
 561                         #
 562                         # Throw away the cached "we found it" answer, so
 563                         # that if we rerun "configure", we don't just blow
 564                         # off this check and blithely assume that we don't
 565                         # need "-lkstat".
 566                         #
 567                         # XXX - autoconf really needs a way to test for
 568                         # a given routine in a given library *and* to test
 569                         # whether additional "-L"/"-R"/whatever flags are
 570                         # needed *before* the "-l" flag for the library
 571                         # and to test whether additional libraries are
 572                         # needed after the library *and* to cache all that
 573                         # information.
 574                         #
 575                         unset ac_cv_lib_snmp_sprint_realloc_objid
 576                         SNMP_LIBS="-lsnmp -lkstat"
 577                       ],,$SOCKET_LIBS $NSL_LIBS $SSL_LIBS -lkstat
 578                     )
 579                   ], $SOCKET_LIBS $NSL_LIBS $SSL_LIBS
 580                 )
 581
 582                 #
 583                 # If we didn't find "sprint_realloc_objid()", fail.
 584                 # Either the user needs a newer version of UCD SNMP
 585                 # with "sprint_realloc_objid()", or they may need to
 586                 # specify "--with-ssl".
 587                 #
 588                 if test "$ac_cv_lib_snmp_sprint_realloc_objid" = no; then
 589                     AC_MSG_ERROR([UCD SNMP header files found, but sprint_realloc_objid not found in SNMP library.])
 590                 fi
 591
 592                 #
 593                 # We found it, so we have UCD SNMP.
 594                 #
 595                 AC_DEFINE(HAVE_UCD_SNMP, 1, [Define to enable support for UCD-SNMP])
 596                 have_ucd_snmp="yes"
 597         ],[
 598                 #
 599                 # No, we don't have it.
 600                 # If the user explicitly asked for UCD SNMP, fail,
 601                 # otherwise just don't use the UCD SNMP library.
 602                 #
 603                 if test "x$want_ucdsnmp" = "xyes" ; then
 604                         AC_MSG_ERROR(Header file ucd-snmp/snmp.h not found.)
 605                 fi
 606         ])
 607 ])
 608
 609 #
 610 # AC_ETHEREAL_SSL_CHECK
 611 #
 612 AC_DEFUN(AC_ETHEREAL_SSL_CHECK,
 613 [
 614         want_ssl=defaultyes
 615
 616         AC_ARG_WITH(ssl,
 617         [  --with-ssl=DIR          use SSL crypto library, located in directory DIR.], [
 618         if   test "x$withval" = "xno";  then
 619                 want_ssl=no
 620         elif test "x$withval" = "xyes"; then
 621                 want_ssl=yes
 622         elif test -d "$withval"; then
 623                 want_ssl=yes
 624                 AC_ETHEREAL_ADD_DASH_L(LDFLAGS, ${withval}/lib)
 625         fi
 626         ])
 627
 628         if test "x$want_ssl" = "xdefaultyes"; then
 629                 want_ssl=yes
 630                 withval=/usr/local/ssl
 631                 if test -d "$withval"; then
 632                         AC_ETHEREAL_ADD_DASH_L(LDFLAGS, ${withval}/lib)
 633                 fi
 634         fi
 635
 636         if test "x$want_ssl" = "xyes"; then
 637                 AC_CHECK_LIB(crypto, EVP_md5,
 638                   [
 639                     SSL_LIBS=-lcrypto
 640                   ],,
 641                 )
 642         else
 643                 AC_MSG_RESULT(not required)
 644         fi
 645 ])
 646
 647 #
 648 # AC_ETHEREAL_RPM_CHECK
 649 # Looks for the rpm program, and checks to see if we can redefine "_topdir".
 650 #
 651 AC_DEFUN(AC_ETHEREAL_RPM_CHECK,
 652 [
 653         AC_CHECK_PROG(ac_cv_ethereal_have_rpm, rpm, "yes", "no")
 654         if test "x$ac_cv_ethereal_have_rpm" = "xyes"; then
 655                 rpm --define '_topdir /tmp' > /dev/null 2>&1
 656                 AC_MSG_CHECKING(to see if we can redefine _topdir)
 657                 if test $? -eq 0 ; then
 658                         AC_MSG_RESULT(yes)
 659                         HAVE_RPM=yes
 660                 else
 661                         AC_MSG_RESULT(no.  You'll have to build packages manually.)
 662                         HAVE_RPM=no
 663                 fi
 664         fi
 665 ])
 666
 667 #
 668 # AC_ETHEREAL_GNU_SED_CHECK
 669 # Checks if GNU sed is the first sed in PATH.
 670 #
 671 AC_DEFUN([AC_ETHEREAL_GNU_SED_CHECK],
 672 [
 673         AC_MSG_CHECKING(for GNU sed as first sed in PATH)
 674         if  ( sh -c "sed --version" </dev/null 2> /dev/null | grep "GNU sed" 2>&1 > /dev/null ) ;  then
 675                 AC_MSG_RESULT(yes)
 676                 HAVE_GNU_SED=yes
 677         else
 678                 AC_MSG_RESULT(no)
 679                 HAVE_GNU_SED=no
 680         fi
 681 ])
 682
 683 #
 684 # AC_ETHEREAL_ADNS_CHECK
 685 #
 686 AC_DEFUN(AC_ETHEREAL_ADNS_CHECK,
 687 [
 688         want_adns=defaultyes
 689
 690         AC_ARG_WITH(adns,
 691         [  --with-adns=DIR          use GNU ADNS, located in directory DIR.], [
 692         if   test "x$withval" = "xno";  then
 693                 want_adns=no
 694         elif test "x$withval" = "xyes"; then
 695                 want_adns=yes
 696         elif test -d "$withval"; then
 697                 want_adns=yes
 698                 AC_ETHEREAL_ADD_DASH_L(LDFLAGS, ${withval}/lib)
 699         fi
 700         ])
 701
 702         if test "x$want_adns" = "xdefaultyes"; then
 703                 want_adns=yes
 704                 withval=/usr/local
 705                 if test -d "$withval"; then
 706                         AC_ETHEREAL_ADD_DASH_L(LDFLAGS, ${withval}/lib)
 707                 fi
 708         fi
 709
 710         if test "x$want_adns" = "xyes"; then
 711                 AC_CHECK_LIB(adns, adns_init,
 712                   [
 713                     ADNS_LIBS=-ladns
 714                 AC_DEFINE(HAVE_GNU_ADNS, 1, [Define to use GNU ADNS library])
 715                   ],,
 716                 )
 717         else
 718                 AC_MSG_RESULT(not required)
 719         fi
 720 ])