acinclude.m4

   1 dnl Macros that test for specific features.
   2 dnl This file is part of the Autoconf packaging for Ethereal.
   3 dnl Copyright (C) 1998-2000 by Gerald Combs.
   4 dnl
   5 dnl $Id: acinclude.m4,v 1.35 2001/09/28 05:41:44 guy Exp $
   6 dnl
   7 dnl This program is free software; you can redistribute it and/or modify
   8 dnl it under the terms of the GNU General Public License as published by
   9 dnl the Free Software Foundation; either version 2, or (at your option)
  10 dnl any later version.
  11 dnl
  12 dnl This program is distributed in the hope that it will be useful,
  13 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 dnl GNU General Public License for more details.
  16 dnl
  17 dnl You should have received a copy of the GNU General Public License
  18 dnl along with this program; if not, write to the Free Software
  19 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  20 dnl 02111-1307, USA.
  21 dnl
  22 dnl As a special exception, the Free Software Foundation gives unlimited
  23 dnl permission to copy, distribute and modify the configure scripts that
  24 dnl are the output of Autoconf.  You need not follow the terms of the GNU
  25 dnl General Public License when using or distributing such scripts, even
  26 dnl though portions of the text of Autoconf appear in them.  The GNU
  27 dnl General Public License (GPL) does govern all other use of the material
  28 dnl that constitutes the Autoconf program.
  29 dnl
  30 dnl Certain portions of the Autoconf source text are designed to be copied
  31 dnl (in certain cases, depending on the input) into the output of
  32 dnl Autoconf.  We call these the "data" portions.  The rest of the Autoconf
  33 dnl source text consists of comments plus executable code that decides which
  34 dnl of the data portions to output in any given case.  We call these
  35 dnl comments and executable code the "non-data" portions.  Autoconf never
  36 dnl copies any of the non-data portions into its output.
  37 dnl
  38 dnl This special exception to the GPL applies to versions of Autoconf
  39 dnl released by the Free Software Foundation.  When you make and
  40 dnl distribute a modified version of Autoconf, you may extend this special
  41 dnl exception to the GPL to apply to your modified version as well, *unless*
  42 dnl your modified version has the potential to copy into its output some
  43 dnl of the text that was the non-data portion of the version that you started
  44 dnl with.  (In other words, unless your change moves or copies text from
  45 dnl the non-data portions to the data portions.)  If your modification has
  46 dnl such potential, you must delete any notice of this special exception
  47 dnl to the GPL from your modified version.
  48 dnl
  49 dnl Written by David MacKenzie, with help from
  50 dnl Franc,ois Pinard, Karl Berry, Richard Pixley, Ian Lance Taylor,
  51 dnl Roland McGrath, Noah Friedman, david d zuhn, and many others.
  52
  53 #
  54 # AC_ETHEREAL_ADD_DASH_L
  55 #
  56 # Add to the variable specified as the first argument a "-L" flag for the
  57 # directory specified as the second argument, and, on Solaris, add a
  58 # "-R" flag for it as well.
  59 #
  60 # XXX - IRIX, and other OSes, may require some flag equivalent to
  61 # "-R" here.
  62 #
  63 AC_DEFUN(AC_ETHEREAL_ADD_DASH_L,
  64 [$1="$$1 -L$2"
  65 case "$host_os" in
  66   solaris*)
  67     $1="$$1 -R$2"
  68   ;;
  69 esac
  70 ])
  71
  72
  73 #
  74 # AC_ETHEREAL_STRUCT_SA_LEN
  75 #
  76 dnl AC_STRUCT_ST_BLKSIZE extracted from the file in question,
  77 dnl "acspecific.m4" in GNU Autoconf 2.12, and turned into
  78 dnl AC_ETHEREAL_STRUCT_SA_LEN, which checks if "struct sockaddr"
  79 dnl has the 4.4BSD "sa_len" member, and defines HAVE_SA_LEN; that's
  80 dnl what's in this file.
  81 dnl Done by Guy Harris <guy@alum.mit.edu> on 1998-11-14.
  82
  83 dnl ### Checks for structure members
  84
  85 AC_DEFUN(AC_ETHEREAL_STRUCT_SA_LEN,
  86 [AC_CACHE_CHECK([for sa_len in struct sockaddr], ac_cv_ethereal_struct_sa_len,
  87 [AC_TRY_COMPILE([#include <sys/types.h>
  88 #include <sys/socket.h>], [struct sockaddr s; s.sa_len;],
  89 ac_cv_ethereal_struct_sa_len=yes, ac_cv_ethereal_struct_sa_len=no)])
  90 if test $ac_cv_ethereal_struct_sa_len = yes; then
  91   AC_DEFINE(HAVE_SA_LEN)
  92 fi
  93 ])
  94
  95 #
  96 # AC_ETHEREAL_IPV6_STACK
  97 #
  98 # By Jun-ichiro "itojun" Hagino, <itojun@iijlab.net>
  99 #
 100 AC_DEFUN(AC_ETHEREAL_IPV6_STACK,
 101 [
 102         v6type=unknown
 103         v6lib=none
 104
 105         AC_MSG_CHECKING([ipv6 stack type])
 106         for i in v6d toshiba kame inria zeta linux linux-glibc; do
 107                 case $i in
 108                 v6d)
 109                         AC_EGREP_CPP(yes, [
 110 #include </usr/local/v6/include/sys/types.h>
 111 #ifdef __V6D__
 112 yes
 113 #endif],
 114                                 [v6type=$i; v6lib=v6;
 115                                 v6libdir=/usr/local/v6/lib;
 116                                 CFLAGS="-I/usr/local/v6/include $CFLAGS"])
 117                         ;;
 118                 toshiba)
 119                         AC_EGREP_CPP(yes, [
 120 #include <sys/param.h>
 121 #ifdef _TOSHIBA_INET6
 122 yes
 123 #endif],
 124                                 [v6type=$i; v6lib=inet6;
 125                                 v6libdir=/usr/local/v6/lib;
 126                                 CFLAGS="-DINET6 $CFLAGS"])
 127                         ;;
 128                 kame)
 129                         AC_EGREP_CPP(yes, [
 130 #include <netinet/in.h>
 131 #ifdef __KAME__
 132 yes
 133 #endif],
 134                                 [v6type=$i; v6lib=inet6;
 135                                 v6libdir=/usr/local/v6/lib;
 136                                 CFLAGS="-DINET6 $CFLAGS"])
 137                         ;;
 138                 inria)
 139                         AC_EGREP_CPP(yes, [
 140 #include <netinet/in.h>
 141 #ifdef IPV6_INRIA_VERSION
 142 yes
 143 #endif],
 144                                 [v6type=$i; CFLAGS="-DINET6 $CFLAGS"])
 145                         ;;
 146                 zeta)
 147                         AC_EGREP_CPP(yes, [
 148 #include <sys/param.h>
 149 #ifdef _ZETA_MINAMI_INET6
 150 yes
 151 #endif],
 152                                 [v6type=$i; v6lib=inet6;
 153                                 v6libdir=/usr/local/v6/lib;
 154                                 CFLAGS="-DINET6 $CFLAGS"])
 155                         ;;
 156                 linux)
 157                         if test -d /usr/inet6; then
 158                                 v6type=$i
 159                                 v6lib=inet6
 160                                 v6libdir=/usr/inet6
 161                                 CFLAGS="-DINET6 $CFLAGS"
 162                         fi
 163                         ;;
 164                 linux-glibc)
 165                         AC_EGREP_CPP(yes, [
 166 #include <features.h>
 167 #if defined(__GLIBC__) && defined(__GLIBC_MINOR__)
 168 #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || __GLIBC__ > 2
 169 yes
 170 #endif
 171 #endif],
 172                         [v6type=$i; v6lib=inet6; CFLAGS="-DINET6 $CFLAGS"])
 173                         ;;
 174                 esac
 175                 if test "$v6type" != "unknown"; then
 176                         break
 177                 fi
 178         done
 179
 180         if test "$v6lib" != "none"; then
 181                 for dir in $v6libdir /usr/local/v6/lib /usr/local/lib; do
 182                         if test -d $dir -a -f $dir/lib$v6lib.a; then
 183                                 LIBS="-L$dir $LIBS -l$v6lib"
 184                                 break
 185                         fi
 186                 done
 187                 enable_ipv6="yes"
 188         else
 189                 enable_ipv6="no"
 190         fi
 191         AC_MSG_RESULT(["$v6type, $v6lib"])
 192 ])
 193
 194 #
 195 # AC_ETHEREAL_GETHOSTBY_LIB_CHECK
 196 #
 197 # Checks whether we need "-lnsl" to get "gethostby*()", which we use
 198 # in "resolv.c".
 199 #
 200 # Adapted from stuff in the AC_PATH_XTRA macro in "acspecific.m4" in
 201 # GNU Autoconf 2.13; the comment came from there.
 202 # Done by Guy Harris <guy@alum.mit.edu> on 2000-01-14.
 203 #
 204 AC_DEFUN(AC_ETHEREAL_GETHOSTBY_LIB_CHECK,
 205 [
 206     # msh@cis.ufl.edu says -lnsl (and -lsocket) are needed for his 386/AT,
 207     # to get the SysV transport functions.
 208     # chad@anasazi.com says the Pyramid MIS-ES running DC/OSx (SVR4)
 209     # needs -lnsl.
 210     # The nsl library prevents programs from opening the X display
 211     # on Irix 5.2, according to dickey@clark.net.
 212     AC_CHECK_FUNC(gethostbyname)
 213     if test $ac_cv_func_gethostbyname = no; then
 214       AC_CHECK_LIB(nsl, gethostbyname, NSL_LIBS="-lnsl")
 215     fi
 216     AC_SUBST(NSL_LIBS)
 217 ])
 218
 219 #
 220 # AC_ETHEREAL_SOCKET_LIB_CHECK
 221 #
 222 # Checks whether we need "-lsocket" to get "socket()", which is used
 223 # by libpcap on some platforms - and, in effect, "gethostby*()" on
 224 # most if not all platforms (so that it can use NIS or DNS or...
 225 # to look up host names).
 226 #
 227 # Adapted from stuff in the AC_PATH_XTRA macro in "acspecific.m4" in
 228 # GNU Autoconf 2.13; the comment came from there.
 229 # Done by Guy Harris <guy@alum.mit.edu> on 2000-01-14.
 230 #
 231 # We use "connect" because that's what AC_PATH_XTRA did.
 232 #
 233 AC_DEFUN(AC_ETHEREAL_SOCKET_LIB_CHECK,
 234 [
 235     # lieder@skyler.mavd.honeywell.com says without -lsocket,
 236     # socket/setsockopt and other routines are undefined under SCO ODT
 237     # 2.0.  But -lsocket is broken on IRIX 5.2 (and is not necessary
 238     # on later versions), says simon@lia.di.epfl.ch: it contains
 239     # gethostby* variants that don't use the nameserver (or something).
 240     # -lsocket must be given before -lnsl if both are needed.
 241     # We assume that if connect needs -lnsl, so does gethostbyname.
 242     AC_CHECK_FUNC(connect)
 243     if test $ac_cv_func_connect = no; then
 244       AC_CHECK_LIB(socket, connect, SOCKET_LIBS="-lsocket",
 245                 AC_MSG_ERROR(Function 'socket' not found.), $NSL_LIBS)
 246     fi
 247     AC_SUBST(SOCKET_LIBS)
 248 ])
 249
 250 #
 251 # AC_ETHEREAL_PCAP_CHECK
 252 #
 253 AC_DEFUN(AC_ETHEREAL_PCAP_CHECK,
 254 [
 255         if test -z "$pcap_dir"
 256         then
 257           #
 258           # The user didn't specify a directory in which libpcap resides;
 259           # we assume that the current library search path will work,
 260           # but we may have to look for the header in a "pcap"
 261           # subdirectory of "/usr/include" or "/usr/local/include",
 262           # as some systems apparently put "pcap.h" in a "pcap"
 263           # subdirectory, and we also check "$prefix/include".
 264           #
 265           # XXX - should we just add "$prefix/include" to the include
 266           # search path and "$prefix/lib" to the library search path?
 267           #
 268           AC_MSG_CHECKING(for extraneous pcap header directories)
 269           found_pcap_dir=""
 270           for pcap_dir in /usr/include/pcap /usr/local/include/pcap $prefix/include
 271           do
 272             if test -d $pcap_dir ; then
 273                 CFLAGS="$CFLAGS -I$pcap_dir"
 274                 CPPFLAGS="$CPPFLAGS -I$pcap_dir"
 275                 found_pcap_dir=" $found_pcap_dir -I$pcap_dir"
 276             fi
 277           done
 278
 279           if test "$found_pcap_dir" != "" ; then
 280             AC_MSG_RESULT(found --$found_pcap_dir added to CFLAGS)
 281           else
 282             AC_MSG_RESULT(not found)
 283           fi
 284         else
 285           #
 286           # The user specified a directory in which libpcap resides,
 287           # so add the "include" subdirectory of that directory to
 288           # the include file search path and the "lib" subdirectory
 289           # of that directory to the library search path.
 290           #
 291           # XXX - if there's also a libpcap in a directory that's
 292           # already in CFLAGS, CPPFLAGS, or LDFLAGS, this won't
 293           # make us find the version in the specified directory,
 294           # as the compiler and/or linker will search that other
 295           # directory before it searches the specified directory.
 296           #
 297           CFLAGS="$CFLAGS -I$pcap_dir/include"
 298           CPPFLAGS="$CPPFLAGS -I$pcap_dir/include"
 299           AC_ETHEREAL_ADD_DASH_L(LDFLAGS, $pcap_dir/lib)
 300         fi
 301
 302         # Pcap header checks
 303         AC_CHECK_HEADER(net/bpf.h,,
 304             AC_MSG_ERROR([[Header file net/bpf.h not found; if you installed libpcap from source, did you also do \"make install-incl\"?]]))
 305         AC_CHECK_HEADER(pcap.h,, AC_MSG_ERROR(Header file pcap.h not found.))
 306
 307         #
 308         # Check to see if we find "pcap_open_live" in "-lpcap".
 309         #
 310         AC_CHECK_LIB(pcap, pcap_open_live,
 311           [
 312             PCAP_LIBS=-lpcap
 313             AC_DEFINE(HAVE_LIBPCAP)
 314           ], AC_MSG_ERROR(Library libpcap not found.),
 315           $SOCKET_LIBS $NSL_LIBS)
 316         AC_SUBST(PCAP_LIBS)
 317 ])
 318
 319 #
 320 # AC_ETHEREAL_PCAP_VERSION_CHECK
 321 #
 322 # Check whether "pcap_version" is defined by libpcap.
 323 #
 324 AC_DEFUN(AC_ETHEREAL_PCAP_VERSION_CHECK,
 325 [
 326         AC_MSG_CHECKING(whether pcap_version is defined by libpcap)
 327         ac_save_LIBS="$LIBS"
 328         LIBS="$PCAP_LIBS $SOCKET_LIBS $NSL_LIBS $LIBS"
 329         AC_TRY_LINK([],
 330            [
 331 char *
 332 return_pcap_version(void)
 333 {
 334         extern char pcap_version[];
 335
 336         return pcap_version;
 337 }
 338            ],
 339            ac_cv_pcap_version_defined=yes,
 340            ac_cv_pcap_version_defined=no,
 341            [echo $ac_n "cross compiling; assumed OK... $ac_c"])
 342         LIBS="$ac_save_LIBS"
 343         if test "$ac_cv_pcap_version_defined" = yes ; then
 344                 AC_MSG_RESULT(yes)
 345                 AC_DEFINE(HAVE_PCAP_VERSION)
 346         else
 347                 AC_MSG_RESULT(no)
 348         fi
 349 ])
 350
 351 #
 352 # AC_ETHEREAL_ZLIB_CHECK
 353 #
 354 AC_DEFUN(AC_ETHEREAL_ZLIB_CHECK,
 355 [
 356         #
 357         # Make sure we have "zlib.h".  If we don't, it means we probably
 358         # don't have zlib, so don't use it.
 359         #
 360         AC_CHECK_HEADER(zlib.h,,enable_zlib=no)
 361
 362         if test x$enable_zlib != xno
 363         then
 364                 #
 365                 # Well, we at least have the zlib header file.
 366                 #
 367                 # Check for "gzseek()" in zlib, because we need it, but
 368                 # some older versions of zlib don't have it.  It appears
 369                 # from the zlib ChangeLog that any released version of zlib
 370                 # with "gzseek()" should have the other routines we
 371                 # depend on, such as "gztell()" and "zError()".
 372                 #
 373                 AC_CHECK_LIB(z, gzseek,,enable_zlib=no)
 374         fi
 375 ])
 376
 377 #
 378 # AC_ETHEREAL_UCDSNMP_CHECK
 379 #
 380 AC_DEFUN(AC_ETHEREAL_UCDSNMP_CHECK,
 381 [
 382         want_ucdsnmp=yes
 383
 384         AC_ARG_WITH(ucdsnmp,
 385         [  --with-ucdsnmp=DIR      use UCD SNMP client library, located in directory DIR.], [
 386         if test $withval = no
 387         then
 388                 want_ucdsnmp=no
 389         else
 390                 want_ucdsnmp=yes
 391                 ucdsnmp_user_dir=$withval
 392         fi
 393         ])
 394
 395         if test $want_ucdsnmp = yes
 396         then
 397                 ucdsnmpdir=""
 398
 399                 for d in $ucdsnmp_user_dir $prefix
 400                 do
 401                         if test x$d != xNONE
 402                         then
 403                                 AC_MSG_CHECKING($d for ucd-snmp)
 404
 405                                 if test x$d != x/usr/local && test -f $d/include/ucd-snmp/snmp.h
 406                                 then
 407                                         AC_MSG_RESULT(found)
 408                                         ucdsnmpdir=$d
 409                                         break
 410                                 else
 411                                         AC_MSG_RESULT(not found)
 412                                 fi
 413                         fi
 414                 done
 415
 416                 if test x$ucdsnmpdir != x
 417                 then
 418                         AC_MSG_RESULT(added $d to paths)
 419                         CFLAGS="$CFLAGS -I${ucdsnmpdir}/include"
 420                         CPPFLAGS="$CPPFLAGS -I${ucdsnmpdir}/include"
 421                         AC_ETHEREAL_ADD_DASH_L(LDFLAGS, ${ucdsnmpdir}/lib)
 422                 fi
 423         fi
 424 ])
 425
 426 #
 427 # AC_ETHEREAL_SSL_CHECK
 428 #
 429 AC_DEFUN(AC_ETHEREAL_SSL_CHECK,
 430 [
 431         want_ssl=defaultyes
 432
 433         AC_ARG_WITH(ssl,
 434         [  --with-ssl=DIR          use SSL crypto library, located in directory DIR.], [
 435         if   test "x$withval" = "xno";  then
 436                 want_ssl=no
 437         elif test "x$withval" = "xyes"; then
 438                 want_ssl=yes
 439         elif test -d "$withval"; then
 440                 want_ssl=yes
 441                 AC_ETHEREAL_ADD_DASH_L(LDFLAGS, ${withval}/lib)
 442         fi
 443         ])
 444
 445         if test "x$want_ssl" = "xdefaultyes"; then
 446                 want_ssl=yes
 447                 withval=/usr/local/ssl
 448                 if test -d "$withval"; then
 449                         AC_ETHEREAL_ADD_DASH_L(LDFLAGS, ${withval}/lib)
 450                 fi
 451         fi
 452
 453         if test "x$want_ssl" = "xyes"; then
 454                 AC_CHECK_LIB(crypto, EVP_md5,
 455                   [
 456                     SSL_LIBS=-lcrypto
 457                   ],,
 458                 )
 459
 460         else
 461                 AC_MSG_RESULT(not required)
 462         fi
 463
 464 ])